Энэ заавар нь Excel-ийн VLOOKUP-г хэрхэн том жижиг жижиг жижиг жижиг үсгээр ялгах талаар тайлбарлаж, текстийн том жижиг жижиг томьёог ялгах өөр хэд хэдэн томьёог харуулж, функц тус бүрийн давуу болон хязгаарлалтыг зааж өгсөн болно.

Би бүх зүйлийг бодож байна. Excel-ийн хэрэглэгч Excel-ийн босоо хайлтыг ямар функцээр гүйцэтгэдэг болохыг мэддэг. Зөв, энэ бол VLOOKUP юм. Гэсэн хэдий ч Excel-ийн VLOOKUP нь том жижиг үсгийг том жижиг үсгээр бичдэг гэдгийг маш цөөхөн хүн мэддэг.

Энэ бол VLOOKUP нь том жижиг үсгийг ялгах чадваргүйг харуулсан жишээ юм. Хэрэв та А2 нүдэнд "тооцоо", А4 нүдэнд "Төлбөр" байна гэж бодъё. Доорх томьёо нь хайлтын массивын эхний байранд орж, B2-ээс тохирох утгыг буцаадаг тул "тооцоо"-г барих болно.

=VLOOKUP("Bill", A2:B4, 2, FALSE)

Цааш нь энэ хэсэгт. нийтлэлд би танд VLOOKUP том жижиг үсгийг харгалзах аргыг харуулах болно. Мөн бид Excel-д том жижиг жижиг үсгээр тохируулах боломжтой хэд хэдэн функцийг судлах болно.

Бага том жижиг жижиг үсгээр харах томьёо

Дээр дурдсанчлан ердийн VLOOKUP томьёо. үсгийн хэргийг танихгүй байна. Гэсэн хэдий ч Excel VLOOKUP-г жижиг жижиг жижиг жижиг харгалзах арга бий. Үүнийг доорх жишээнд үзүүлэв.

Та А баганад Зүйлийн ID байгаа бөгөөд тухайн зүйлийн үнэ болон тайлбарыг авахыг хүсэж байна гэж бодъё. B ба C баганаас. Асуудал нь ID-д жижиг болон том үсэг хоёуланг нь багтаасан байдаг. Жишээлбэл, A4 (001Tvci3u) ба A5 (001Tvci3U) дээрх утгууд нь зөвхөн дараах байдлаар ялгаатай байна.сүүлийн тэмдэгт "u" ба "U" тус тус.

"001Tvci3 U "-г хайхад стандарт VLOOKUP томьёо нь "001Tvci3 u"-тай холбоотой $90 гарна. " учир нь хайлтын массив дахь "001Tvci3 U "-ын өмнө ирдэг. Гэхдээ энэ бол таны хүссэн зүйл биш биз дээ?

=VLOOKUP(F2, A2:C7, 2, FALSE)

Excel дээр том жижиг үсгээр хайлт хийхийн тулд бид DLOOKUP, CHOOSE, EXACT-ыг нэгтгэдэг. функцууд:

Энэ ерөнхий томъёо нь бүх нөхцөлд төгс ажилладаг. Та баруунаас зүүн тийш хүртэл харж болно, үүнийг энгийн VLOOKUP томьёо хийх боломжгүй. Энэхүү энгийн бөгөөд дэгжин шийдлийг санал болгосон Поурияд талархаж байна!

Манай тохиолдолд бодит томъёонууд дараах байдалтай байна.

Үнийг F3-д татахын тулд:

=VLOOKUP(TRUE, CHOOSE({1,2}, EXACT(F2, A2:A7), B2:B7), 2, FALSE)

F4 тайлбарыг авахын тулд:

=VLOOKUP(TRUE, CHOOSE({1,2}, EXACT(F2, A2:A7), C2:C7), 2, FALSE)

Тайлбар. Excel 365-аас бусад Excel-ийн бүх хувилбарт энэ нь зөвхөн массивын томьёо хэлбэрээр ажилладаг тул зөв бөглөхийн тулд Ctrl + Shift + Enter дарахаа мартуузай. Excel 365 дээр динамик массивыг дэмждэг тул ердийн томъёогоор ажилладаг.

Энэ томьёо хэрхэн ажилладаг вэ:

Тэмдэглэлийг гүйцэтгэдэг гол хэсэг нь CHOOSE томьёо нь ECACT-тай:

CHOOSE({1,2}, EXACT(F2, A2:A7), C2:C7)

Энд, EXACT функц нь F2 дахь утгыг A2:A7 дахь утга тус бүртэй харьцуулж, үсгийн том үсгийг оруулаад яг ижил байвал ҮНЭНийг буцаана.Үгүй бол ХУДАЛ:

{FALSE;FALSE;FALSE;TRUE;FALSE;FALSE}

CHOOSE-ийн индекс_тоо аргументын хувьд бид {1,2} массив тогтмолыг ашиглана. Үүний үр дүнд функц нь дээрх массивын логик утгууд болон C2:C7-ийн утгуудыг дараах байдлаар хоёр хэмжээст массив болгон нэгтгэдэг:

{FALSE,155;FALSE,186;FALSE,90;TRUE,54;FALSE,159;FALSE,28}

VLOOKUP функц нь үүнийг тэндээс авдаг. мөн 2 хэмжээст массивын 1-р баганад (логик утгуудаар илэрхийлэгддэг) хайлтын утгыг (ҮНЭН) хайж, 2-р баганаас бидний хайж буй үнэ болох тохирохыг буцаана:

VLOOKUP(TRUE, {FALSE,155;FALSE,186;FALSE,90;TRUE,54;FALSE,159;FALSE,28}, 2, 0)

Бага томьёо мэдрэгчтэй XLOOKUP томьёо

Microsoft 365-ын захиалагчид Excel-д илүү энгийн томъёогоор том жижиг үсгээр хайлт хийх боломжтой. Таны таамаглаж байгаагаар би VLOOKUP-ийн илүү хүчирхэг залгамжлагч болох XLOOKUP функцийн тухай ярьж байна.

XLOOKUP нь массив хайх болон буцаах функцийг тусад нь гүйцэтгэдэг тул өмнөх хоёр хэмжээст массивын трик бидэнд хэрэггүй. жишээ. Зүгээр л хайлтын_массив аргументын хувьд EXACT-ыг ашиглана уу:

Сүүлийн аргумент ("Одоогүй") нь сонголттой. Хэрэв тохирох зүйл олдохгүй бол ямар утгыг буцаахыг л тодорхойлдог. Хэрэв та үүнийг орхигдуулсан бол томьёо нь юу ч олоогүй тохиолдолд стандарт #N/A алдаа гарна.

Манай жишээ хүснэгтийн хувьд эдгээр нь том жижиг үсгийн томьёог ашиглах XLOOKUP томьёо юм.

F3-д үнийг авахын тулд:

=XLOOKUP(TRUE, EXACT(F2, A2:A7), B2:B7, "Not found")

Гадахтайлбар F4:

=XLOOKUP(TRUE, EXACT(F2, A2:A7), C2:C7, "Not found")

Энэ томьёо хэрхэн ажилладаг вэ:

Өмнөх жишээний адил EXACT нь буцаана. ҮНЭН ба ХУДАЛ утгуудын массив, энд ҮНЭН нь жижиг жижиг том үсгийг илэрхийлдэг. XLOOKUP нь дээрх массиваас ҮНЭН утгыг хайж, буцах_массив -аас тохирохыг буцаана. Хайлтын баганад хоёр буюу түүнээс дээш яг ижил утга байгаа бол (үсгийн томьёог оруулаад) томьёо нь эхний олдсон тохирохыг буцаана гэдгийг анхаарна уу.

XLOOKUP хязгаарлалт : зөвхөн боломжтой. Excel 365 болон Excel 2021 дээр.

SUMPRODUCT - тохирох тоог буцаахын тулд том жижиг үсгээр хайх

Таны гарчигнаас ойлгосноор SUMPRODUCT нь том жижиг үсгээр хайх боломжтой Excel-ийн өөр нэг функц юм. , гэхдээ энэ нь зөвхөн тоон утгыг буцаана. Хэрэв энэ нь таны хэрэг биш бол бүх төрлийн өгөгдлийн шийдэл бүхий INDEX MATCH жишээ рүү очно уу.

Excel-ийн SUMPRODUCT нь заасан массив дахь бүрэлдэхүүн хэсгүүдийг үржүүлж, бүтээгдэхүүний нийлбэрийг буцаадаг гэдгийг та мэдэж байгаа байх. Бид том жижиг үсгээр хайхыг хүсч байгаа тул эхний массивыг авахын тулд EXACT функцийг ашигладаг:

=SUMPRODUCT((EXACT(A2:A7,F2) * (B2:B7)))

Харамсалтай нь, SUMPRODUCT функц нь текстийн утгыг үржүүлэх боломжгүй тул текстийн тохирлыг буцааж өгөх боломжгүй. Энэ тохиолдолд та # ҮНЭ ЦЭНЭ авах болно! Доорх дэлгэцийн зургийн F4 нүдэн дээрх алдаа:

Энэ томьёо хэрхэн ажилладаг вэ:

VLOOKUP жишээн дээрх шиг EXACT функцийг шалгадагF2 дахь утгыг A2:A7 дээрх бүх утгуудтай харьцуулж, том жижиг том жижиг харгалзах үед ҮНЭНийг буцаана, үгүй ​​бол ХУДАЛ:

SUMPRODUCT(({FALSE;FALSE;FALSE;TRUE;FALSE;FALSE}*{155;186;90;54;159;28}))

Ихэнх томъёонд Excel нь ҮНЭНийг 1, ХУДАЛ-ыг 0 гэж үнэлдэг. Тиймээс, SUMPRODUCT нь хоёр массивын элементүүдийг ижил байрлалд үржүүлэхэд бүх тохирохгүй (FALSE) нь тэг болно:

SUMPRODUCT({0;0;0;54;0;0})

Үүний үр дүнд томъёо нь дараахаас тоо буцаана. А баганын жижиг том жижиг харгалзах B багана.

SUMPRODUCT хязгаарлалт : зөвхөн тоон утгыг буцаана.

INDEX MATCH - том жижиг үсгээр хайх бүх өгөгдлийн төрлүүд

Эцэст нь бид Excel-ийн бүх хувилбарууд болон бүх өгөгдлийн багц дээр ажиллах хязгаарлалтгүй том жижиг жижиг үсгээр хайх томьёог олж авахад ойрхон байна.

Энэ жишээ нь зөвхөн сүүлийнх биш, учир нь биш юм. Хамгийн сайн нь хамгийн сүүлд хадгалагдах болно, гэхдээ өмнөх жишээн дээр олж авсан мэдлэг тань том жижиг жижиг үсгээр ялгах MATCH INDEX томьёог илүү сайн ойлгоход тусална.

INDEX болон MATCH функцуудын хослолыг ихэвчлэн ашигладаг. Жишээ нь cel нь VLOOKUP-ийн илүү уян хатан, олон талт хувилбар юм. Дараах нийтлэл сайн ажиллаж байна (найдаж :) эдгээр хоёр функц хэрхэн хамт ажилладагийг тайлбарласан болно - VLOOKUP биш INDEX TATCH-ийг ашиглах.

Энд би танд гол санааг сануулъя:

• MATCH функц нь заасан хайлтын массив дахь хайлтын утгыг хайж, түүний харьцангуй байрлалыг буцаана.
• ХарьцангуйХайлтын утгын байрлал нь INDEX функцийн мөрийн_тоо аргумент руу шууд очдог бөгөөд энэ мөрөөс утгыг буцаахыг зааварчилдаг.

Томьёоны текстийн томьёог танихын тулд та зүгээр л хангалттай. Сонгодог INDEX MATCH хослолд дахиад нэг функц нэмэх шаардлагатай. Мэдээжийн хэрэг, танд яг тодорхой функц дахин хэрэгтэй болно:

F3 дээрх бодит томьёо нь:

=INDEX(B2:B7, MATCH(TRUE, EXACT(A2:A7, F2), 0))

F4 дээр бид үүнийг ашиглаж байна:

=INDEX(C2:C7, MATCH(TRUE, EXACT(A2:A7, F2), 0))

Энэ нь зөвхөн дараах байдлаар ажилладаг гэдгийг санаарай. Excel 365-аас бусад бүх хувилбарт массивын томьёо байх тул Ctrl + Shift + Enter товчийг хамтад нь оруулна уу. Хэрэв зөв хийсэн бол томъёог доорх дэлгэцийн агшинд үзүүлсэн шиг буржгар хаалтанд оруулах болно:

Энэ томъёо хэрхэн ажилладаг вэ:

Өмнөх бүх жишээнүүдийн нэгэн адил EXACT нь F2 дээрх утгатай яг таарч байгаа A2:A7 дээрх утга бүрийн хувьд ҮНЭНийг буцаана. Бид MATCH-н хайлтын_утга -д ҮНЭНийг ашигладаг тул энэ нь яг том жижиг жижиг харьцах харьцааны харьцангуй байрлалыг буцаадаг бөгөөд энэ нь INDEX-д B2:B7-с тохирохыг буцаахад яг хэрэгтэй зүйл юм.

Нарийвчилсан том жижиг жижиг үсгээр хайх томьёо

Дээр дурдсан INDEX MATCH томъёо төгс харагдаж байна, тийм үү? Гэвч үнэн хэрэгтээ тийм биш. Би чамд яагаад гэдгийг харуулъя.

Буцах баганын хайлтын утгатай харгалзах нүд хоосон байна гэж бодъё. Томъёо нь юу буцаах вэ? Юу ч биш.Одоо энэ нь яг юуг буцаадаг болохыг харцгаая:

=INDEX(C2:C7, MATCH(TRUE, EXACT(A2:A7, F2), 0))

Өө, томъёо нь тэгийг буцаана! Магадгүй, энэ нь зөвхөн текстийн утгыг авч үзэхэд тийм ч чухал биш юм. Гэсэн хэдий ч, хэрэв таны ажлын хуудсанд тоонууд байгаа бөгөөд тэдгээрийн зарим нь бодит тэг байвал энэ нь асуудал болно.

Үнэн хэрэгтээ, өмнө нь авч үзсэн бусад хайлтын томьёо ижилхэн ажилладаг. Харин одоо та өө сэвгүй томьёо авахыг хүсч байна, тийм үү?

Үг үсгийн томьёог төгс төгөлдөр болгохын тулд буцах нүд хоосон эсэхийг шалгадаг IF функцэд оруулаад юу ч буцаадаггүй. энэ тохиолдолд:

=IF(INDIRECT("C"&(1+MATCH(TRUE,EXACT(A2:A7, F2), 0)))"", INDEX(C2:C7, MATCH(TRUE, EXACT(A2:A7, F2), 0)), "")

Дээрх томъёонд:

• "C" нь буцах багана.
• "1" нь тоо юм. Энэ нь MATCH функцээр буцаасан нүдний харьцангуй байрлалыг бодит нүдний хаяг болгон хувиргадаг.

Жишээ нь, манай MATCH функцын хайлтын массив нь A2:A7 бөгөөд энэ нь массивын эхний нүд учраас A2 нүдний харьцангуй байрлал "1" гэсэн үг юм. Гэвч бодит байдал дээр хайлтын массив нь 2-р эгнээнээс эхэлдэг. Зөрүүг нөхөхийн тулд бид 1-ийг нэмдэг тул ШУУД RECT функц нь баруун нүднээс утгыг буцаана.

Доорх дэлгэцийн агшинд том жижиг үсгийн мэдрэгч бүхий сайжруулсан INDEX-ийг харуулж байна. MATCH томьёо ажиллаж байна.

Хэрэв буцах нүд хоосон байвал томьёо нь юу ч гаргахгүй (хоосон мөр):

Хэрэв буцах нүдэнд тэг байвал , томъёо нь 0-г буцаана:

Хэрэв та хүсвэлБуцах нүд хоосон байх үед зарим мессежийг харуулах, IF-ийн сүүлчийн аргумент дахь хоосон мөрийг ("") зарим текстээр солино:

=IF(INDIRECT("C"&(1+MATCH(TRUE, EXACT(A2:A7, F2), 0)))"", INDEX(C2:C7, MATCH(TRUE, EXACT(A2:A7, F2), 0)), "There is nothing to return, sorry.")

Том, нарийн ширийн хүснэгтүүдийг хайж олоход хялбар, стрессгүй болгодог тусгай хэрэгсэлтэй байдаг. Хамгийн сайн зүйл бол Хоёр Хүснэгтийг нэгтгэх нь том жижиг үсгийн сонголттой бөгөөд доорх жишээнд үүнийг бодитоор харуулж байна.

Та Qty-г татахыг хүсч байна гэж бодъё. Өвөрмөц Зүйлийн ID-д тулгуурлан Үндсэн хүснэгтээс Үндсэн хүснэгт рүү:

Таны хийх зүйл бол Хүснэгтүүдийг нэгтгэхийг ажиллуулах явдал юм. шидтэнг сонгоод дараах алхмуудыг хийгээрэй:

1. Шинэ өгөгдөл татах үндсэн хүснэгтийг сонгоно уу.
2. Шинэ өгөгдөл хайх хайлтын хүснэгтийг сонгоно уу.
3. Нэг буюу хэд хэдэн гол баганыг сонгоно уу (манай тохиолдолд зүйлийн ID). Мөн Бага том жижиг үсгээр тохирох нүдийг чагтална уу.

Хэсэг хугацааны дараа та хүссэн үр дүндээ хүрэх болно :)

Текстийн тохиолдлыг харгалзан Excel дээр ингэж хайх боломжтой. Уншсан танд баярлалаа, дараа долоо хоногт манай блог дээр уулзана гэж найдаж байна!

Татаж авах дасгалын ном

Үсгийн том жижиг үсгийн мэдрэмжтэй VLOOKUP жишээнүүд (.xlsx файл)