La lernilo klarigas kiel fari Excel VLOOKUP uskle-distinta, montras kelkajn aliajn formulojn, kiuj distingas tekstajn uskojn, kaj montras fortojn kaj limojn de ĉiu funkcio.

Mi supozas, ke ĉiuj Excel-uzanto scias, kia funkcio faras vertikalan serĉon en Excel. Ĝuste, ĝi estas VLOOKUP. Tamen tre malmultaj homoj konscias, ke la VLOOKUP de Excel estas majuskle-malsentema, tio signifas, ke ĝi traktas minusklojn kaj MAJUSKLULOJ kiel la samajn signojn.

Jen rapida ekzemplo, kiu pruvas la malkapablon de VLOOKUP distingi tekston. Supozu, se vi havas "fakturon" en ĉelo A2 kaj "Bill" en A4. La suba formulo kaptos "fakturo" ĉar ĝi venas unue en la serĉa tabelo kaj redonos kongruan valoron de B2.

=VLOOKUP("Bill", A2:B4, 2, FALSE)

Plue en ĉi tiu artikolon, mi montros al vi manieron fari VLOOKUP uskle-distingebla. Ni ankaŭ esploros kelkajn aliajn funkciojn, kiuj povas fari uskle-distintan kongruon en Excel.

Maskle-distinga VLOOKUP-formulo

Kiel supre menciite, kutima VLOOKUP-formulo ne rekonas la literon. Tamen, ekzistas maniero fari Excel VLOOKUP uskle-distinta, kiel montrite en la suba ekzemplo.

Supozi vi havas Identigilojn en kolumno A kaj volas tiri la prezon de la objekto kaj komenti de kolumnoj B kaj C. La problemo estas ke ID-oj inkluzivas kaj minusklajn kaj majusklojn. Ekzemple, la valoroj en A4 (001Tvci3u) kaj A5 (001Tvci3U) diferencas nur enla lasta signo, "u" kaj "U", respektive.

Kiam serĉas "001Tvci3 U ", norma VLOOKUP-formulo eligas $90 kiu estas asociita kun "001Tvci3 u " ĉar ĝi venas antaŭ "001Tvci3 U " en la serĉa tabelo. Sed ĉi tio ne estas tio, kion vi volas, ĉu ne?

=VLOOKUP(F2, A2:C7, 2, FALSE)

Por fari uskle-distintan serĉon en Excel, ni kombinas la VLOOKUP, CHOose and EXACT. funkcioj:

Ĉi tiu ĝenerala formulo perfekte funkcias en ĉiuj situacioj. Vi eĉ povas rigardi supren de dekstre maldekstren , ion, kion regula VLOOKUP-formulo ne kapablas fari. Gratulon al Pouriya pro sugesti ĉi tiun simplan kaj elegantan solvon!

En nia kazo, la veraj formuloj iras jene.

Por tiri la prezon en F3:

=VLOOKUP(TRUE, CHOOSE({1,2}, EXACT(F2, A2:A7), B2:B7), 2, FALSE)

Por preni la komenton F4:

=VLOOKUP(TRUE, CHOOSE({1,2}, EXACT(F2, A2:A7), C2:C7), 2, FALSE)

Notu. En ĉiuj Excel-versioj krom Excel 365, ĉi tio funkcias nur kiel tabelformulo, do memoru premi Ctrl + Shift + Enter por kompletigi ĝin ĝuste. En Excel 365, pro subteno por dinamikaj tabeloj, ĝi ankaŭ funkcias kiel regula formulo.

Kiel ĉi tiu formulo funkcias:

La kerna parto, kiu faras la lertaĵon, estas la ELEKTU-formulo kun nestita EXACT:

CHOOSE({1,2}, EXACT(F2, A2:A7), C2:C7)

Ĉi tie, la EKZAKTA funkcio komparas la valoron en F2 kontraŭ ĉiu valoro en A2:A7 kaj resendas VERA se ili estas ekzakte la samaj inkluzive de la litera majusklo,FALSO alie:

{FALSE;FALSE;FALSE;TRUE;FALSE;FALSE}

Por la argumento index_num de CHOOS, ni uzas la tabelkonstanto {1,2}. Kiel rezulto, la funkcio kombinas la logikajn valorojn de la ĉi-supra tabelo kaj la valorojn de C2:C7 en dudimensian tabelon jene:

{FALSE,155;FALSE,186;FALSE,90;TRUE,54;FALSE,159;FALSE,28}

La funkcio VLOOKUP prenas ĝin de tie. kaj serĉas la serĉvaloron (kiu estas VERA) en la 1-a kolumno de la 2-dimensia tabelo (reprezentita per la logikaj valoroj) kaj resendas kongruon de la 2-a kolumno, kiu estas la prezo, kiun ni serĉas:

VLOOKUP(TRUE, {FALSE,155;FALSE,186;FALSE,90;TRUE,54;FALSE,159;FALSE,28}, 2, 0)

Uskle-distinga XLOOKUP-formulo

Microsoft 365-abonantoj povas fari uskle-distintan serĉon en Excel kun eĉ pli simpla formulo. Kiel vi povas supozi, mi parolas pri pli potenca posteulo de VLOOKUP - la funkcio XLOOKUP.

Ĉar XLOOKUP funkcias per serĉo kaj reveno tabeloj aparte, ni ne bezonas la dudimensian tabelan trukon de la antaŭa ekzemplo. Simple, uzu EKZAKTA por la argumento serĉa_tabelo :

La lasta argumento ("Ne trovita") estas nedeviga. Ĝi nur difinas kian valoron redoni se neniu kongruo estas trovita. Se vi preterlasas ĝin, tiam norma #N/A-eraro estos resendita se la formulo trovas nenion.

Por nia specimena tabelo, ĉi tiuj estas la uzeblaj XLOOKUP-formuloj.

Por akiri la prezon en F3:

=XLOOKUP(TRUE, EXACT(F2, A2:A7), B2:B7, "Not found")

Por eltiri lakomento F4:

=XLOOKUP(TRUE, EXACT(F2, A2:A7), C2:C7, "Not found")

Kiel ĉi tiu formulo funkcias:

Kiel en la antaŭa ekzemplo, EXACT liveras tabelo de VERA kaj FALSA valoroj, kie VERA reprezentas uskle-distintajn kongruojn. XLOOKUP serĉas la supran tabelon por la VERA valoro kaj resendas kongruon de la return_array . Bonvolu noti, se estas du aŭ pli ekzakte la samaj valoroj en la serĉkolumno (inkluzive de la litero-minuskleco), la formulo redonos la unuan trovitan kongruon.

XLOOKUP-limigo : disponebla nur en Excel 365 kaj Excel 2021.

SUMPRODUCT - uskle-distinta serĉo por redoni kongruajn nombrojn

Kiel vi komprenas de la titolo, SUMPRODUCT estas ankoraŭ alia Excel-funkcio kiu povas fari uskle-distintan serĉon. , sed ĝi povas resendi nombrajn valorojn nur. Se ĉi tio ne estas via kazo, tiam saltu al la ekzemplo de INDEX MATCH, kiu provizas solvon por ĉiuj datumtipoj.

Kiel vi verŝajne scias, la SUMPRODUCT de Excel multobligas komponantojn en la specifitaj tabeloj kaj redonas la sumon de la produktoj. Ĉar ni volas majuskle-senteman serĉon, ni uzas la EKZAKTAN funkcion por akiri la unuan tabelon:

=SUMPRODUCT((EXACT(A2:A7,F2) * (B2:B7)))

Bedaŭrinde, la funkcio SUMPRODUCT ne povas resendi tekstajn kongruojn ĉar tekstvaloroj ne povas esti multobligitaj. En ĉi tiu kazo, vi ricevos #VALORON! eraro kiel en ĉelo F4 en la suba ekrankopio:

Kiel ĉi tiu formulo funkcias:

Kiel en la ekzemplo de VLOOKUP, la EKZAKTA funkciokontrolojla valoro en F2 kontraŭ ĉiuj valoroj en A2:A7 kaj resendas VERA por majusksentemaj kongruoj, FALSE alie:

SUMPRODUCT(({FALSE;FALSE;FALSE;TRUE;FALSE;FALSE}*{155;186;90;54;159;28}))

En la plej multaj formuloj, Excel taksas VERA al 1 kaj FALSE al 0 Do, kiam SUMPRODUCT multobligas la elementojn de la du tabeloj en la samaj pozicioj, ĉiuj ne-kongruoj (FALSA) fariĝas nuloj:

SUMPRODUCT({0;0;0;54;0;0})

Kiel rezulto, la formulo liveras nombron de kolumno B kiu respondas al la ĝusta majuskla kongruo en kolumno A.

SUMPRODUCT-limigo : povas resendi nur nombrajn valorojn.

INDEX MATCH - majusklan serĉon por ĉiuj datumtipoj

Fine, ni estas proksimaj al ricevi senlimigan uskle-distintan serĉformulon, kiu funkcias en ĉiuj Excel-versioj kaj en ĉiuj datumaro.

Ĉi tiu ekzemplo venas la lasta ne nur ĉar la plej bona estas konservita por la lasta, sed ankaŭ ĉar la scio, kiun vi akiris en la antaŭaj ekzemploj, eble helpos vin pli bone kompreni la uskle-distintan formulon MATCH INDEX.

Ofte estas uzata la kombinaĵo de INDEX kaj MATCH-funkcioj. en Ekz cel kiel pli fleksebla kaj diverstalenta alternativo al VLOOKUP. La sekva artikolo faras bonan laboron (espereble :) klarigante kiel ĉi tiuj du funkcioj funkcias kune - Uzante INDEX MATCH anstataŭ VLOOKUP.

Ĉi tie, mi nur memorigos al vi la ĉefajn punktojn:

• La MATCH-funkcio serĉas la serĉvaloron en la specifita serĉtabelo kaj resendas ĝian relativan pozicion.
• La relativapozicio de la serĉvaloro iras rekte al la argumento row_num de la INDEX-funkcio instrukciante ĝin redoni valoron de tiu vico.

Por ke la formulo rekonu tekstmajskon, vi nur bezonas aldoni unu plian funkcion al la klasika INDEX MATCH-kombinaĵo. Evidente, vi denove bezonas la EKZAKTAN funkcion:

La vera formulo en F3 estas:

=INDEX(B2:B7, MATCH(TRUE, EXACT(A2:A7, F2), 0))

En F4, ni uzas ĉi tiun:

=INDEX(C2:C7, MATCH(TRUE, EXACT(A2:A7, F2), 0))

Bonvolu memori, ke ĝi funkcias nur kiel tabelformulo en ĉiuj versioj krom Excel 365, do nepre enigu ĝin per premu la klavojn Ctrl + Shift + Enigu kune. Se farite ĝuste, la formulo estos enfermita en krampojn kiel montrite en la ekrankopio sube:

Kiel ĉi tiu formulo funkcias:

Kiel en ĉiuj antaŭaj ekzemploj, EXACT liveras VERA por ĉiu valoro en A2:A7 kiu precize kongruas kun la valoro en F2. Ĉar ni uzas VERA por la serĉa_valoro de MATCH, ĝi resendas relativan pozicion de la ĝusta majuskle-distinga kongruo, kio estas ĝuste tio, kion INDEX bezonas por resendi kongruon de B2:B7.

Altnivela uskle-distinta serĉformulo

La supre menciita INDEX MATCH-formulo aspektas perfekta, ĉu ne? Sed fakte, ĝi ne estas. Mi montru al vi kial.

Supozi ĉelon en la revenkolumno responda al la serĉvaloro estas malplena. Kion redonos la formulo? Nenio.Kaj nun, ni vidu, kion ĝi efektive resendas:

=INDEX(C2:C7, MATCH(TRUE, EXACT(A2:A7, F2), 0))

Ho, la formulo donas nulon! Eble, ĝi ne vere gravas kiam oni traktas nur tekstajn valorojn. Tamen, se via laborfolio enhavas nombrojn kaj kelkaj el ili estas realaj nuloj, tio estas problemo.

Vere, ĉiuj aliaj serĉformuloj pridiskutitaj antaŭe kondutas en la sama maniero. Sed nun vi volas neriproĉeblan formulon, ĉu ne?

Por fari la formulon INDEX MATCH absolute perfekta, vi envolvas ĝin en la funkcio SE kiu kontrolas ĉu revenĉelo estas malplena kaj resendas nenion en ĉi tiu kazo:

=IF(INDIRECT("C"&(1+MATCH(TRUE,EXACT(A2:A7, F2), 0)))"", INDEX(C2:C7, MATCH(TRUE, EXACT(A2:A7, F2), 0)), "")

En la supra formulo:

• "C" estas la revenkolumno.
• "1" estas la nombro tio igas relativan pozicion de la ĉelo redonita de la MATCH-funkcio en realan ĉeladreson .

Ekzemple, la serĉa tabelo en nia MATCH-funkcio estas A2:A7, kio signifas, ke la relativa pozicio de ĉelo A2 estas "1", ĉar ĉi tiu estas la unua ĉelo en la tabelo. Sed fakte, la serĉa tabelo komenciĝas en la vico 2. Por kompensi la diferencon, ni aldonas 1, do la INDIREKTA funkcio resendos valoron el la dekstra ĉelo.

La malsupraj ekrankopioj montras la plibonigitan INDEXOn senteman minuskle. MATCH formulo en ago.

Se la revena ĉelo estas malplena, la formulo eligas nenion (malplena ĉeno):

Se la revena ĉelo enhavas nulon , la formulo liveras 0:

Se vi preferasmontri iun mesaĝon kiam revenĉelo estas malplena, anstataŭigu malplenan ĉenon ("") en la lasta argumento de IF per iu teksto:

=IF(INDIRECT("C"&(1+MATCH(TRUE, EXACT(A2:A7, F2), 0)))"", INDEX(C2:C7, MATCH(TRUE, EXACT(A2:A7, F2), 0)), "There is nothing to return, sorry.")

Faru uskle-distintan VLOOKUP facilan manieron

La uzantoj de nia Ultimate Suite for Excel havas specialan ilon, kiu faciligas kaj senstreĉigas rigardi supren en grandaj kaj kompleksaj tabeloj. La plej bona afero estas, ke Kunfandi Du Tabelojn havas majusklan opcion, kaj la suba ekzemplo montras ĝin en ago.

Supozi vi volas tiri Kvanton. de la Serĉo tabelo al la Ĉefa tabelo surbaze de unikaj Item-ID-oj:

Kion vi faras estas ruli la Kunfandi Tabelojn asistanto kaj faru ĉi tiujn paŝojn:

1. Elektu la ĉefan tabelon en kiun tiri novajn datumojn.
2. Elektu la serĉtabelon kie serĉi la novajn datumojn.
3. Elektu unu aŭ plurajn ŝlosilajn kolumnojn (Identigilo en nia kazo). Kaj nepre kontrolu la skatolon Majuskklan kongruon .

Momenton poste, vi ricevos la deziratan rezulton :)

Jen kiel serĉi en Excel konsiderante la tekstan kazon. Mi dankas vin pro legado kaj esperas vidi vin en nia blogo venontsemajne!

Praktiku laborlibron por elŝuto

Uskle-distingeblaj VLOOKUP-ekzemploj (.xlsx-dosiero)