V učbeniku je razloženo, kako v Excelovem programu VLOOKUP razločiti velike in male črke, prikazanih je nekaj drugih formul, ki razlikujejo velike in male črke besedila, ter poudarjene prednosti in omejitve posameznih funkcij.

Verjetno vsak uporabnik programa Excel ve, katera funkcija v njem izvaja navpično iskanje. Prav, to je VLOOKUP. Vendar se le redki zavedajo, da Excelova funkcija VLOOKUP ne upošteva velikih in malih črk, kar pomeni, da male in velike črke obravnava kot enake znake.

Tukaj je hiter primer, ki prikazuje, da VLOOKUP ne more razlikovati velikosti črk besedila. Predpostavimo, da imate v celici A2 napis "bill", v celici A4 pa "Bill". Spodnja formula bo ujela "bill", ker je prvi v polju iskanja, in vrnila ustrezno vrednost iz celice B2.

=VLOOKUP("Bill", A2:B4, 2, FALSE)

V nadaljevanju tega članka vam bom pokazal način, kako v funkciji VLOOKUP določiti, da se razlikujejo velike in male črke. Raziskali bomo tudi nekaj drugih funkcij, s katerimi lahko v Excelu določimo, da se razlikujejo velike in male črke.

Formula VLOOKUP, občutljiva na velikost črk

Kot je navedeno zgoraj, običajna formula VLOOKUP ne prepozna velikosti črk. Vendar pa obstaja način, da Excelov VLOOKUP upošteva velikost črk, kot je prikazano v spodnjem primeru.

Predpostavimo, da imate ID-ji predmetov v stolpcu A ter želite iz stolpcev B in C pridobiti ceno in komentar izdelka. Težava je v tem, da ID-ji vključujejo tako male kot velike črke. Na primer, vrednosti v A4 (001Tvci3u) in A5 (001Tvci3U) se razlikujeta le v zadnjem znaku, "u" oziroma "U".

Pri iskanju "001Tvci3 U ", standardna formula VLOOKUP izpiše 90 USD, ki so povezani z "001Tvci3 u ", ker je pred "001Tvci3 U " v polju iskanja. Toda to ni tisto, kar želite, kajne?

=VLOOKUP(F2, A2:C7, 2, FALSE)

Če želite v Excelu izvesti iskanje, ki upošteva velikost črk, združite funkcije VLOOKUP, CHOOSE in EXACT:

Ta splošna formula se odlično obnese v vseh situacijah. od desne proti levi , česar običajna formula VLOOKUP ne zmore. Pohvala Pouriyi za to preprosto in elegantno rešitev!

V našem primeru so prave formule naslednje.

Za prikaz cene v F3:

=VLOOKUP(TRUE, CHOOSE({1,2}, EXACT(F2, A2:A7), B2:B7), 2, FALSE)

Pridobitev komentarja F4:

=VLOOKUP(TRUE, CHOOSE({1,2}, EXACT(F2, A2:A7), C2:C7), 2, FALSE)

Opomba: V vseh različicah programa Excel, razen v Excelu 365, ta formula deluje le kot formula za matriko, zato ne pozabite pritisniti Ctrl + Shift + Enter, da jo pravilno dokončate. V Excelu 365 zaradi podpore za dinamične matrike deluje tudi kot običajna formula.

Kako deluje ta formula:

Osrednji del, ki omogoča izvedbo trika, je formula CHOOSE z vgnezdenimi EXACT:

CHOOSE({1,2}, EXACT(F2, A2:A7), C2:C7)

Funkcija EXACT primerja vrednost v F2 z vsako vrednostjo v A2:A7 in vrne TRUE, če sta popolnoma enaki, vključno z velikostjo črk, in FALSE v nasprotnem primeru:

{FALSE;FALSE;FALSE;FALSE;TRUE;FALSE;FALSE;FALSE}

Za index_num kot argument funkcije CHOOSE uporabimo konstanto polja {1,2}. Funkcija tako združi logične vrednosti iz zgornjega polja in vrednosti iz C2:C7 v dvodimenzionalno polje, kot sledi:

{FALSE,155;FALSE,186;FALSE,90;TRUE,54;FALSE,159;FALSE,28}

Funkcija VLOOKUP jo prevzame in poišče vrednost iskanja (ki je TRUE) v prvem stolpcu dvodimenzionalnega polja (ki ga predstavljajo logične vrednosti) ter vrne ujemanje iz drugega stolpca, kar je cena, ki jo iščemo:

VLOOKUP(TRUE, {FALSE,155;FALSE,186;FALSE,90;TRUE,54;FALSE,159;FALSE,28}, 2, 0)

Formula XLOOKUP, občutljiva na velikost črk

Naročniki na Microsoft 365 lahko v Excelu s še preprostejšo formulo izvedete iskanje, ki upošteva velikost črk. Kot lahko uganete, govorim o zmogljivejši naslednici funkcije VLOOKUP - funkciji XLOOKUP.

Ker XLOOKUP deluje ločeno na polja iskanja in vračanja, ne potrebujemo trika z dvodimenzionalnim poljem iz prejšnjega primera. Preprosto uporabite EXACT za lookup_array argument:

Zadnji argument ("Ni najden") ni obvezen. Določa le vrednost, ki naj se vrne, če se ne najde nobeno ujemanje. Če ga izpustite, se vrne standardna napaka #N/A, če formula ne najde ničesar.

Za našo vzorčno tabelo so to formule XLOOKUP, ki so občutljive na velikost črk.

Za prikaz cene v F3:

=XLOOKUP(TRUE, EXACT(F2, A2:A7), B2:B7, "Ni najden")

Izpis komentarja F4:

=XLOOKUP(TRUE, EXACT(F2, A2:A7), C2:C7, "Ni najden")

Kako deluje ta formula:

Podobno kot v prejšnjem primeru EXACT vrne polje vrednosti TRUE in FALSE, pri čemer TRUE pomeni ujemanje, občutljivo na velikost črk. XLOOKUP v zgornjem polju poišče vrednost TRUE in vrne ujemanje iz polja return_array Če sta v stolpcu iskanja dve ali več popolnoma enakih vrednosti (vključno z velikostjo črk), formula vrne prvo najdeno ujemanje.

omejitev XLOOKUP : na voljo samo v Excelu 365 in Excelu 2021.

SUMPRODUCT - iskanje z upoštevanjem velikih in malih črk za vračanje ujemajočih se številk

Kot je razvidno iz naslova, je SUMPRODUCT še ena Excelova funkcija, ki lahko izvede iskanje, občutljivo na velikost črk, vendar lahko vrne številčne vrednosti Če to ni vaš primer, preidite na primer INDEX MATCH, ki ponuja rešitev za vse vrste podatkov.

Kot verjetno veste, Excelova funkcija SUMPRODUCT pomnoži komponente v določenih poljih in vrne vsoto zmnožkov. Ker želimo poizvedbo, ki upošteva velike in male črke, uporabimo funkcijo EXACT, da dobimo prvo polje:

=SUMPRODUKT((TOČNO(A2:A7,F2) * (B2:B7))

Žal funkcija SUMPRODUCT ne more vrniti besedilnih ujemanj, saj besedilnih vrednosti ni mogoče množiti. V tem primeru se pojavi napaka #VALUE!, kot v celici F4 na spodnji sliki zaslona:

Kako deluje ta formula:

Tako kot v primeru VLOOKUP funkcija EXACT preveri vrednost v F2 glede na vse vrednosti v A2:A7 in vrne TRUE pri ujemanju, občutljivem na velikost črk, v nasprotnem primeru pa FALSE:

POVZETEK(({FALSE;FALSE;FALSE;TRUE;FALSE;FALSE;FALSE}*{155;186;90;54;159;28}))

V večini formul Excel vrednoti TRUE kot 1 in FALSE kot 0. Ko torej SUMPRODUCT pomnoži elemente obeh polj na istih mestih, postanejo vsa neskladja (FALSE) ničle:

SUMPRODUCT({0;0;0;54;0;0})

Kot rezultat formula vrne številko iz stolpca B, ki ustreza natančnemu ujemanju, občutljivemu na velikost črk, v stolpcu A.

Omejitev SUMPRODUCT : lahko vrne samo številčne vrednosti.

INDEX MATCH - iskanje za vse vrste podatkov z upoštevanjem velikih in malih črk

Končno smo blizu formuli za iskanje brez omejitev, ki upošteva velike in male črke ter deluje v vseh različicah programa Excel in na vseh podatkovnih nizih.

Ta primer je zadnji ne le zato, ker je najboljše prihranjeno za konec, temveč tudi zato, ker vam lahko znanje, ki ste ga pridobili v prejšnjih primerih, pomaga bolje razumeti formulo MATCH INDEX, ki upošteva velike in male črke.

Kombinacija funkcij INDEX in MATCH se v Excelu pogosto uporablja kot bolj prilagodljiva in vsestranska alternativa funkciji VLOOKUP. V naslednjem članku je (upajmo :) dobro razloženo, kako ti dve funkciji delujeta skupaj - Using INDEX MATCH instead of VLOOKUP.

Na tem mestu vas bom samo spomnil na ključne točke:

• Funkcija MATCH poišče vrednost iskanja v navedenem polju iskanja in vrne njen relativni položaj.
• Relativni položaj iskalne vrednosti se neposredno prenese v vrstica_številka argumenta funkcije INDEX, ki ji naroči, da vrne vrednost iz te vrstice.

Če želite, da formula prepozna velikost besedila, morate klasični kombinaciji INDEX MATCH dodati še eno funkcijo. Očitno je, da ponovno potrebujete funkcijo EXACT:

Prava formula v F3 je:

=INDEX(B2:B7, MATCH(TRUE, EXACT(A2:A7, F2), 0))

V programu F4 uporabljamo to:

=INDEX(C2:C7, MATCH(TRUE, EXACT(A2:A7, F2), 0))

Ne pozabite, da deluje kot formula za polje samo v vseh različicah, razen v Excelu 365, zato jo vnesite tako, da skupaj pritisnete tipki Ctrl + Shift + Enter. Če je formula pravilno vnesena, bo zaprta v oglate oklepaje, kot je prikazano na spodnji sliki zaslona:

Kako deluje ta formula:

Tako kot v vseh prejšnjih primerih EXACT vrne TRUE za vsako vrednost v A2:A7, ki se natančno ujema z vrednostjo v F2. lookup_value MATCH, vrne relativni položaj natančnega ujemanja, občutljivega na velikost črk, kar je točno to, kar INDEX potrebuje, da vrne ujemanje od B2:B7.

Napredna formula za iskanje, občutljiva na velikost črk

Zgoraj navedena formula INDEX MATCH je videti popolna, kajne? Vendar v resnici ni.

Predpostavimo, da je celica v stolpcu vrnitve, ki ustreza vrednosti iskanja, prazna. Kaj vrne formula? Nič. Zdaj pa poglejmo, kaj dejansko vrne:

=INDEX(C2:C7, MATCH(TRUE, EXACT(A2:A7, F2), 0))

Ups, formula vrne ničlo! Morda to ni pomembno, če imate opravka samo z besedilnimi vrednostmi. Če pa vaš delovni list vsebuje številke in so nekatere med njimi prave ničle, je to težava.

V resnici se vse druge formule za iskanje, ki smo jih obravnavali prej, obnašajo na enak način. Toda zdaj želite brezhibno formulo, kajne?

Da bi bila formula INDEX MATCH, ki upošteva velike in male črke, popolnoma popolna, jo zavijete v funkcijo IF, ki preveri, ali je vrnjena celica prazna, in v tem primeru ne vrne ničesar:

=IF(INDIRECT("C"&(1+MATCH(TRUE,EXACT(A2:A7, F2), 0)))"", INDEX(C2:C7, MATCH(TRUE, EXACT(A2:A7, F2), 0)), "")

V zgornji formuli:

• "C" je stolpec za vrnitev.
• "1" je število, ki spremeni relativni položaj celice, ki jo je vrnila funkcija MATCH, v dejanski naslov celice .

Na primer, polje iskanja v naši funkciji MATCH je A2:A7, kar pomeni, da je relativni položaj celice A2 "1", ker je to prva celica v polju. V resnici pa se polje iskanja začne v vrstici 2. Da bi izravnali razliko, dodamo 1, tako da bo funkcija INDIRECT vrnila vrednost iz desne celice.

Spodnje slike prikazujejo delovanje izboljšane formule INDEX MATCH, ki upošteva velike in male črke.

Če je vrnjena celica prazna, formula ne izpiše ničesar (prazen niz):

Če je v celici vrnitve nič, formula vrne 0:

Če bi raje prikazali sporočilo, ko je celica vrnitve prazna, nadomestite prazen niz ("") v zadnjem argumentu IF z nekim besedilom:

=IF(INDIRECT("C"&(1+MATCH(TRUE, EXACT(A2:A7, F2), 0)))"", INDEX(C2:C7, MATCH(TRUE, EXACT(A2:A7, F2), 0)), "Ni kaj vrniti, žal.")

Enostaven način izvedbe VLOOKUP, občutljivega na velikost črk

Uporabniki našega paketa Ultimate Suite za Excel imajo na voljo posebno orodje, s katerim je iskanje v velikih in zapletenih tabelah lažje in brez stresa. Najboljše je, da ima možnost Merge Two Tables (Združitev dveh tabel), ki razlikuje velike in male črke, spodnji primer pa prikazuje njeno delovanje.

Recimo, da želite izpisati Qty. iz Iskanje tabelo v Glavna stran na podlagi edinstvenih identifikatorjev elementov:

Zaženite čarovnika za združevanje tabel in izvedite naslednje korake:

1. Izberite glavno tabelo, v katero želite vnesti nove podatke.
2. Izberite preglednico za iskanje, v kateri želite poiskati nove podatke.
3. Izberite enega ali več ključnih stolpcev (v našem primeru ID predmeta). Ujemanje, občutljivo na velikost črk škatla.

Čez trenutek boste dobili želeni rezultat :)

To je način iskanja v Excelu ob upoštevanju velikosti besedila. Zahvaljujem se vam za branje in upam, da se naslednji teden vidimo na našem blogu!

Praktični delovni zvezek za prenos

Primeri VLOOKUP z upoštevanjem velikosti črk (.xlsx datoteka)