Упатството објаснува како да се направи Excel VLOOKUP чувствителен на букви, демонстрира неколку други формули кои разликуваат букви на текст и ги посочува предностите и ограничувањата на секоја функција.

Претпоставувам дека секоја Корисникот на Excel знае која функција врши вертикално пребарување во Excel. Точно, тоа е VLOOKUP. Сепак, многу малку луѓе се свесни дека VLOOKUP-от на Excel не е чувствителен на големи букви, што значи дека ги третира малите и големите букви како исти знаци.

Еве брз пример што ја покажува неможноста на VLOOKUP да разликува текстуални букви. Да претпоставиме дека имате „сметка“ во ќелијата А2 и „Бил“ во А4. Формулата подолу ќе фати „сметка“ затоа што е прва во низата за пребарување и ќе врати соодветна вредност од B2.

=VLOOKUP("Bill", A2:B4, 2, FALSE)

Понатаму во ова статија, ќе ви покажам начин да го направите VLOOKUP чувствителен на букви. Ќе истражиме и неколку други функции кои можат да направат совпаѓање чувствително на големи букви во Excel.

Формула VLOOKUP чувствителна на големи букви

Како што споменавме погоре, вообичаена формула VLOOKUP не ја препознава буквата буква. Сепак, постои начин да се направи Excel VLOOKUP чувствителен на букви, како што е прикажано во примерот подолу.

Да претпоставиме дека имате Идентификатори на ставки во колоната А и сакате да ја повлечете цената и коментарот на ставката од колоните B и C. Проблемот е што ID-овите вклучуваат и мали и големи знаци. На пример, вредностите во A4 (001Tvci3u) и A5 (001Tvci3U) се разликуваат само вопоследниот знак, „u“ и „U“, соодветно.

Кога барате „001Tvci3 U “, стандардната формула VLOOKUP дава 90$ што е поврзана со „001Tvci3 u “ бидејќи доаѓа пред „001Tvci3 U “ во низата за пребарување. Но, ова не е она што го сакате, нели?

=VLOOKUP(F2, A2:C7, 2, FALSE)

За да извршиме пребарување чувствително на големи букви во Excel, ги комбинираме VLOOKUP, CHOOSE и EXACT функции:

Оваа генеричка формула совршено функционира во сите ситуации. Можете дури и да барате од десно кон лево , нешто што обичната формула VLOOKUP не може да го направи. Секоја чест за Pouriya што го предложи ова едноставно и елегантно решение!

Во нашиот случај, вистинските формули одат на следниов начин.

За да ја повлечете цената во F3:

=VLOOKUP(TRUE, CHOOSE({1,2}, EXACT(F2, A2:A7), B2:B7), 2, FALSE)

За да го земете коментарот F4:

=VLOOKUP(TRUE, CHOOSE({1,2}, EXACT(F2, A2:A7), C2:C7), 2, FALSE)

Забелешка. Во сите верзии на Excel, освен Excel 365, ова работи само како формула за низа, затоа не заборавајте да притиснете Ctrl + Shift + Enter за правилно да ја завршите. Во Excel 365, поради поддршката за динамички низи, работи и како редовна формула.

Како функционира оваа формула:

Основниот дел што го прави трикот е формулата CHOOSE со вгнездена EXACT:

CHOOSE({1,2}, EXACT(F2, A2:A7), C2:C7)

Тука, функцијата EXACT ја споредува вредноста во F2 со секоја вредност во A2:A7 и враќа TRUE ако тие се потполно исти вклучувајќи ја и буквата,НЕТОЧНО инаку:

{FALSE;FALSE;FALSE;TRUE;FALSE;FALSE}

За аргументот index_num на CHOOSE, ја користиме константата на низата {1,2}. Како резултат на тоа, функцијата ги комбинира логичките вредности од горната низа и вредностите од C2:C7 во дводимензионална низа како оваа:

{FALSE,155;FALSE,186;FALSE,90;TRUE,54;FALSE,159;FALSE,28}

Функцијата VLOOKUP ја зема од таму и ја бара вредноста за пребарување (која е ВИСТИНА) во 1-та колона од 2-димензионалната низа (претставена со логичките вредности) и враќа совпаѓање од 2-та колона, што е цената што ја бараме:

VLOOKUP(TRUE, {FALSE,155;FALSE,186;FALSE,90;TRUE,54;FALSE,159;FALSE,28}, 2, 0)

Формула XLOOKUP чувствителна на големи букви

Претплатниците на Microsoft 365 можат да направат пребарување чувствително на големи букви во Excel со дури и поедноставна формула. Како што можете да претпоставите, зборувам за помоќен наследник на VLOOKUP - функцијата XLOOKUP.

Бидејќи XLOOKUP работи на низи за пребарување и враќање одделно, не ни треба трикот со дводимензионална низа од претходниот пример. Едноставно, користете EXACT за аргументот lookup_array :

Последниот аргумент („Не е пронајден“) е изборен. Тоа само дефинира која вредност да се врати ако не се најде совпаѓање. Ако го испуштите, тогаш ќе се врати стандардна грешка #N/A во случај формулата да не најде ништо.

За нашата примерна табела, ова се формули XLOOKUP чувствителни на големи букви.

За да ја добиете цената во F3:

=XLOOKUP(TRUE, EXACT(F2, A2:A7), B2:B7, "Not found")

За да ја извадитекоментар F4:

=XLOOKUP(TRUE, EXACT(F2, A2:A7), C2:C7, "Not found")

Како функционира оваа формула:

Како во претходниот пример, EXACT враќа низа од TRUE и FALSE вредности, каде што TRUE претставува совпаѓања чувствителни на букви. XLOOKUP ја пребарува горната низа за ВИСТИНСКАТА вредност и враќа совпаѓање од return_array . Ве молиме имајте предвид, ако има две или повеќе точно исти вредности во колоната за пребарување (вклучувајќи го и буквата), формулата ќе го врати првото пронајдено совпаѓање.

Ограничување XLOOKUP : достапно само во Excel 365 и Excel 2021.

SUMPRODUCT - пребарување чувствително на големи букви за враќање на соодветните броеви

Како што разбирате од насловот, SUMPRODUCT е уште една функција на Excel што може да направи пребарување чувствително на големи букви , но може да враќа само нумерички вредности . Ако ова не е вашиот случај, тогаш префрлете се на примерот INDEX MATCH кој дава решение за сите типови податоци.

Како што веројатно знаете, SUMPRODUCT на Excel ги множи компонентите во наведените низи и го враќа збирот на производите. Бидејќи сакаме пребарување чувствително на големи букви, ја користиме функцијата EXACT за да ја добиеме првата низа:

=SUMPRODUCT((EXACT(A2:A7,F2) * (B2:B7)))

За жал, функцијата SUMPRODUCT не може да врати совпаѓања на текст бидејќи вредностите на текстот не можат да се множат. Во овој случај, ќе добиете #ВРЕДНОСТ! грешка како во ќелијата F4 на сликата подолу:

Како функционира оваа формула:

Како во примерот VLOOKUP, ТОЧНО функционални проверкивредноста во F2 во однос на сите вредности во A2:A7 и враќа TRUE за совпаѓања чувствителни на букви, FALSE во спротивно:

SUMPRODUCT(({FALSE;FALSE;FALSE;TRUE;FALSE;FALSE}*{155;186;90;54;159;28}))

Во повеќето формули, Excel оценува TRUE на 1 и FALSE на 0 Значи, кога SUMPRODUCT ги множи елементите на двете низи на исти позиции, сите неусогласени (FALSE) стануваат нули:

SUMPRODUCT({0;0;0;54;0;0})

Како резултат, формулата враќа број од колона B што одговара на точното совпаѓање чувствително на големи букви во колоната А.

Ограничување на SUMPRODUCT : може да враќа само нумерички вредности.

INDEX MATCH - пребарување чувствително на букви за сите типови податоци

Конечно, блиску сме до добивање формула за пребарување чувствителна на големи букви без ограничувања која работи во сите верзии на Excel и на сите збирки податоци.

Овој пример е последен не само затоа што најдоброто се зачувува за последно, но и затоа што знаењето што го стекнавте во претходните примери може да ви помогне подобро да ја разберете формулата MATCH INDEX чувствителна на големи букви.

Комбинацијата на функции INDEX и MATCH често се користи во Пр cel како пофлексибилна и разновидна алтернатива на VLOOKUP. Следната статија прави добра работа (се надевам :) објаснувајќи како овие две функции функционираат заедно - Користење INDEX MATCH наместо VLOOKUP.

Овде, само ќе ве потсетам на клучните точки:

• Функцијата MATCH ја бара вредноста за пребарување во наведената низа за пребарување и ја враќа нејзината релативна позиција.
• Релативнатапозицијата на бараната вредност оди директно до аргументот row_num на функцијата INDEX и наредува да врати вредност од тој ред.

За формулата да препознае букви на текст, само треба да се додаде уште една функција на класичната комбинација INDEX MATCH. Очигледно, повторно ви е потребна EXACT функцијата:

Вистинската формула во F3 е:

=INDEX(B2:B7, MATCH(TRUE, EXACT(A2:A7, F2), 0))

Во F4, ја користиме оваа:

=INDEX(C2:C7, MATCH(TRUE, EXACT(A2:A7, F2), 0))

Ве молиме запомнете дека работи само како формула за низа во сите верзии освен Excel 365, затоа не заборавајте да ја внесете со притискање на копчињата Ctrl + Shift + Enter заедно. Ако се направи правилно, формулата ќе биде затворена во кадрави загради како што е прикажано на сликата подолу:

Како функционира оваа формула:

Како и во сите претходни примери, EXACT враќа TRUE за секоја вредност во A2:A7 што точно се совпаѓа со вредноста во F2. Со оглед на тоа што користиме ТОЧНО за преглед_вредност на MATCH, таа враќа релативна позиција на точното совпаѓање чувствително на големи букви, што е токму она што INDEX му треба за да врати совпаѓање од B2:B7.

Напредна формула за пребарување чувствителна на големи букви

Гореспоменатата формула INDEX MATCH изгледа совршено, нели? Но, всушност, тоа не е. Дозволете ми да ви покажам зошто.

Да претпоставиме дека ќелијата во колоната за враќање што одговара на вредноста за пребарување е празна. Што ќе врати формулата? Ништо.И сега, ајде да видиме што всушност враќа:

=INDEX(C2:C7, MATCH(TRUE, EXACT(A2:A7, F2), 0))

Упс, формулата враќа нула! Можеби, тоа не е навистина важно кога се работи само со текстуални вредности. Меѓутоа, ако вашиот работен лист содржи броеви, а некои од нив се реални нули, ова е проблем.

Навистина, сите други формули за пребарување што беа дискутирани претходно се однесуваат на ист начин. Но, сега сакате беспрекорна формула, нели?

За да ја направите формулата INDEX MATCH чувствителна на големи букви апсолутно совршена, ја завиткувате во функцијата IF која проверува дали повратната ќелија е празна и не враќа ништо во овој случај:

=IF(INDIRECT("C"&(1+MATCH(TRUE,EXACT(A2:A7, F2), 0)))"", INDEX(C2:C7, MATCH(TRUE, EXACT(A2:A7, F2), 0)), "")

Во горната формула:

• „C“ е повратната колона.
• „1“ е бројот што ја претвора релативната позиција на ќелијата вратена од функцијата MATCH во реална адреса на ќелија .

На пример, низата за пребарување во нашата функција MATCH е A2:A7, што значи дека релативната позиција на ќелијата A2 е „1“, бидејќи ова е првата ќелија во низата. Но, во реалноста, низата за пребарување започнува во редот 2. За да ја компензираме разликата, додаваме 1, па функцијата INDIRECT ќе врати вредност од десната ќелија.

Подолу сликите од екранот го демонстрираат подобрениот ИНДЕКС чувствителен на големи букви MATCH формула во акција.

Ако повратната ќелија е празна, формулата не дава ништо (празна низа):

Ако повратната ќелија содржи нула , формулата враќа 0:

Ако сакатеприкажете некоја порака кога повратната ќелија е празна, заменете ја празната низа („“) во последниот аргумент на IF со некој текст:

=IF(INDIRECT("C"&(1+MATCH(TRUE, EXACT(A2:A7, F2), 0)))"", INDEX(C2:C7, MATCH(TRUE, EXACT(A2:A7, F2), 0)), "There is nothing to return, sorry.")

Направете го VLOOKUP чувствителен на големи букви на лесен начин

Корисниците на нашиот Ultimate Suite за Excel имаат специјална алатка што го олеснува пребарувањето во големи и сложени табели полесно и без стрес. Најдоброто нешто е што Merge Two Tables има опција чувствителна на големи букви, а примерот подолу ја покажува на дело.

Да претпоставиме дека сакате да повлечете Количина. од табелата Пребарување до табелата Главната врз основа на единствените ID на ставки:

Она што го правите е да ги извршите табелите за спојување волшебник и направете ги овие чекори:

1. Изберете ја главната табела во која ќе се повлечат нови податоци.
2. Изберете ја табелата за пребарување каде да ги барате новите податоци.
3. Изберете една или повеќе клучни колони (ID на ставка во нашиот случај). И не заборавајте да го проверите полето совпаѓање чувствително на букви .

Момент подоцна, ќе го добиете посакуваниот резултат :)

Така да барате во Excel земајќи ја предвид големината на текстот. Ви благодарам што прочитавте и се надевам дека ќе се видиме на нашиот блог следната недела!

Вежбајте работна книга за преземање

Примери VLOOKUP чувствителни на големи букви (датотека .xlsx)