एक्सेल VLOOKUP केस-सेन्सिटिव्ह कसे बनवायचे हे ट्युटोरियल स्पष्ट करते, मजकूर केस वेगळे करणारे काही इतर सूत्रे दाखवते आणि प्रत्येक फंक्शनची ताकद आणि मर्यादा दर्शवते.

माझ्या अंदाजानुसार प्रत्येक एक्सेलमध्ये कोणते फंक्शन व्हर्टिकल लुकअप करते हे एक्सेल वापरकर्त्याला माहीत असते. बरोबर, ते VLOOKUP आहे. तथापि, फार कमी लोकांना माहिती आहे की Excel चे VLOOKUP केस-संवेदनशील आहे, म्हणजे ते लोअरकेस आणि अपरकेस अक्षरे समान वर्णांप्रमाणे हाताळते.

येथे एक द्रुत उदाहरण आहे जे मजकूर केस वेगळे करण्यास VLOOKUP ची असमर्थता दर्शवते. समजा तुमच्या सेल A2 मध्ये "बिल" आणि A4 मध्ये "बिल" असेल तर. खालील सूत्र "बिल" पकडेल कारण ते लुकअप अॅरेमध्ये प्रथम येते आणि B2 वरून जुळणारे मूल्य परत करते.

=VLOOKUP("Bill", A2:B4, 2, FALSE)

यामध्ये पुढे लेख, मी तुम्हाला VLOOKUP केस-सेन्सेटिव्ह बनवण्याचा मार्ग दाखवतो. आम्ही एक्सेलमध्ये केस-सेन्सिटिव्ह जुळणी करू शकणारी काही इतर फंक्शन्स देखील एक्सप्लोर करू.

केस-सेन्सिटिव्ह VLOOKUP फॉर्म्युला

वर नमूद केल्याप्रमाणे, एक नेहमीचा VLOOKUP फॉर्म्युला पत्र केस ओळखत नाही. तथापि, खाली दिलेल्या उदाहरणात दाखवल्याप्रमाणे Excel VLOOKUP केस-सेन्सिटिव्ह बनवण्याचा एक मार्ग आहे.

समजा तुमच्याकडे स्तंभ A मध्ये आयटम आयडी आहेत आणि तुम्हाला आयटमची किंमत आणि टिप्पणी खेचायची आहे. स्तंभ B आणि C मधून. समस्या अशी आहे की ID मध्ये लोअरकेस आणि अपरकेस वर्ण दोन्ही समाविष्ट आहेत. उदाहरणार्थ, A4 (001Tvci3u) आणि A5 (001Tvci3U) मधील मूल्ये फक्त यामध्ये भिन्न आहेतशेवटचे वर्ण, "u" आणि "U", अनुक्रमे.

"001Tvci3 U " वर शोधताना, मानक VLOOKUP सूत्र $90 आउटपुट करतो जो "001Tvci3 u शी संबंधित आहे. " कारण ते लुकअप अॅरेमध्ये "001Tvci3 U " च्या आधी येते. पण हे तुम्हाला हवे आहे, बरोबर?

=VLOOKUP(F2, A2:C7, 2, FALSE)

एक्सेलमध्ये केस-सेन्सिटिव्ह लुकअप करण्यासाठी, आम्ही VLOOKUP, निवडा आणि अचूक एकत्र करतो कार्ये:

हे जेनेरिक सूत्र सर्व परिस्थितींमध्ये उत्तम प्रकारे कार्य करते. तुम्ही उजवीकडून डावीकडे देखील पाहू शकता, जे नियमित VLOOKUP सूत्र करू शकत नाही. हा सोपा आणि सुंदर उपाय सुचवल्याबद्दल पौरियाचे अभिनंदन!

आमच्या बाबतीत, वास्तविक सूत्रे खालीलप्रमाणे आहेत.

F3 मध्ये किंमत काढण्यासाठी:

=VLOOKUP(TRUE, CHOOSE({1,2}, EXACT(F2, A2:A7), B2:B7), 2, FALSE)

टिप्पणी आणण्यासाठी F4:

=VLOOKUP(TRUE, CHOOSE({1,2}, EXACT(F2, A2:A7), C2:C7), 2, FALSE)

टीप. Excel 365 व्यतिरिक्त इतर सर्व एक्सेल आवृत्त्यांमध्ये, हे फक्त अॅरे फॉर्म्युला म्हणून कार्य करते, म्हणून ते योग्यरित्या पूर्ण करण्यासाठी Ctrl + Shift + Enter दाबण्याचे लक्षात ठेवा. एक्सेल 365 मध्ये, डायनॅमिक अॅरेच्या समर्थनामुळे, ते नियमित सूत्र म्हणून देखील कार्य करते.

हे फॉर्म्युला कसे कार्य करते:

येथे, नेस्टेड EXACT सह CHOOSE फॉर्म्युला आहे. EXACT फंक्शन F2 मधील मूल्याची A2:A7 मधील प्रत्येक मूल्याशी तुलना करते आणि अक्षर केससह ते अगदी सारखे असल्यास TRUE मिळवते,FALSE अन्यथा:

{FALSE;FALSE;FALSE;TRUE;FALSE;FALSE}

CHOOSE च्या index_num युक्तिवादासाठी, आम्ही अॅरे स्थिरांक {1,2} वापरतो. परिणामी, फंक्शन वरील अॅरेमधील तार्किक मूल्ये आणि C2:C7 मधील मूल्ये अशा द्विमितीय अॅरेमध्ये एकत्रित करते:

{FALSE,155;FALSE,186;FALSE,90;TRUE,54;FALSE,159;FALSE,28}

VLOOKUP फंक्शन तेथून ते घेते आणि 2-आयामी अॅरेच्या 1ल्या स्तंभामध्ये (जे सत्य आहे) लुकअप मूल्य शोधते (तार्किक मूल्यांद्वारे प्रस्तुत केले जाते) आणि 2ऱ्या स्तंभातून एक जुळणी मिळवते, जी आम्ही शोधत असलेली किंमत आहे:

VLOOKUP(TRUE, {FALSE,155;FALSE,186;FALSE,90;TRUE,54;FALSE,159;FALSE,28}, 2, 0)

केस-सेन्सिटिव्ह XLOOKUP फॉर्म्युला

Microsoft 365 सदस्य अगदी सोप्या सूत्रासह Excel मध्ये केस-सेन्सिटिव्ह लुकअप करू शकतात. तुम्ही अंदाज लावू शकता की, मी VLOOKUP च्या अधिक शक्तिशाली उत्तराधिकारी - XLOOKUP फंक्शनबद्दल बोलत आहे.

कारण XLOOKUP लुकअप आणि रिटर्न अ‍ॅरेवर स्वतंत्रपणे कार्य करते, आम्हाला आधीच्या द्विमितीय अॅरे युक्तीची गरज नाही. उदाहरण फक्त, lookup_array युक्तिवादासाठी EXACT वापरा:

शेवटचा युक्तिवाद ("न सापडला") पर्यायी आहे. कोणतीही जुळणी न आढळल्यास कोणते मूल्य परत करावे हे ते फक्त परिभाषित करते. तुम्ही ते वगळल्यास, सूत्रात काहीही आढळले नाही तर मानक #N/A त्रुटी परत केली जाईल.

आमच्या नमुना सारणीसाठी, हे केस-सेन्सिटिव्ह XLOOKUP सूत्र वापरण्यासाठी आहेत.

F3 मध्ये किंमत मिळवण्यासाठी:

=XLOOKUP(TRUE, EXACT(F2, A2:A7), B2:B7, "Not found")

एक्सट्रैक्ट करण्यासाठीटिप्पणी F4:

=XLOOKUP(TRUE, EXACT(F2, A2:A7), C2:C7, "Not found")

हे सूत्र कसे कार्य करते:

मागील उदाहरणाप्रमाणे, अचूक परतावा TRUE आणि FALSE मूल्यांचा अॅरे, जेथे TRUE केस-संवेदनशील जुळण्यांचे प्रतिनिधित्व करतो. XLOOKUP TRUE मूल्यासाठी वरील अॅरे शोधते आणि return_array मधून जुळणी मिळवते. कृपया लक्षात ठेवा, लुकअप कॉलममध्ये (लेटर केससह) दोन किंवा अधिक समान मूल्ये असल्यास, सूत्र प्रथम आढळलेली जुळणी देईल.

XLOOKUP मर्यादा : फक्त उपलब्ध Excel 365 आणि Excel 2021 मध्ये.

SUMPRODUCT - जुळणारे क्रमांक परत करण्यासाठी केस-सेन्सिटिव्ह लुकअप

जसे तुम्हाला हेडिंगवरून समजले आहे, SUMPRODUCT हे आणखी एक एक्सेल फंक्शन आहे जे केस-सेन्सिटिव्ह लुकअप करू शकते. , परंतु ते फक्त संख्यात्मक मूल्ये परत करू शकतात. हे तुमचे केस नसल्यास, सर्व डेटा प्रकारांसाठी उपाय प्रदान करणार्‍या INDEX MATCH उदाहरणावर जा.

तुम्हाला माहीत असेलच, Excel चे SUMPRODUCT निर्दिष्ट अॅरेमधील घटकांचा गुणाकार करते आणि उत्पादनांची बेरीज देते. आम्हाला केस सेन्सिटिव्ह लुकअप हवा असल्याने, आम्ही प्रथम अॅरे मिळविण्यासाठी EXACT फंक्शन वापरतो:

=SUMPRODUCT((EXACT(A2:A7,F2) * (B2:B7)))

खेदाची गोष्ट म्हणजे, SUMPRODUCT फंक्शन मजकूर जुळणी देऊ शकत नाही कारण मजकूर मूल्ये गुणाकार केली जाऊ शकत नाहीत. या प्रकरणात, तुम्हाला #VALUE मिळेल! खालील स्क्रीनशॉटमध्ये सेल F4 मधील त्रुटी:

हे सूत्र कसे कार्य करते:

VLOOKUP उदाहरणाप्रमाणे, अचूक कार्य तपासणीF2 मधील मूल्य A2:A7 मधील सर्व मूल्यांविरुद्ध आणि केस-संवेदनशील जुळण्यांसाठी सत्य मिळवते, अन्यथा असत्य:

SUMPRODUCT(({FALSE;FALSE;FALSE;TRUE;FALSE;FALSE}*{155;186;90;54;159;28}))

बहुतेक सूत्रांमध्ये, एक्सेल 1 ते 1 आणि असत्य 0 चे मूल्यमापन करते . म्हणून, जेव्हा SUMPRODUCT दोन अॅरेच्या घटकांचा समान स्थानांवर गुणाकार करते, तेव्हा सर्व जुळणारे नसलेले (FALSE) शून्य होतात:

SUMPRODUCT({0;0;0;54;0;0})

परिणामी म्हणून, सूत्र वरून संख्या मिळवते स्तंभ B जो स्तंभ A मधील अचूक केस-संवेदनशील जुळणीशी संबंधित आहे.

SUMPRODUCT मर्यादा : केवळ अंकीय मूल्ये देऊ शकतात.

इंडेक्स जुळणी - केस-संवेदनशील शोध सर्व डेटा प्रकार

शेवटी, आम्ही मर्यादा-मुक्त केस-सेन्सिटिव्ह लुकअप फॉर्म्युला मिळविण्याच्या जवळ आहोत जे सर्व एक्सेल आवृत्त्यांमध्ये आणि सर्व डेटा सेटवर कार्य करते.

हे उदाहरण केवळ कारण नाही. सर्वोत्कृष्ट शेवटसाठी जतन केले जाते, परंतु मागील उदाहरणांमध्ये तुम्हाला मिळालेले ज्ञान तुम्हाला केस-सेन्सिटिव्ह मॅच इंडेक्स फॉर्म्युला अधिक चांगल्या प्रकारे समजून घेण्यास मदत करू शकते.

इंडेक्स आणि मॅच फंक्शन्सचे संयोजन अनेकदा वापरले जाते माजी मध्ये VLOOKUP ला अधिक लवचिक आणि बहुमुखी पर्याय म्हणून cel. ही दोन कार्ये एकत्र कशी कार्य करतात हे स्पष्ट करणारा पुढील लेख चांगला काम करतो (आशा आहे :) - VLOOKUP ऐवजी INDEX MATCH वापरणे.

येथे, मी तुम्हाला फक्त मुख्य मुद्दे लक्षात आणून देतो:

• MATCH फंक्शन निर्दिष्ट लुकअप अॅरेमध्ये लुकअप मूल्य शोधते आणि त्याचे सापेक्ष स्थान परत करते.
• सापेक्षलुकअप व्हॅल्यूची स्थिती थेट INDEX फंक्शनच्या row_num युक्तिवादावर जाते आणि त्यास त्या पंक्तीमधून मूल्य परत करण्यास सूचित करते.

टेक्स्ट केस ओळखण्यासाठी सूत्रासाठी, तुम्ही फक्त क्लासिक INDEX MATCH संयोजनात आणखी एक कार्य जोडणे आवश्यक आहे. अर्थात, तुम्हाला पुन्हा अचूक फंक्शनची आवश्यकता आहे:

F3 मधील वास्तविक सूत्र आहे:

=INDEX(B2:B7, MATCH(TRUE, EXACT(A2:A7, F2), 0))

F4 मध्ये, आम्ही हे वापरत आहोत:

=INDEX(C2:C7, MATCH(TRUE, EXACT(A2:A7, F2), 0))

कृपया लक्षात ठेवा की ते फक्त म्हणून कार्य करते एक्सेल 365 व्यतिरिक्त इतर सर्व आवृत्त्यांमध्ये अॅरे फॉर्म्युला, त्यामुळे Ctrl + Shift + Enter की एकत्र दाबून ते एंटर करण्याचे सुनिश्चित करा. योग्यरित्या केले असल्यास, खालील स्क्रीनशॉटमध्ये दर्शविल्याप्रमाणे सूत्र कुरळे ब्रेसेसमध्ये बंद केले जाईल:

हे सूत्र कसे कार्य करते:

मागील सर्व उदाहरणांप्रमाणे, F2 मधील मूल्याशी तंतोतंत जुळणाऱ्या A2:A7 मधील प्रत्येक मूल्यासाठी EXACT TRUE मिळवते. आम्ही जुळणीच्या lookup_value साठी TRUE वापरत असल्याने, ते अचूक केस-संवेदनशील जुळणीची सापेक्ष स्थिती मिळवते, जी B2:B7 वरून जुळणी परत करण्यासाठी INDEX ला आवश्यक असते.

प्रगत केस-संवेदनशील लुकअप फॉर्म्युला

वर नमूद केलेला इंडेक्स मॅच फॉर्म्युला परिपूर्ण दिसत आहे, बरोबर? पण प्रत्यक्षात तसे नाही. मी तुम्हाला का दाखवतो.

समजा, लुकअप मूल्याशी संबंधित रिटर्न कॉलममधील सेल रिक्त आहे. सूत्र काय परत येईल? काहीही नाही.आणि आता, ते प्रत्यक्षात काय मिळवते ते पाहू:

=INDEX(C2:C7, MATCH(TRUE, EXACT(A2:A7, F2), 0))

अरेरे, सूत्र शून्य मिळवते! कदाचित, केवळ मजकूर मूल्यांसह व्यवहार करताना ते खरोखर महत्वाचे नाही. तथापि, जर तुमच्या वर्कशीटमध्ये संख्या असतील आणि त्यापैकी काही वास्तविक शून्य असतील, तर ही एक समस्या आहे.

खरं तर, इतर सर्व लुकअप फॉर्म्युले ज्यावर आधी चर्चा केली आहे ते त्याच प्रकारे वागतात. पण आता तुम्हाला एक निर्दोष फॉर्म्युला हवा आहे, नाही का?

केस-सेन्सिटिव्ह इंडेक्स मॅच फॉर्म्युला पूर्णपणे परिपूर्ण बनवण्यासाठी, तुम्ही ते IF फंक्शनमध्ये गुंडाळता जे रिटर्न सेल रिक्त आहे की नाही हे तपासते आणि त्यात काहीही परत करत नाही. या प्रकरणात:

=IF(INDIRECT("C"&(1+MATCH(TRUE,EXACT(A2:A7, F2), 0)))"", INDEX(C2:C7, MATCH(TRUE, EXACT(A2:A7, F2), 0)), "")

वरील सूत्रात:

• "C" हा रिटर्न कॉलम आहे.
• "1" ही संख्या आहे. जे MATCH फंक्शनद्वारे परत केलेल्या सेलचे सापेक्ष स्थान वास्तविक सेल अॅड्रेस मध्ये बदलते.

उदाहरणार्थ, आमच्या मॅच फंक्शनमधील लुकअप अॅरे A2:A7 आहे, म्हणजे सेल A2 चे सापेक्ष स्थान "1" आहे, कारण हा अॅरेमधील पहिला सेल आहे. परंतु प्रत्यक्षात, लुकअप अ‍ॅरे पंक्ती 2 मध्ये सुरू होते. फरक भरून काढण्यासाठी, आम्ही 1 जोडतो, त्यामुळे INDIRECT फंक्शन उजव्या सेलमधून एक मूल्य परत करेल.

खालील स्क्रीनशॉट सुधारित केस-संवेदनशील INDEX प्रदर्शित करतात. कृतीमध्ये सूत्र जुळवा.

रिटर्न सेल रिकामे असल्यास, सूत्र काहीही आउटपुट करत नाही (रिकामी स्ट्रिंग):

जर रिटर्न सेलमध्ये शून्य असेल , सूत्र ०:

आपण इच्छित असल्यासरिटर्न सेल रिक्त असताना काही संदेश प्रदर्शित करा, IF च्या शेवटच्या युक्तिवादात काही मजकूरासह रिक्त स्ट्रिंग ("") बदला:

=IF(INDIRECT("C"&(1+MATCH(TRUE, EXACT(A2:A7, F2), 0)))"", INDEX(C2:C7, MATCH(TRUE, EXACT(A2:A7, F2), 0)), "There is nothing to return, sorry.")

केस-सेन्सिटिव्ह VLOOKUP सोप्या मार्गाने करा

आमच्या Ultimate Suite for Excel च्या वापरकर्त्यांकडे एक विशेष साधन आहे जे मोठ्या आणि जटिल टेबल्समध्ये पाहणे सोपे आणि तणावमुक्त करते. सर्वात चांगली गोष्ट म्हणजे मर्ज टू टेबल्समध्ये केस-सेन्सिटिव्ह पर्याय आहे आणि खालील उदाहरण ते कृतीत दाखवते.

समजा तुम्हाला Qty खेचायचा आहे. युनिक आयटम आयडीच्या आधारावर लुकअप टेबलवरून मुख्य टेबलवर:

तुम्ही काय करता ते म्हणजे मर्ज टेबल्स चालवणे. विझार्ड करा आणि या चरणांचे पालन करा:

1. नवीन डेटा खेचण्यासाठी मुख्य टेबल निवडा.
2. नवीन डेटा कुठे शोधायचा ते लुकअप टेबल निवडा.
3. एक किंवा अधिक की कॉलम निवडा (आमच्या बाबतीत आयटम आयडी). आणि केस-संवेदनशील जुळणी बॉक्स तपासण्याचे सुनिश्चित करा.

थोड्या वेळाने, तुम्हाला अपेक्षित परिणाम मिळेल :)

मजकूर केस लक्षात घेऊन एक्सेलमध्ये कसे पहावे. वाचल्याबद्दल मी तुमचा आभारी आहे आणि पुढील आठवड्यात तुम्हाला आमच्या ब्लॉगवर भेटण्याची आशा आहे!

डाउनलोड करण्यासाठी सराव वर्कबुक

केस-सेन्सिटिव्ह VLOOKUP उदाहरणे (.xlsx फाइल)