Opplæringen vil lære deg hvordan du konstruerer If match-formelen i Excel, slik at den returnerer logiske verdier, egendefinert tekst eller en verdi fra en annen celle.

En Excel-formel å se Hvis to celler samsvarer, kan det være så enkelt som A1=B1. Det kan imidlertid være andre omstendigheter når denne åpenbare løsningen ikke vil fungere eller gi resultater som er annerledes enn du forventet. I denne opplæringen vil vi diskutere ulike måter å sammenligne celler i Excel på, slik at du kan finne en optimal løsning for oppgaven din.

Hvordan sjekke om to celler samsvarer i Excel

Det finnes mange varianter av Excel If-formelen. Bare se gjennom eksemplene nedenfor og velg det som fungerer best for ditt scenario.

Hvis to celler er like, returner TRUE

Den enkleste " Hvis en celle er lik en annen, så sant" Excel-formel er denne:

celle A= celle B

For å sammenligne celler i kolonne A og B i hver rad, skriver du inn denne formelen i C2, og kopier den ned i kolonnen:

=A2=B2

Som et resultat vil du få TRUE hvis to celler er like, ellers FALSE:

Merknader:

• Denne formelen returnerer to boolske verdier: hvis to celler er like - TRUE; hvis ikke lik - FALSE. For bare å returnere TRUE-verdiene, bruk i IF-setningen som vist i neste eksempel.
• Denne formelen er uavhengig av store og små bokstaver , så den behandler store og små bokstaver som de samme tegnene. Hvis tekstenBruk denne formelen som skiller mellom store og små bokstaver.

Hvis to celler samsvarer, returner verdi

For å returnere din egen verdi hvis to celler samsvarer, konstruer en IF-setning ved å bruke dette mønsteret :

IF( celle A = celle B , value_if_true, value_if_false)

For eksempel for å sammenligne A2 og B2 og returnere "ja" hvis de inneholder de samme verdiene , "nei" ellers er formelen:

=IF(A2=B2, "yes", "no")

Hvis du bare vil returnere en verdi hvis cellene er like, oppgi en tom streng ("") for verdi_hvis_falsk .

Hvis samsvar, så ja :

=IF(A2=B2, "yes", "")

Hvis samsvar, så TRUE:

=IF(A2=B2, TRUE, "")

Merk. For å returnere den logiske verdien TRUE, ikke skriv den i doble anførselstegn. Bruk av doble anførselstegn vil konvertere den logiske verdien til en vanlig tekststreng.

Hvis en celle er lik en annen, returner en annen celle

Og her er en variant av Excel if match -formelen som løser denne spesifikke oppgaven: sammenlign verdiene i to celler og hvis data samsvarer, kopier deretter en verdi fra en annen celle.

I Excel-språket er den formulert slik:

IF( celle A = celle B , celle C , "")

For å sjekke elementene i kolonne A og B og returnere en verdi fra kolonne C hvis tekst samsvarer, er formelen i D2, kopiert ned,:

=IF(A2=B2, C2, "")

Stillingssensitiv formel for å se om to celler samsvarer

I situasjoner hvor du har å gjøre med store og små bokstaver, bruk EXACTfunksjon for å sammenligne cellene nøyaktig, inkludert store og små bokstaver:

IF(EXACT( celle A , celle B ), value_if_true, value_if_false)

For eksempel for å sammenligne elementene i A2 og B2 og returner "ja" hvis teksten samsvarer nøyaktig, "nei" hvis noen forskjell er funnet, kan du bruke denne formelen:

=IF(EXACT(A2, B2), "Yes", "No")

Hvordan sjekke om flere celler er like

Som med å sammenligne to celler, kan sjekking av flere celler for samsvar også gjøres på noen forskjellige måter.

OG formel for å se om flere celler samsvarer

Til sjekk om flere verdier samsvarer, du kan bruke OG-funksjonen med to eller flere logiske tester:

OG( celle A = celle B , celle A = celle C , …)

For å se for eksempel om cellene A2, B2 og C2 er like, er formelen:

=AND(A2=B2, A2=C2)

I dynamisk matrise Excel (365 og 2021) kan du også bruke syntaksen nedenfor. I Excel 2019 og lavere vil dette bare fungere som en tradisjonell CSE-matriseformel, fullført ved å trykke Ctrl + Shift + Enter-tastene samtidig.

=AND(A2=B2:C2)

Resultatet av både OG-formler er logiske verdier TRUE og FALSE.

For å returnere dine egne verdier, pakk OG inn i HVIS-funksjonen slik:

=IF(AND(A2=B2:C2), "yes", "")

Denne formelen returnerer "ja" hvis alle tre cellene er like, ellers en tom celle.

ANTALLHVIS-formel for å sjekke om flere kolonner samsvarer

En annen måte å se etter flere samsvar på er å bruke ANTALLHVIS-funksjonen i denne formen:

ANTALLHVIS( område , celle )= n

Hvor område er et område med celler som skal sammenlignes med hverandre, celle er en hvilken som helst enkeltcelle i området, og n er antall celler i området.

For eksempeldatasettet vårt kan formelen skrives i denne formen :

=COUNTIF(A2:C2, A2)=3

Hvis du sammenligner mange kolonner, kan COLUMNS-funksjonen hente cellenes antall (n) for deg automatisk:

=COUNTIF(A2:C2, A2)=COLUMNS(A2:C2)

Og HVIS-funksjonen vil hjelpe deg å returnere alt du vil ha som et resultat:

=IF(COUNTIF(A2:C2, A2)=3, "All match", "")

Stillingssensitiv formel for flere treff

Som med å sjekke to celler, bruk EXACT-funksjonen for å utføre den nøyaktige sammenligningen, inkludert store og små bokstaver. For å håndtere flere celler må EXACT nestes inn i OG-funksjonen slik:

AND(EXACT( område , celle ))

I Excel 365 og Excel 2021 , på grunn av støtte for dynamiske matriser, fungerer dette som en normal formel. I Excel 2019 og lavere, husk å trykke Ctrl + Shift + Enter for å gjøre det til en matriseformel .

For eksempel, for å sjekke om cellene A2:C2 inneholder de samme verdiene, en kasus -sensitiv formel er:

=AND(EXACT(A2:C2, A2))

I kombinasjon med IF har den denne formen:

=IF(AND(EXACT(A2:C2, A2)), "Yes", "No")

Sjekk om cellen samsvarer med en celle i området

For å se om en celle samsvarer med en celle i et gitt område, bruk en av følgende formler:

ELLER-funksjon

Det er best å brukes for kontroll av 2 - 3 celler.

ELLER( celle A = celle B , celle A = celle C , celle A = celle D , …)

Excel 365 og Excel 2021 forstår også denne syntaksen:

ELLER( celle = område )

I Excel 2019 og lavere, bør dette angis som en matriseformel ved å trykke Ctrl + Shift + Enter-snarveien.

COUNTIF-funksjon

COUNTIF( område , celle )>0

For å sjekke om A2 for eksempel er lik en celle i B2:D2, vil en av disse formlene gjøre:

=OR(A2=B2, A2=C2, A2=D2)

=OR(A2=B2:D2)

=COUNTIF(B2:D2, A2)>0

Hvis du bruker Excel 2019 eller lavere, husk å trykke Ctrl + Shift + Enter for å få den andre ELLER-formelen for å levere de riktige resultatene.

For å returnere Ja/Nei eller andre verdier du ønsker, vet du hva du skal gjøre - nest en av formlene ovenfor i den logiske testen av HVIS-funksjonen. For eksempel:

=IF(COUNTIF(B2:D2, A2)>0, "Yes", "No")

For mer informasjon, se Sjekk om verdien finnes i et område.

Sjekk om to områder er like

For å sammenligne to områder celle-for-celle og returnerer den logiske verdien TRUE hvis alle cellene i de tilsvarende posisjonene samsvarer, oppgi de like store områdene til den logiske testen av OG-funksjonen:

OG( område A = område B )

For for eksempel å sammenligne matrise A i B3:F6 og matrise B i B11:F14, er formelen:

=AND(B3:F6= B11:F14)

Til få Ja / Nei som resultat, bruk følgende IF AND-kombinasjon:

=IF(AND(B3:F6=B11:F14), "Yes", "No")

Slik bruker du If-match-formeleni Excel. Jeg takker for at du leser og håper å se deg på bloggen vår neste uke!

Øvningsarbeidsbok

Hvis cellene samsvarer i Excel - formeleksempler (.xlsx-fil)