De handleiding laat zien hoe u IFERROR in Excel kunt gebruiken om fouten op te vangen en te vervangen door een lege cel, een andere waarde of een aangepast bericht. U leert hoe u de IFERROR-functie kunt gebruiken met Vlookup en Index Match, en hoe deze zich verhoudt tot IF ISERROR en IFNA.

"Geef me een standplaats en ik zal de aarde verplaatsen", zei Archimedes ooit. "Geef me een formule en ik zal zorgen dat deze een fout oplevert", zou een Excel-gebruiker zeggen. In deze tutorial bekijken we niet hoe je fouten in Excel kunt teruggeven, maar leren we liever hoe je ze kunt voorkomen om je werkbladen schoon en je formules transparant te houden.

Excel IFERROR-functie - syntaxis en basisgebruik

De IFERROR-functie in Excel is ontworpen om fouten in formules en berekeningen op te vangen en te beheren. Meer in het bijzonder controleert IFERROR een formule, en indien deze op een fout uitkomt, retourneert het een andere waarde die u opgeeft; anders retourneert het het resultaat van de formule.

De syntaxis van de Excel IFERROR-functie is als volgt:

Waar:

• Waarde (vereist) - wat moet worden gecontroleerd op fouten. Het kan een formule, uitdrukking, waarde of celverwijzing zijn.
• Waarde_indien_fout (vereist) - wat moet worden teruggegeven als een fout wordt gevonden. Dit kan een lege tekenreeks (lege cel), een tekstbericht, een numerieke waarde, een andere formule of berekening zijn.

Als u bijvoorbeeld twee kolommen met getallen deelt, kunt u een heleboel verschillende fouten krijgen als een van de kolommen lege cellen, nullen of tekst bevat.

Om dat te voorkomen kunt u de IFERROR-functie gebruiken om fouten op te vangen en af te handelen zoals u dat wilt.

Indien fout, dan blanco

Geef een lege tekenreeks (") aan de value_if_error argument om een lege cel terug te geven als er een fout is gevonden:

=IFERROR(A2/B2, "")

Indien fout, toon dan een bericht

U kunt ook uw eigen bericht weergeven in plaats van de standaard foutnotatie van Excel:

=IFERROR(A2/B2, "Fout in de berekening")

5 dingen die u moet weten over de IFERROR-functie in Excel

1. De IFERROR-functie in Excel behandelt alle fouttypen, waaronder #DIV/0!, #N/A, #NAME?, #NULL!, #NUM!, #REF! en #VALUE!
2. Afhankelijk van de inhoud van de value_if_error argument kan IFERROR fouten vervangen door uw aangepaste tekstbericht, getal, datum of logische waarde, het resultaat van een andere formule, of een lege tekenreeks (lege cel).
3. Als de waarde argument een lege cel is, wordt het behandeld als een lege tekenreeks ('') maar geen fout.
4. IFERROR werd geïntroduceerd in Excel 2007 en is beschikbaar in alle volgende versies van Excel 2010, Excel 2013, Excel 2016, Excel 2019, Excel 2021 en Excel 365.
5. Om fouten in Excel 2003 en eerdere versies op te vangen, gebruikt u de functie ISERROR in combinatie met IF, zoals in dit voorbeeld.

IFERROR-formule voorbeelden

De volgende voorbeelden laten zien hoe u IFERROR in Excel kunt gebruiken in combinatie met andere functies om complexere taken uit te voeren.

Excel IFERROR met Vlookup

Een van de meest voorkomende toepassingen van de IFERROR-functie is de gebruikers vertellen dat de waarde die zij zoeken niet bestaat in de gegevensverzameling. Hiervoor wikkelt u een VLOOKUP-formule als volgt in IFERROR:

Als de opzoekwaarde niet voorkomt in de tabel waarin u zoekt, zou een gewone Vlookup-formule de foutmelding #N/A opleveren:

Om uw gebruikers gerust te stellen, kunt u VLOOKUP in IFERROR verpakken en een meer informatieve en gebruiksvriendelijke boodschap weergeven:

=IFERROR(VLOOKUP(A2, "Lookup table"!$A$2:$B$4, 2,FALSE), "Niet gevonden")

De onderstaande schermafbeelding toont deze Iferror-formule in Excel:

Als u alleen #N/A fouten wilt vangen, maar niet alle fouten, gebruik dan de IFNA-functie in plaats van IFERROR.

Bekijk voor meer Excel IFERROR VLOOKUP formule voorbeelden deze tutorials:

• Iferror met Vlookup om fouten op te vangen en af te handelen
• Hoe krijg ik het Nde voorkomen van de opzoekwaarde
• Hoe krijg ik alle occurrences van lookup waarde

Geneste IFERROR-functies voor opeenvolgende Vlookups in Excel

In situaties waarin u meerdere Vlookups moet uitvoeren op basis van de vraag of de vorige Vlookup geslaagd of mislukt is, kunt u twee of meer IFERROR-functies in elkaar nesten.

Stel dat u een aantal verkooprapporten hebt van regionale vestigingen van uw bedrijf, en u wilt een bedrag krijgen voor een bepaalde order-ID. Met A2 als de lookup-waarde in het huidige blad, en A2:B5 als het lookup-bereik in 3 lookup-bladen (Rapport 1, Rapport 2 en Rapport 3), gaat de formule als volgt:

=IFERROR(VLOOKUP(A2,'Report 1'!A2:B5,2,0),IFERROR(VLOOKUP(A2,'Report 2'!A2:B5,2,0),IFERROR(VLOOKUP(A2,'Report 3'!A2:B5,2,0),"not found"))

Het resultaat ziet er ongeveer zo uit:

Voor een gedetailleerde uitleg van de logica van de formule, zie Hoe opeenvolgende Vlookups doen in Excel.

IFERROR in matrixformules

Zoals u waarschijnlijk weet, zijn matrixformules in Excel bedoeld om meerdere berekeningen uit te voeren binnen één formule. Als u een matrixformule of expressie opgeeft die resulteert in een matrix in de waarde argument van de IFERROR-functie, geeft het een array van waarden voor elke cel in het opgegeven bereik. Het onderstaande voorbeeld toont de details.

Laten we zeggen dat je Totaal in kolom B en Prijs in kolom C, en je wilt berekenen Totale hoeveelheid Dit kan als volgt worden gedaan array formule, die elke cel van het bereik B2:B4 deelt door de overeenkomstige cel van het bereik C2:C4, en vervolgens de resultaten optelt:

=SUM($B$2:$B$4/$C$2:$C$4)

De formule werkt goed zolang het delerbereik geen nullen of lege cellen bevat. Als er ten minste één 0-waarde of lege cel is, wordt de fout #DIV/0! geretourneerd:

Om die fout op te lossen, doet u gewoon de deling binnen de IFERROR-functie:

=SUM(IFERROR($B$2:$B$4/$C$2:$C$4,0))

Wat de formule doet is in elke rij (100/2, 200/5 en 0/0) een waarde in kolom B delen door een waarde in kolom C en de resultaten teruggeven {50; 40; #DIV/0!}. De IFERROR-functie vangt alle #DIV/0! fouten op en vervangt ze door nullen. En dan telt de SUM-functie de waarden in de resulterende matrix {50; 40; 0} op en geeft het eindresultaat (50+40=90).

Opmerking: vergeet niet dat arrayformules moeten worden ingevuld met de sneltoets Ctrl + Shift + Enter.

IFERROR vs. IF ISERROR

Nu u weet hoe eenvoudig het is om de IFERROR functie in Excel te gebruiken, vraagt u zich misschien af waarom sommige mensen nog steeds de IF ISERROR combinatie gebruiken. Heeft deze functie voordelen ten opzichte van IFERROR? Geen. In de slechte oude tijd van Excel 2003 en lager, toen IFERROR nog niet bestond, was IF ISERROR de enige mogelijke manier om fouten op te vangen. In Excel 2007 en later is het gewoon een wat complexere manier omhetzelfde resultaat bereiken.

Om bijvoorbeeld Vlookup-fouten op te vangen, kunt u een van de onderstaande formules gebruiken.

In Excel 2007 - Excel 2016:

In alle Excel-versies:

Merk op dat u in de IF ISERROR VLOOKUP-formule twee keer moet Vlookup-en. In gewoon Engels kan de formule als volgt worden gelezen: Als Vlookup een fout oplevert, retourneer dan "Niet gevonden", anders voert u het Vlookup-resultaat uit.

En hier is een praktijkvoorbeeld van een Excel If Iserror Vlookup formule:

=IF(ISERROR(VLOOKUP(D2, A2:B5,2,FALSE)),"Niet gevonden", VLOOKUP(D2, A2:B5,2,FALSE ))

Voor meer informatie, zie Gebruik van de functie ISERROR in Excel.

IFERROR vs. IFNA

IFNA, geïntroduceerd met Excel 2013, is nog een functie om een formule te controleren op fouten. De syntaxis is vergelijkbaar met die van IFERROR:

Waarin verschilt IFNA van IFERROR? De IFNA-functie vangt op alleen #N/A fouten terwijl IFERROR alle soorten fouten afhandelt.

In welke situaties kunt u IFNA gebruiken? Wanneer het onverstandig is om alle fouten te verhullen. Wanneer u bijvoorbeeld werkt met belangrijke of gevoelige gegevens, wilt u wellicht gewaarschuwd worden voor mogelijke fouten in uw gegevensverzameling, en kunnen standaard Excel-foutmeldingen met het "#"-symbool levendige visuele indicatoren zijn.

Laten we eens kijken hoe u een formule kunt maken die het bericht "Niet gevonden" weergeeft in plaats van de N/A-fout, die verschijnt wanneer de opzoekwaarde niet aanwezig is in de gegevensreeks, maar andere Excel-fouten onder de aandacht brengt.

Stel dat u Qty. uit de opzoektabel naar de overzichtstabel wilt trekken, zoals in de onderstaande schermafbeelding. Gebruik van de Excel Iferror Vlookup formule zou een esthetisch mooi resultaat opleveren, dat technisch onjuist is omdat Citroenen bestaan in de opzoektabel:

Gebruik de IFNA-functie in Excel 2013 en Excel 2016 om #N/A op te vangen maar de fout #DIV/0 weer te geven:

=IFNA(VLOOKUP(F3,$A$3:$D$6,4,FALSE), "Niet gevonden")

Of de combinatie IF ISNA in Excel 2010 en eerdere versies:

=IF(ISNA(VLOOKUP(F3,$A$3:$D$6,4,FALSE)),"Niet gevonden", VLOOKUP(F3,$A$3:$D$6,4,FALSE))

De syntaxis van de formules IFNA VLOOKUP en IF ISNA VLOOKUP is vergelijkbaar met die van de eerder besproken IFERROR VLOOKUP en IF ISERROR VLOOKUP.

Zoals in onderstaande schermafbeelding te zien is, geeft de Ifna Vlookup-formule alleen "Niet gevonden" terug voor het item dat niet aanwezig is in de opzoektabel ( Perziken ). Citroenen toont het #DIV/0! wat aangeeft dat onze opzoektabel een fout door delen door nul bevat:

Zie voor meer details IFNA-functie gebruiken in Excel.

Beste praktijken voor het gebruik van IFERROR in Excel

Inmiddels weet u al dat de IFERROR-functie de gemakkelijkste manier is om fouten in Excel op te vangen en deze te maskeren met lege cellen, nulwaarden of eigen aangepaste berichten. Dat betekent echter niet dat u elke formule moet omwikkelen met foutafhandeling. De volgende eenvoudige aanbevelingen kunnen u helpen het evenwicht te bewaren.

1. Trap geen fouten af zonder reden.
2. Wikkel het kleinst mogelijke deel van een formule in IFERROR.
3. Om alleen specifieke fouten te behandelen, gebruikt u een foutbehandelingsfunctie met een kleiner bereik:
   • IFNA of IF ISNA om alleen #N/A fouten op te vangen.
   • ISERR om alle fouten op te vangen behalve #N/A.

Dit is hoe u de IFERROR-functie in Excel gebruikt om fouten op te vangen en af te handelen. Om de formules die in deze tutorial worden besproken nader te bekijken, kunt u onze voorbeeld IFERROR Excel-werkmap downloaden. Ik dank u voor het lezen en hoop u volgende week op onze blog te zien.