Kennsluefnið kynnir XLOOKUP - nýja aðgerðina fyrir lóðrétta og lárétta uppflettingu í Excel. Vinstri uppfletting, síðasta samsvörun, Vlookup með mörgum viðmiðum og margt fleira sem áður þurfti að hafa eldflaugafræðigráðu til að ná er nú orðið eins auðvelt og ABC.

Hvenær sem þú þarft að fletta upp í Excel , hvaða aðgerð myndir þú nota? Er það hornsteinn VLOOKUP eða lárétt systkini þess HLOOKUP? Í flóknari tilviki, munt þú treysta á kanónísku INDEX MATCH samsetninguna eða skuldbinda starfið til Power Query? Góðu fréttirnar eru þær að þú hefur ekki valið lengur - allar þessar aðferðir eru að rýma fyrir öflugri og fjölhæfari arftaka, XLOOKUP aðgerðina.

Hvernig er XLOOKUP betra? Á marga vegu! Það getur horft lóðrétt og lárétt, til vinstri og fyrir ofan, leitað með mörgum forsendum og jafnvel skilað heilum dálki eða röð af gögnum, ekki bara einu gildi. Það hefur tekið Microsoft meira en 3 áratugi, en loksins hefur þeim tekist að hanna öfluga aðgerð sem sigrar margar pirrandi villur og veikleika VLOOKUP.

Hvað er málið? Æ, það er einn. XLOOKUP aðgerðin er aðeins fáanleg í Excel fyrir Microsoft 365, Excel 2021 og Excel fyrir vefinn.

Excel XLOOKUP aðgerð - setningafræði og notar

XLOOKUP aðgerðina í Excel leitar á sviði eða fylki að tilteknu gildi og skilar tengdu gildi úr öðrum dálki. Það getur flett upp bæðisækja allar upplýsingar sem varða sölumanninn sem er áhugaverður (F2). Það sem þú þarft að gera er að gefa upp svið, ekki einn dálk eða röð, fyrir return_array rökin:

=XLOOKUP(F2, A2:A7, B2:D7)

Þú slærð inn formúluna efst til vinstri reit niðurstöðusviðsins og Excel hellir niðurstöðunum sjálfkrafa niður í aðliggjandi auðar reiti. Í okkar tilviki inniheldur skilafylkingin (B2:D7) 3 dálka ( Dagsetning , Item og Upphæð ), og öllum þremur gildunum er skilað inn á sviðið G2:I2.

Ef þú vilt frekar raða niðurstöðunum lóðrétt í dálk skaltu hreiðra XLOOKUP inn í TRANSPOSE fallið til að snúa skilaða fylkinu:

=TRANSPOSE(XLOOKUP(G1, A2:A7, B2:D7))

Á svipaðan hátt geturðu skilað heilum dálki af gögnum, segjum dálkinn Upphæð . Fyrir þetta skaltu nota reit F1 sem inniheldur "Amount" sem uppflettingargildi , sviðið A1:D1 sem inniheldur dálkahausana sem uppflettifylki og sviðið A2:D7 sem inniheldur öll gögn sem return_array .

=XLOOKUP(F1, A1:D1, A2:D7)

Athugið. Vegna þess að mörg gildi eru fyllt út í nálægum hólfum, vertu viss um að þú hafir nóg af auðum hólfum til hægri eða niður. Ef Excel getur ekki fundið nógu margar tómar frumur, þá er #SPILL! villa kemur upp.

Ábending. XLOOKUP getur ekki aðeins skilað mörgum færslum heldur einnig skipt þeim út fyrir önnur gildi sem þú tilgreinir. Dæmi um slíka magnskipti er að finna hér: Hvernig á að leita og skipta út mörgum gildum með XLOOKUP.

XLOOKUP meðmörg skilyrði

Annar stór kostur við XLOOKUP er að það meðhöndlar fylki innbyggt. Vegna þessa hæfileika geturðu metið mörg viðmið beint í leitarfylki röksemdinni:

Hvernig þessi formúla virkar : Niðurstaða hvers viðmiðunarprófs er fylki af RÖNT og FALSK gildi. Margföldun fylkanna breytir TRUE og FALSE í 1 og 0, í sömu röð, og framleiðir endanlega uppflettifylki. Eins og þú veist gefur það alltaf núll að margfalda með 0, þannig að í uppflettifylki eru aðeins atriðin sem uppfylla öll skilyrðin táknuð með 1. Og vegna þess að uppflettingargildið okkar er „1“ tekur Excel fyrsta „1“ í uppflettifylki (fyrsta samsvörun) og skilar gildinu frá afturfylki í sömu stöðu.

Til að sjá formúluna í aðgerð skulum við draga upphæð úr D2:D10 ( skilafjöldi ) með eftirfarandi skilyrðum:

• Forsendur1 (dagsetning) = G1
• Forsendur2 (sölumaður) = G2
• Forsendur3 (hlutur) = G3

Með dagsetningum í A2:A10 ( viðmiðunarsvið1 ), nöfnum sölumanna í B2:B10 ( viðmiðunarsvið2 ) og hlutum í C2:C10 ( criteria_range3 ), tekur formúlan þessa lögun:

=XLOOKUP(1, (B2:B10=G1) * (A2:A10=G2) * (C2:C10=G3), D2:D10)

Þó að Excel XLOOKUP aðgerðin vinni fylki, virkar hún sem venjuleg formúla og er lokið með venjulegu Enterásláttur.

XLOOKUP formúlan með mörgum viðmiðum er ekki takmörkuð við "jafn við" skilyrði. Þér er frjálst að nota aðra rökræna rekstraraðila líka. Til dæmis, til að sía pantanir sem gerðar eru á dagsetningu í G1 eða fyrr, settu "<=G1" í fyrstu viðmiðunina:

=XLOOKUP(1, (A2:A10<=G1) * (B2:B10=G2) * (C2:C10=G3), D2:D10)

Tvöfalt XLOOKUP

Til að finna gildi á skurðpunkti ákveðinnar línu og dálks, framkvæma svokallaða tvíflettingu eða fylkisuppflettingu . Já, Excel XLOOKUP getur gert það líka! Þú hreiður einfaldlega einni aðgerð inni í annarri:

Hvernig þessi formúla virkar : Formúlan er byggð á getu XLOOKUP til að skila heilli röð eða dálki. Innri aðgerðin leitar að uppflettigildi sínu og skilar dálki eða röð af tengdum gögnum. Það fylki fer í ytri fallið sem aftur_fylki .

Fyrir þetta dæmi ætlum við að finna sölu tiltekins sölumanns innan ákveðins ársfjórðungs. Til þess sláum við inn uppflettingargildin í H1 (nafn sölumanns) og H2 (fjórðungur), og gerum tvíhliða Xlookup með eftirfarandi formúlu:

=XLOOKUP(H1, A2:A6, XLOOKUP(H2, B1:E1, B2:E6))

Eða öfugt :

=XLOOKUP(H2, B1:E1, XLOOKUP(H1, A2:A6, B2:E6))

Þar sem A2:A6 eru nöfn sölumanna, B1:E1 eru fjórðungar (dálkahausar) og B2:E6 eru gagnagildi.

Tvíhliða leit er einnig hægt að framkvæma með INDEX Match formúlu og í anokkrar aðrar leiðir. Fyrir frekari upplýsingar, vinsamlega sjá Tvíhliða leit í Excel.

Ef Villa XLOOKUP

Þegar uppflettingargildið finnst ekki, skilar Excel XLOOKUP #N/A villu. Nokkuð kunnuglegt og skiljanlegt fyrir sérfræðinga notendur, það gæti verið frekar ruglingslegt fyrir byrjendur. Til að skipta út venjulegu villumerkinu með notendavænum skilaboðum skaltu slá inn þinn eigin texta í 4. rifrildið sem heitir if_not_found .

Aftur í fyrsta dæmið sem fjallað er um í þessari kennslu. Ef einhver setur inn ógilt úthafsnafn í E1 mun eftirfarandi formúla segja þeim beinlínis að "Engin samsvörun fannst":

=XLOOKUP(E1, A2:A6, B2:B6, "No match is found")

Athugasemdir:

• if_not_found röksemdin fangar aðeins #N/A villur, ekki allar villur.
• #N/A villur er einnig hægt að meðhöndla með IFNA og VLOOKUP, en setningafræðin er aðeins flóknari og formúla er lengri.

Lástastafir og hástafir XLOOKUP

Sjálfgefið er að XLOOKUP fallið meðhöndlar lágstafi og hástafi sem sömu stafi. Til að gera það há- og hástöfum næmt, notaðu EXACT fallið fyrir uppflettisfylki rökin:

Hvernig þessi formúla virkar : EXACT fallið ber saman uppflettingargildið á móti hverju gildi í uppflettingarfylki og skilar TRUE ef þau eru nákvæmlega eins með stafina með háum og háum, FALSE annars. Þetta fylki af rökréttum gildum fer í leitarfylki rök XLOOKUP. Fyrir vikið leitar XLOOKUP að TRUE gildinu í fylkinu hér að ofan og skilar samsvörun frá skilafylkingunni.

Til dæmis, til að fá verðið frá B2:B7 ( return_array ) fyrir hluturinn í E1 ( leit_gildi) , formúlan í E2 er:

=XLOOKUP(TRUE, EXACT(E1, A2:A7), B2:B7, "Not found")

Athugið. Ef það eru tvö eða fleiri nákvæmlega sömu gildi í uppflettifylkingunni (þar á meðal stafina) er fyrsta samsvörunin sem fannst skilað.

Excel XLOOKUP virkar ekki

Ef formúlan þín virkar ekki rétt eða leiðir til villu er það líklega af eftirfarandi ástæðum:

XLOOKUP er ekki í boði í Excel

XLOOKUP aðgerðin er ekki afturábaksamhæf. Það er aðeins fáanlegt í Excel fyrir Microsoft 365 og Excel 2021 og mun ekki birtast í fyrri útgáfum.

XLOOKUP skilar rangri niðurstöðu

Ef augljóslega rétta Xlookup formúlan þín skilar rangu gildi, eru líkurnar á því að uppflettingar- eða skilasviðið „breyttist“ þegar formúlan var afrituð niður eða þvert yfir. Til að koma í veg fyrir að þetta gerist, vertu viss um að læsa alltaf báðum sviðum með algerum frumutilvísunum (eins og $A$2:$A$10).

XLOOKUP skilar #N/A villu

An #N /Villa þýðir bara að uppflettingargildið finnst ekki. Til að laga þetta skaltu reyna að leita að áætlaðri samsvörun eða láta notendur þína vita að engin samsvörun finnst.

XLOOKUP skilar #VALUE villa

A #VALUE! villa kemur upp ef leitar- og skilafylki eru ósamrýmanlegmál. Til dæmis er ekki hægt að leita í láréttu fylki og skila gildum úr lóðréttu fylki.

XLOOKUP skilar #REF villa

A #REF! villa birtist þegar flett er upp á milli tveggja mismunandi vinnubóka, þar af ein lokuð. Til að laga villuna skaltu einfaldlega opna báðar skrárnar.

Eins og þú sást nýlega hefur XLOOKUP marga frábæra eiginleika sem gera það að aðgerðinni fyrir nánast hvaða uppflettingu sem er í Excel. Ég þakka þér fyrir lesturinn og vonast til að sjá þig á blogginu okkar í næstu viku!

Æfingabók til niðurhals

Excel XLOOKUP formúludæmi (.xlsx skrá)

Setjafræði XLOOKUP fallsins er sem hér segir:

Fyrstu 3 rökin eru nauðsynleg og síðustu þrjú eru valfrjáls.

• Uppflettingargildi - gildið til leita að.
• Upplitsfylki - svið eða fylki þar sem leita á.
• Return_array - svið eða fylki sem skila skal gildum úr.
• Ef_ekki_finnst [valfrjálst] - gildið sem á að skila ef engin samsvörun finnst. Ef því er sleppt er #N/A villa skilað.
• Passunarhamur [valfrjálst] - samsvörunargerðin sem á að framkvæma:
  • 0 eða sleppt (sjálfgefið) - nákvæm samsvörun . Ef hún finnst ekki er #N/A villa skilað.
  • -1 - nákvæm samsvörun eða næst minni. Ef nákvæm samsvörun finnst ekki er næsta minna gildi skilað.
  • 1 - nákvæm samsvörun eða næst stærra. Ef nákvæm samsvörun finnst ekki er næsta stærra gildi skilað.
  • 2 - samsvörun með algildi.
• Search_mode [valfrjálst] - leitarstefna:
  • 1 eða sleppt (sjálfgefið) - til að leita frá fyrsta til síðasta.
  • -1 - til að leita í öfugri röð, frá síðasta til fyrsta.
  • 2 - tvíundarleit á gögnum raðað stígandi.
  • -2 - tvíundarleit á gögnum raðað lækkandi.

  Samkvæmt Microsoft, tvíundarleitleit er innifalið fyrir lengra komna notendur. Það er sérstakt reiknirit sem finnur staðsetningu uppflettingargildis innan flokkaðs fylkis með því að bera það saman við miðhluta fylkisins. Tvíundarleit er miklu hraðari en venjuleg leit en virkar aðeins rétt á flokkuðum gögnum.

Grunnuppskrift XLOOKUP

Til að öðlast meiri skilning skulum við búa til Xlookup formúlu í sinni einföldustu mynd til að framkvæma nákvæma uppflettingu. Til þess þurfum við aðeins fyrstu 3 rökin.

Segjum sem svo að þú hafir yfirlitstöflu með upplýsingum um höfin fimm á jörðinni. Þú vilt fá flatarmál tiltekins sjávarinntaks í F1 ( leit_gildi ). Með úthafsnöfnunum í A2:A6 ( útlitsfylki ) og svæði í C2:C6 ( afkomufylki ) er formúlan svona:

=XLOOKUP(F1, A2:A6, C2:C6)

Þýtt á venjulega ensku segir það: leitaðu að F1 gildinu í A2:A6 og skilaðu gildi frá C2:C6 í sömu röð. Engar dálkavísitölur, engin flokkun, engin önnur fáránleg einkenni Vlookup! Það virkar bara :)

XLOOKUP vs VLOOKUP í Excel

Í samanburði við hefðbundna VLOOKUP hefur XLOOKUP marga kosti. Á hvaða hátt er það betra en VLOOKUP? Hér er listi yfir bestu 10 eiginleikana sem sprengja hurðirnar af öllum öðrum uppflettiaðgerðum í Excel:

1. Lóðrétt og lárétt uppfletting . XLOOKUP aðgerðin fékk nafn sitt vegna getu þess til að fletta upp bæði lóðrétt oglárétt.
2. Horfðu í hvaða átt sem er: hægri, vinstri, neðst eða upp . Þó VLOOKUP geti aðeins leitað í dálknum lengst til vinstri og HLOOKUP í efstu röðinni, þá hefur XLOOKUP engar slíkar takmarkanir. Hin alræmda vinstri uppfletting í Excel er ekki sársauka lengur!
3. Nákvæm samsvörun sjálfgefið . Í flestum tilfellum muntu leita að nákvæmri samsvörun og XLOOKUP skilar henni sjálfgefið (ólíkt VLOOKUP fallinu sem sjálfgefið er áætluð samsvörun). Auðvitað geturðu fengið XLOOKUP til að framkvæma áætlaða samsvörun líka ef þörf krefur.
4. Hlutasamsvörun með jokertáknum . Þegar þú þekkir aðeins hluta af uppflettingargildinu, ekki öllu, kemur samsvörun algildis sér vel.
5. Leita í öfugri röð . Fyrr, til að fá síðasta tilvikið, þurftir þú að snúa við röð upprunagagna þinna. Nú stillirðu einfaldlega search_mode röksemdin á -1 til að þvinga Xlookup formúluna þína til að leita að aftan og skila síðustu samsvörun.
6. Skilaðu mörgum gildum . Með því að vinna með return_array röksemdinni geturðu dregið heila röð eða dálk af gögnum sem tengjast uppflettigildinu þínu.
7. Leita með mörgum skilyrðum . Excel XLOOKUP meðhöndlar fylki innbyggt, sem gerir það mögulegt að framkvæma leit með mörgum forsendum.
8. Ef villuvirkni . Hefð er fyrir því að við notum IFNA aðgerðina til að fanga #N/A villur. XLOOKUP inniheldur þessa virkni í if_not_found rök sem gerir kleift að gefa út eigin texta ef engin gild samsvörun finnst.
9. Innsetningar/eyðingar dálka . Eitt af pirrandi vandamálunum við VLOOKUP er að það að bæta við eða fjarlægja dálka brýtur formúlu vegna þess að skiladálkurinn er auðkenndur með vísitölu hans. Með XLOOKUP gefur þú upp skilasviðið, ekki töluna, sem þýðir að þú getur sett inn og fjarlægt eins marga dálka og þú þarft án þess að brjóta neitt.
10. Betri afköst . VLOOKUP gæti hægt á vinnublöðunum þínum vegna þess að það inniheldur alla töfluna í útreikningum, sem leiðir til vinnslu mun fleiri fruma en raunverulega þarf. XLOOKUP sér aðeins um uppflettingar og skila fylki sem það veltur svo sannarlega á.

Hvernig á að nota XLOOKUP í Excel - formúludæmi

Eftirfarandi dæmi sýna gagnlegustu XLOOKUP eiginleikana í aðgerð. Að auki munt þú uppgötva nokkrar óléttar notkunaraðferðir sem munu færa Excel uppflettingarhæfileika þína á nýtt stig.

Fletta upp lóðrétt og lárétt

Microsoft Excel hafði áður tvær aðgerðir fyrir mismunandi uppflettingu gerðir sem hver um sig hefur sína setningafræði og notkunarreglur: VLOOKUP til að líta lóðrétt í dálki og HLOOKUP til að líta lárétt í röð.

XLOOKUP aðgerðin getur gert bæði með sömu setningafræði. Munurinn liggur í því hvað þú gefur upp fyrir uppflettingar- og skilafylki.

Fyrir v-leit, gefðu upp dálka:

=XLOOKUP(E1, A2:A6, B2:B6)

Fyrirh-leit, sláðu inn línur í stað dálka:

=XLOOKUP(I1, B1:F1, B2:F2)

Vinstri uppfletting framkvæmd með upprunalegri gerð

Í fyrri útgáfum af Excel, INDEX MATCH formúla var eina áreiðanlega leiðin til að horfa til vinstri eða fyrir ofan. Nú þarftu ekki lengur að sameina tvær aðgerðir þar sem ein myndi nægja. Tilgreindu bara uppflettingarfylkinguna, og XLOOKUP mun sjá um það án vandræða óháð staðsetningu þess.

Sem dæmi skulum við bæta Rank dálknum vinstra megin við sýnistöfluna okkar. Markmiðið er að fá stöðu sjávarinntaksins í F1. VLOOKUP myndi hrasa hér vegna þess að það getur aðeins skilað gildi úr dálki hægra megin við uppflettisdálkinn. Xlookup formúla tekst auðveldlega:

=XLOOKUP(F1, B2:B6, A2:A6)

Á svipaðan hátt geturðu horft hér að ofan þegar leitað er lárétt í röðum.

XLOOKUP með nákvæmri og áætluðu samsvörun

Samsvörunarhegðun er stjórnað af 5. röksemdinni sem kallast match_mode . Sjálfgefið er að nákvæm samsvörun er framkvæmd.

Vinsamlegast athugaðu að jafnvel þegar þú velur áætlaða samsvörun ( match_mode stillt á 1 eða -1), mun aðgerðin samt leita að nákvæmri samsvörun passa fyrst. Munurinn er í því hvað það skilar ef nákvæmt uppflettingargildi finnst ekki.

Match_mode argument:

• 0 eða sleppt - nákvæm samsvörun; ef ekki fannst - #N/A villa.
• -1 - nákvæm samsvörun; ef ekki finnst - næsti minni hlutur.
• 1 - nákvæm samsvörun; ef ekki finnst- næst stærri hlutur.

Nákvæm samsvörun XLOOKUP

Þetta er valkosturinn sem þú notar líklega 99% af þeim tíma sem þú flettir upp í Excel. Þar sem nákvæm samsvörun er sjálfgefin hegðun XLOOKUP geturðu sleppt match_mode og gefið aðeins upp fyrstu 3 nauðsynlegu rökin.

Í sumum tilfellum mun nákvæm samsvörun hins vegar ekki virka. Dæmigerð atburðarás er þegar uppflettitaflan þín inniheldur ekki öll gildin, heldur frekar „áfanga“ eða „mörk“ eins og magnbundinn afslátt, sölumiðaða þóknun o.s.frv.

Útsýnistaflan okkar sýnir fylgnina á milli prófskora og einkunna. Eins og þú sérð á skjáskotinu hér að neðan, virkar nákvæm samsvörun aðeins þegar stig tiltekins nemanda passar nákvæmlega við gildið í uppflettitöflunni (eins og Christian í röð 3). Í öllum öðrum tilvikum er #N/A villa skilað.

=XLOOKUP(F2, $B$2:$B$6, $C$2:$C$6)

Til að fá einkunnirnar í stað #N/A villu þurfum við til að leita að áætlaðri samsvörun eins og sýnt er í næsta dæmi.

Áætluð samsvörun XLOOKUP

Til að framkvæma áætlaða uppflettingu skaltu stilla match_mode röksemdin á annað hvort -1 eða 1 , allt eftir því hvernig gögnin þín eru skipulögð.

Í okkar tilviki listar uppflettingartaflan upp neðri mörk einkunna. Þannig að við stillum match_mode á -1 til að leita að næsta lægra gildi þegar nákvæm samsvörun finnst ekki:

=XLOOKUP(F11, $B$11:$B$15, $C$11:$C$15, ,-1)

Til dæmis, Brian hefur einkunnina 98 (F2). Formúlan leitar að þessu uppflettigildi í B2:B6en finn það ekki. Síðan leitar það að næsta minni atriði og finnur 90, sem samsvarar einkunn A:

Ef uppflettitaflan okkar innihélt efri mörk einkunnanna, myndum við setja match_mode til 1 til að leita að næsta stærri hlut ef nákvæm samsvörun mistekst:

=XLOOKUP(F2, $B$2:$B$6, $C$2:$C$6, ,1)

Formúlan leitar að 98 og finnur hana aftur ekki. Að þessu sinni reynir það að finna næsta stærra gildi og fær 100, sem samsvarar einkunn A:

Ábending. Þegar Xlookup formúla er afrituð í margar reiti skaltu læsa uppflettingunni eða skila sviðum með algerum frumutilvísunum (eins og $B$2:$B$6) til að koma í veg fyrir að þær breytist.

XLOOKUP með hluta samsvörun (algildisstákn)

Til að framkvæma leit að hluta skaltu stilla match_mode röksemdin á 2, sem gefur XLOOKUP aðgerðinni fyrirmæli um að vinna úr algildisstöfunum:

• Stjarna (*) - táknar hvaða röð stafa sem er.
• Spuramerki (?) - táknar hvaða staka staf sem er.

Til að sjá hvernig það virkar , vinsamlegast skoðaðu eftirfarandi dæmi. Í dálki A ertu með nokkrar snjallsímagerðir og, í dálki B, rafhlöðugetu þeirra. Þú ert forvitinn um rafhlöðu ákveðins snjallsíma. Vandamálið er að þú ert ekki viss um að þú getir slegið inn heiti líkansins nákvæmlega eins og það birtist í dálki A. Til að vinna bug á þessu skaltu slá inn hlutann sem er örugglega til staðar og skipta út stöfunum sem eftir eru með jokertáknum.

Til dæmis, að fáupplýsingar um rafhlöðuna á iPhone X, notaðu þessa formúlu:

=XLOOKUP("*iphone X*", A2:A8, B2:B8, ,2)

Eða sláðu inn þekktan hluta uppflettigildisins í einhverjum reit og tengdu frumutilvísunina við algildisstafina:

=XLOOKUP("*"&E1&"*", A2:A8, B2:B8, ,2)

XLOOKUP í öfugri röð til að fá síðasta tilvik

Ef taflan þín inniheldur nokkur tilvik af uppflettingargildinu gætirðu stundum þurft til að skila síðasta leik . Til að gera það skaltu stilla Xlookup formúluna þína til að leita í öfugri röð.

Leiðarstefnunni er stjórnað með 6. röksemdinni sem heitir search_mode :

• 1 eða sleppt (sjálfgefið) - leitar frá fyrsta til síðasta gildi, þ.e.a.s. frá toppi til botns með lóðréttri uppflettingu eða vinstri til hægri með láréttri uppflettingu.
• -1 - leitar í öfugri röð frá síðasta til fyrsta gildi .

Sem dæmi skulum við skila síðustu sölu sem ákveðinn sölumaður gerði. Til þess settum við saman fyrstu þrjár nauðsynlegu rökin (G1 fyrir útlitsgildi , B2:B9 fyrir uppflettifylki og D2:D9 fyrir afturfylki ) og setjum - 1 í 5. röksemd:

=XLOOKUP(G1, B2:B9, D2:D9, , ,-1)

Beint og auðvelt, er það ekki?

XLOOKUP til að skila mörgum dálkum eða línum

Einn ótrúlegur eiginleiki XLOOKUP er hæfileikinn til að skila fleiri en einu gildi sem tengist sömu samsvörun. Allt er gert með stöðluðu setningafræðinni og án frekari aðgerða!

Út frá töflunni hér að neðan, að því gefnu að þú viljir