Í síðustu greinum höfum við fjallað um mismunandi textaaðgerðir - þær sem eru notaðar til að vinna með textastrengi. Í dag er áhersla okkar á RIGHT aðgerðina, sem er hönnuð til að skila tilteknum fjölda stafa frá hægri hlið strengs. Eins og aðrar Excel-textaaðgerðir er RIGHT mjög einfalt og einfalt, en engu að síður hefur það nokkra óljósa notkun sem gæti reynst gagnleg í vinnu þinni.

setningafræði Excel RIGHT aðgerða

RIGHT fallið í Excel skilar tilgreindum fjölda stafa frá enda textastrengs.

Setjafræði RIGHT fallsins er sem hér segir:

Hvar :

• Texti (áskilið) - textastrengurinn sem þú vilt draga stafi úr.
• Num_chars (valfrjálst) - the fjöldi stafa til að draga út, byrjað á stafnum lengst til hægri.
  • Ef fjöldi_stöfum er sleppt, er 1 síðasti stafur strengsins skilað (sjálfgefið).
  • Ef fjöldi_stafir er meiri en heildarfjöldi stöfum í strengnum eru allir stafir skilaðir.
  • Ef fjöldi_stafir er neikvæð tala, þá skilar Hægri formúla #VALUE! villa.

Til dæmis, til að draga síðustu 3 stafina úr strengnum í reit A2, notaðu þessa formúlu:

=RIGHT(A2, 3)

Niðurstaðan gæti litið svipað út og þessi:

Mikilvægt athugið! Excel RIGHT aðgerðin skilar alltaf textastreng , jafnvel þótt upprunalega gildið sé tala. Til að þvinga Hægri formúlu til að gefa út tölu skaltu nota hana ásamt VALUE fallinu eins og sýnt er í þessu dæmi.

Hvernig á að nota RIGHT fall í Excel - formúludæmi

Í raunveruleikanum vinnublöð, Excel RIGHT aðgerðin er sjaldan notuð ein og sér. Í flestum tilfellum muntu nota það ásamt öðrum Excel aðgerðum sem hluta af flóknari formúlum.

Hvernig á að fá undirstreng sem kemur á eftir ákveðnum staf

Ef þú vilt draga út undirstreng sem fylgir ákveðnum staf, notaðu annað hvort SEARCH eða FIND aðgerðina til að ákvarða staðsetningu þess stafs, dragðu staðsetninguna frá heildarlengd strengsins sem LEN aðgerðin skilar og dragðu þá marga stafi frá hægri hlið upprunalega strengsins.

Segjum, reit A2 inniheldur fornafn og eftirnafn aðskilið með bili og þú miðar að því að draga eftirnafnið í annan reit. Taktu bara almennu formúluna hér að ofan og þú setur A2 í staðinn fyrir streng og " " (bil) í hraða stafa:

=RIGHT(A2,LEN(A2)-SEARCH(" ",A2))

Formúlan mun gefa eftirfarandi niðurstöðu:

Á svipaðan hátt geturðu fengið undirstreng sem kemur á eftir hvaða öðrum staf sem er, t.d. kommu, semíkomma, bandstrik osfrv. Til dæmis, til að draga út undirstreng sem kemur á eftir bandstrik,notaðu þessa formúlu:

=RIGHT(A2,LEN(A2)-SEARCH("-",A2))

Niðurstaðan mun líta svipað út:

Hvernig á að draga út undirstreng eftir síðasta tilvik afmörkunar

Þegar að takast á við flókna strengi sem innihalda mörg tilvik af sama afmörkun, gætir þú oft þurft að sækja textann hægra megin við síðasta afmörkunartilvik. Til að gera hlutina auðveldari að skilja skaltu skoða eftirfarandi upprunagögn og æskilega niðurstöðu:

Eins og þú sérð á skjáskotinu hér að ofan inniheldur dálkur A lista yfir villur. Markmið þitt er að draga villulýsinguna sem kemur á eftir síðasta tvípunktinum í hverjum streng. Auka fylgikvilli er að upprunalegu strengirnir geta innihaldið mismunandi fjölda afmörkunartilvika, t.d. A3 inniheldur 3 tvípunkta á meðan A5 bara einn.

Lykillinn að því að finna lausn er að ákvarða staðsetningu síðasta afmörkunarmerkis í upprunastrengnum (síðasta tilvik tvípunkts í þessu dæmi). Til að gera þetta þarftu að nota handfylli af mismunandi aðgerðum:

1. Fáðu fjölda afmarka í upprunalega strengnum. Það er auðveldur hluti:
   • Í fyrsta lagi reiknarðu út heildarlengd strengsins með því að nota LEN fallið: LEN(A2)
   • Í öðru lagi reiknar þú lengd strengsins án afmarka með því að nota SUBSTITUTE fall sem kemur í stað allra tilvika af ristli með engu: LEN(SUBSTITUTE(A2,":",""))
   • Að lokum dregurðu frá lengd upprunalega strengsinsán afmarka frá heildarlengd strengsins: LEN(A2)-LEN(SUBSTITUTE(A2,":",""))

   Til að tryggja að formúlan virki rétt geturðu slegið hana inn í aðskilin reit, og útkoman verður 2, sem er fjöldi ristils í reiti A2.

2. Skiptu út síðasta afmörkun fyrir einhvern einstakan staf. Til þess að draga út textann sem kemur á eftir síðasta afmörkunarmerkinu í strengnum þurfum við að "merkja" lokatilvik afmarkans á einhvern hátt. Til þess skulum við skipta út síðasta tilviki ristils fyrir staf sem kemur hvergi fyrir í upprunalegu strengjunum, til dæmis með pundsmerki (#).

   Ef þú þekkir setningafræði Excel SUBSTITUTE fallsins, gætirðu muna að hún hefur 4. valkvæða frumbreytu (instance_num) sem gerir aðeins kleift að skipta út tilteknu tilviki tilgreinds stafs. Og þar sem við höfum þegar reiknað út fjölda afmörkunarmerkja í strengnum, gefðu einfaldlega upp fallið hér að ofan í fjórðu viðfangsefni annars SUBSTITUTE falls:

   =SUBSTITUTE(A2,":","#",LEN(A2)-LEN(SUBSTITUTE(A2,":","")))

   Ef þú setur þessa formúlu í sérstakan reit , það myndi skila þessum streng: ERROR:432#Connection time out

3. Fáðu staðsetningu síðasta afmörkunarmerkisins í strengnum. Það fer eftir því hvaða staf þú skipti um síðasta afmörkun fyrir, notaðu annað hvort SEARCH eða FIND sem er há- og hástafanæm til að ákvarða staðsetningu þess stafs í strengnum. Við skiptum út síðasta ristlinummeð # tákninu, þannig að við notum eftirfarandi formúlu til að finna út staðsetningu hennar:

   =SEARCH("#", SUBSTITUTE(A2,":","#",LEN(A2)-LEN(SUBSTITUTE(A2,":",""))))

   Í þessu dæmi skilar formúlan 10, sem er staðsetning # í strengnum sem skipt er út.

4. Skiltu undirstreng hægra megin við síðasta afmörkun. Nú þegar þú veist staðsetningu síðasta afmörkunarmerkisins í streng, þarftu bara að draga þá tölu frá heildarlengd strengsins og fá RÉTT fall til að skila þessum mörgum stöfum frá enda upphaflega strengsins:

   =RIGHT(A2,LEN(A2)-SEARCH("$",SUBSTITUTE(A2,":","$",LEN(A2)-LEN(SUBSTITUTE(A2,":","")))))

Eins og sést á skjámyndinni hér að neðan virkar formúlan fullkomlega:

Ef þú ert að vinna með stórt gagnasafn þar sem mismunandi frumur geta innihaldið mismunandi afmörkun, gætirðu viljað að setja ofangreinda formúlu inn í IFERROR fallið til að koma í veg fyrir hugsanlegar villur:

=IFERROR(RIGHT(A2,LEN(A2)-SEARCH("$",SUBSTITUTE(A2,":","$",LEN(A2)-LEN(SUBSTITUTE(A2,":",""))))), A2)

Ef tiltekinn strengur inniheldur ekki eitt tilvik af tilgreindu afmörkunarmerki, verður upprunalega strengnum skilað, eins og í röð 6 í skjámyndinni hér að neðan:

Hvernig á að fjarlægja fyrstu N stafina úr streng

Fyrir utan að draga út undirstreng úr enda strengs, kemur Excel RIGHT aðgerðin að góðum notum í aðstæðum þegar þú vilt fjarlægja ákveðinn fjölda stafa frá upphafi strengsins.

Í gagnasafninu sem notað var í fyrri Í þessu tilfelli gætirðu viljað fjarlægja orðið „VILLA“ sem birtist í upphafi hvers strengs og skilja aðeins eftir villunúmerið og lýsinguna. Að hafa þaðbúið, dragðu fjölda stafa sem á að fjarlægja frá heildarlengd strengsins og gefðu þá tölu inn í fjölda_stafir rökin í Excel RIGHT fallinu:

Í þessu dæmi fjarlægjum við fyrstu 6 stafi (5 stafir og tvípunktur) úr textastrengnum í A2, þannig að formúlan okkar er eins og eftirfarandi:

=RIGHT(A2, LEN(A2)-6)

Getur Excel RIGHT fallið skilað tölu?

Eins og getið er um í upphafi þessa kennsluefnis, þá skilar RIGHT fallið í Excel alltaf textastreng jafnvel ef upprunalega gildið er tala. En hvað ef þú vinnur með tölulegt gagnasafn og vilt að úttakið sé líka tölulegt? Auðveld lausn er að hreiðra rétta formúlu í VALUE fallinu, sem er sérstaklega hönnuð til að umbreyta streng sem táknar tölu í tölu.

Til dæmis til að draga síðustu 5 stafina (póstnúmer) úr strengnum í A2 og umbreyttu útdrættu stöfunum í tölu, notaðu þessa formúlu:

=VALUE(RIGHT(A2, 5))

Skjámyndin hér að neðan sýnir niðurstöðuna - vinsamlegast taktu eftir tölunum til hægri í dálki B, öfugt við vinstri -jafnaðir textastrengir í dálki A:

Hvers vegna virkar RIGHT aðgerðin ekki með dagsetningum?

Þar sem Excel RIGHT aðgerðin er hönnuð til að vinna með textastrengi á meðan dagsetningar eru táknaðar með tölum í innra Excel kerfi, Rétt formúla er ófær um að sækja einstaklinghluti af dagsetningu eins og degi, mánuði eða ári. Ef þú reynir að gera þetta færðu bara nokkra síðustu tölustafi númersins sem táknar dagsetningu.

Svo sem þú hefur dagsetninguna 18-jan-2017 í reit A1. Ef þú reynir að draga út árið með formúlunni RIGHT(A1,4), þá yrði niðurstaðan 2753, sem eru síðustu 4 tölustafirnir í númerinu 42753 sem táknar 18. janúar 2017 í Excel kerfinu.

"Svo, hvernig sæki ég ákveðinn hluta stefnumóts?", gætirðu spurt mig. Með því að nota eina af eftirfarandi aðgerðum:

• DAY fall til að draga út dag: =DAY(A1)
• MONTH fall til að fá mánuð: =MONTH(A1)
• YEAR fall til að draga ár: =YEAR(A1)

Eftirfarandi skjámynd sýnir niðurstöðurnar:

Ef dagsetningar þínar eru táknaðar með textastrengi , sem er oft raunin þegar þú flytur út gögn frá utanaðkomandi uppruna, ekkert kemur í veg fyrir að þú notir RIGHT aðgerðina til að draga síðustu stafina í strengnum sem tákna ákveðinn hluta dagsetningar:

Excel RIGHT aðgerð virkar ekki - ástæður og lausnir

Ef rétt formúla virkar ekki rétt í vinnublaðinu þínu er það líklega af einni af eftirfarandi ástæðum:

1. Það er ein eða fleiri slóðbil í upprunalegu gögnunum. Til að fjarlægja aukabil í hólfum fljótt skaltu nota annaðhvort Excel TRIM aðgerðina eða Cell Cleaner viðbótina.
2. tal_stafir rökin eru minna en núll . Afauðvitað muntu varla vilja setja neikvæða tölu í formúluna þína viljandi, en ef tal_stafir rökin eru reiknuð út af öðru Excel falli eða samsetningu mismunandi falla og Hægri formúlan þín skilar #VALUE! villa, vertu viss um að athuga hvort villur séu í hreiðri aðgerð(um).
3. Upprunalega gildið er dagsetning . Ef þú hefur fylgst vel með þessari kennslu, veistu nú þegar hvers vegna RIGHT aðgerðin getur ekki virkað með dagsetningum. Ef einhver sleppti fyrri hlutanum geturðu fundið allar upplýsingar í Hvers vegna Excel RIGHT aðgerðin virkar ekki með dagsetningum.

Svona notarðu RIGHT aðgerðina í Excel. Til að skoða betur formúlurnar sem fjallað er um í þessari kennslu er þér hjartanlega velkomið að hlaða niður sýnishornsvinnubókinni okkar hér að neðan. Ég þakka þér fyrir lesturinn og vonast til að sjá þig á blogginu okkar í næstu viku.

Lagt niðurhal

Excel RIGHT aðgerð - dæmi (.xlsx skrá)