De tutorial ferklearret de moeren en bouten fan Excel MONTH en EOMONTH funksjes. Jo sille in array fan formulefoarbylden fine dy't demonstrearje hoe't jo moanne fan datum yn Excel kinne ekstrahearje, de earste en lêste dei fan 'e moanne krije, moannenamme konvertearje nei nûmer en mear.

Yn it foarige artikel, wy ûndersocht in ferskaat oan formules te berekkenjen wurkdagen. Hjoed sille wy operearje op in gruttere tiidienheid en leare de funksjes dy't Microsoft Excel foar moannen jout.

Yn dizze tutorial sille jo leare:

Excel MONTH-funksje - syntaksis en brûkt

Microsoft Excel biedt in spesjale MONTH-funksje om in moanne fan datum ôf te heljen, dy't it moannenûmer werombringt fan 1 (jannewaris) oant 12 (desimber).

De MONTH funksje kin brûkt wurde yn alle ferzjes fan Excel 2016 - 2000 en syn syntaksis is sa ienfâldich as it kin wêze:

Wêr serial_number is in jildige datum fan 'e moanne dy't jo besykje te finen.

Foar it juste wurk fan Excel MONTH-formules moat in datum ynfierd wurde troch de funksje DATE (jier, moanne, dei) te brûken. Bygelyks, de formule =MONTH(DATE(2015,3,1)) jout 3 werom, om't DATE de 1e dei fan maart 2015 stiet.

Formules lykas =MONTH("1-Mar-2015") wurkje ek goed, hoewol problemen kinne foarkomme yn kompleksere senario's as datums as tekst ynfierd wurde.

Yn 'e praktyk, ynstee fan in datum op te jaan binnen de MONTH-funksje, is it handiger om te ferwizen nei in sel mei in datum ofMONTH- en EOMONTH-funksjes om ferskate berekkeningen yn jo wurkblêden út te fieren, kinne jo in stap fierder nimme en de fisuele presintaasje ferbetterje. Hjirfoar sille wy de mooglikheden fan Excel-betingele opmaak brûke foar datums.

Njonken de foarbylden dy't yn it hjirboppe neamde artikel oanbean wurde, sil ik jo no sjen litte hoe't jo alle sellen of folsleine rigen fluch markearje kinne relatearre oan in bepaalde moanne.

Foarbyld 1. Markearje datums binnen de aktuele moanne

Stel yn 'e tabel út it foarige foarbyld dat jo alle rigen markearje wolle mei de aktuele moannedatums.

Earst ekstrahearje jo de moannenûmers út datums yn kolom A mei de ienfâldichste =MONTH($A2) formule. En dan fergelykje jo dizze nûmers mei de aktuele moanne weromjûn troch =MONTH(TODAY()). As gefolch hawwe jo de folgjende formule dy't TRUE werombringt as de nûmers fan 'e moannen oerienkomme, oars FALSE:

=MONTH($A2)=MONTH(TODAY())

Meitsje in Excel betingsten opmaakregel basearre op dizze formule, en jo resultaat kin lykje op de skermôfdruk hjirûnder (it artikel is skreaun yn april, dus alle aprildatums binne markearre).

Foarbyld 2. Markearje datums per moanne en dei

En hjir is in oare útdaging. Stel dat jo de grutte feestdagen yn jo wurkblêd markearje wolle, nettsjinsteande it jier. Litte wy sizze Kryst- en Nijjiersdagen. Hoe soene jo dizze taak oanpakke?

Gebrûk gewoan de Excel DAY-funksje omekstrahearje de dei fan 'e moanne (1 - 31) en de MOANNE-funksje om it moannenûmer te krijen, en kontrolearje dan as de DAY gelyk is oan 25 of 31, en as de MOANNE lyk is oan 12:

=AND(OR(DAY($A2)=25, DAY($A2)=31), MONTH(A2)=12)

Dit is hoe't de funksje MOANNE yn Excel wurket. It liket folle alsidiger te wêzen dan it liket, hè?

Yn in pear fan 'e folgjende berjochten sille wy wiken en jierren berekkenje en hooplik sille jo in pear mear nuttige trúkjes leare. As jo ​​​​ynteressearre binne yn lytsere tiidienheden, kontrolearje dan de foarige dielen fan ús Excel Dates-searje (jo sille de keppelings hjirûnder fine). Ik tankje jo foar it lêzen en hoopje jo nije wike te sjen!

=MONTH(A1) - jout de moanne fan in datum werom yn sel A1.

=MONTH(TODAY()) - jout it nûmer fan 'e aktuele moanne werom.

Op it earste gesicht, de Excel MOANNE funksje kin sjen plain. Mar sjoch troch de ûndersteande foarbylden en jo sille fernuverje om te witten hoefolle nuttige dingen it eins kin dwaan.

Hoe kinne jo moannenûmer fan datum krije yn Excel

Der binne ferskate manieren om moanne te krijen fan datum yn Excel. Hokker te kiezen hinget ôf fan krekt hokker resultaat jo besykje te berikken.

MONTH-funksje yn Excel - krije moannenûmer fan datum

Dit is de meast foar de hân lizzende en maklikste manier om datum nei moanne te konvertearjen yn Excel. Bygelyks:

• =MONTH(A2) - jout de moanne fan in datum werom yn sel A2.
• =MONTH(DATE(2015,4,15)) - jout 4 werom dy't oerienkomme mei april.
• =MONTH("15-Apr-2015") - fansels, jout nûmer 4 ek.

TEKSTfunksje yn Excel - ekstrahearje moanne as in tekststring

In alternative manier om in moannenûmer te krijen fan in Excel-datum is it brûken fan de TEXT-funksje:

• =TEXT(A2, "m") - jout in moannenûmer sûnder in foarrinnende nul, as 1 - 12.
• =TEXT(A2,"mm") - jout in moannenûmer mei in foarrinnende nul, as 01 - 12.

Wês asjebleaft tige foarsichtich by it brûken fan TEKST-formules, om't se altyd moannenûmers weromjaan as tekststrings. Dus, as jo fan plan binne wat fierdere berekkeningen út te fieren of de weromjûne nûmers yn oare formules te brûken, kinne jo better bliuwe by de Excel MOANNEfunction.

De folgjende skermôfbylding lit de resultaten sjen dy't weromjûn binne troch alle boppesteande formules. Sjoch asjebleaft de juste ôfstimming fan sifers weromjûn troch de MOANNE-funksje (sellen C2 en C3) yn tsjinstelling ta lofts rjochte tekstwearden weromjûn troch de TEKST-funksjes (sellen C4 en C5).

Hoe kinne jo moannenamme út datum ekstrahearje yn Excel

Yn gefal jo in moannenamme wolle krije ynstee fan in nûmer, brûke jo de TEXT-funksje nochris, mar mei in oare datumkoade:

• =TEXT(A2, "mmm") - jout in ôfkoarte moannenamme werom, lykas Jan - Des.
• =TEXT(A2,"mmmm") - jout in folsleine moannenamme werom, as jannewaris - Desimber.

As jo ​​eins gjin datum nei moanne wolle konvertearje yn jo Excel-wurkblêd, wolle jo gewoan in moannenamme werjaan ynstee fan de folsleine datum, dan wolle jo net alle formules.

Selektearje in sel(en) mei datums, druk op Ctrl+1 om it dialoochfinster Sellen opmaak te iepenjen. Selektearje op it ljepblêd Nûmer Aanpast en typ "mmm" of "mmmm" yn it fak Type om respektivelik ôfkoarte of folsleine moannenammen wer te jaan. Yn dit gefal sille jo ynstjoerings folslein funksjonele Excel-datums bliuwe dy't jo kinne brûke yn berekkeningen en oare formules. Foar mear details oer it feroarjen fan it datumformaat, sjoch asjebleaft In oanpaste datumopmaak yn Excel oanmeitsje.

Hoe kinne jo moannenûmer nei moannenamme konvertearje yn Excel

Stel dat jo in list mei nûmers hawwe (1 oant 12)yn jo Excel-wurkblêd dat jo wolle konvertearje nei moannenammen. Om dit te dwaan, kinne jo ien fan 'e folgjende formules brûke:

Om in ôfkoarte moannenamme werom te jaan (jannewaris - desimber):

=TEXT(A2*28, "mmm")

=TEXT(DATE(2015, A2, 1), "mmm")

Om in folsleine moannenamme werom te jaan (jannewaris - desimber):

=TEXT(A2*28, "mmmm")

=TEXT(DATE(2015, A2, 1), "mmmm")

Yn alle boppesteande formules, A2 is in sel mei in moannenûmer. En it ienige echte ferskil tusken de formules is de moannekoades:

• "mmm" - 3-letterige ôfkoarting fan 'e moanne, lykas Jan - Dec
• "mmmm" - moanne folslein útskreaun
• "mmmmm" - de earste letter fan 'e moanne namme

Hoe't dizze formules wurkje

As brûkt tegearre mei moanne opmaak koades lykas "mmm" en "mmmm", Excel beskôget it getal 1 as Dei 1 yn jannewaris 1900. Fermannichfâldigje 1, 2, 3 ensfh mei 28, jo krije Dagen 28, 56, 84, ensfh. fan it jier 1900, dy't yn jannewaris, febrewaris, maart, ensfh. De opmaakkoade "mmm" of "mmmm" lit allinich de moannenamme sjen.

Hoe kinne jo moannenamme konvertearje nei nûmer yn Excel

D'r binne twa Excel-funksjes dy't jo kinne helpe om moannenammen te konvertearjen nei nûmers - DATEVALUE en MOANNE. De funksje DATEVALUE fan Excel konvertearret in datum opslein as tekst nei in serialnûmer dat Microsoft Excel herkent as in datum. En dan hellet de MONTH-funksje in moannenûmer út fan dy datum.

De folsleine formule is as folget:

=MONTH(DATEVALUE(A2 & "1"))

Dêr't A2 yn in sel mei de moannenammejo wolle feroarje yn in nûmer (&"1" wurdt tafoege foar de DATEVALUE-funksje om te begripen dat it in datum is).

Hoe kinne jo de lêste dei fan 'e moanne krije yn Excel (EOMONTH-funksje)

De EOMONTH-funksje yn Excel wurdt brûkt om de lêste dei fan 'e moanne werom te jaan op basis fan de opjûne startdatum. It hat de folgjende arguminten, dy't beide ferplicht binne:

• Startdatum - de begjindatum of in ferwizing nei in sel mei de startdatum.
• Moannen - it oantal moannen foar of nei de startdatum. Brûk in positive wearde foar takomstige datums en negative wearde foar ferline datums.

Hjir binne in pear EOMONTH-formulefoarbylden:

=EOMONTH(A2, 1) - jout de lêste dei fan 'e moanne werom, ien moanne nei de datum yn sel A2.

=EOMONTH(A2, -1) - jout de lêste dei fan 'e moanne werom, ien moanne foar de datum yn sel A2.

Ynstee fan in selferwizing, kinne jo in datum hardcode yn jo EOMONTH formule. Bygelyks, beide formules hjirûnder jouwe de lêste dei yn april werom.

=EOMONTH("15-Apr-2015", 0)

=EOMONTH(DATE(2015,4,15), 0)

Om de lêste dei fan de aktuele moanne werom te jaan , brûke jo de funksje TODAY() yn it earste argumint fan jo EOMONTH-formule, sadat de datum fan hjoed wurdt nommen as de startdatum. En jo sette 0 yn it argumint months , om't jo de moanne yn beide gefallen net feroarje wolle.

=EOMONTH(TODAY(), 0)

Opmerking. Sûnt de Excel EOMONTH-funksje it searjenûmer weromjout dat de datum fertsjintwurdiget, hawwe joom it datumformaat oan te passen op in sel(en) mei jo formules. Sjoch asjebleaft Hoe kinne jo datumformaat feroarje yn Excel foar de detaillearre stappen.

En hjir binne de resultaten weromjûn troch de Excel EOMONTH-formules dy't hjirboppe besprutsen binne:

As jo ​​​​berekkenje wolle hoefolle dagen noch binne oant it ein fan 'e aktuele moanne, jo lûke gewoan de datum werom troch TODAY () fan 'e datum weromjûn troch EOMONTH en tapasse it Algemiene formaat op in sel:

=EOMONTH(TODAY(), 0)-TODAY()

Hoe kinne jo de earste dei fan 'e moanne fine yn Excel

Sa't jo al witte, biedt Microsoft Excel mar ien funksje om de lêste dei fan 'e moanne (EOMONTH) werom te jaan. As it giet om de earste dei fan 'e moanne, is d'r mear dan ien manier om it te krijen.

Foarbyld 1. Krij de 1e dei fan 'e moanne troch it moannenûmer

As jo ​​de moannenûmer, brûk dan in ienfâldige DATE-formule sa as dizze:

Bygelyks =DATE(2015, 4, 1) sil weromkomme 1-apr-15.

As jo ​​nûmers lizze yn in bepaalde kolom, sis yn kolom A, kinne jo in selferwizing direkt tafoegje yn 'e formule:

=DATE(2015, B2, 1)

Foarbyld 2. Krij de 1e dei fan 'e moanne fan in datum

As jo ​​de earste dei fan 'e moanne op basis fan in datum berekkenje wolle, kinne jo brûk de Excel DATE-funksje nochris, mar dizze kear sille jo ek de MONTH-funksje nedich wêze om it moannenûmer út te pakken:

FoarBygelyks, de folgjende formule sil de earste dei fan 'e moanne weromjaan op basis fan de datum yn sel A2:

=DATE(2015,MONTH(A2),1)

Foarbyld 3. Fyn de earste dei fan moanne basearre op de aktuele datum

As jo ​​berekkeningen binne basearre op de datum fan hjoed, brûk dan in ferbining fan de Excel-funksjes EOMONTH en TODAY:

=EOMONTH(TODAY(),0) +1 - jout de 1e werom dei fan de folgjende moanne.

Sa't jo ûnthâlde, hawwe wy al in ferlykbere EOMONTH-formule brûkt om de lêste dei fan 'e aktuele moanne te krijen. En no foegje jo gewoan 1 ta oan dy formule om de earste dei fan 'e folgjende moanne te krijen.

Op deselde manier kinne jo de earste dei fan 'e foarige en aktuele moanne krije:

=EOMONTH(TODAY(),-2) +1 - jout de 1e dei fan 'e foarige moanne werom.

=EOMONTH(TODAY(),-1) +1 - jout de 1e dei fan 'e aktuele moanne werom.

Jo kinne ek de Excel-funksje DATE brûke om te behanneljen dizze taak, hoewol't de formules soe wêze in bytsje langer. Bygelyks, riede wat de folgjende formule docht?

=DATE(YEAR(TODAY()), MONTH(TODAY()), 1)

Ja, it jout de earste dei fan 'e aktuele moanne werom.

En hoe twinge jo it om de earste dei fan 'e folgjende of foarige moanne? Hannen del :) Gewoan 1 taheakje of ôflûke fan 'e aktuele moanne:

Om de earste dei fan 'e folgjende moanne werom te jaan:

=DATE(YEAR(TODAY()), MONTH(TODAY())+1, 1)

Om de earste dei werom te jaan fan 'e foarige moanne:

=DATE(YEAR(TODAY()), MONTH(TODAY())-1, 1)

Hoe kinne jo it oantal dagen yn in moanne berekkenje

Yn Microsoft Excel bestiet d'r in ferskaat oan funksjes om te wurkjen mei datums enkear. It mist lykwols in funksje foar it berekkenjen fan it oantal dagen yn in opjûne moanne. Dat, wy moatte dat weilitten goed goedmeitsje mei ús eigen formules.

Foarbyld 1. Om it oantal dagen op basis fan it moannenûmer te krijen

As jo ​​it moannenûmer kenne, de folgjende DAY/DATE-formule sil it oantal dagen yn dy moanne weromjaan:

Yn de boppesteande formule jout de funksje DATE de earste dei fan 'e folgjende moanne werom, wêrfan jo 1 subtrahearje om de lêste dei fan 'e moanne te krijen dy't jo wolle. En dan konvertearret de DAY-funksje de datum nei in deinûmer.

De folgjende formule jout bygelyks it oantal dagen yn april werom (de 4e moanne yn it jier).

=DAY(DATE(2015, 4 +1, 1) -1)

Foarbyld 2. Om it oantal dagen yn in moanne op basis fan datum te krijen

As jo ​​gjin moannenûmer kenne, mar in datum binnen dy moanne hawwe, kinne jo de JAAR en MOANNE brûke funksjes om it jier- en moannenûmer út 'e datum te heljen. Foegje se gewoan yn 'e DAY / DATE-formule besprutsen yn it boppesteande foarbyld, en it sil jo fertelle hoefolle dagen in opjûne moanne befettet:

=DAY(DATE(YEAR(A2), MONTH(A2) +1, 1) -1)

Wêr't A2 sel is mei in datum.

As alternatyf kinne jo in folle ienfâldiger DAY / EOMONTH-formule brûke. Sa't jo ûnthâlde, jout de Excel EOMONTH-funksje de lêste dei fan 'e moanne werom, dus jo hawwe gjin ekstra berekkeningen nedich:

=DAY(EOMONTH(A1, 0))

De folgjende skermôfbylding toant deresultaten weromjûn troch alle formules, en sa't jo sjogge, binne se identyk:

Hoe kinne jo gegevens per moanne optelle yn Excel

Yn in grutte tabel mei in protte gegevens, jo moatte faaks in som fan wearden krije foar in opjûne moanne. En dit kin in probleem wêze as de gegevens net yn gronologyske folchoarder ynfierd binne.

De maklikste oplossing is om in helpkolom ta te foegjen mei in ienfâldige Excel MONTH-formule dy't datums omsette sil nei moannenûmers. Sis, as jo datums yn kolom A steane, brûke jo =MONTH(A2).

En skriuw no in list mei nûmers op (fan 1 oant 12, of allinich de moannenûmers dy't jo ynteressearje ) yn in lege kolom, en som wearden foar elke moanne mei in SUMIF formule fergelykber mei dizze:

=SUMIF(C2:C15, E2, B2:B15)

Wêr't E2 it moannenûmer is.

De folgjende skermôfbylding lit sjen it resultaat fan de berekkeningen:

As jo ​​leaver gjin helpkolom tafoegje wolle oan jo Excel-blêd, gjin probleem, jo ​​kinne sûnder. In bytsje mear lestiger SUMPRODUCT-funksje sil in traktaasje wurkje:

=SUMPRODUCT((MONTH($A$2:$A$15)=$E2) * ($B$2:$B$15))

Wêr't kolom A datums befettet, befettet kolom B de wearden om te sommen en E2 is it moannenûmer.

Noat. Hâld asjebleaft yn gedachten dat beide boppesteande oplossingen alle wearden foar in opjûne moanne optelle, nettsjinsteande it jier. Dus, as jo Excel-wurkblêd gegevens foar ferskate jierren befettet, sil it allegear wurde gearfette.

Hoe kinne jo datums betingst opmaak op basis fan moanne

No't jo witte hoe't jo de Excel brûke