La lernilo montras kiel vi povas utiligi la novan SEQUENCE-funkcion por rapide generi liston de datoj en Excel kaj uzi la Aŭtomatan plenigon por plenigi kolumnon per datoj, labortagoj, monatoj aŭ jaroj.

Ĝis antaŭ nelonge, ekzistas nur unu facila maniero por generi datojn en Excel - la Aŭtomata Plenigo. La enkonduko de la nova dinamika tabel SEQUENCE funkcio ebligis ankaŭ fari serion da datoj kun formulo. Ĉi tiu lernilo profunde rigardas ambaŭ metodojn por ke vi povu elekti tiun, kiu funkcias plej bone por vi.

Kiel plenigi datajn seriojn en Excel

Kiam vi devas plenigi kolumnon per datoj en Excel, la plej rapida maniero estas uzi la Aŭtomatan plenigaĵon.

Aŭtomate plenigi datserion en Excel

Plenigi kolumnon aŭ vicon per datoj kiuj pliiĝas je unu tago estas tre facila:

1. Tajpu la komencan daton en la unua ĉelo.
2. Elektu la ĉelon kun la komenca dato kaj trenu la plentenilon (malgranda verda kvadrato malsupre). -dekstra angulo) malsupren aŭ dekstren.

Excel tuj generos serion da datoj en la sama formato kiel la unua dato kiun vi tajpis permane.

Plenigu kolumnon per labortagoj, monatoj aŭ jaroj

Por krei serion de labortagoj, monatoj aŭ jaroj, faru unu el la jenaj:

• Plenigu kolumnon per sinsekvaj datoj kiel priskribite supre. Post tio, alklaku la butonon Aŭtomatplenigaj Opcioj kaj elektu ladezirata opcio, diru Plenigi Monatojn :

  

• Aŭ vi povas enigi vian unuan daton, dekstre alklaku la plenigan tenilon, tenu kaj trenu tra tiom da ĉeloj. laŭ bezono. Kiam vi liberigas la musbutonon, aperos kunteksta menuo, kiu ebligas al vi elekti la bezonatan opcion, Plenigu Jarojn en nia kazo:

  

Plenigu serion da datoj pliiĝantaj je N tagoj

Por aŭtomate generi serion da tagoj, labortagoj, monatoj aŭ jaroj per specifa paŝo , jen kion vi devas fari:

1. Enigu la komencan daton en la unua ĉelo.
2. Elektu tiun ĉelon, dekstre alklaku la plenigan tenilon, trenu ĝin tra tiom da ĉeloj kiom bezonas, kaj poste liberigu.
3. Enigu la komencan daton en la unua ĉelo. 11>En la ŝprucmenuo, elektu Serio (la lasta ero).
4. En la dialogkesto Serio , elektu la Data unuo interesa kaj agordu la Paŝovaloron .
5. Alklaku OK.

Por pliaj ekzemploj, bonvolu vidi Kiel enmeti kaj aŭtomate plenigi datojn en Excel.

Kiel fari datan sinsekvon en Excel kun formulo

En unu el la antaŭaj lerniloj, ni rigardis kiel uzi la novan dinamikan tabelan SEQUENCE-funkcion por generi nombran sinsekvon. Ĉar interne en Excel datoj estas stokitaj kiel seriaj numeroj, la funkcio povas facile produkti datajn seriojn ankaŭ. Ĉio, kion vi devas fari, estas ĝuste agordi la argumentojn kiel klarigite en la sekvaj ekzemploj.

Noto. Ĉiuj formuloj ĉi tie diskutitaj nur funkcias en laplej novaj versioj de Excel 365, kiuj subtenas dinamikajn tabelojn. En antaŭdinamika Excel 2019, Excel 2016 kaj Excel 2013, bonvolu uzi la funkcion Aŭtomata Plenigo kiel montrite en la unua parto de ĉi tiu lernilo.

Kreu serion da datoj en Excel

Por generi sekvenco de datoj en Excel, agordu la jenajn argumentojn de la funkcio SEQUENCE:

• Vicoj - la nombro da vicoj por plenigi per datoj.
• Kolumnoj - la nombro da kolumnoj por plenigi per datoj.
• Komenco - la komenca dato en la formato kiun Excel povas kompreni, kiel "8/1/2020" aŭ "1-aug-2020". Por eviti erarojn, vi povas provizi la daton uzante la DATO-funkcion kiel DATE(2020, 8, 1).
• Paŝo - la pliigo por ĉiu posta dato en sinsekvo.

Ekzemple, por fari liston de 10 datoj ekde la 1-a de aŭgusto 2020 kaj pliiĝantaj de 1 tago, la formulo estas:

=SEQUENCE(10, 1, "8/1/2020", 1)

aŭ

=SEQUENCE(10, 1, DATE(2020, 8, 1), 1)

Alternative, vi povas enigi la nombron da datoj (B1), komencan daton (B2) kaj paŝon (B3) en antaŭdifinitaj ĉeloj kaj referenci tiujn ĉelojn en via formulo. Ĉar ni generas liston, la kolumnoj nombro (1) estas malmola kodita:

=SEQUENCE(B1, 1, B2, B3)

Tajpu la suban formulon en la plej supra ĉelo (A6 en nia kazo), premu la Enigu klavon, kaj la rezultoj disverŝiĝos trans la specifitan nombron da vicoj kaj kolumnoj aŭtomate.

Noto. Kun la defaŭlta Ĝenerala formato, la rezultoj aperos kiel seriaj numeroj. Por ke ili montru ilin ĝuste, nepre apliki la Dato-formaton al ĉiuj ĉeloj en la disverŝa gamo.

Faru serion da labortagoj en Excel

Por akiri nur serion da labortagoj, envolvu SEQUENCE en la funkcio WORKDAY aŭ WORKDAY.INTL jene:

Ĉar la funkcio WORKDAY aldonas la nombron da tagoj specifita en la dua argumento al la komenca dato, ni subtrahas 1 de ĝi por havi la komencan daton mem inkluzivita en la rezultoj.

Ekzemple, por generi sinsekvon de labortagoj ekde la dato en B2, la formulo estas:

=WORKDAY(B2-1, SEQUENCE(B1))

Kie B1 estas la sinsekvogrando.

Konsiletoj kaj notoj:

• Se komencdato estas sabato aŭ dimanĉo, la serio komenciĝos en la sekva labortago.
• La funkcio Excel WORKDAY supozas ke sabato kaj dimanĉo estas semajnfinoj. Por agordi kutimajn semajnfinojn kaj feriojn, uzu anstataŭe la funkcion WORKDAY.INTL.

Generu monatan sinsekvon en Excel

Por krei serion da datoj pliigitaj je unu monato, vi povas uzi ĉi tiu ĝenerala formulo:

En ĉi tiu kazo, vi metas la celjaron en la 1-an argumenton kaj tagon en la 3-a argumento. Por la dua argumento, la SEQUENCE-funkcio liveras sinsekvajn nombrojn de 1 ĝis 12. Surbaze de la supraj parametroj, la DATO-funkcio produktas serion dedatoj kiel montrite en la maldekstra parto de la malsupra ekrankopio:

=DATE(2020, SEQUENCE(12), 1)

Por montri nur la monatajn nomojn , agordu unu el la malsupraj kutimaj datformatoj por la disverŝa intervalo :

• mmm - mallonga formo kiel Jan , Feb , Mar , ktp.
• mmmm - plena formo kiel januaro , februaro , marto ktp.

Kiel rezulto, nur la monataj nomoj aperos en ĉeloj, sed la subaj valoroj ankoraŭ estos plenaj datoj. En ambaŭ serioj en la ekrankopio malsupre, bonvolu rimarki la defaŭltan dekstran vicigon tipan por nombroj kaj datoj en Excel:

Por generi datan sinsekvon kiu pliiĝas je unu monato kaj komencas per specifa dato , uzu la SEQUENCE-funkcion kune kun EDATE:

La EDATE-funkcio liveras daton, kiu estas la specifita nombro da monatoj antaŭ aŭ post la komenca dato. Kaj la SEQUENCE-funkcio produktas tabelon de 12 nombroj (aŭ tiom da kiom vi specifas) por devigi EDATE antaŭeniri en unumonataj pliigoj. Bonvolu rimarki, ke la argumento komenco estas agordita al 0, tiel ke la komenca dato estas inkluzivita en la rezultoj.

Kun la komenca dato en B1, la formulo prenas ĉi tiun formon:

=EDATE(B1, SEQUENCE(12, 1, 0))

Notu. Post kompletigado de formulo, bonvolu memori apliki taŭgan datformaton al la rezultoj por ke ili aperu ĝuste.

Kreu jarsekvencon en Excel

Por fariserio da datoj pliigitaj laŭ jaro, uzu ĉi tiun ĝeneralan formulon:

Kie n estas la nombro da datoj kiujn vi volas generi.

En ĉi tiu kazo, la DATO (jaro, monato, tago) funkcio konstruas daton tiamaniere:

• Jaro estas resendita de la SEQUENCE funkcio kiu estas agordita por generi n vicojn je 1 kolumna tabelo de nombroj, komencante je la jarvaloro de komenca_dato .
• Monato kaj tago valoroj estas tiritaj rekte de la komenca dato.

Ekzemple, se vi enigas la komencan daton en B1, la sekva formulo eligos serion de 10 datoj en unujaraj pliigoj:

=DATE(SEQUENCE(10, 1, YEAR(B1)), MONTH(B1), DAY(B1))

Post estante formatitaj kiel datoj, la rezultoj aspektos jene:

Generu temposekvencon en Excel

Ĉar tempoj estas stokitaj en Excel kiel decimalaj nombroj reprezentantaj frakcio de la tago, la SEQUENCE funkcio povas funkcii kun tempoj rekte.

A supozante, ke la komenca tempo estas en B1, vi povas uzi unu el la sekvaj formuloj por produkti serion de 10 fojojn. La diferenco estas nur en la argumento paŝo . Ĉar estas 24 horoj en tago, uzu 1/24 por pligrandigi je horo, 1/48 por pligrandigi je 30 minutoj, kaj tiel plu.

30 minutoj dise:

=SEQUENCE(10, 1, B1, 1/48)

1 horo dise:

=SEQUENCE(10, 1, B1, 1/24)

2 horoj dise:

=SEQUENCE(10, 1, B1, 1/12)

La ekrankopio sube montras larezultoj:

Se vi ne volas ĝeni kalkuli la paŝon permane, vi povas difini ĝin uzante la TEMP-funkcion:

Por ĉi tiu ekzemplo, ni enigos ĉiujn variablojn en apartaj ĉeloj kiel montrite en la ekrankopio sube. . Kaj tiam, vi povas uzi la suban formulon por generi temposerion kun iu ajn pliiga paŝogrando, kiun vi specifigas en ĉeloj E2 (horoj), E3 (minutoj) kaj E4 (sekundoj):

=SEQUENCE(B2, B3, B4, TIME(E2, E3, E4))

Kiel krei monatan kalendaron en Excel

En ĉi tiu fina ekzemplo, ni uzos la SEQUENCE-funkcion kune kun DATEVALUE kaj WEEKDAY por krei monatan kalendaron kiu ĝisdatigos aŭtomate surbaze de la jaro kaj monato, kiujn vi specifas.

La formulo en A5 estas jena:

=SEQUENCE(6, 7, DATEVALUE("1/"&B2&"/"&B1) - WEEKDAY(DATEVALUE("1/"&B2&"/"&B1)) + 1, 1)

Kiel ĉi tiu formulo funkcias:

Vi uzas la SEQUENCE-funkcion por generi 6 vicojn (la maksimuman ebla nombro da semajnoj en monato) per 7 kolumnoj (la nombro da tagoj en semajno) tabelo de datoj pliigita je 1 tago. Tial la argumentoj vicoj , kolumnoj kaj paŝo ne starigas demandojn.

La plej malfacila parto en la argumento komenco . Ni ne povas komenci nian kalendaron per la 1-a tago de la celmonato ĉar ni ne scias, kiu tago de la semajno ĝi estas. Do, ni uzas la sekvan formulon por trovi la unuan dimanĉon antaŭ la 1-a tago de la specifita monato kajjaro:

DATEVALUE("1/"&B2&"/"&B1) - WEEKDAY(DATEVALUE("1/"&B2&"/"&B1)) + 1

La unua DATEVALUE-funkcio liveras serian numeron kiu, en la interna Excel-sistemo, reprezentas la 1-an tagon de la monato en B2 kaj la jaron en B1. En nia kazo, ĝi estas 44044 responda al aŭgusto 1, 2020. Je ĉi tiu punkto, ni havas:

44044 - WEEKDAY(DATEVALUE("1/"&B2&"/"&B1)) + 1

La WEEKDAY-funkcio redonas la semajnotagon respondan al la 1-a tago de la celo. monato kiel nombro de 1 (dimanĉo) ĝis 7 (sabato). En nia kazo, estas la 7-a ĉar la 1-a de aŭgusto 2020 estas sabato. Kaj nia formulo reduktas al:

44044 - 7 + 1

44044 - 7 estas 4403, kio respondas al sabato la 25-an de julio 2020. Ĉar ni bezonas dimanĉon, ni aldonas la +1-korekton.

Tiel, ni ricevas simplan formulon, kiu eligas tabelon da seriaj numeroj komenciĝantaj per 4404:

=SEQUENCE(6, 7, 4404, 1)

Formatigu la rezultojn kiel datojn, kaj vi ricevos kalendaron montritan en la supra ekrankopio. Ekzemple, vi povas uzi unu el la sekvaj datformatoj:

• d-mmm-yy por montri datojn kiel 1-aug-20
• mmm d por montri monaton kaj tagon kiel aŭg 20
• d por montri nur la tagon

Atendu, sed ni celas krei monatan kalendaron. Kial aperas iuj datoj de la antaŭa kaj venonta monato? Por kaŝi tiujn senrilatajn datojn, starigu kondiĉan formatregulon kun la suba formulo kaj apliku la blankan tiparon koloron:

=MONTH(A5)MONTH(DATEVALUE($B$2 & "1"))

Kie A5 estas la plej maldekstra ĉelo de via kalendaro kaj B2 estas la celomonato.

Por la detalaj paŝoj, bonvolu vidi Kiel krei formul-bazitan kondiĉan formatregulon en Excel.

Tiel vi povas generi sekvencon. de datoj en Excel. Mi dankas vin pro legado kaj esperas vidi vin en nia blogo venontsemajne!

Praktiku laborlibron por elŝuto

Data sinsekvo en Excel - formulekzemploj (.xlsx-dosiero)