Πίνακας περιεχομένων
Το Google Sheets COUNTIF είναι μία από τις πιο εύκολες λειτουργίες για να μάθει κανείς και μία από τις πιο εύχρηστες.
Ήρθε η ώρα να αποκτήσετε κάποιες γνώσεις σχετικά με το πώς χρησιμοποιείται η COUNTIF στο Google Spreadsheet και να μάθετε γιατί αυτή η συνάρτηση αποτελεί έναν πραγματικό σύντροφο του Google Spreadsheet.
Τι είναι η συνάρτηση COUNTIF στο Google Sheets;
Αυτό το σύντομο βοήθημα μας επιτρέπει να μετρήσουμε πόσες φορές εμφανίζεται μια συγκεκριμένη τιμή σε ένα καθορισμένο εύρος δεδομένων.
Σύνταξη COUNTIF στο Google Sheets
Η σύνταξη της συνάρτησης και τα ορίσματά της έχουν ως εξής:
=COUNTIF(εύρος, κριτήριο)- εύρος - μια σειρά κελιών όπου θέλουμε να μετρήσουμε μια συγκεκριμένη τιμή. Απαιτείται.
- κριτήριο ή κριτήριο αναζήτησης - μια τιμή για την εύρεση και την καταμέτρηση σε όλο το εύρος δεδομένων που αναφέρεται στο πρώτο όρισμα.
Φύλλο Google COUNTIF στην πράξη
Μπορεί να φαίνεται ότι η COUNTIF είναι τόσο απλή που δεν μετράει καν ως συνάρτηση (το λογοπαίγνιο προορίζεται), αλλά στην πραγματικότητα οι δυνατότητές της είναι αρκετά εντυπωσιακές. Τα κριτήρια αναζήτησης της και μόνο είναι αρκετά για να κερδίσουν έναν τέτοιο χαρακτηρισμό.
Το θέμα είναι ότι μπορούμε να αποφασίσουμε να αναζητήσουμε όχι μόνο συγκεκριμένες αξίες αλλά και εκείνες που πληρούν ορισμένα κριτήρια.
Είναι καιρός να προσπαθήσουμε να φτιάξουμε μια φόρμουλα από κοινού.
Google Spreadsheet COUNTIF για κείμενο και αριθμούς (ακριβής αντιστοιχία)
Ας υποθέσουμε ότι η εταιρεία σας πουλάει διάφορα είδη σοκολάτας σε διάφορες καταναλωτικές περιοχές και συνεργάζεται με πολλούς πελάτες.
Έτσι φαίνονται τα δεδομένα των πωλήσεών σας στο Google Sheets:
Ας ξεκινήσουμε με τα βασικά.
Πρέπει να μετρήσουμε τον αριθμό των "Σοκολάτας γάλακτος" που πουλήθηκαν. Τοποθετήστε τον κέρσορα στο κελί όπου θέλετε να πάρετε το αποτέλεσμα και πληκτρολογήστε το σύμβολο ισότητας (=). Το Google Sheets καταλαβαίνει αμέσως ότι πρόκειται να εισάγουμε έναν τύπο. Μόλις πληκτρολογήσετε το γράμμα "C", θα σας ζητήσει να επιλέξετε μια συνάρτηση που αρχίζει με αυτό το γράμμα. Επιλέξτε "COUNTIF".
Το πρώτο επιχείρημα της COUNTIF αντιπροσωπεύεται από το ακόλουθο εύρος : D6:D16. Παρεμπιπτόντως, δεν χρειάζεται να εισαγάγετε το εύρος χειροκίνητα - αρκεί η επιλογή με το ποντίκι. Στη συνέχεια, εισάγετε ένα κόμμα (,) και καθορίστε το δεύτερο όρισμα - τα κριτήρια αναζήτησης.
Το δεύτερο επιχείρημα είναι μια τιμή που θα αναζητήσουμε σε όλο το επιλεγμένο εύρος. Στην περίπτωσή μας θα είναι το κείμενο - "Σοκολάτα γάλακτος". Θυμηθείτε να ολοκληρώσετε τη συνάρτηση με μια κλειστή αγκύλη ")" και πατήστε "Enter".
Επίσης, μην ξεχνάτε να εισάγετε διπλά εισαγωγικά ("") όταν χρησιμοποιείτε τιμές κειμένου.
Ο τελικός μας τύπος έχει ως εξής:
=COUNTIF(D6:D16, "Σοκολάτα γάλακτος")
Ως αποτέλεσμα, έχουμε τρεις πωλήσεις αυτού του τύπου σοκολάτας.
Σημείωση. Η συνάρτηση COUNTIF λειτουργεί με ένα μόνο κελί ή γειτονικές στήλες. Με άλλα λόγια, δεν μπορείτε να υποδείξετε μερικά ξεχωριστά κελιά ή στήλες και γραμμές. Παρακαλούμε δείτε τα παρακάτω παραδείγματα.
Λανθασμένοι τύποι:
=COUNTIF(C6:C16, D6:D16, "Σοκολάτα γάλακτος")
=COUNTIF(D6, D8, D10, D12, D14, "Milk Chocolate")
Σωστή χρήση:
=COUNTIF(C6:D16, "Σοκολάτα γάλακτος")
=COUNTIF(D6, "Σοκολάτα γάλακτος") + COUNTIF(D8, "Σοκολάτα γάλακτος") + COUNTIF(D10, "Σοκολάτα γάλακτος") + COUNTIF(D12, "Σοκολάτα γάλακτος") + COUNTIF(D14, "Σοκολάτα γάλακτος")
Ίσως έχετε παρατηρήσει ότι δεν είναι πραγματικά βολικό να ορίσετε τα κριτήρια αναζήτησης στον τύπο - πρέπει να τα επεξεργάζεστε κάθε φορά. Η καλύτερη απόφαση θα ήταν να γράψετε τα κριτήρια σε άλλο κελί του Google Sheets και να αναφέρετε αυτό το κελί στον τύπο.
Ας μετρήσουμε τον αριθμό των εμφανιζόμενων πωλήσεων στην περιοχή "Δύση" χρησιμοποιώντας την αναφορά κελιού στο COUNTIF. Θα έχουμε τον ακόλουθο τύπο:
=COUNTIF(C6:C16,A3)
Η συνάρτηση χρησιμοποιεί το περιεχόμενο του A3 (την τιμή κειμένου "West") στους υπολογισμούς της. Όπως μπορείτε να δείτε, είναι πολύ πιο εύκολο τώρα να επεξεργαστείτε τον τύπο και τα κριτήρια αναζήτησης.
Φυσικά, μπορούμε να κάνουμε το ίδιο πράγμα με αριθμητικές τιμές Μπορούμε να μετρήσουμε τον αριθμό των εμφανίσεων του αριθμού "125", δηλώνοντας τον ίδιο τον αριθμό ως δεύτερο όρισμα:
=COUNTIF(E7:E17,125)
ή αντικαθιστώντας το με μια αναφορά κελιού:
=COUNTIF(E7:E17,A3)
Λειτουργία COUNTIF του φύλλου Google και χαρακτήρες μπαλαντέρ (μερική αντιστοίχιση)
Το σπουδαίο με το COUNTIF είναι ότι μπορεί να μετρήσει ολόκληρα κύτταρα καθώς και μέρη του περιεχομένου του κυττάρου Για το σκοπό αυτό, χρησιμοποιούμε χαρακτήρες μπαλαντέρ : "?", "*".
Για παράδειγμα, για να μετρήσουμε τις πωλήσεις σε κάποια συγκεκριμένη περιοχή μπορούμε να χρησιμοποιήσουμε μόνο το μέρος του ονόματός της: πληκτρολογήστε "?est" στο B3. A ερωτηματικό (?) αντικαθιστά ένας χαρακτήρας Θα ψάξουμε για τις λέξεις με 4 γράμματα που τελειώνει με "est" , συμπεριλαμβανομένων των διαστημάτων.
Χρησιμοποιήστε τον ακόλουθο τύπο COUNTIF στο B3:
=COUNTIF(C7:C17,A3)
Όπως ήδη γνωρίζετε, ο τύπος μπορεί εύκολα να πάρει την επόμενη μορφή:
=COUNTIF(C7:C17, "?est")
Και βλέπουμε 5 πωλήσεις στην περιοχή "Δύση".
Τώρα ας χρησιμοποιήσουμε το κελί B4 για έναν άλλο τύπο:
=COUNTIF(C7:C17,A4)
Επιπλέον, θα αλλάξουμε το κριτήριο σε "??st" στο A4. Αυτό σημαίνει ότι τώρα θα ψάχνουμε για λέξεις με 4 γράμματα. που τελειώνει με "st" Εφόσον σε αυτή την περίπτωση δύο περιοχές ("Δύση" και "Ανατολή") πληρούν τα κριτήριά μας, θα δούμε εννέα πωλήσεις:
Ομοίως, μπορούμε να μετρήσουμε τον αριθμό των πωλήσεων των αγαθών χρησιμοποιώντας ένα αστερίσκος (*). Αυτό το σύμβολο αντικαθιστά όχι μόνο ένα, αλλά οποιοσδήποτε αριθμός χαρακτήρων :
"*Σοκολάτα" το κριτήριο μετράει όλα τα προϊόντα που τελειώνουν με "Σοκολάτα".
"Σοκολάτα*" τα κριτήρια μετράνε όλα τα προϊόντα που αρχίζουν με "Σοκολάτα".
Και, όπως μπορείτε να μαντέψετε, αν εισέλθουμε "*Σοκολάτα*" , θα αναζητήσουμε όλα τα προϊόντα που περιέχουν τη λέξη "Σοκολάτα".
Σημείωση. Αν θέλετε να μετρήσετε τον αριθμό των λέξεων που περιέχουν αστερίσκο (*) και ερωτηματικό (?), τότε χρησιμοποιήστε σύμβολο tilde (~) πριν από αυτούς τους χαρακτήρες. Σε αυτή την περίπτωση, η COUNTIF θα τους αντιμετωπίσει ως απλά σύμβολα και όχι ως χαρακτήρες αναζήτησης. Για παράδειγμα, αν θέλουμε να αναζητήσουμε τις τιμές που περιέχουν "?", ο τύπος θα είναι:
=COUNTIF(D7:D15,"*~?*")
COUNTIF Φύλλα Google για μικρότερο από, μεγαλύτερο από ή ίσο με
Η συνάρτηση COUNTIF είναι σε θέση να μετράει όχι μόνο πόσες φορές εμφανίζεται κάποιος αριθμός, αλλά και πόσοι από τους αριθμούς είναι μεγαλύτερο/μικρότερο/ίσο/μη ίσο άλλος καθορισμένος αριθμός.
Για το σκοπό αυτό, χρησιμοποιούμε τους αντίστοιχους μαθηματικούς τελεστές: "=", ">", "=", "<=", "".
Ελέγξτε τον παρακάτω πίνακα για να δείτε πώς λειτουργεί:
| Κριτήρια | Παράδειγμα τύπου | Περιγραφή |
| Ο αριθμός είναι μεγαλύτερος από | =COUNTIF(F9:F19,">100") | Καταμετρήστε τα κελιά όπου οι τιμές είναι μεγαλύτερες από 100. |
| Ο αριθμός είναι μικρότερος από | =COUNTIF(F9:F19,"<100") | Καταμετρήστε τα κελιά όπου οι τιμές είναι μικρότερες από 100. |
| Ο αριθμός ισούται με | =COUNTIF(F9:F19,"=100") | Μετράει τα κελιά όπου οι τιμές είναι ίσες με 100. |
| Ο αριθμός δεν είναι ίσος με | =COUNTIF(F9:F19,"100") | Καταμετρήστε τα κελιά όπου οι τιμές δεν είναι ίσες με 100. |
| Ο αριθμός είναι μεγαλύτερος ή ίσος με | =COUNTIF(F9:F19,">=100") | Καταμετρήστε τα κελιά όπου οι τιμές είναι μεγαλύτερες ή ίσες του 100. |
| Ο αριθμός είναι μικρότερος ή ίσος με | =COUNTIF(F9:F19,"<=100") | Καταμετρήστε τα κελιά όπου οι τιμές είναι μικρότερες ή ίσες με 100. |
Σημείωση. Είναι πολύ σημαντικό να επισυνάψτε το ο μαθηματικός τελεστής μαζί με έναν αριθμό σε διπλά εισαγωγικά .
Αν θέλετε να αλλάξετε τα κριτήρια χωρίς να αλλάξετε τον τύπο, μπορείτε να αναφερθείτε και στα κελιά.
Ας αναφερθούμε στο Α3 και ας τοποθετήσουμε τον τύπο στο Β3, όπως ακριβώς κάναμε προηγουμένως:
=COUNTIF(F9:F19,A3)
Για να δημιουργήσετε πιο περίπλοκα κριτήρια, χρησιμοποιήστε ένα ampersand (&).
Για παράδειγμα, το B4 περιέχει έναν τύπο που μετρά τον αριθμό των τιμών μεγαλύτερων ή ίσων με 100 στην περιοχή E9:E19:
=COUNTIF(E9:E19,">="&A4)
Το B5 έχει τα ίδια ακριβώς κριτήρια, αλλά δεν αναφερόμαστε μόνο στον αριθμό σε αυτό το κελί, αλλά και σε έναν μαθηματικό τελεστή. Αυτό καθιστά ακόμη πιο εύκολη την προσαρμογή του τύπου COUNTIF, εάν είναι απαραίτητο:
=COUNTIF(E9:E19,A6&A5)
Συμβουλή. Μας έχουν ρωτήσει πολλές φορές σχετικά με την καταμέτρηση των κελιών που είναι μεγαλύτερα ή μικρότερα από τις τιμές σε μια άλλη στήλη. Αν αυτό είναι που ψάχνετε, θα χρειαστείτε μια άλλη συνάρτηση για τη δουλειά αυτή - την SUMPRODUCT.
Για παράδειγμα, ας μετρήσουμε όλες τις γραμμές όπου οι πωλήσεις στη στήλη F είναι μεγαλύτερες από ό,τι στην ίδια γραμμή της στήλης G:
=SUMPRODUCT(--(F6:F16>G6:G16))
- Το μέρος που βρίσκεται στον πυρήνα της φόρμουλας - F6:F16>G6:G16 - συγκρίνει τις τιμές στις στήλες F και G. Όταν ο αριθμός στη στήλη F είναι μεγαλύτερος, ο τύπος τον λαμβάνει ως ΑΛΗΘΕΙΑ, διαφορετικά ως ΨΕΥΔΗ.
Θα δείτε ότι αν εισαγάγετε το ίδιο στην ArrayFormula:
=ArrayFormula(F6:F16>G6:G16)
- Τότε ο τύπος παίρνει αυτό το ΣΩΣΤΟ/ΛΑΘΟΣ αποτέλεσμα και το μετατρέπει σε 1/0 αριθμούς με τη βοήθεια του διπλού μοναδιαίου τελεστή (--) .
- Αυτό αφήνει το SUM να κάνει τα υπόλοιπα - να αθροίσει τον αριθμό των περιπτώσεων που το F είναι μεγαλύτερο από το G.
Φύλλο Google COUNTIF με πολλαπλά κριτήρια
Μερικές φορές είναι απαραίτητο να μετρήσετε τον αριθμό των τιμών που απαντούν σε τουλάχιστον μία από τις αναφερόμενες συνθήκες (λογική OR) ή σε πολλαπλά κριτήρια ταυτόχρονα (λογική AND). Με βάση αυτό, μπορείτε να χρησιμοποιήσετε είτε μερικές συναρτήσεις COUNTIF σε ένα μόνο κελί κάθε φορά είτε την εναλλακτική συνάρτηση COUNTIFS.
Καταμέτρηση σε Φύλλα Google με πολλαπλά κριτήρια - λογική AND
Ο μόνος τρόπος που θα σας συμβούλευα να χρησιμοποιήσετε εδώ είναι με μια ειδική συνάρτηση που έχει σχεδιαστεί για να μετράει με πολλαπλά κριτήρια - COUNTIFS:
=COUNTIFS(criteria_range1, criterion1, [criteria_range2, criterion2, ...])Συνήθως χρησιμοποιείται όταν υπάρχουν τιμές σε δύο περιοχές που πρέπει να πληρούν κάποια κριτήρια ή όταν πρέπει να λάβετε τον αριθμό που εμπίπτει μεταξύ μιας συγκεκριμένης περιοχής αριθμών.
Ας προσπαθήσουμε να μετρήσουμε τον αριθμό των συνολικών πωλήσεων μεταξύ 200 και 400:
=COUNTIFS(F8:F18,">=200",F8:F18,"<=400")
Συμβουλή. Μάθετε πώς να χρησιμοποιείτε COUNTIFS με χρώματα στο Google Sheets σε αυτό το άρθρο.
Καταμέτρηση μοναδικών σε Φύλλα Google με πολλαπλά κριτήρια
Μπορείτε να προχωρήσετε περισσότερο και να μετρήσετε τον αριθμό των μοναδικών προϊόντων μεταξύ 200 και 400.
Όχι, δεν είναι το ίδιο με το παραπάνω! :) Το παραπάνω COUNTIFS μετράει κάθε εμφάνιση πωλήσεων μεταξύ 200 και 400. Αυτό που προτείνω είναι να εξετάσετε και το προϊόν. Αν το όνομά του εμφανίζεται περισσότερες από μία φορές, δεν θα συμπεριληφθεί στο αποτέλεσμα.
Υπάρχει μια ειδική συνάρτηση γι' αυτό - COUNTUNIQUEIFS:
COUNTUNIQUEIFS(count_unique_range, criteria_range1, criterion1, [criteria_range2, criterion2, ...])Σε σύγκριση με το COUNTIFS, το πρώτο επιχείρημα είναι αυτό που κάνει τη διαφορά. Count_unique_range είναι η περιοχή στην οποία η συνάρτηση θα μετράει μοναδικές εγγραφές.
Ακολουθεί ο τύπος και το αποτέλεσμά του:
=COUNTUNIQUEIFS(D6:D16,F6:F16,">=200",F6:F16,"<=400")
Κοιτάξτε, υπάρχουν 3 σειρές που πληρούν τα κριτήριά μου: οι πωλήσεις είναι 200 και άνω και ταυτόχρονα 400 ή λιγότερες.
Ωστόσο, 2 από αυτά ανήκουν στο ίδιο προϊόν - Σοκολάτα γάλακτος Η COUNTUNIQUEIFS μετρά μόνο την πρώτη αναφορά του προϊόντος.
Έτσι, γνωρίζω ότι υπάρχουν μόνο 2 προϊόντα που πληρούν τα κριτήριά μου.
Καταμέτρηση στο Google Sheets με πολλαπλά κριτήρια - λογική OR
Όταν μόνο ένα από όλα τα κριτήρια είναι αρκετό, καλύτερα να χρησιμοποιείτε πολλές συναρτήσεις COUNTIF.
Παράδειγμα 1. COUNTIF + COUNTIF
Ας μετρήσουμε τον αριθμό των πωλήσεων μαύρης και λευκής σοκολάτας. Για να το κάνετε αυτό, εισαγάγετε τον ακόλουθο τύπο στο B4:
=COUNTIF(D7:D17, "*Γάλα*") + COUNTIF(D7:D17, "*Σκούρο*")
Συμβουλή. Χρησιμοποιώ αστερίσκο (*) για να διασφαλίσω ότι οι λέξεις "dark" και "milk" θα καταμετρηθούν ανεξάρτητα από το πού βρίσκονται στο κελί - στην αρχή, στη μέση ή στο τέλος.
Συμβουλή. Μπορείτε πάντα να εισαγάγετε αναφορές κελιών στους τύπους σας. Δείτε πώς φαίνεται στο παρακάτω στιγμιότυπο οθόνης στο B3, το αποτέλεσμα παραμένει το ίδιο:
Παράδειγμα 2. COUNTIF - COUNTIF
Τώρα, θα μετρήσω τον αριθμό των συνολικών πωλήσεων μεταξύ 200 και 400:
Παίρνω τον αριθμό των συνολικών πωλήσεων κάτω των 400 και αφαιρώ τον αριθμό των συνολικών πωλήσεων κάτω των 200 χρησιμοποιώντας τον επόμενο τύπο:
=C0UNTIF(F7:F17,"<=400") - COUNTIF(F7:F17,"<=200")
Ο τύπος επιστρέφει τον αριθμό των πωλήσεων άνω των 200 αλλά κάτω των 400.
Αν αποφασίσετε να αναφέρετε τα A3 και A4 που περιέχουν τα κριτήρια, ο τύπος θα είναι λίγο πιο απλός:
=COUNTIF(F7:F17, A4) - COUNTIF(F7:F17, A3)
Το κελί A3 θα έχει τα κριτήρια "<=200", ενώ το A4 - "<=400". Βάλτε και τους δύο τύπους στα B3 και B4 και βεβαιωθείτε ότι το αποτέλεσμα δεν αλλάζει - 3 πωλήσεις στο απαιτούμενο εύρος.
COUNTIF Φύλλα Google για κενά και μη κενά κελιά
Με τη βοήθεια της COUNTIF, μπορούμε επίσης να μετρήσουμε τον αριθμό των κενών ή μη κενών κελιών εντός κάποιας περιοχής.
Ας υποθέσουμε ότι πουλήσαμε επιτυχώς το προϊόν και το σημειώσαμε ως "Πληρώθηκε". Εάν ο πελάτης αρνήθηκε τα αγαθά, γράφουμε μηδέν (0) στο κελί. Εάν η συμφωνία δεν έκλεισε, το κελί παραμένει κενό.
Για να μετρήσετε μη κενά κύτταρα με οποιαδήποτε τιμή, χρησιμοποιήστε τα ακόλουθα:
=COUNTIF(F7:F15,"")
ή
=COUNTIF(F7:F15,A3)
Για να μετρήσετε τον αριθμό των κενά κελιά , φροντίστε να βάλετε τον τύπο COUNTIF με τον ακόλουθο τρόπο:
=COUNTIF(F7:F15,"")
ή
=COUNTIF(F7:F15,A4)
Ο αριθμός των κυττάρων με τιμή κειμένου υπολογίζεται ως εξής:
=COUNTIF(F7:F15, "*")
ή
=COUNTIF(F7:F15,A5)
Το παρακάτω στιγμιότυπο οθόνης δείχνει ότι τα κελιά A3, A4 και A5 περιλαμβάνουν τα κριτήριά μας:
Έτσι, μπορούμε να δούμε 4 κλειστές συμφωνίες, 3 από τις οποίες έχουν πληρωθεί και 5 από τις οποίες δεν έχουν ακόμη καμία σήμανση και, κατά συνέπεια, δεν έχουν κλείσει.
COUNTIF και μορφοποίηση υπό όρους
Υπάρχει μια ενδιαφέρουσα ευκαιρία που προσφέρουν τα Φύλλα Google - να να αλλάξετε τη μορφή του κελιού (όπως το χρώμα του) ανάλογα με κάποια κριτήρια. Για παράδειγμα, μπορούμε να επισημάνουμε τις τιμές που εμφανίζονται πιο συχνά με πράσινο χρώμα.
Η λειτουργία COUNTIF μπορεί να παίξει και εδώ έναν μικρό ρόλο.
Επιλέξτε την περιοχή των κελιών που θέλετε να μορφοποιήσετε με κάποιον ειδικό τρόπο. Μορφή ->, Μορφοποίηση υπό όρους...
Στο Μορφοποίηση κελιών αν... επιλέξτε την τελευταία επιλογή Ο προσαρμοσμένος τύπος είναι , και πληκτρολογήστε τον ακόλουθο τύπο στο πεδίο appeared:
=COUNTIF($B$10:$B$39,B10)/COUNTIF($B$10:$B$39,"*")>0.4
Αυτό σημαίνει ότι η συνθήκη θα απαντηθεί εάν η τιμή από το B10 εμφανίζεται εντός των B10:B39 σε περισσότερες από το 40% των περιπτώσεων:
Με παρόμοιο τρόπο, προσθέτουμε δύο ακόμη κριτήρια κανόνα μορφοποίησης - εάν η τιμή του κελιού εμφανίζεται συχνότερα από το 25% των περιπτώσεων και συχνότερα από το 15%:
=COUNTIF($B$10:$B$39,B10)/COUNTIF($B$10:$B$39,"*")>0.25
=COUNTIF($B$10:$B$39,B10)/COUNTIF($B$10:$B$39,"*")>0.15
Λάβετε υπόψη ότι το πρώτο κριτήριο θα ελεγχθεί εκ των προτέρων και αν ικανοποιείται, τα υπόλοιπα δεν θα ισχύουν. Γι' αυτό καλύτερα να ξεκινήσετε με τις πιο μοναδικές τιμές και να προχωρήσετε στις πιο κοινές. Αν η τιμή του κελιού δεν ικανοποιεί κανένα κριτήριο, η μορφή του θα παραμείνει ανέπαφη.
Μπορείτε να δείτε ότι το χρώμα των κελιών έχει αλλάξει σύμφωνα με τα κριτήριά μας.
Για να βεβαιωθούμε, μετρήσαμε επίσης τη συχνότητα ορισμένων τιμών στα C3:C6 χρησιμοποιώντας τη συνάρτηση COUNTIF. Τα αποτελέσματα επιβεβαιώνουν ότι η COUNTIF στον κανόνα μορφοποίησης εφαρμόστηκε σωστά.
Συμβουλή. Βρείτε περισσότερα παραδείγματα για το πώς να μετράτε και να επισημαίνετε τα διπλότυπα στα φύλλα Google.
Όλα αυτά τα παραδείγματα λειτουργιών μας δίνουν μια σαφή εικόνα του πώς το Google Spreadsheet COUNTIF προσφέρει πολλαπλές ευκαιρίες για να εργαστείτε με τα δεδομένα με τον πιο αποτελεσματικό τρόπο.
