Google Sheets COUNTIF je ena od najlažjih funkcij za učenje in ena od najbolj priročnih za uporabo.

Čas je, da se seznanite z uporabo funkcije COUNTIF v preglednici Google Spreadsheet in ugotovite, zakaj je ta funkcija pravi spremljevalec preglednice Google Spreadsheet.

Kaj je funkcija COUNTIF v Google preglednicah?

Ta kratek pomočnik nam omogoča, da preštejemo, kolikokrat se določena vrednost pojavi v določenem podatkovnem območju.

Skladnja COUNTIF v Google preglednicah

Sintaksa naše funkcije in njeni argumenti so naslednji:

• obseg - obseg celic, v katerih želimo prešteti določeno vrednost. Zahtevano.
• merilo ali merilo za iskanje - vrednost, ki jo je treba poiskati in prešteti v območju podatkov, navedenem v prvem argumentu. Zahtevano.

Preglednica Google COUNTIF v praksi

Morda se zdi, da je funkcija COUNTIF tako preprosta, da sploh ne šteje kot funkcija (besedna igra), vendar je njen potencial v resnici zelo impresiven. Že samo njena iskalna merila so dovolj, da si zasluži tak opis.

Gre za to, da se lahko odločimo, da ne bomo iskali le konkretnih vrednot, temveč tudi tiste, ki ustrezajo določenim merilom.

Skrajni čas je, da poskusimo skupaj oblikovati formulo.

Preglednica Google COUNTIF za besedilo in številke (natančno ujemanje)

Predpostavimo, da vaše podjetje prodaja različne vrste čokolade v več potrošniških regijah in sodeluje s številnimi strankami.

Tako so videti vaši podatki o prodaji v Google Sheets:

Začnimo z osnovami.

Prešteti moramo število prodanih čokolad z mlekom. Postavite kazalec v celico, v kateri želite dobiti rezultat, in vnesite znak enakosti (=). Google Sheets takoj razume, da bomo vnesli formulo. Ko vnesete črko "C", vas bo pozval k izbiri funkcije, ki se začne s to črko. Izberite "COUNTIF".

Prvi argument za COUNTIF predstavlja naslednje območje : D6:D16. Mimogrede, območja vam ni treba vnašati ročno - dovolj je izbira z miško. Nato vnesite vejico (,) in določite drugi argument - iskalna merila.

Drugi argument je vrednost, ki jo bomo poiskali v izbranem območju. V našem primeru je to besedilo - "Mlečna čokolada". Ne pozabite končati funkcije z zaključnim oklepajem ")" in pritisnite "Enter".

Prav tako ne pozabite vnesti dvojnih narekovajev (""), kadar uporabljate besedilne vrednosti.

Naša končna formula je videti takole:

=COUNTIF(D6:D16, "Mlečna čokolada")

Tako dobimo tri prodaje te vrste čokolade.

Opomba: Funkcija COUNTIF deluje z eno samo celico ali sosednjimi stolpci. Z drugimi besedami, ne morete navesti nekaj ločenih celic ali stolpcev in vrstic. Oglejte si spodnje primere.

Nepravilne formule:

=COUNTIF(C6:C16, D6:D16, "Mlečna čokolada")

=COUNTIF(D6, D8, D10, D12, D14, "Mlečna čokolada")

Pravilna uporaba:

=COUNTIF(C6:D16, "Mlečna čokolada")

=COUNTIF(D6, "Mlečna čokolada") + COUNTIF(D8, "Mlečna čokolada") + COUNTIF(D10, "Mlečna čokolada") + COUNTIF(D12, "Mlečna čokolada") + COUNTIF(D14, "Mlečna čokolada")

Morda ste opazili, da določanje meril za iskanje v formuli ni ravno priročno - vsakič jo morate urediti. Bolje bi bilo, če bi merila zapisali v drugo celico Google Sheets in se nanjo sklicevali v formuli.

Preštejmo število opravljenih prodaj v regiji "Zahod" z uporabo sklica na celico COUNTIF. Dobili bomo naslednjo formulo:

=COUNTIF(C6:C16,A3)

Funkcija pri svojih izračunih uporablja vsebino A3 (besedilno vrednost "West"). Kot vidite, je zdaj urejanje formule in njenih meril za iskanje veliko lažje.

Seveda lahko enako storimo tudi mi. s številčnimi vrednostmi Število pojavitev števila "125" lahko preštejemo tako, da kot drugi argument navedemo samo število:

=COUNTIF(E7:E17,125)

ali tako, da ga nadomestite s sklicevanjem na celico:

=COUNTIF(E7:E17,A3)

Funkcija COUNTIF v preglednici Google in nadomestni znaki (delno ujemanje)

COUNTIF je odličen v tem, da lahko šteje cele celice kot tudi deli vsebine celice. V ta namen uporabljamo nadomestni znaki : "?", "*".

Za štetje prodaje v določeni regiji lahko na primer uporabimo le del njenega imena: v polje B3 vnesite "?est". vprašalno znamenje (?) nadomesti en znak . Poiskali bomo štiričrkovne besede ki se konča z "est" , vključno s presledki.

V B3 uporabite naslednjo formulo COUNTIF:

=COUNTIF(C7:C17,A3)

Kot že veste, lahko formula preprosto dobi naslednjo obliko:

=COUNTIF(C7:C17, "?est")

V regiji "Zahod" je bilo prodanih 5 izdelkov.

Zdaj uporabimo celico B4 za drugo formulo:

=COUNTIF(C7:C17,A4)

Poleg tega bomo spremenili kriterij na "??st" v A4. To pomeni, da bomo zdaj iskali 4-črkovne besede. ki se končajo na "st" Ker v tem primeru dve regiji ("Zahod" in "Vzhod") izpolnjujeta naša merila, bomo videli devet prodaj:

Podobno lahko štejemo število prodaj blaga z uporabo zvezdica (*). Ta simbol ne nadomešča le enega, temveč poljubno število znakov :

"*Čokolada" kriterij šteje vse izdelke, ki se končajo na "Čokolada".

"Čokolada*" merila štejejo vse izdelke, ki se začnejo s "Čokolada".

In kot lahko uganete, če vstopimo v "*Čokolada*" poiskali bomo vse izdelke, ki vsebujejo besedo "čokolada".

Opomba: Če želite prešteti število besed, ki vsebujejo zvezdico (*) in vprašalni znak (?), uporabite znak tilde (~) pred temi znaki. V tem primeru jih bo COUNTIF obravnaval kot preproste znake in ne kot iskalne znake. Če želimo na primer poiskati vrednosti, ki vsebujejo "?", bo formula naslednja:

=COUNTIF(D7:D15,"*~?*")

COUNTIF Google preglednice za manj kot, več kot ali enako

Funkcija COUNTIF lahko šteje ne le, kolikokrat se neko število pojavi, temveč tudi, koliko številk je večja od/manjša od/enaka/ne enaka drugo določeno število.

V ta namen uporabljamo ustrezne matematične operatorje: "=", ">", "=", "<=", "".

V spodnji tabeli si oglejte, kako deluje:

Opomba: Zelo pomembno je, da priložite . matematični operator skupaj s številom v dvojnih narekovajih .

Če želite spremeniti merila, ne da bi spremenili formulo, se lahko sklicujete tudi na celice.

Sklicevanje na A3 in vnos formule v B3, tako kot prej:

=COUNTIF(F9:F19,A3)

Če želite ustvariti zahtevnejša merila, uporabite ampersand (&).

Na primer, B4 vsebuje formulo, ki šteje število vrednosti, večjih ali enakih 100 v območju E9:E19:

=COUNTIF(E9:E19,">="&A4)

B5 ima povsem enaka merila, vendar se poleg števila v tej celici sklicujemo tudi na matematični operator. Tako lahko formulo COUNTIF po potrebi še lažje prilagodimo:

=COUNTIF(E9:E19,A6&A5)

Nasvet: Velikokrat smo dobili vprašanje o štetju celic, ki so večje ali manjše od vrednosti v drugem stolpcu. Če iščete to, boste za to potrebovali drugo funkcijo - SUMPRODUCT.

Na primer, preštejmo vse vrstice, v katerih je prodaja v stolpcu F večja kot v isti vrstici stolpca G:

=SUMPRODUCT(--(F6:F16>G6:G16))

• Osrednji del formule - F6:F16>G6:G16 - primerja vrednosti v stolpcih F in G. Če je število v stolpcu F večje, formula to upošteva kot TRUE, v nasprotnem primeru pa kot FALSE.

  Če v polje ArrayFormula vnesete enako, boste videli, da:

  =ArrayFormula(F6:F16>G6:G16)

  

• Potem je formula takšna RESNIČNO/NERESNIČNO in ga spremeni v 1/0 števila s pomočjo dvojnega enojnega operatorja (--) .
• SUM tako opravi vse ostalo - sešteje število primerov, ko je F večji od G.

Preglednica Google COUNTIF z več merili

Včasih je treba prešteti število vrednosti, ki ustrezajo vsaj enemu od navedenih pogojev (logika OR) ali več kriterijem hkrati (logika AND). Na podlagi tega lahko uporabite več funkcij COUNTIF v eni celici hkrati ali nadomestno funkcijo COUNTIFS.

Štetje v Google preglednicah z več merili - logika AND

Edini način, ki bi vam ga svetoval, je uporaba posebne funkcije, ki je namenjena štetju po več merilih - COUNTIFS:

Običajno se uporablja, kadar sta v dveh razponih vrednosti, ki morata ustrezati določenim merilom, ali kadar želite dobiti število, ki spada med določen razpon števil.

Poskusimo prešteti število skupnih prodaj med 200 in 400:

=COUNTIFS(F8:F18,">=200",F8:F18,"<=400")

Nasvet. V tem članku se naučite, kako uporabljati COUNTIFS z barvami v Google Sheets.

Štetje unikatov v Google preglednicah z več merili

Lahko greste še dlje in preštejete število edinstvenih izdelkov med 200 in 400.

Ne, to ni isto kot zgoraj! :) Zgornji COUNTIFS šteje vsako pojavitev prodaje med 200 in 400. Predlagam, da si ogledate tudi izdelek. Če se njegovo ime pojavi več kot enkrat, ne bo vključen v rezultat.

Za to obstaja posebna funkcija COUNTUNIQUEIFS:

V primerjavi s COUNTIFS je razlika v prvem argumentu. Count_unique_range je območje, v katerem bo funkcija štela edinstvene zapise.

Tukaj je prikazana formula in njen rezultat:

=COUNTUNIQUEIFS(D6:D16,F6:F16,">=200",F6:F16,"<=400")

Poglejte, obstajajo 3 vrstice, ki ustrezajo mojim merilom: prodaja je 200 ali več in hkrati 400 ali manj.

Vendar sta dva od njih pripadala istemu izdelku - Mlečna čokolada . COUNTUNIQUEIFS šteje samo prvo omembo izdelka.

Tako vem, da sta le dva izdelka, ki izpolnjujeta moja merila.

Štetje v Google preglednicah z več merili - logika OR

Kadar je dovolj le eno od vseh meril, je bolje uporabiti več funkcij COUNTIF.

Primer 1. COUNTIF + COUNTIF

Preštejmo število prodaj črne in bele čokolade. To storimo tako, da v polje B4 vnesemo naslednjo formulo:

=COUNTIF(D7:D17, "*Mleko*") + COUNTIF(D7:D17, "*Temno*")

Nasvet: Z zvezdico (*) zagotovim, da bosta besedi "temno" in "mleko" upoštevani ne glede na to, kje sta v celici - na začetku, na sredini ali na koncu.

Nasvet: v formule lahko vedno vnesete sklice na celice. Na spodnji sliki zaslona si oglejte, kako je to videti v B3, rezultat ostaja enak:

Primer 2. COUNTIF - COUNTIF

Zdaj bom preštel število vseh prodaj med 200 in 400:

Vzamem število skupnih zneskov pod 400 in odštejem število skupnih prodaj pod 200 z naslednjo formulo:

=C0UNTIF(F7:F17,"<=400") - COUNTIF(F7:F17,"<=200")

Formula vrne število prodaj, ki je večje od 200 in manjše od 400.

Če se odločite za sklicevanje na A3 in A4, ki vsebujeta merila, bo formula nekoliko preprostejša:

=COUNTIF(F7:F17, A4) - COUNTIF(F7:F17, A3)

Celica A3 bo imela merilo "<=200", celica A4 pa "<=400". Obe formuli vstavite v B3 in B4 ter se prepričajte, da se rezultat ne spremeni - 3 prodaje v potrebnem območju.

COUNTIF Google Sheets za prazne in neprazne celice

S pomočjo COUNTIF lahko preštejemo tudi število praznih ali nepraznih celic v nekem območju.

Predpostavimo, da smo izdelek uspešno prodali in ga označili kot "Plačano". Če je kupec blago zavrnil, v celico zapišemo nič (0). Če posel ni bil sklenjen, celica ostane prazna.

Za štetje celice, ki niso prazne. s katero koli vrednostjo, uporabite naslednje:

=COUNTIF(F7:F15,"")

ali

=COUNTIF(F7:F15,A3)

Za štetje števila prazne celice , poskrbite, da bo formula COUNTIF zapisana na naslednji način:

=COUNTIF(F7:F15,"")

ali

=COUNTIF(F7:F15,A4)

Število celic z besedilna vrednost se šteje na naslednji način:

=COUNTIF(F7:F15, "*")

ali

=COUNTIF(F7:F15,A5)

Spodnja zaslonska slika prikazuje, da celice A3, A4 in A5 vključujejo naša merila:

Tako lahko vidimo 4 zaključene posle, od katerih so bili 3 plačani, 5 pa jih še ni označenih in zato niso zaključeni.

COUNTIF in pogojno oblikovanje

Googlove preglednice ponujajo eno zanimivo priložnost - da spremenite obliko celice (kot je njegova barva) glede na nekatera merila. Na primer, vrednosti, ki se pogosteje pojavljajo, lahko označimo z zeleno barvo.

Pri tem ima lahko majhno vlogo tudi funkcija COUNTIF.

Izberite obseg celic, ki jih želite oblikovati na poseben način. Format -> Pogojno oblikovanje...

V Oblikujte celice, če... v spustnem seznamu izberite zadnjo možnost Formula po meri je in v prikazano polje vnesite naslednjo formulo:

=COUNTIF($B$10:$B$39,B10)/COUNTIF($B$10:$B$39,"*")>0.4

To pomeni, da bo pogoj izpolnjen, če se vrednost iz B10 pojavi znotraj B10:B39 v več kot 40 % primerov:

Na podoben način dodamo še dve merili za pravilo oblikovanja - če se vrednost celice pojavi pogosteje kot v 25 % primerov in pogosteje kot v 15 % primerov:

=COUNTIF($B$10:$B$39,B10)/COUNTIF($B$10:$B$39,"*")>0.25

=COUNTIF($B$10:$B$39,B10)/COUNTIF($B$10:$B$39,"*")>0.15

Ne pozabite, da bo prvo merilo predhodno preverjeno, in če bo izpolnjeno, ostala merila ne bodo veljala. Zato je bolje, da začnete z najbolj edinstvenimi vrednostmi in nadaljujete z najpogostejšimi. Če vrednost celice ne izpolnjuje nobenega merila, bo njena oblika ostala nespremenjena.

Vidite, da se je barva celic spremenila v skladu z našimi merili.

Da bi se prepričali, smo s funkcijo COUNTIF prešteli tudi pogostost nekaterih vrednosti v C3:C6. Rezultati potrjujejo, da je bila funkcija COUNTIF v pravilu oblikovanja uporabljena pravilno.

Nasvet. Poiščite več primerov, kako prešteti in poudariti podvojitve v Google preglednicah.

Vsi ti primeri funkcij nam jasno pokažejo, kako Googlova preglednica COUNTIF ponuja številne možnosti za najbolj učinkovito delo s podatki.