Google Sheets COUNTIF este una dintre cele mai ușor de învățat și una dintre cele mai la îndemână funcții de utilizat.

Este timpul să acumulați câteva cunoștințe despre modul în care COUNTIF este utilizat în Google Spreadsheet și să aflați de ce această funcție este un adevărat partener în Google Spreadsheet.

Ce este funcția COUNTIF în Google Sheets?

Acest scurt ajutor ne permite să numărăm de câte ori apare o anumită valoare într-un interval de date specificat.

Sintaxa COUNTIF în Google Sheets

Sintaxa funcției noastre și argumentele sale sunt următoarele:

• gama - un interval de celule în care dorim să numărăm o anumită valoare. Necesar.
• criteriu sau criteriu de căutare - o valoare care trebuie găsită și contabilizată în intervalul de date indicat în primul argument. Necesar.

Foaia de calcul Google COUNTIF în practică

S-ar putea părea că COUNTIF este atât de simplă încât nici măcar nu se consideră o funcție (joc de cuvinte), dar, în realitate, potențialul său este destul de impresionant. Numai criteriile sale de căutare sunt suficiente pentru a merita o astfel de descriere.

Ideea este că putem decide să căutăm nu doar valori concrete, ci și pe cele care îndeplinesc anumite criterii.

Este timpul să încercăm să construim împreună o formulă.

Google Spreadsheet COUNTIF pentru text și numere (potrivire exactă)

Să presupunem că societatea dumneavoastră vinde diverse tipuri de ciocolată în mai multe regiuni de consum și lucrează cu mai mulți clienți.

Iată cum arată datele de vânzări în Google Sheets:

Să începem cu elementele de bază.

Trebuie să numărăm numărul de "Ciocolată cu lapte" vândute. Așezați cursorul în celula în care doriți să obțineți rezultatul și introduceți semnul de egalitate (=). Google Sheets înțelege imediat că vom introduce o formulă. Imediat ce veți introduce litera "C", vi se va cere să alegeți o funcție care începe cu această literă. Selectați "COUNTIF".

Primul argument de COUNTIF este reprezentat de următorul interval : D6:D16. Apropo, nu trebuie să introduceți manual intervalul - este suficientă selectarea cu mouse-ul. Apoi introduceți o virgulă (,) și specificați al doilea argument - criteriile de căutare.

Al doilea argument este o valoare pe care o vom căuta în intervalul selectat. În cazul nostru va fi textul - "Ciocolată cu lapte". Nu uitați să terminați funcția cu o paranteză de închidere ")" și apăsați "Enter".

De asemenea, nu uitați să introduceți ghilimele duble ("") atunci când utilizați valori text.

Formula noastră finală arată după cum urmează:

=COUNTIF(D6:D16, "Ciocolată cu lapte")

Ca urmare, avem trei vânzări de acest tip de ciocolată.

Notă. Funcția COUNTIF funcționează cu o singură celulă sau cu coloane învecinate. Cu alte cuvinte, nu puteți indica câteva celule separate sau coloane și rânduri. Vă rugăm să consultați exemplele de mai jos.

Formule incorecte:

=COUNTIF(C6:C16, D6:D16, "Ciocolată cu lapte")

=COUNTIF(D6, D8, D10, D12, D14, "Ciocolată cu lapte")

Utilizarea corectă:

=COUNTIF(C6:D16, "Ciocolată cu lapte")

=COUNTIF(D6, "Ciocolată cu lapte") + COUNTIF(D8, "Ciocolată cu lapte") + COUNTIF(D10, "Ciocolată cu lapte") + COUNTIF(D12, "Ciocolată cu lapte") + COUNTIF(D14, "Ciocolată cu lapte") + COUNTIF(D14, "Ciocolată cu lapte")

Poate ați observat că nu este foarte convenabil să setați criteriile de căutare în formulă - trebuie să o editați de fiecare dată. Cea mai bună decizie ar fi să scrieți criteriile într-o altă celulă din Google Sheets și să faceți referire la acea celulă în formulă.

Să numărăm numărul de vânzări apărute în regiunea "Vest" folosind referința celulei din COUNTIF. Vom obține următoarea formulă:

=COUNTIF(C6:C16,A3)

Funcția utilizează conținutul lui A3 (valoarea textului "West") în calculele sale. După cum puteți vedea, acum este mult mai ușor să editați formula și criteriile de căutare.

Bineînțeles, putem face același lucru cu valori numerice Putem număra numărul de apariții ale numărului "125", indicând numărul însuși ca al doilea argument:

=COUNTIF(E7:E17,125)

sau înlocuind-o cu o referință de celulă:

=COUNTIF(E7:E17,A3)

Funcția COUNTIF din foaia de calcul Google și caractere wildcard (potrivire parțială)

Ceea ce este grozav la COUNTIF este că poate număra celule întregi, precum și părți din conținutul celulei În acest scop, folosim caractere wildcard : "?", "*".

De exemplu, pentru a număra vânzările dintr-o anumită regiune, putem folosi doar partea din numele acesteia: introduceți "?est" în B3. A semn de întrebare (?) înlocuiește un caracter Vom căuta cuvintele din 4 litere. care se termină cu "est" , inclusiv spațiile.

Utilizați următoarea formulă COUNTIF în B3:

=COUNTIF(C7:C17,A3)

După cum știți deja, formula poate lua cu ușurință următoarea formă:

=COUNTIF(C7:C17, "?est")

Și putem vedea 5 vânzări în regiunea "Vest".

Acum, să folosim celula B4 pentru o altă formulă:

=COUNTIF(C7:C17,A4)

Mai mult, vom schimba criteriul în "??st" în A4. Aceasta înseamnă că acum vom căuta cuvinte din 4 litere. care se termină cu "st" Deoarece în acest caz, două regiuni ("Vest" și "Est") îndeplinesc criteriile noastre, vom vedea nouă vânzări:

În mod similar, putem număra numărul de vânzări de bunuri folosind un asterisc (*). acest simbol înlocuiește nu doar unul, ci orice număr de caractere :

"*Chocolată" criteriul numără toate produsele care se termină cu "Ciocolată".

"Ciocolată*" criteriul numără toate produsele care încep cu "ciocolată".

Și, după cum puteți ghici, dacă intrăm în "*Chocolată*" , vom căuta toate produsele care conțin cuvântul "Ciocolată".

Notă. Dacă trebuie să numărați numărul de cuvinte care conțin un asterisc (*) și un semn de întrebare (?), utilizați semnul tilde (~) înaintea acestor caractere. În acest caz, COUNTIF le va trata ca pe niște semne simple, mai degrabă decât ca pe niște caractere de căutare. De exemplu, dacă dorim să căutăm valorile care conțin "?", formula va fi:

=COUNTIF(D7:D15,"*~?*")

COUNTIF Google Sheets pentru mai mic decât, mai mare decât sau egal cu

Funcția COUNTIF este capabilă să numere nu numai de câte ori apare un anumit număr, ci și câte dintre numere sunt mai mare decât/mai mic decât/egal cu/neegal cu/neegal cu un alt număr specificat.

În acest scop, folosim operatorii matematici corespunzători: "=", ">", "=", "<=", "".

Consultați tabelul de mai jos pentru a vedea cum funcționează:

Notă. Este foarte important să anexa operatorul matematic împreună cu un număr în ghilimele duble .

Dacă doriți să modificați criteriile fără a modifica formula, puteți face referire și la celule.

Să facem trimitere la A3 și să introducem formula în B3, așa cum am făcut înainte:

=COUNTIF(F9:F19,A3)

Pentru a crea criterii mai sofisticate, folosiți un ampersandă (&).

De exemplu, B4 conține o formulă care numără numărul de valori mai mari sau egale cu 100 în intervalul E9:E19:

=COUNTIF(E9:E19,">="&A4)

B5 are exact aceleași criterii, dar facem referire nu numai la numărul din acea celulă, ci și la un operator matematic. Acest lucru facilitează și mai mult adaptarea formulei COUNTIF, dacă este necesar:

=COUNTIF(E9:E19,A6&A5)

Sfat. Am fost întrebați de multe ori despre numărarea acelor celule care sunt mai mari sau mai mici decât valorile dintr-o altă coloană. Dacă asta este ceea ce căutați, veți avea nevoie de o altă funcție pentru această sarcină - SUMPRODUCT.

De exemplu, să numărăm toate rândurile în care vânzările din coloana F sunt mai mari decât cele din același rând al coloanei G:

=SUMPRODUCT(--(F6:F16>G6:G16))

• Partea care se află în centrul formulei - F6:F16>G6:G16 - compară valorile din coloanele F și G. Dacă numărul din coloana F este mai mare, formula îl consideră ca fiind ADEVĂRAT, iar în caz contrar - FALS.

  Veți vedea că, dacă introduceți același lucru în ArrayFormula:

  =ArrayFormula(F6:F16>G6:G16)

  

• Apoi, formula are următoarea formulă ADEVĂRAT/FALSE și îl transformă în 1/0 numere cu ajutorul operatorului dublu unitar (--) .
• Acest lucru lasă SUM să facă restul - să totalizeze numărul de cazuri în care F este mai mare decât G.

Foaie de calcul Google COUNTIF cu criterii multiple

Uneori este necesar să se numere numărul de valori care răspund la cel puțin una dintre condițiile menționate (logica OR) sau mai multe criterii deodată (logica AND). Pe această bază, puteți utiliza fie câteva funcții COUNTIF într-o singură celulă la un moment dat, fie funcția alternativă COUNTIFS.

Numărătoarea în Google Sheets cu mai multe criterii - logică AND

Singura modalitate pe care v-aș sfătui să o utilizați aici este o funcție specială care este concepută pentru a număra după mai multe criterii - COUNTIFS:

În mod normal, se utilizează atunci când există valori în două intervale care trebuie să îndeplinească anumite criterii sau atunci când trebuie să obțineți numărul care se încadrează între un anumit interval de numere.

Să încercăm să numărăm numărul total de vânzări între 200 și 400:

=COUNTIFS(F8:F18,">=200",F8:F18,"<=400")

Sfat. Aflați cum să utilizați COUNTIFS cu culori în Google Sheets în acest articol.

Numărați unici în Google Sheets cu criterii multiple

Puteți merge mai departe și să numărați numărul de produse unice între 200 și 400.

Nu, nu este același lucru ca mai sus! :) COUNTIFS de mai sus numără fiecare apariție a vânzărilor între 200 și 400. Ceea ce vă sugerez este să vă uitați și la produs. Dacă numele acestuia apare de mai multe ori, nu va fi inclus în rezultat.

Există o funcție specială pentru acest lucru - COUNTUNIQUEIFS:

În comparație cu COUNTIFS, primul argument este cel care face diferența. Numărătoare_unică_range este intervalul în care funcția va număra înregistrările unice.

Iată cum va arăta formula și rezultatul acesteia:

=COUNTUNIQUEIFS(D6:D16,F6:F16,">=200",F6:F16,"<=400")

Uite, există 3 rânduri care îndeplinesc criteriile mele: vânzările sunt mai mari sau egale cu 200 și, în același timp, sunt mai mici sau egale cu 400.

Cu toate acestea, 2 dintre ele aparțin aceluiași produs - Ciocolată cu lapte COUNTUNIQUEIFS ia în considerare doar prima mențiune a produsului.

Astfel, știu că există doar 2 produse care îndeplinesc criteriile mele.

Numărătoarea în Google Sheets cu mai multe criterii - logica OR

Atunci când numai unul dintre toate criteriile este suficient, ar fi mai bine să utilizați mai multe funcții COUNTIF.

Exemplul 1. COUNTIF + COUNTIF

Să numărăm numărul de vânzări de ciocolată albă și neagră. Pentru a face acest lucru, introduceți următoarea formulă în B4:

=COUNTIF(D7:D17, "*Milk*") + COUNTIF(D7:D17, "*Dark*")

Sfat: Folosesc asterisc (*) pentru a mă asigura că cuvintele "întuneric" și "lapte" vor fi numărate indiferent de locul în care se află în celulă - la început, la mijloc sau la sfârșit.

Sfat. Puteți introduce întotdeauna referințe de celule în formulele dvs. Vedeți cum arată în captura de ecran de mai jos, în B3, rezultatul rămâne același:

Exemplul 2. COUNTIF - COUNTIF

Acum, voi număra numărul total de vânzări între 200 și 400:

Iau numărul de totaluri sub 400 și scad numărul de vânzări totale sub 200 folosind următoarea formulă:

=C0UNTIF(F7:F17,"<=400") - COUNTIF(F7:F17,"<=200")

Formula returnează numărul de vânzări mai mari de 200 și mai mici de 400.

Dacă decideți să faceți trimitere la A3 și A4 care conțin criteriile, formula va fi puțin mai simplă:

=COUNTIF(F7:F17, A4) - COUNTIF(F7:F17, A3)

Celula A3 va avea criteriul "<=200", în timp ce A4 - "<=400". Puneți ambele formule în B3 și B4 și asigurați-vă că rezultatul nu se schimbă - 3 vânzări pe intervalul necesar.

COUNTIF Google Sheets pentru celule goale și non-goale

Cu ajutorul COUNTIF, putem, de asemenea, să numărăm numărul de celule goale sau ne-goale din cadrul unui anumit interval.

Să presupunem că am vândut cu succes produsul și l-am marcat ca fiind "Plătit". Dacă clientul a refuzat marfa, scriem zero (0) în celulă. Dacă afacerea nu a fost încheiată, celula rămâne goală.

Pentru a număra celule fără goluri cu orice valoare, utilizați următoarele:

=COUNTIF(F7:F15,"")

sau

=COUNTIF(F7:F15,A3)

Pentru a număra numărul de celule goale , asigurați-vă că formula COUNTIF este pusă în felul următor:

=COUNTIF(F7:F15,"")

sau

=COUNTIF(F7:F15,A4)

Numărul de celule cu un valoare textuală se numără astfel:

=COUNTIF(F7:F15, "*")

sau

=COUNTIF(F7:F15,A5)

Captura de ecran de mai jos arată că celulele A3, A4 și A5 includ criteriile noastre:

Astfel, putem vedea 4 tranzacții încheiate, dintre care 3 au fost plătite și 5 nu au încă marcaje și, prin urmare, nu sunt încheiate.

COUNTIF și formatarea condiționată

Există o oportunitate interesantă pe care o oferă Google Sheets - să modificați formatul celulei (De exemplu, putem evidenția valorile care apar mai des cu culoarea verde.

Funcția COUNTIF poate juca un rol important și în acest caz.

Selectați intervalul de celule pe care doriți să le formatați într-un mod special. Faceți clic pe Format -> Formatarea condiționată...

În Formatați celulele dacă... lista derulantă alegeți ultima opțiune Formula personalizată este , și introduceți următoarea formulă în câmpul apărut:

=COUNTIF($B$10:$B$39,B10)/COUNTIF($B$10:$B$39,"*")>0.4

Aceasta înseamnă că se va răspunde la această condiție dacă valoarea din B10 apare în B10:B39 în mai mult de 40% din cazuri:

În mod similar, adăugăm încă două criterii de regulă de formatare - dacă valoarea celulei apare mai des decât în 25% din cazuri și mai des decât în 15%:

=COUNTIF($B$10:$B$39,B10)/COUNTIF($B$10:$B$39,"*")>0.25

=COUNTIF($B$10:$B$39,B10)/COUNTIF($B$10:$B$39,"*")>0.15

Rețineți că primul criteriu va fi verificat în prealabil, iar dacă este îndeplinit, celelalte nu se vor aplica. De aceea, ar fi bine să începeți cu cele mai unice valori, trecând la cele mai comune. Dacă valoarea celulei nu îndeplinește niciun criteriu, formatul acesteia va rămâne intact.

Puteți vedea că culoarea celulelor s-a schimbat în funcție de criteriile noastre.

Pentru a ne asigura, am numărat, de asemenea, frecvența unor valori din C3:C6 folosind funcția COUNTIF. Rezultatele confirmă faptul că COUNTIF din regula de formatare a fost aplicată corect.

Sfat. Găsiți mai multe exemple despre cum să numărați & evidențiați duplicatele în Google Sheets.

Toate aceste exemple de funcții ne oferă o înțelegere clară a modului în care Google Spreadsheet COUNTIF oferă multiple oportunități de a lucra cu datele în cel mai eficient mod.