Tabla de contenido
Google Sheets COUNTIF es una de las funciones más fáciles de aprender y una de las más prácticas de utilizar.
Es hora de aprender cómo se utiliza COUNTIF en Google Spreadsheet y por qué esta función es una verdadera compañera de Google Spreadsheet.
¿Qué es la función COUNTIF en Google Sheets?
Este breve ayudante nos permite contar cuántas veces aparece un determinado valor dentro de un rango de datos especificado.
Sintaxis COUNTIF en Google Sheets
La sintaxis de nuestra función y sus argumentos son los siguientes:
=COUNTIF(intervalo, criterio)- gama - un rango de celdas donde queremos contar un determinado valor. Obligatorio.
- criterio o criterio de búsqueda: un valor que buscar y contar en el intervalo de datos indicado en el primer argumento. Obligatorio.
Hoja de cálculo de Google COUNTIF en la práctica
Puede parecer que COUNTIF es tan simple que ni siquiera cuenta como función (valga el juego de palabras), pero en realidad su potencial es bastante impresionante. Su criterio de búsqueda por sí solo es suficiente para ganarse tal descripción.
La cuestión es que podemos decidir buscar no sólo valores concretos, sino también aquellos que cumplan determinados criterios.
Ya es hora de intentar construir juntos una fórmula.
Hoja de cálculo de Google COUNTIF para texto y números (coincidencia exacta)
Supongamos que su empresa vende diversos tipos de chocolate en varias regiones consumidoras y trabaja con muchos clientes.
Así es como se ven tus datos de ventas en Google Sheets:
Empecemos por lo básico.
Necesitamos contar el número de "Chocolate con leche" vendidos. Coloca el cursor en la celda donde quieras obtener el resultado e introduce el signo de igualdad (=). Google Sheets entiende inmediatamente que vamos a introducir una fórmula. En cuanto escribas la letra "C", te pedirá que elijas una función que empiece por esa letra. Selecciona "COUNTIF".
El primer argumento de COUNTIF está representado por la siguiente gama D6:D16. Por cierto, no es necesario introducir el rango manualmente, basta con seleccionar con el ratón. A continuación, introduzca una coma (,) y especifique el segundo argumento: los criterios de búsqueda.
El segundo argumento es un valor que vamos a buscar en el rango seleccionado. En nuestro caso va a ser el texto - "Chocolate con leche". Recuerda terminar la función con un corchete de cierre ")" y pulsa "Intro".
Además, no olvides introducir comillas dobles ("") cuando utilices valores de texto.
Nuestra fórmula final es la siguiente:
=COUNTIF(D6:D16, "Chocolate con leche")
Como resultado, obtenemos tres ventas de este tipo de chocolate.
Nota. La función COUNTIF funciona con una sola celda o columnas vecinas. Es decir, no se pueden indicar varias celdas o columnas y filas separadas. Consulte los ejemplos siguientes.
Fórmulas incorrectas:
=COUNTIF(C6:C16, D6:D16, "Chocolate con leche")
=COUNTIF(D6, D8, D10, D12, D14, "Chocolate con leche")
Uso correcto:
=COUNTIF(C6:D16, "Chocolate con leche")
=COUNTIF(D6, "Chocolate con leche") + COUNTIF(D8, "Chocolate con leche") + COUNTIF(D10, "Chocolate con leche") + COUNTIF(D12, "Chocolate con leche") + COUNTIF(D14, "Chocolate con leche")
Te habrás dado cuenta de que no es muy cómodo establecer los criterios de búsqueda en la fórmula, ya que tienes que editarla cada vez. La mejor decisión sería escribir los criterios en otra celda de Google Sheets y hacer referencia a esa celda en la fórmula.
Contemos el número de ventas ocurridas en la región "Oeste" utilizando la referencia de celda en COUNTIF. Obtendremos la siguiente fórmula:
=COUNTIF(C6:C16,A3)
La función utiliza el contenido de A3 (el valor de texto "Oeste") en sus cálculos. Como puede ver, ahora es mucho más fácil editar la fórmula y sus criterios de búsqueda.
Por supuesto, podemos hacer lo mismo con valores numéricos Podemos contar el número de apariciones del número "125" indicando el propio número como segundo argumento:
=COUNTIF(E7:E17,125)
o sustituyéndola por una referencia de celda:
=COUNTIF(E7:E17,A3)
Función COUNTIF de Google Spreadsheet y caracteres comodín (coincidencia parcial)
Lo bueno de COUNTIF es que puede contar tanto células enteras como partes del contenido de la célula Para ello, utilizamos caracteres comodín : "?", "*".
Por ejemplo, para contar las ventas en una región concreta podemos utilizar sólo la parte de su nombre: introduzca "?est" en B3. A signo de interrogación (?) sustituye un carácter Vamos a buscar las palabras de 4 letras... que termina con "est" incluidos los espacios.
Utilice la siguiente fórmula COUNTIF en B3:
=COUNTIF(C7:C17,A3)
Como ya sabes, la fórmula puede adoptar fácilmente la siguiente forma:
=COUNTIF(C7:C17, "?est")
Y podemos ver 5 ventas en la región "Oeste".
Ahora empleemos la celda B4 para otra fórmula:
=COUNTIF(C7:C17,A4)
Además, cambiaremos el criterio por "??st" en A4. Esto significa que ahora buscaremos palabras de 4 letras que termina en "st Como en este caso dos regiones ("Oeste" y "Este") cumplen nuestros criterios, veremos nueve ventas:
Del mismo modo, podemos contar el número de ventas de las mercancías utilizando un asterisco (*). Este símbolo sustituye no sólo a uno, sino a cualquier número de caracteres :
"*Chocolate" cuenta todos los productos que terminan en "Chocolate".
"Chocolate*" cuenta todos los productos que empiezan por "Chocolate".
Y, como puede adivinar, si entramos en "*Chocolate*" vamos a buscar todos los productos que contengan la palabra "Chocolate".
Nota: si necesita contar el número de palabras que contienen un asterisco (*) y un signo de interrogación (?), utilice signo de tilde (~) antes de esos caracteres. En este caso, COUNTIF los tratará como simples signos en lugar de caracteres de búsqueda. Por ejemplo, si queremos buscar los valores que contengan "?", la fórmula será:
=COUNTIF(D7:D15,"*~?*")
COUNTIF Hojas de cálculo de Google para menor, mayor o igual que
La función COUNTIF es capaz de contar no sólo cuántas veces aparece algún número, sino también cuántos de los números son mayor que/menor que/igual a/no igual a otro número especificado.
Para ello, utilizamos los operadores matemáticos correspondientes: "=", ">", "=", "<=", "".
Consulta la tabla siguiente para ver cómo funciona:
| Criterios | Ejemplo de fórmula | Descripción |
| El número es mayor que | =COUNTIF(F9:F19,">100") | Contar las celdas en las que los valores son superiores a 100. |
| El número es inferior a | =COUNTIF(F9:F19,"<100") | Contar las celdas cuyos valores son inferiores a 100. |
| El número es igual a | =COUNTIF(F9:F19,"=100") | Contar las celdas cuyos valores son iguales a 100. |
| El número no es igual a | =COUNTIF(F9:F19,"100") | Contar las celdas en las que los valores no son iguales a 100. |
| El número es mayor o igual que | =COUNTIF(F9:F19,">=100") | Contar las celdas cuyos valores son mayores o iguales a 100. |
| El número es menor o igual que | =COUNTIF(F9:F19,"<=100") | Contar las celdas cuyos valores son inferiores o iguales a 100. |
Nota. Es muy importante incluya el operador matemático junto con un número entre comillas dobles .
Si desea modificar los criterios sin alterar la fórmula, también puede hacer referencia a las celdas.
Hagamos referencia a A3 y pongamos la fórmula en B3, igual que hicimos antes:
=COUNTIF(F9:F19,A3)
Para crear criterios más sofisticados, utilice un ampersand (&).
Por ejemplo, B4 contiene una fórmula que cuenta el número de valores mayores o iguales que 100 en el rango E9:E19:
=COUNTIF(E9:E19,">="&A4)
B5 tiene el mismo criterio, pero no sólo hacemos referencia al número de esa celda, sino también a un operador matemático, lo que facilita aún más la adaptación de la fórmula COUNTIF en caso necesario:
=COUNTIF(E9:E19,A6&A5)
Consejo: Nos han preguntado mucho sobre cómo contar las celdas que son mayores o menores que los valores de otra columna. Si eso es lo que buscas, necesitarás otra función para el trabajo: SUMPRODUCTO.
Por ejemplo, contemos todas las filas en las que las ventas de la columna F son mayores que las de la misma fila de la columna G:
=SUMPRODUCT(--(F6:F16>G6:G16))
- La parte central de la fórmula - F6:F16>G6:G16 - compara los valores de las columnas F y G. Cuando el número de la columna F es mayor, la fórmula lo toma como VERDADERO, en caso contrario - FALSO.
Verás que si introduces lo mismo en la ArrayFormula:
=ArrayFormula(F6:F16>G6:G16)
- Entonces la fórmula toma este VERDADERO/FALSO y lo convierte en 1/0 números con la ayuda del operador unario doble (--) .
- Esto permite a SUM hacer el resto - sumar el número de veces que F es mayor que G.
Hoja de cálculo de Google COUNTIF con múltiples criterios
A veces es necesario contar el número de valores que responden al menos a una de las condiciones mencionadas (lógica OR) o a varios criterios a la vez (lógica AND). En función de ello, puede utilizar varias funciones COUNTIF en una sola celda a la vez o la función alternativa COUNTIFS.
Recuento en Google Sheets con múltiples criterios - lógica AND
La única forma que te aconsejo utilizar aquí es con una función especial que está diseñada para contar por múltiples criterios - COUNTIFS:
=COUNTIFS(rango_criterios1, criterio1, [rango_criterios2, criterio2, ...])Normalmente se utiliza cuando hay valores en dos rangos que deben cumplir algún criterio o siempre que se necesite obtener el número que cae entre un rango específico de números.
Intentemos contar el número de ventas totales entre 200 y 400:
=COUNTIFS(F8:F18,">=200",F8:F18,"<=400")
Consejo. Aprende a utilizar COUNTIFS con colores en Google Sheets en este artículo.
Contar uniques en Google Sheets con múltiples criterios
Se puede ir más lejos y contar el número de productos únicos entre 200 y 400.
No, ¡no es lo mismo que arriba! :) El COUNTIFS de arriba cuenta cada ocurrencia de ventas entre 200 y 400. Lo que sugiero es mirar también el producto. Si su nombre aparece más de una vez, no se incluirá en el resultado.
Existe una función especial para ello: COUNTUNIQUEIFS:
COUNTUNIQUEIFS(count_unique_range, criteria_range1, criterion1, [criteria_range2, criterion2, ...])En comparación con COUNTIFS, es el primer argumento el que marca la diferencia. Contar_rango_único es el rango en el que la función contará los registros únicos.
Así es como se verá la fórmula y su resultado:
=COUNTUNIQUEIFS(D6:D16,F6:F16,">=200",F6:F16,"<=400")
Mira, hay 3 filas que cumplen mis criterios: las ventas son 200 o más y al mismo tiempo son 400 o menos.
Sin embargo, 2 de ellos pertenecen al mismo producto - Chocolate con leche COUNTUNIQUEIFS sólo cuenta la primera mención del producto.
Así, sé que sólo hay 2 productos que cumplen mis criterios.
Conteo en Google Sheets con múltiples criterios - Lógica OR
Cuando sólo basta con uno de todos los criterios, es mejor utilizar varias funciones COUNTIF.
Ejemplo 1. COUNTIF + COUNTIF
Vamos a contar el número de ventas de chocolate blanco y negro. Para ello, introduce la siguiente fórmula en B4:
=COUNTIF(D7:D17, "*Leche*") + COUNTIF(D7:D17, "*Oscuro*")
Consejo: Utilizo un asterisco (*) para asegurarme de que las palabras "oscuro" y "leche" se cuentan independientemente de dónde se encuentren en la celda: al principio, en medio o al final.
Consejo. Siempre puedes introducir referencias de celda en tus fórmulas. Mira cómo queda en la captura de pantalla de abajo en B3, el resultado sigue siendo el mismo:
Ejemplo 2. COUNTIF - COUNTIF
Ahora voy a contar el número de ventas totales entre 200 y 400:
Tomo el número de totales inferiores a 400 y le resto el número de ventas totales inferiores a 200 utilizando la siguiente fórmula:
=C0UNTIF(F7:F17,"<=400") - COUNTIF(F7:F17,"<=200")
La fórmula devuelve el número de ventas superiores a 200 pero inferiores a 400.
Si decide hacer referencia a A3 y A4 que contienen los criterios, la fórmula será un poco más sencilla:
=COUNTIF(F7:F17, A4) - COUNTIF(F7:F17, A3)
La celda A3 tendrá el criterio "<=200", mientras que A4 - "<=400". Ponga ambas fórmulas en B3 y B4 y asegúrese de que el resultado no cambia - 3 ventas en el rango necesario.
COUNTIF Google Sheets para celdas en blanco y no en blanco
Con la ayuda de COUNTIF, también podemos contar el número de celdas en blanco o no en blanco dentro de algún rango.
Supongamos que vendimos con éxito el producto y lo marcamos como "Pagado". Si el cliente rechazó la mercancía, escribimos cero (0) en la celda. Si el trato no se cerró, la celda permanece vacía.
Contar células no en blanco con cualquier valor, utilice lo siguiente:
=COUNTIF(F7:F15,"")
o
=COUNTIF(F7:F15,A3)
Para contar el número de celdas vacías asegúrate de poner la fórmula COUNTIF de la siguiente manera:
=COUNTIF(F7:F15,"")
o
=COUNTIF(F7:F15,A4)
El número de celdas con un valor textual se cuenta así:
=COUNTIF(F7:F15, "*")
o
=COUNTIF(F7:F15,A5)
La siguiente captura de pantalla muestra que las celdas A3, A4 y A5 incluyen nuestros criterios:
Así, podemos ver 4 operaciones cerradas, 3 de las cuales fueron pagadas y 5 de las cuales aún no tienen marcas y, en consecuencia, no están cerradas.
COUNTIF y el formato condicional
Google Sheets ofrece una oportunidad interesante para cambiar el formato de la celda (como su color) en función de algunos criterios. Por ejemplo, podemos resaltar en verde los valores que aparecen más a menudo.
La función COUNTIF también puede desempeñar un pequeño papel en este caso.
Seleccione el rango de celdas que desea formatear de alguna manera especial. Haga clic en Formato -> Formato condicional...
En el Formatear celdas si... elija la última opción La fórmula personalizada es e introduce la siguiente fórmula en el campo aparecido:
=COUNTIF($B$10:$B$39,B10)/COUNTIF($B$10:$B$39,"*")>0.4
Significa que se responderá a la condición si el valor de B10 aparece dentro de B10:B39 en más del 40% de los casos:
De forma similar, añadimos otros dos criterios de regla de formato: si el valor de la celda aparece más a menudo que en el 25% de los casos y más a menudo que en el 15%:
=COUNTIF($B$10:$B$39,B10)/COUNTIF($B$10:$B$39,"*")>0.25
=COUNTIF($B$10:$B$39,B10)/COUNTIF($B$10:$B$39,"*")>0.15
Tenga en cuenta que el primer criterio se comprobará de antemano y, si se cumple, el resto no se aplicarán. Por eso es mejor que empiece por los valores más singulares para pasar a los más comunes. Si el valor de la celda no cumple ningún criterio, su formato permanecerá intacto.
Puede ver que el color de las celdas ha cambiado según nuestro criterio.
Para asegurarnos, también contamos la frecuencia de algunos valores en C3:C6 utilizando la función COUNTIF. Los resultados confirman que COUNTIF en la regla de formato se aplicó correctamente.
Sugerencia. Encuentra más ejemplos sobre cómo contar & resaltar duplicados en Hojas de cálculo de Google.
Todos estos ejemplos de funciones nos dan una clara comprensión de cómo Google Spreadsheet COUNTIF ofrece múltiples oportunidades para trabajar con los datos de la manera más eficiente.
