Obsah
Funkce COUNTIF v tabulkách Google je jednou z nejjednodušších na naučení a jednou z nejpraktičtějších na používání.
Je na čase si osvojit znalosti o tom, jak se v tabulkovém procesoru Google používá funkce COUNTIF, a zjistit, proč je tato funkce skutečným společníkem tabulkového procesoru Google.
Co je to funkce COUNTIF v Tabulkách Google?
Tento krátký pomocník nám umožňuje spočítat, kolikrát se určitá hodnota objeví v zadaném rozsahu dat.
Syntaxe COUNTIF v Tabulkách Google
Syntaxe naší funkce a její argumenty jsou následující:
=COUNTIF(rozsah, kritérium)- rozsah - rozsah buněk, ve kterých chceme počítat určitou hodnotu. Požadováno.
- kritérium nebo vyhledávací kritérium - hodnota, kterou je třeba najít a spočítat v rozsahu dat uvedeném v prvním argumentu. Povinné.
Tabulka Google COUNTIF v praxi
Může se zdát, že COUNTIF je tak jednoduchý, že se ani nepočítá jako funkce (slovní hříčka), ale ve skutečnosti je jeho potenciál docela působivý. Už jen jeho vyhledávací kritéria stačí k tomu, aby si zasloužil takový popis.
Jde o to, že se můžeme rozhodnout hledat nejen konkrétní hodnoty, ale i ty, které splňují určitá kritéria.
Je nejvyšší čas pokusit se vytvořit společný vzorec.
Tabulka Google COUNTIF pro text a čísla (přesná shoda)
Předpokládejme, že vaše společnost prodává různé druhy čokolády v několika spotřebitelských oblastech a spolupracuje s mnoha zákazníky.
Takto vypadají vaše údaje o prodeji v tabulkách Google:
Začněme od základů.
Potřebujeme spočítat počet prodaných "mléčných čokolád". Umístěte kurzor do buňky, kde chcete získat výsledek, a zadejte znak rovnosti (=). Google Sheets okamžitě pochopí, že budeme zadávat vzorec. Jakmile zadáte písmeno "C", vyzve vás k výběru funkce, která tímto písmenem začíná. Vyberte "COUNTIF".
První argument společnosti COUNTIF představuje následující rozsah : D6:D16. Mimochodem, rozsah nemusíte zadávat ručně - stačí výběr myší. Dále zadejte čárku (,) a zadejte druhý argument - vyhledávací kritéria.
Druhý argument je hodnota, kterou budeme hledat ve vybraném rozsahu. V našem případě to bude hodnota text - "Mléčná čokoláda". Nezapomeňte funkci ukončit uzavírací závorkou ")" a stiskněte "Enter".
Při použití textových hodnot nezapomeňte také na dvojité uvozovky ("").
Náš konečný vzorec vypadá takto:
=COUNTIF(D6:D16, "Mléčná čokoláda")
Výsledkem jsou tři prodeje tohoto typu čokolády.
Poznámka: Funkce COUNTIF pracuje s jednou buňkou nebo sousedními sloupci. Jinými slovy, nelze uvést několik samostatných buněk nebo sloupců a řádků. Viz příklady níže.
Nesprávné vzorce:
=COUNTIF(C6:C16, D6:D16, "Mléčná čokoláda")
=COUNTIF(D6, D8, D10, D12, D14, "Mléčná čokoláda")
Správné použití:
=COUNTIF(C6:D16, "Mléčná čokoláda")
=COUNTIF(D6, "Mléčná čokoláda") + COUNTIF(D8, "Mléčná čokoláda") + COUNTIF(D10, "Mléčná čokoláda") + COUNTIF(D12, "Mléčná čokoláda") + COUNTIF(D14, "Mléčná čokoláda")
Možná jste si všimli, že není úplně pohodlné nastavovat kritéria vyhledávání ve vzorci - musíte je pokaždé upravovat. Lepší by bylo zapsat kritéria do jiné buňky Tabulky Google a na tuto buňku se ve vzorci odkazovat.
Spočítejme počet uskutečněných prodejů v regionu "Západ" pomocí odkazu na buňku COUNTIF. Získáme následující vzorec:
=COUNTIF(C6:C16,A3)
Funkce používá ve svých výpočtech obsah pole A3 (textovou hodnotu "West"). Jak vidíte, úprava vzorce a jeho vyhledávacích kritérií je nyní mnohem jednodušší.
Samozřejmě můžeme udělat totéž s číselnými hodnotami . Počet výskytů čísla "125" můžeme spočítat tak, že jako druhý argument uvedeme samotné číslo:
=COUNTIF(E7:E17,125)
nebo nahrazením odkazem na buňku:
=COUNTIF(E7:E17,A3)
Funkce COUNTIF v tabulkovém procesoru Google a zástupné znaky (částečná shoda)
COUNTIF je skvělý v tom, že dokáže počítat celé buňky a také části obsahu buňky K tomuto účelu používáme zástupné znaky : "?", "*".
Chceme-li například spočítat prodeje v určitém regionu, můžeme použít pouze část jeho názvu: do pole B3 zadáme "?est". A otazník (?) nahrazuje jedna postava . Budeme hledat slova na 4 písmena. končící na "est" , včetně mezer.
Použijte následující vzorec COUNTIF v B3:
=COUNTIF(C7:C17,A3)
Jak již víte, vzorec může snadno nabýt další podoby:
=COUNTIF(C7:C17, "?est")
A v regionu "Západ" vidíme 5 prodejů.
Nyní použijeme buňku B4 pro další vzorec:
=COUNTIF(C7:C17,A4)
Navíc změníme kritérium na "??st" ve formátu A4. To znamená, že nyní budeme hledat slova na 4 písmena. končící na "st" Protože v tomto případě splňují naše kritéria dva regiony ("Západ" a "Východ"), zobrazí se devět prodejů:
Podobně můžeme spočítat počet prodejů zboží pomocí číselníku hvězdička (*). Tento symbol nenahrazuje pouze jeden, ale libovolný počet znaků :
"*Čokoláda" kritéria počítají všechny produkty končící na "Chocolate".
"Čokoláda*" kritéria počítají všechny produkty začínající na "Chocolate".
A jak asi tušíte, pokud vstoupíme do "*Čokoláda*" , budeme hledat všechny výrobky, které obsahují slovo "čokoláda".
Poznámka: Pokud potřebujete spočítat počet slov, která obsahují hvězdičku (*) a otazník (?), použijte příkaz znak tilda (~) před těmito znaky. V tomto případě je COUNTIF bude považovat za jednoduché znaky, nikoli za vyhledávací znaky. Například pokud chceme vyhledat hodnoty, které obsahují "?", vzorec bude:
=COUNTIF(D7:D15,"*~?*")
COUNTIF Tabulky Google pro menší než, větší než nebo rovno
Funkce COUNTIF dokáže spočítat nejen to, kolikrát se nějaké číslo objeví, ale také kolik z těchto čísel je. větší než/menší než/rovná se/nerovná se jiné zadané číslo.
K tomuto účelu používáme odpovídající matematické operátory: "=", ">", "=", "<=", "".
Podívejte se do tabulky níže a zjistěte, jak to funguje:
| Kritéria | Příklad vzorce | Popis |
| Číslo je větší než | =COUNTIF(F9:F19,">100") | Spočítejte buňky, ve kterých jsou hodnoty větší než 100. |
| Číslo je menší než | =COUNTIF(F9:F19,"<100") | Spočítejte buňky, ve kterých jsou hodnoty menší než 100. |
| Číslo se rovná | =COUNTIF(F9:F19,"=100") | Spočítejte buňky, v nichž se hodnoty rovnají 100. |
| Číslo se nerovná | =COUNTIF(F9:F19,"100") | Spočítejte buňky, jejichž hodnoty se nerovnají 100. |
| Číslo je větší nebo rovno | =COUNTIF(F9:F19,">=100") | Spočítejte buňky, ve kterých jsou hodnoty větší nebo rovny 100. |
| Číslo je menší nebo rovno | =COUNTIF(F9:F19,"<=100") | Spočítejte buňky, ve kterých jsou hodnoty menší nebo rovny 100. |
Poznámka: Je velmi důležité, abyste přiložit matematický operátor spolu s číslem v uvozovkách .
Pokud chcete změnit kritéria, aniž byste měnili vzorec, můžete se na buňky také odkázat.
Odkažme se na A3 a vložme vzorec do B3, stejně jako jsme to udělali dříve:
=COUNTIF(F9:F19,A3)
Chcete-li vytvořit sofistikovanější kritéria, použijte příkaz ampersand (&).
Například B4 obsahuje vzorec, který počítá počet hodnot větších nebo rovných 100 v rozsahu E9:E19:
=COUNTIF(E9:E19,">="&A4)
B5 má úplně stejná kritéria, ale odkazujeme nejen na číslo v této buňce, ale také na matematický operátor. Díky tomu je v případě potřeby ještě snazší vzorec COUNTIF upravit:
=COUNTIF(E9:E19,A6&A5)
Tip: Často se nás ptáte na počítání těch buněk, které jsou větší nebo menší než hodnoty v jiném sloupci. Pokud hledáte právě toto, budete potřebovat jinou funkci pro tuto práci - SUMPRODUCT.
Například spočítejme všechny řádky, kde jsou tržby ve sloupci F větší než ve stejném řádku sloupce G:
=SUMPRODUCT(--(F6:F16>G6:G16))
- Část, která je jádrem vzorce - F6:F16>G6:G16 - porovnává hodnoty ve sloupcích F a G. Pokud je číslo ve sloupci F větší, vzorec ho považuje za TRUE, jinak za FALSE.
Uvidíte, že pokud zadáte stejný údaj do pole ArrayFormula:
=ArrayFormula(F6:F16>G6:G16)
- Vzorec pak vypadá takto PRAVDA/NEPRAVDA a změní jej na 1/0 čísla pomocí dvojitého unárního operátoru (--) .
- SUMA se postará o zbytek - sečte počet případů, kdy je F větší než G.
Tabulka Google COUNTIF s více kritérii
Někdy je potřeba spočítat počet hodnot, které odpovídají alespoň jedné z uvedených podmínek (logika OR) nebo více kritérií najednou (logika AND). Na základě toho můžete použít buď několik funkcí COUNTIF v jedné buňce najednou, nebo alternativní funkci COUNTIFS.
Počítání v tabulkách Google s více kritérii - logika AND
Jediný způsob, který bych vám zde doporučil, je použití speciální funkce, která je určena k počítání podle více kritérií - COUNTIFS:
=COUNTIFS(kritérium_rozsah1, kritérium1, [kritérium_rozsah2, kritérium2, ...])Obvykle se používá, když jsou ve dvou rozsazích hodnoty, které by měly splňovat nějaká kritéria, nebo když potřebujete získat číslo spadající mezi určitý rozsah čísel.
Zkusme spočítat počet celkových prodejů mezi 200 a 400:
=COUNTIFS(F8:F18,">=200",F8:F18,"<=400")
Tip: V tomto článku se dozvíte, jak používat COUNTIFS s barvami v tabulkách Google.
Počítání unikátů v tabulkách Google s více kritérii
Můžete jít ještě dál a spočítat počet jedinečných produktů mezi 200 a 400.
Kdepak, není to stejné jako výše! :) Výše uvedený COUNTIFS počítá každý výskyt prodeje mezi 200 a 400. Co doporučuji, je podívat se také na produkt. Pokud se jeho název vyskytuje více než jednou, nebude do výsledku zahrnut.
K tomu slouží speciální funkce COUNTUNIQUEIFS:
COUNTUNIQUEIFS(count_unique_range, criteria_range1, criterion1, [criteria_range2, criterion2, ...])V porovnání s COUNTIFS je rozdíl v prvním argumentu. Count_unique_range je rozsah, ve kterém bude funkce počítat jedinečné záznamy.
Zde je uveden vzorec a jeho výsledek:
=COUNTUNIQUEIFS(D6:D16,F6:F16,">=200",F6:F16,"<=400")
Podívejte se, jsou zde 3 řádky, které splňují moje kritéria: prodeje jsou 200 a více a zároveň jsou 400 a méně.
Dva z nich však patří ke stejnému produktu - Mléčná čokoláda . COUNTUNIQUEIFS počítá pouze první zmínku o produktu.
Vím tedy, že mým kritériím vyhovují pouze 2 produkty.
Počítání v tabulkách Google s více kritérii - logika OR
Pokud stačí pouze jedno ze všech kritérií, je lepší použít několik funkcí COUNTIF.
Příklad 1. COUNTIF + COUNTIF
Spočítejme počet prodejů černé a bílé čokolády. Za tímto účelem zadejte do pole B4 následující vzorec:
=COUNTIF(D7:D17, "*Mléko*") + COUNTIF(D7:D17, "*Tmavé*")
Tip: Hvězdičku (*) používám proto, aby se slova "tmavý" a "mléčný" započítala bez ohledu na to, kde se v buňce nacházejí - na začátku, uprostřed nebo na konci.
Tip: Do vzorců můžete vždy zavést odkazy na buňky. Podívejte se, jak to vypadá na snímku obrazovky níže v B3, výsledek zůstává stejný:
Příklad 2. COUNTIF - COUNTIF
Nyní budu počítat počet celkových prodejů mezi 200 a 400:
Vezmu počet celkových prodejů pod 400 a odečtu počet celkových prodejů pod 200 pomocí dalšího vzorce:
=C0UNTIF(F7:F17,"<=400") - COUNTIF(F7:F17,"<=200")
Vzorec vrací počet prodejů větší než 200, ale menší než 400.
Pokud se rozhodnete odkazovat na A3 a A4, které obsahují kritéria, bude vzorec o něco jednodušší:
=COUNTIF(F7:F17, A4) - COUNTIF(F7:F17, A3)
Buňka A3 bude mít kritérium "<=200", zatímco A4 - "<=400". Vložte oba vzorce do B3 a B4 a ujistěte se, že se výsledek nezmění - 3 prodeje v potřebném rozsahu.
COUNTIF Tabulky Google pro prázdné a neprázdné buňky
Pomocí COUNTIF můžeme také spočítat počet prázdných nebo neprázdných buněk v určitém rozsahu.
Předpokládejme, že jsme výrobek úspěšně prodali a označili jej jako "Zaplaceno". Pokud zákazník zboží odmítl, zapíšeme do buňky nulu (0). Pokud obchod nebyl uzavřen, zůstane buňka prázdná.
Počítat neprázdné buňky s libovolnou hodnotou, použijte následující:
=COUNTIF(F7:F15,"")
nebo
=COUNTIF(F7:F15,A3)
Počítání počtu prázdné buňky , dbejte na to, abyste vzorec COUNTIF vložili následujícím způsobem:
=COUNTIF(F7:F15,"")
nebo
=COUNTIF(F7:F15,A4)
Počet buněk s textová hodnota se počítá takto:
=COUNTIF(F7:F15, "*")
nebo
=COUNTIF(F7:F15,A5)
Snímek obrazovky níže ukazuje, že buňky A3, A4 a A5 obsahují naše kritéria:
Vidíme tedy 4 uzavřené obchody, z nichž 3 byly zaplaceny a 5 zatím nemá žádné označení, a proto nejsou uzavřené.
COUNTIF a podmíněné formátování
Tabulky Google nabízejí jednu zajímavou možnost, a to změnit formát buňky (jako je jeho barva) v závislosti na určitých kritériích. Můžeme například zvýraznit hodnoty, které se častěji objevují zeleně.
Malou roli zde může hrát i funkce COUNTIF.
Vyberte rozsah buněk, které chcete nějakým zvláštním způsobem naformátovat. Formát -> Podmíněné formátování...
V Formátování buněk, pokud... v rozevíracím seznamu vyberte poslední možnost Vlastní vzorec je a do pole appeared zadejte následující vzorec:
=COUNTIF($B$10:$B$39,B10)/COUNTIF($B$10:$B$39,"*")>0.4
To znamená, že podmínka bude splněna, pokud se hodnota z B10 objeví v rámci B10:B39 ve více než 40 % případů:
Podobným způsobem přidáme další dvě kritéria formátovacího pravidla - pokud se hodnota buňky objevuje častěji než ve 25 % případů a častěji než v 15 % případů:
=COUNTIF($B$10:$B$39,B10)/COUNTIF($B$10:$B$39,"*")>0.25
=COUNTIF($B$10:$B$39,B10)/COUNTIF($B$10:$B$39,"*")>0.15
Mějte na paměti, že první kritérium bude předem zkontrolováno, a pokud bude splněno, ostatní se neuplatní. Proto raději začněte od nejunikátnějších hodnot a přejděte k těm nejběžnějším. Pokud hodnota buňky nesplňuje žádné kritérium, její formát zůstane zachován.
Vidíte, že barva buněk se změnila podle našich kritérií.
Pro jistotu jsme také spočítali četnost některých hodnot v C3:C6 pomocí funkce COUNTIF. Výsledky potvrdily, že COUNTIF ve formátovacím pravidle bylo použito správně.
Tip. Najděte další příklady, jak počítat & amp; zvýraznit duplicity v tabulkách Google.
Všechny tyto příklady funkcí nám dávají jasnou představu o tom, jak tabulkový procesor Google COUNTIF nabízí mnoho možností, jak co nejefektivněji pracovat s daty.
