İçindekiler
Google Sheets COUNTIF, öğrenmesi en kolay ve kullanımı en kolay işlevlerden biridir.
COUNTIF'in Google Spreadsheet'te nasıl kullanıldığı hakkında biraz bilgi edinmenin ve bu işlevin neden gerçek bir Google Spreadsheet arkadaşı olduğunu öğrenmenin zamanı geldi.
Google E-Tablolar'da COUNTIF işlevi nedir?
Bu kısa yardımcı, belirli bir değerin belirli bir veri aralığında kaç kez göründüğünü saymamızı sağlar.
Google E-Tablolar'da COUNTIF sözdizimi
Fonksiyonumuzun sözdizimi ve argümanları aşağıdaki gibidir:
=COUNTIF(aralık, kriter)- aralık - belirli bir değeri saymak istediğimiz bir hücre aralığı. Gerekli.
- KRİTER veya arama kriteri - ilk bağımsız değişkende belirtilen veri aralığında bulunacak ve sayılacak bir değer.
Uygulamada Google Spreadsheet COUNTIF
COUNTIF bir fonksiyon olarak bile sayılmayacak kadar basit görünebilir (kelime oyunu amaçlanmıştır), ancak gerçekte potansiyeli oldukça etkileyicidir. Sadece arama kriterleri bile böyle bir tanımlamayı hak etmek için yeterlidir.
Mesele şu ki, sadece somut değerleri değil, aynı zamanda belirli kriterleri karşılayanları da aramaya karar verebiliriz.
Birlikte bir formül oluşturmaya çalışmanın tam zamanı.
Metin ve sayılar için Google Spreadsheet COUNTIF (tam eşleşme)
Şirketinizin çeşitli tüketici bölgelerinde çeşitli çikolata türleri sattığını ve birçok müşteriyle çalıştığını varsayalım.
Satış verileriniz Google E-Tablolar'da bu şekilde görünür:
Temel bilgilerle başlayalım.
Satılan "Sütlü Çikolata" sayısını saymamız gerekiyor. İmleci sonucu almak istediğiniz hücreye getirin ve eşitlik işaretini (=) girin. Google E-Tablolar bir formül gireceğimizi hemen anlar. "C" harfini yazar yazmaz, sizden bu harfle başlayan bir işlev seçmenizi isteyecektir. "COUNTIF "i seçin.
İlk argüman COUNTIF tarafından temsil edilir aşağıdaki aralık Bu arada, aralığı manuel olarak girmeniz gerekmez - fare seçimi yeterlidir. Ardından bir virgül (,) girin ve ikinci bağımsız değişkeni - arama kriterlerini belirtin.
İkinci argüman seçilen aralıkta arayacağımız bir değerdir. Bizim durumumuzda bu değer metin - "Sütlü Çikolata". Fonksiyonu bir kapama parantezi ")" ile bitirmeyi unutmayın ve "Enter" tuşuna basın.
Ayrıca, metin değerlerini kullanırken çift tırnak ("") girmeyi unutmayın.
Nihai formülümüz aşağıdaki gibidir:
=COUNTIF(D6:D16, "Sütlü Çikolata")
Sonuç olarak, bu tür çikolatadan üç satış elde ettik.
Not: COUNTIF işlevi tek bir hücre veya komşu sütunlarla çalışır. Başka bir deyişle, birkaç ayrı hücreyi veya sütun ve satırı belirtemezsiniz. Lütfen aşağıdaki örneklere bakın.
Yanlış formüller:
=COUNTIF(C6:C16, D6:D16, "Sütlü Çikolata")
=COUNTIF(D6, D8, D10, D12, D14, "Sütlü Çikolata")
Doğru kullanım:
=COUNTIF(C6:D16, "Sütlü Çikolata")
=COUNTIF(D6, "Sütlü Çikolata") + COUNTIF(D8, "Sütlü Çikolata") + COUNTIF(D10, "Sütlü Çikolata") + COUNTIF(D12, "Sütlü Çikolata") + COUNTIF(D14, "Sütlü Çikolata")
Arama ölçütlerini formülde ayarlamanın pek uygun olmadığını fark etmiş olabilirsiniz - her seferinde düzenlemeniz gerekir. Ölçütleri başka bir Google E-Tablolar hücresine yazmak ve formülde bu hücreye başvurmak daha iyi bir karar olacaktır.
COUNTIF'teki hücre referansını kullanarak "Batı" bölgesinde gerçekleşen satışların sayısını sayalım. Aşağıdaki formülü elde edeceğiz:
=COUNTIF(C6:C16,A3)
İşlev, hesaplamalarında A3'ün içeriğini ("West" metin değeri) kullanır. Gördüğünüz gibi, formülü ve arama kriterlerini düzenlemek artık çok daha kolay.
Tabii ki, aynı şeyi biz de yapabiliriz sayısal değerlerle Sayının kendisini ikinci bir argüman olarak göstererek "125" sayısının kaç kez geçtiğini sayabiliriz:
=COUNTIF(E7:E17,125)
veya bir hücre referansı ile değiştirerek:
=COUNTIF(E7:E17,A3)
Google Spreadsheet COUNTIF işlevi ve joker karakterler (kısmi eşleşme)
COUNTIF ile ilgili harika olan şey, tüm hücreleri sayabilmesinin yanı sıra hücre içeriğinin parçaları Bu amaç doğrultusunda joker karakterler : "?", "*".
Örneğin, belirli bir bölgedeki satışları saymak için yalnızca adının bir kısmını kullanabiliriz: B3'e "?est" girin. A soru işareti (?) değiştirir bir karakter . 4 harfli kelimeleri arayacağız "est" ile biten boşluklar da dahil olmak üzere.
B3'te aşağıdaki COUNTIF formülünü kullanın:
=COUNTIF(C7:C17,A3)
Bildiğiniz gibi, formül kolayca bir sonraki şekli alabilir:
=COUNTIF(C7:C17, "?est")
Ve "Batı" bölgesinde 5 satış görebiliyoruz.
Şimdi B4 hücresini başka bir formül için kullanalım:
=COUNTIF(C7:C17,A4)
Dahası, kriteri A4'te "??st" olarak değiştireceğiz. Bu, artık 4 harfli kelimeleri arayacağımız anlamına geliyor "st" ile biten Bu durumda iki bölge ("Batı" ve "Doğu") kriterlerimizi karşıladığından, dokuz satış göreceğiz:
Benzer şekilde, malların satış sayısını da bir yıldız işareti (*). Bu sembol sadece bir tanesinin değil, aynı zamanda herhangi bir sayıda karakter :
"*Çikolata" kriteri "Çikolata" ile biten tüm ürünleri sayar.
"Çikolata*" kriterleri "Çikolata" ile başlayan tüm ürünleri sayar.
Ve tahmin edebileceğiniz gibi, eğer "*Çikolata*" "Çikolata" kelimesini içeren tüm ürünleri arayacağız.
Not: Yıldız işareti (*) ve soru işareti (?) içeren sözcüklerin sayısını saymanız gerekiyorsa tilde işareti (Bu durumda, COUNTIF bunları arama karakterleri yerine basit işaretler olarak değerlendirecektir. Örneğin, "?" içeren değerleri aramak istiyorsak, formül şöyle olacaktır:
=COUNTIF(D7:D15,"*~?*")
COUNTIF Daha küçük, daha büyük veya eşit için Google E-Tablolar
COUNTIF fonksiyonu sadece bir sayının kaç kez göründüğünü değil, aynı zamanda sayıların kaç tanesinin daha büyük / daha küçük / eşit / eşit değil belirtilen başka bir sayı.
Bu amaçla, ilgili matematiksel operatörleri kullanırız: "=", ">", "=", "<=", "".
Nasıl çalıştığını görmek için aşağıdaki tabloya göz atın:
| Kriterler | Formül örneği | Açıklama |
| Sayı şu değerden büyüktür | =COUNTIF(F9:F19,">100") | Değerlerin 100'den büyük olduğu hücreleri sayın. |
| Sayı şu değerden azdır | =COUNTIF(F9:F19,"<100") | Değerlerin 100'den küçük olduğu hücreleri sayın. |
| Sayı şu değere eşittir | =COUNTIF(F9:F19,"=100") | Değerlerin 100'e eşit olduğu hücreleri sayın. |
| Bu sayı aşağıdakilere eşit değildir | =COUNTIF(F9:F19,"100") | Değerlerin 100'e eşit olmadığı hücreleri sayın. |
| Sayı aşağıdakilerden büyük veya eşittir | =COUNTIF(F9:F19,">=100") | Değerlerin 100'den büyük veya 100'e eşit olduğu hücreleri sayın. |
| Sayı aşağıdakilerden küçük veya eşittir | =COUNTIF(F9:F19,"<=100") | Değerlerin 100'den küçük veya 100'e eşit olduğu hücreleri sayın. |
Not. Şunları yapmak çok önemlidir içine almak bir sayı ile birlikte matematiksel operatör çift tırnak içinde .
Formülü değiştirmeden ölçütü değiştirmek isterseniz, hücrelere de başvurabilirsiniz.
A3'e referans verelim ve formülü daha önce yaptığımız gibi B3'e koyalım:
=COUNTIF(F9:F19,A3)
Daha karmaşık ölçütler oluşturmak için ampersand (&).
Örneğin, B4, E9:E19 aralığında 100'den büyük veya 100'e eşit değerlerin sayısını sayan bir formül içerir:
=COUNTIF(E9:E19,">="&A4)
B5 aynı kriterlere sahiptir, ancak yalnızca o hücredeki sayıya değil, aynı zamanda bir matematiksel işlece de başvururuz. Bu, gerektiğinde EĞERSAY formülünü uyarlamayı daha da kolaylaştırır:
=COUNTIF(E9:E19,A6&A5)
İpucu: Başka bir sütundaki değerlerden büyük veya küçük olan hücrelerin sayılmasıyla ilgili çok soru aldık. Aradığınız şey buysa, bu iş için başka bir işleve ihtiyacınız olacak - SUMPRODUCT.
Örneğin, F sütunundaki satışların G sütununun aynı satırındakilerden daha büyük olduğu tüm satırları sayalım:
=SUMPRODUCT(--(F6:F16>G6:G16))
- Formülün özündeki kısım - F6:F16>G6:G16 - F ve G sütunlarındaki değerleri karşılaştırır. F sütunundaki sayı daha büyük olduğunda, formül bunu DOĞRU olarak alır, aksi takdirde - YANLIŞ.
Aynı şeyi ArrayFormula'ya girerseniz bunu göreceksiniz:
=ArrayFormula(F6:F16>G6:G16)
- O zaman formül şu şekilde olur DOĞRU/YANLIŞ sonucuna dönüştürür ve 1/0 çift tekli operatör yardımıyla sayılar (--) .
- Bu, SUM'un geri kalanını yapmasına izin verir - F'nin G'den büyük olduğu zamanların sayısını toplar.
Birden fazla ölçüt içeren Google Elektronik Tablosu COUNTIF
Bazen, belirtilen koşullardan en az birine (VEYA mantığı) veya aynı anda birden fazla kritere (VE mantığı) yanıt veren değerlerin sayısını saymak gerekir. Buna bağlı olarak, bir seferde tek bir hücrede birkaç COUNTIF işlevini veya alternatif COUNTIFS işlevini kullanabilirsiniz.
Google E-Tablolar'da birden çok ölçütle sayma - AND mantığı
Burada kullanmanızı tavsiye edeceğim tek yol, birden fazla kritere göre saymak için tasarlanmış özel bir işlevdir - COUNTIFS:
=COUNTIFS(criteria_range1, criterion1, [criteria_range2, criterion2, ...])Normalde, bazı kriterleri karşılaması gereken iki aralıkta değerler olduğunda veya belirli bir sayı aralığının arasına düşen sayıyı almanız gerektiğinde kullanılır.
Şimdi 200 ile 400 arasındaki toplam satış sayısını saymaya çalışalım:
=COUNTIFS(F8:F18,">=200",F8:F18,"<=400")
İpucu: Bu makalede Google E-Tablolar'da COUNTIFS'i renklerle birlikte nasıl kullanacağınızı öğrenin.
Google E-Tablolar'da birden çok ölçütle tekil öğeleri sayma
Daha da ileri gidebilir ve 200 ile 400 arasındaki benzersiz ürün sayısını sayabilirsiniz.
Hayır, yukarıdakiyle aynı değil! :) Yukarıdaki COUNTIFS, 200 ile 400 arasındaki satışların her bir oluşumunu sayar. Önerdiğim şey, ürüne de bakmaktır. Adı birden fazla kez geçerse, sonuca dahil edilmeyecektir.
Bunun için özel bir fonksiyon vardır - COUNTUNIQUEIFS:
COUNTUNIQUEIFS(count_unique_range, criteria_range1, criterion1, [criteria_range2, criterion2, ...])COUNTIFS ile karşılaştırıldığında, farkı yaratan ilk argümandır. Count_unique_range fonksiyonun benzersiz kayıtları sayacağı aralıktır.
Formül ve sonucu şu şekilde görünecektir:
=COUNTUNIQUEIFS(D6:D16,F6:F16,">=200",F6:F16,"<=400")
Bakın, kriterlerimi karşılayan 3 satır var: satışlar 200 ve üzeri ve aynı zamanda 400 veya daha az.
Ancak, 2 tanesi aynı ürüne aittir - Sütlü Çikolata . COUNTUNIQUEIFS yalnızca üründen ilk bahsedileni sayar.
Böylece, kriterlerimi karşılayan sadece 2 ürün olduğunu biliyorum.
Google E-Tablolar'da birden çok ölçütle sayma - VEYA mantığı
Tüm kriterlerden yalnızca biri yeterli olduğunda, birkaç COUNTIF fonksiyonu kullanmanız daha iyi olur.
Örnek 1. COUNTIF + COUNTIF
Siyah ve beyaz çikolata satışlarının sayısını sayalım. Bunu yapmak için B4'e aşağıdaki formülü girin:
=COUNTIF(D7:D17, "*Milk*") + COUNTIF(D7:D17, "*Dark*")
İpucu: "Koyu" ve "süt" kelimelerinin hücrenin neresinde olursa olsun (başında, ortasında veya sonunda) sayılacağından emin olmak için yıldız işareti (*) kullanıyorum.
İpucu: Formüllerinize her zaman hücre referansları ekleyebilirsiniz. Aşağıdaki ekran görüntüsünde B3'te nasıl göründüğüne bakın, sonuç aynı kalır:
Örnek 2. COUNTIF - COUNTIF
Şimdi, 200 ile 400 arasındaki toplam satış sayısını sayacağım:
400'ün altındaki toplam satış sayısını alıyorum ve bir sonraki formülü kullanarak 200'ün altındaki toplam satış sayısını çıkarıyorum:
=C0UNTIF(F7:F17,"<=400") - COUNTIF(F7:F17,"<=200")
Formül, 200'den fazla ancak 400'den az satış sayısını döndürür.
Kriterleri içeren A3 ve A4'e başvurmaya karar verirseniz, formül biraz daha basit olacaktır:
=COUNTIF(F7:F17, A4) - COUNTIF(F7:F17, A3)
A3 hücresi "<=200" kriterine sahip olurken A4 - "<=400" olacaktır. Her iki formülü de B3 ve B4'e yerleştirin ve sonucun değişmediğinden emin olun - gerekli aralıkta 3 satış.
COUNTIF Boş ve boş olmayan hücreler için Google E-Tablolar
COUNTIF yardımıyla, belirli bir aralıktaki boş veya boş olmayan hücrelerin sayısını da sayabiliriz.
Ürünü başarıyla sattığımızı ve "Ödendi" olarak işaretlediğimizi varsayalım. Müşteri malları reddettiyse, hücreye sıfır (0) yazarız. Anlaşma kapanmadıysa, hücre boş kalır.
Saymak için boş olmayan hücreler herhangi bir değerle, aşağıdakileri kullanın:
=COUNTIF(F7:F15,"")
veya
=COUNTIF(F7:F15,A3)
sayısını saymak için boş hücreler COUNTIF formülünü aşağıdaki şekilde yerleştirdiğinizden emin olun:
=COUNTIF(F7:F15,"")
veya
=COUNTIF(F7:F15,A4)
olan hücre sayısı metinsel değer bu şekilde sayılır:
=COUNTIF(F7:F15, "*")
veya
=COUNTIF(F7:F15,A5)
Aşağıdaki ekran görüntüsü A3, A4 ve A5 hücrelerinin kriterlerimizi içerdiğini göstermektedir:
Böylece, 3'ünün ödemesi yapılmış ve 5'i henüz işaretlenmemiş ve dolayısıyla kapanmamış olan 4 kapanmış anlaşma görebiliyoruz.
COUNTIF ve koşullu biçimlendirme
Google E-Tablolar'ın sunduğu ilginç bir fırsat var hücrenin biçimini değiştirme (rengi gibi) bazı kriterlere bağlı olarak. Örneğin, daha sık görünen değerleri yeşil renkte vurgulayabiliriz.
COUNTIF fonksiyonu da burada küçük bir rol oynayabilir.
Özel bir şekilde biçimlendirmek istediğiniz hücre aralığını seçin. Biçim -> Koşullu biçimlendirme...
İçinde Eğer hücreleri biçimlendir... açılır listeden son seçeneği seçin Özel formül şudur 'yi seçin ve görüntülenen alana aşağıdaki formülü girin:
=COUNTIF($B$10:$B$39,B10)/COUNTIF($B$10:$B$39,"*")>0.4
Bu, B10'daki değerin vakaların %40'ından fazlasında B10:B39 içinde görünmesi halinde koşulun yanıtlanacağı anlamına gelir:
Benzer şekilde, iki biçimlendirme kuralı ölçütü daha ekleriz - hücre değeri vakaların %25'inden daha sık ve %15'inden daha sık görünüyorsa:
=COUNTIF($B$10:$B$39,B10)/COUNTIF($B$10:$B$39,"*")>0.25
=COUNTIF($B$10:$B$39,B10)/COUNTIF($B$10:$B$39,"*")>0.15
İlk kriterin önceden kontrol edileceğini ve karşılanması durumunda diğerlerinin uygulanmayacağını unutmayın. Bu nedenle, en yaygın olanlara doğru ilerleyen en benzersiz değerlerle başlamanız daha iyi olur. Hücre değeri herhangi bir kriteri karşılamıyorsa, biçimi bozulmadan kalacaktır.
Hücrelerin renginin kriterlerimize göre değiştiğini görebilirsiniz.
Emin olmak için, COUNTIF işlevini kullanarak C3:C6'daki bazı değerlerin sıklığını da saydık. Sonuçlar, biçimlendirme kuralındaki COUNTIF'in doğru uygulandığını doğrulamaktadır.
İpucu: Google E-Tablolar'da kopyaların nasıl sayılacağı ve vurgulanacağı hakkında daha fazla örnek bulun.
Tüm bu işlev örnekleri, Google Spreadsheet COUNTIF'in verilerle en verimli şekilde çalışmak için nasıl çok sayıda fırsat sunduğunu net bir şekilde anlamamızı sağlar.
