Google Sheets COUNTIF ist eine der am einfachsten zu erlernenden und am leichtesten zu bedienenden Funktionen.

Es ist an der Zeit, etwas Wissen darüber zu sammeln, wie COUNTIF in Google Spreadsheet verwendet wird, und zu erfahren, warum diese Funktion ein echter Google Spreadsheet-Begleiter ist.

Was ist die Funktion COUNTIF in Google Sheets?

Mit diesem kurzen Hilfsmittel können wir zählen, wie oft ein bestimmter Wert in einem bestimmten Datenbereich vorkommt.

COUNTIF-Syntax in Google Sheets

Die Syntax unserer Funktion und ihre Argumente lauten wie folgt:

• Bereich - einen Bereich von Zellen, in dem ein bestimmter Wert gezählt werden soll. erforderlich.
• Kriterium oder Suchkriterium - ein Wert, der in dem im ersten Argument angegebenen Datenbereich gesucht und gezählt werden soll. erforderlich.

Google Spreadsheet COUNTIF in der Praxis

Es mag den Anschein haben, dass COUNTIF so einfach ist, dass es nicht einmal als Funktion zählt (Wortspiel beabsichtigt), aber in Wahrheit ist sein Potenzial ziemlich beeindruckend. Allein seine Suchkriterien verdienen eine solche Beschreibung.

Die Sache ist die, dass wir uns entscheiden können, nicht nur nach konkreten Werten zu suchen, sondern auch nach solchen, die bestimmte Kriterien erfüllen.

Es ist höchste Zeit, dass wir versuchen, gemeinsam eine Formel zu entwickeln.

Google Spreadsheet COUNTIF für Text und Zahlen (exakte Übereinstimmung)

Nehmen wir an, Ihr Unternehmen vertreibt verschiedene Schokoladensorten in mehreren Verbraucherregionen und arbeitet mit vielen Kunden zusammen.

So sehen Ihre Verkaufsdaten in Google Sheets aus:

Beginnen wir mit den Grundlagen.

Wir müssen die Anzahl der verkauften "Milchschokolade" zählen. Setzen Sie den Cursor in die Zelle, in der Sie das Ergebnis erhalten möchten, und geben Sie das Gleichheitszeichen (=) ein. Google Sheets versteht sofort, dass wir eine Formel eingeben werden. Sobald Sie den Buchstaben "C" eingeben, werden Sie aufgefordert, eine Funktion zu wählen, die mit diesem Buchstaben beginnt. Wählen Sie "COUNTIF".

Das erste Argument des COUNTIF wird dargestellt durch den folgenden Bereich D6:D16. Übrigens müssen Sie den Bereich nicht manuell eingeben - die Auswahl mit der Maus genügt. Geben Sie dann ein Komma (,) ein und geben Sie das zweite Argument an - die Suchkriterien.

Das zweite Argument ist ein Wert, nach dem wir im gesamten ausgewählten Bereich suchen. In unserem Fall wird es sein den Text - Vergessen Sie nicht, die Funktion mit einer schließenden Klammer ")" abzuschließen und die Eingabetaste zu drücken.

Vergessen Sie außerdem nicht, bei der Verwendung von Textwerten doppelte Anführungszeichen ("") zu verwenden.

Unsere endgültige Formel sieht wie folgt aus:

=COUNTIF(D6:D16, "Milchschokolade")

Infolgedessen erhalten wir drei Verkäufe dieser Art von Schokolade.

Hinweis: Die Funktion COUNTIF arbeitet mit einer einzigen Zelle oder benachbarten Spalten. Mit anderen Worten, Sie können nicht mehrere separate Zellen oder Spalten und Zeilen angeben. Siehe die folgenden Beispiele.

Falsche Formeln:

=COUNTIF(C6:C16, D6:D16, "Milchschokolade")

=COUNTIF(D6, D8, D10, D12, D14, "Vollmilchschokolade")

Korrekte Verwendung:

=COUNTIF(C6:D16, "Milchschokolade")

=COUNTIF(D6, "Vollmilchschokolade") + COUNTIF(D8, "Vollmilchschokolade") + COUNTIF(D10, "Vollmilchschokolade") + COUNTIF(D12, "Vollmilchschokolade") + COUNTIF(D14, "Vollmilchschokolade")

Sie haben vielleicht bemerkt, dass es nicht sehr bequem ist, die Suchkriterien in der Formel festzulegen - Sie müssen sie jedes Mal bearbeiten. Die bessere Entscheidung wäre, die Kriterien in eine andere Google Sheets-Zelle zu schreiben und in der Formel auf diese Zelle zu verweisen.

Zählen wir nun die Anzahl der getätigten Verkäufe in der Region "West" mit Hilfe des Zellbezugs in COUNTIF, so erhalten wir folgende Formel:

=COUNTIF(C6:C16,A3)

Die Funktion verwendet den Inhalt von A3 (den Textwert "West") in ihren Berechnungen. Wie Sie sehen, ist es jetzt viel einfacher, die Formel und ihre Suchkriterien zu bearbeiten.

Natürlich können wir das Gleiche tun mit numerischen Werten Wir können die Anzahl der Vorkommen der Zahl "125" zählen, indem wir die Zahl selbst als zweites Argument angeben:

=COUNTIF(E7:E17,125)

oder durch einen Zellverweis ersetzt werden:

=COUNTIF(E7:E17,A3)

Google Spreadsheet COUNTIF-Funktion und Platzhalterzeichen (teilweise Übereinstimmung)

Das Besondere am COUNTIF ist, dass er sowohl ganze Zellen als auch Teile des Inhalts der Zelle Zu diesem Zweck verwenden wir Platzhalterzeichen : "?", "*".

Um zum Beispiel die Verkäufe in einer bestimmten Region zu zählen, können wir nur den Teil des Namens verwenden: Geben Sie "?est" in B3 ein. A Fragezeichen (?) ersetzt ein Zeichen Wir werden nach den Wörtern mit 4 Buchstaben suchen. endend mit "est" , einschließlich Leerzeichen.

Verwenden Sie die folgende COUNTIF-Formel in B3:

=COUNTIF(C7:C17,A3)

Wie Sie bereits wissen, kann die Formel leicht die nächste Form annehmen:

=COUNTIF(C7:C17, "?est")

Und wir sehen 5 Verkäufe in der Region "West".

Lassen Sie uns nun die Zelle B4 für eine andere Formel verwenden:

=COUNTIF(C7:C17,A4)

Außerdem ändern wir das Kriterium in A4 in "??st", d.h. wir suchen jetzt nach Wörtern mit 4 Buchstaben endend mit "st" Da in diesem Fall zwei Regionen ("West" und "Ost") unsere Kriterien erfüllen, werden wir neun Verkäufe sehen:

In ähnlicher Weise können wir die Anzahl der Verkäufe der Waren zählen, indem wir eine Sternchen (*). Dieses Symbol ersetzt nicht nur eine, sondern beliebige Anzahl von Zeichen :

"*Schokolade" Kriterien zählen alle Produkte, die mit "Schokolade" enden.

"Schokolade*" Kriterien zählen alle Produkte, die mit "Chocolate" beginnen.

Und, wie Sie sich vielleicht denken können, wenn wir die "*Schokolade*" suchen wir nach allen Produkten, die das Wort "Schokolade" enthalten.

Hinweis: Wenn Sie die Anzahl der Wörter zählen müssen, die ein Sternchen (*) und ein Fragezeichen (?) enthalten, verwenden Sie Tilde-Zeichen (~) vor diesen Zeichen. In diesem Fall behandelt COUNTIF sie als einfache Zeichen und nicht als Suchzeichen. Wenn wir zum Beispiel nach den Werten suchen wollen, die "?" enthalten, lautet die Formel:

=COUNTIF(D7:D15,"*~?*")

COUNTIF Google Sheets für kleiner als, größer als oder gleich

Die Funktion COUNTIF kann nicht nur zählen, wie oft eine Zahl vorkommt, sondern auch, wie viele der Zahlen größer als/kleiner als/gleich/ungleich eine andere angegebene Nummer.

Zu diesem Zweck verwenden wir entsprechende mathematische Operatoren: "=", ">", "=", "<=", "".

In der folgenden Tabelle sehen Sie, wie das funktioniert:

Hinweis: Es ist sehr wichtig, dass beifügen. der mathematische Operator zusammen mit einer Zahl in Anführungszeichen .

Wenn Sie die Kriterien ändern möchten, ohne die Formel zu verändern, können Sie auch auf die Zellen verweisen.

Wir beziehen uns auf A3 und setzen die Formel in B3 ein, so wie wir es zuvor getan haben:

=COUNTIF(F9:F19,A3)

Um anspruchsvollere Kriterien zu erstellen, verwenden Sie eine Ampersand (&).

Zum Beispiel enthält B4 eine Formel, die die Anzahl der Werte größer oder gleich 100 im Bereich E9:E19 zählt:

=COUNTIF(E9:E19,">="&A4)

B5 hat die gleichen Kriterien, aber wir beziehen uns nicht nur auf die Zahl in dieser Zelle, sondern auch auf einen mathematischen Operator, was es noch einfacher macht, die COUNTIF-Formel bei Bedarf anzupassen:

=COUNTIF(E9:E19,A6&A5)

Tipp: Wir wurden oft gefragt, wie man die Zellen zählen kann, die größer oder kleiner als die Werte in einer anderen Spalte sind. Wenn Sie das wollen, brauchen Sie eine andere Funktion für diese Aufgabe - SUMPRODUCT.

Zählen wir zum Beispiel alle Zeilen, in denen der Umsatz in Spalte F größer ist als in der gleichen Zeile der Spalte G:

=SUMPRODUCT(--(F6:F16>G6:G16))

• Der Teil, der den Kern der Formel bildet - F6:F16>G6:G16 - vergleicht die Werte in den Spalten F und G. Wenn die Zahl in Spalte F größer ist, nimmt die Formel sie als WAHR an, andernfalls - FALSCH.

  Sie werden sehen, wenn Sie dasselbe in die ArrayFormula eingeben:

  =ArrayFormula(F6:F16>G6:G16)

  

• Dann sieht die Formel so aus WAHR/FALSCH Ergebnis und verwandelt es in 1/0 Zahlen mit Hilfe des doppelten unären Operators (--) .
• Damit kann SUM den Rest erledigen - die Anzahl der Fälle summieren, in denen F größer als G ist.

Google Tabellenkalkulation COUNTIF mit mehreren Kriterien

Manchmal ist es notwendig, die Anzahl der Werte zu zählen, die mindestens eine der genannten Bedingungen (ODER-Logik) oder mehrere Kriterien auf einmal (UND-Logik) erfüllen. Auf dieser Grundlage können Sie entweder mehrere COUNTIF-Funktionen in einer einzigen Zelle auf einmal oder die alternative COUNTIFS-Funktion verwenden.

Zählen in Google Sheets mit mehreren Kriterien - UND-Logik

Die einzige Möglichkeit, die ich Ihnen hier empfehlen würde, ist die Verwendung einer speziellen Funktion, die für die Zählung nach mehreren Kriterien ausgelegt ist - COUNTIFS:

Sie wird in der Regel verwendet, wenn es Werte in zwei Bereichen gibt, die bestimmte Kriterien erfüllen müssen, oder wenn Sie die Zahl ermitteln müssen, die zwischen einem bestimmten Bereich von Zahlen liegt.

Versuchen wir, die Anzahl der Gesamtverkäufe zwischen 200 und 400 zu zählen:

=COUNTIFS(F8:F18,">=200",F8:F18,"<=400")

Tipp: In diesem Artikel erfahren Sie, wie Sie COUNTIFS mit Farben in Google Sheets verwenden können.

Zählen von Unikaten in Google Sheets mit mehreren Kriterien

Sie können noch weiter gehen und die Anzahl der einzigartigen Produkte zwischen 200 und 400 zählen.

Nein, es ist nicht das Gleiche wie oben :) Das obige COUNTIFS zählt jedes Vorkommen von Verkäufen zwischen 200 und 400. Ich schlage vor, auch das Produkt zu betrachten. Wenn sein Name mehr als einmal vorkommt, wird er im Ergebnis nicht berücksichtigt.

Dafür gibt es eine spezielle Funktion - COUNTUNIQUEIFS:

Im Vergleich zu COUNTIFS ist es das erste Argument, das den Unterschied ausmacht. Anzahl_eindeutiger_Bereiche ist der Bereich, in dem die Funktion eindeutige Datensätze zählen soll.

So sehen die Formel und ihr Ergebnis aus:

=COUNTUNIQUEIFS(D6:D16,F6:F16,">=200",F6:F16,"<=400")

Schauen Sie, es gibt 3 Zeilen, die meine Kriterien erfüllen: die Verkäufe sind 200 und mehr und gleichzeitig 400 oder weniger.

Allerdings gehören 2 von ihnen zum selben Produkt - Vollmilchschokolade COUNTUNIQUEIFS zählt nur die erste Erwähnung des Produkts.

Ich weiß also, dass es nur 2 Produkte gibt, die meine Kriterien erfüllen.

Zählen in Google Sheets mit mehreren Kriterien - OR-Logik

Wenn nur eines von allen Kriterien ausreicht, sollten Sie besser mehrere COUNTIF-Funktionen verwenden.

Beispiel 1: COUNTIF + COUNTIF

Zählen wir die Anzahl der Verkäufe von schwarzer und weißer Schokolade, so geben wir in B4 folgende Formel ein:

= COUNTIF(D7:D17, "*Milch*") + COUNTIF(D7:D17, "*Dunkel*")

Tipp: Ich verwende Sternchen (*), um sicherzustellen, dass die Wörter "dunkel" und "Milch" gezählt werden, egal wo sie in der Zelle stehen - am Anfang, in der Mitte oder am Ende.

Tipp: Sie können jederzeit Zellbezüge in Ihre Formeln einfügen. Sehen Sie, wie es auf dem Screenshot unten in B3 aussieht, das Ergebnis bleibt dasselbe:

Beispiel 2: COUNTIF - COUNTIF

Jetzt zähle ich die Anzahl der Gesamtverkäufe zwischen 200 und 400:

Ich nehme die Anzahl der Summen unter 400 und ziehe die Anzahl der Gesamtverkäufe unter 200 mit der nächsten Formel ab:

=C0UNTIF(F7:F17,"<=400") - COUNTIF(F7:F17,"<=200")

Die Formel liefert die Anzahl der Verkäufe, die größer als 200, aber kleiner als 400 sind.

Wenn Sie sich dafür entscheiden, auf A3 und A4 zu verweisen, die die Kriterien enthalten, wird die Formel etwas einfacher sein:

=COUNTIF(F7:F17, A4) - COUNTIF(F7:F17, A3)

In die Zelle A3 wird das Kriterium "<=200" eingegeben, in die Zelle A4 "<=400". Geben Sie beide Formeln in B3 und B4 ein und stellen Sie sicher, dass sich das Ergebnis nicht ändert - 3 Verkäufe in dem benötigten Bereich.

COUNTIF Google Sheets für leere und nicht leere Zellen

Mit Hilfe von COUNTIF können wir auch die Anzahl der leeren oder nicht leeren Zellen innerhalb eines Bereichs zählen.

Nehmen wir an, wir haben das Produkt erfolgreich verkauft und als "Bezahlt" markiert. Wenn der Kunde die Ware abgelehnt hat, schreiben wir eine Null (0) in die Zelle. Wenn das Geschäft nicht abgeschlossen wurde, bleibt die Zelle leer.

Zählen nicht-leere Zellen mit einem beliebigen Wert, verwenden Sie Folgendes:

=COUNTIF(F7:F15,"")

oder

=COUNTIF(F7:F15,A3)

So zählen Sie die Anzahl der leere Zellen Die COUNTIF-Formel muss folgendermaßen formuliert werden:

=COUNTIF(F7:F15,"")

oder

=COUNTIF(F7:F15,A4)

Die Anzahl der Zellen mit einem textueller Wert wird wie folgt gezählt:

=COUNTIF(F7:F15, "*")

oder

=COUNTIF(F7:F15,A5)

Der Screenshot unten zeigt, dass die Zellen A3, A4 und A5 unsere Kriterien enthalten:

Wir sehen also 4 abgeschlossene Geschäfte, von denen 3 bezahlt wurden und 5 noch keine Markierungen haben und somit nicht abgeschlossen sind.

COUNTIF und bedingte Formatierung

Es gibt eine interessante Möglichkeit, die Google Sheets bietet - um das Format der Zelle ändern (Wir können zum Beispiel die Werte hervorheben, die häufiger in grüner Farbe erscheinen.

Auch hier kann die Funktion COUNTIF eine kleine Rolle spielen.

Wählen Sie den Bereich der Zellen aus, die Sie auf besondere Weise formatieren möchten. Klicken Sie auf Format -> Bedingte Formatierung...

In der Zellen formatieren, wenn... Dropdown-Liste wählen Sie die letzte Option Die benutzerdefinierte Formel lautet und geben Sie die folgende Formel in das angezeigte Feld ein:

=COUNTIF($B$10:$B$39,B10)/COUNTIF($B$10:$B$39,"*")>0.4

Das bedeutet, dass die Bedingung erfüllt ist, wenn der Wert aus B10 in mehr als 40 % der Fälle innerhalb von B10:B39 erscheint:

In ähnlicher Weise fügen wir zwei weitere Kriterien für Formatierungsregeln hinzu - wenn der Zellwert häufiger als in 25 % der Fälle und häufiger als in 15 % der Fälle erscheint:

=COUNTIF($B$10:$B$39,B10)/COUNTIF($B$10:$B$39,"*")>0.25

=COUNTIF($B$10:$B$39,B10)/COUNTIF($B$10:$B$39,"*")>0.15

Denken Sie daran, dass das erste Kriterium vorher geprüft wird, und wenn es erfüllt ist, gelten die anderen nicht. Deshalb sollten Sie mit den eindeutigsten Werten beginnen und zu den häufigsten übergehen. Wenn der Zellwert kein Kriterium erfüllt, bleibt sein Format erhalten.

Sie können sehen, dass sich die Farbe der Zellen entsprechend unseren Kriterien geändert hat.

Um sicherzugehen, haben wir auch die Häufigkeit einiger Werte in C3:C6 mit der Funktion COUNTIF gezählt. Die Ergebnisse bestätigen, dass COUNTIF in der Formatierungsregel korrekt angewendet wurde.

Tipp: Hier finden Sie weitere Beispiele für das Zählen & Markieren von Duplikaten in Google Sheets.

All diese Funktionsbeispiele geben uns ein klares Verständnis dafür, wie Google Spreadsheet COUNTIF vielfältige Möglichkeiten bietet, mit den Daten auf höchst effiziente Weise zu arbeiten.