Google Sheets COUNTIF jest jedną z najłatwiejszych do nauczenia się i jedną z najprostszych w użyciu funkcji.

Nadszedł czas, aby zebrać trochę wiedzy o tym, jak COUNTIF jest używany w Google Spreadsheet i dowiedzieć się, dlaczego ta funkcja jest prawdziwym towarzyszem Google Spreadsheet.

Czym jest funkcja COUNTIF w arkuszach Google?

Ten krótki helper pozwala nam policzyć ile razy dana wartość pojawia się w określonym zakresie danych.

Składnia COUNTIF w Google Sheets

Składnia naszej funkcji i jej argumenty są następujące:

• zakres - zakres komórek, w których chcemy policzyć określoną wartość.Wymagane.
• kryterium lub kryterium wyszukiwania - wartość, którą należy znaleźć i policzyć w całym zakresie danych wskazanym w pierwszym argumencie. Wymagane.

Google Spreadsheet COUNTIF w praktyce

Może się wydawać, że COUNTIF jest tak prosty, że nawet nie liczy się jako funkcja (pun intended), ale w rzeczywistości jego potencjał jest dość imponujący. Same kryteria wyszukiwania są wystarczające, aby zasłużyć na taki opis.

Rzecz w tym, że możemy zdecydować się na poszukiwanie nie tylko konkretnych wartości, ale także takich, które spełniają określone kryteria.

Najwyższy czas podjąć próbę wspólnego budowania formuły.

Arkusz kalkulacyjny Google COUNTIF dla tekstu i liczb (dokładne dopasowanie)

Załóżmy, że Twoja firma sprzedaje różne rodzaje czekolady w kilku regionach konsumenckich i współpracuje z wieloma klientami.

Tak wyglądają dane dotyczące Twojej sprzedaży w Google Sheets:

Zacznijmy od podstaw.

Musimy policzyć liczbę sprzedanych "Czekolad mlecznych".Umieść kursor w komórce, w której chcesz uzyskać wynik i wpisz znak równości (=).Google Sheets od razu rozumie, że zamierzamy wprowadzić formułę.Gdy tylko wpiszesz literę "C", poprosi Cię o wybranie funkcji, która zaczyna się na tę literę.Wybierz "COUNTIF".

Pierwszy argument COUNTIF jest reprezentowany przez następujący zakres : D6:D16. Przy okazji nie musisz wpisywać zakresu ręcznie - wystarczy wybór myszką. Następnie wpisz przecinek (,) i określ drugi argument - kryteria wyszukiwania.

Drugi argument to wartość, której będziemy szukać w całym wybranym zakresie. W naszym przypadku będzie to tekst - "Czekolada mleczna". Pamiętaj, aby zakończyć funkcję nawiasem zamykającym ")" i naciśnij "Enter".

Nie zapomnij również wprowadzić podwójnych cudzysłowów (""), gdy używasz wartości tekstowych.

Nasza ostateczna formuła wygląda następująco:

=COUNTIF(D6:D16, "Milk Chocolate")

W efekcie otrzymujemy trzy sprzedaże tego typu czekolady.

Uwaga. Funkcja COUNTIF działa z pojedynczą komórką lub sąsiednimi kolumnami. Innymi słowy, nie można wskazać kilku oddzielnych komórek lub kolumn i wierszy. Proszę zobaczyć poniższe przykłady.

Nieprawidłowe wzory:

=COUNTIF(C6:C16, D6:D16, "Milk Chocolate")

=COUNTIF(D6, D8, D10, D12, D14, "Milk Chocolate")

Prawidłowe użycie:

=COUNTIF(C6:D16, "Milk Chocolate")

=COUNTIF(D6, "Milk Chocolate") + COUNTIF(D8, "Milk Chocolate") + COUNTIF(D10, "Milk Chocolate") + COUNTIF(D12, "Milk Chocolate") + COUNTIF(D14, "Milk Chocolate")

Być może zauważyłeś, że ustawienie kryteriów wyszukiwania w formule nie jest zbyt wygodne - musisz je za każdym razem edytować. Lepszą decyzją byłoby zapisanie kryteriów w innej komórce Google Sheets i odwołanie się do niej w formule.

Policzmy liczbę zaistniałych sprzedaży w regionie "West" korzystając z odwołania do komórki w COUNTIF. Otrzymamy następującą formułę:

=COUNTIF(C6:C16,A3)

Funkcja wykorzystuje w swoich obliczeniach zawartość A3 (wartość tekstową "Zachód"). Jak widać, edycja formuły i jej kryteriów wyszukiwania jest teraz dużo łatwiejsza.

Oczywiście, możemy zrobić to samo z wartościami liczbowymi Możemy policzyć liczbę wystąpień liczby "125", wskazując samą liczbę jako drugi argument:

=COUNTIF(E7:E17,125)

lub zastępując go odwołaniem do komórki:

=COUNTIF(E7:E17,A3)

Funkcja COUNTIF arkusza kalkulacyjnego Google i znaki wieloznaczne (dopasowanie częściowe)

Wspaniałą cechą COUNTIF jest to, że może on liczyć zarówno całe komórki, jak i części zawartości komórki W tym celu wykorzystujemy znaki wieloznaczne : "?", "*".

Na przykład, aby policzyć sprzedaż w jakimś konkretnym regionie, możemy użyć tylko części jego nazwy: do B3 wpisujemy "?est". A znak zapytania (?) zastępuje jeden znak Będziemy szukać 4-literowych słów. kończący się na "est" , łącznie ze spacjami.

Użyj następującej formuły COUNTIF w B3:

=COUNTIF(C7:C17,A3)

Jak już wiesz, wzór może łatwo przyjąć następną formę:

=COUNTIF(C7:C17, "?est")

I możemy zauważyć 5 sprzedaży w regionie "West".

Teraz wykorzystajmy komórkę B4 do innej formuły:

=COUNTIF(C7:C17,A4)

Co więcej, w A4 zmienimy kryterium na "??st", co oznacza, że teraz będziemy szukać słów 4-literowych kończący się na "st" Ponieważ w tym przypadku dwa regiony ("West" i "East") spełniają nasze kryteria, zobaczymy dziewięć sprzedaży:

Podobnie możemy policzyć liczbę sprzedaży towarów za pomocą gwiazdka (*). Ten symbol zastępuje nie tylko jeden, ale dowolna liczba znaków :

"*Czekolada" kryteria zlicza wszystkie produkty kończące się na "Chocolate".

"Czekolada*" kryteria zlicza wszystkie produkty zaczynające się od "Chocolate".

I jak się pewnie domyślasz, jeśli wejdziemy "*Czekolada*" , będziemy szukać wszystkich produktów, które zawierają słowo "Czekolada".

Uwaga. Jeśli chcesz policzyć liczbę słów, które zawierają gwiazdkę (*) i znak zapytania (?), użyj znak tyldy (~) przed tymi znakami. W tym przypadku COUNTIF potraktuje je jako zwykłe znaki, a nie znaki wyszukiwania. Na przykład, jeśli chcemy szukać wartości zawierających "?", formuła będzie:

=COUNTIF(D7:D15,"*~?*")

COUNTIF Arkusze Google dla mniejszy niż, większy niż lub równy niż

Funkcja COUNTIF potrafi policzyć nie tylko ile razy pojawia się jakaś liczba, ale także ile jest tych liczb większe niż/mniejsze niż/równe z/nierówne z inny określony numer.

W tym celu stosujemy odpowiednie operatory matematyczne: "=", ">", "=", "<=", "".

Sprawdź poniższą tabelę, aby zobaczyć, jak to działa:

Uwaga. To bardzo ważne, aby załączyć operator matematyczny wraz z liczbą w cudzysłowie .

Jeśli chcesz zmienić kryteria bez zmiany formuły, możesz odwołać się również do komórek.

Odwołajmy się do A3 i umieśćmy formułę w B3, tak jak zrobiliśmy to wcześniej:

=COUNTIF(F9:F19,A3)

Aby stworzyć bardziej skomplikowane kryteria, użyj opcji ampersand (&).

Na przykład B4 zawiera formułę, która liczy liczbę wartości większych lub równych 100 w zakresie E9:E19:

=COUNTIF(E9:E19,">="&A4)

B5 ma te same kryteria, ale odwołujemy się nie tylko do liczby w tej komórce, ale także do operatora matematycznego. Dzięki temu jeszcze łatwiej jest dostosować formułę COUNTIF w razie potrzeby:

=COUNTIF(E9:E19,A6&A5)

Wskazówka. Często pytano nas o liczenie tych komórek, które są większe lub mniejsze od wartości w innej kolumnie. Jeśli to jest to, czego szukasz, będziesz potrzebował innej funkcji do tego zadania - SUMPRODUCT.

Na przykład policzmy wszystkie wiersze, w których sprzedaż w kolumnie F jest większa niż w tym samym wierszu w kolumnie G:

=SUMPRODUCT(--(F6:F16>G6:G16))

• Część stanowiąca rdzeń formuły -. F6:F16>G6:G16 - porównuje wartości w kolumnach F i G. Gdy liczba w kolumnie F jest większa, formuła przyjmuje ją jako TRUE, w przeciwnym razie - FALSE.

  Zobaczysz, że jeśli wpiszesz to samo do ArrayFormula:

  =ArrayFormula(F6:F16>G6:G16)

  

• Wtedy formuła przyjmuje postać TRUE/FALSE i zamienia go na 1/0 liczby za pomocą podwójnego operatora jednoargumentowego (--) .
• To pozwala SUM zrobić resztę - zsumować liczbę, kiedy F jest większe niż G.

Arkusz kalkulacyjny Google COUNTIF z wieloma kryteriami

Czasami trzeba policzyć liczbę wartości, które odpowiadają na co najmniej jeden z wymienionych warunków (logika OR) lub na wiele kryteriów jednocześnie (logika AND). Na tej podstawie można użyć albo kilku funkcji COUNTIF w jednej komórce naraz, albo alternatywnej funkcji COUNTIFS.

Liczenie w arkuszach Google z wieloma kryteriami - logika AND

Jedyny sposób, jaki radziłbym tu zastosować, to specjalna funkcja, która służy do liczenia według wielu kryteriów - COUNTIFS:

Zwykle używa się go, gdy w dwóch zakresach znajdują się wartości, które powinny spełniać jakieś kryteria lub zawsze, gdy trzeba uzyskać liczbę mieszczącą się między określonym zakresem liczb.

Spróbujmy policzyć liczbę całkowitych sprzedaży pomiędzy 200 a 400:

=COUNTIFS(F8:F18,">=200",F8:F18,"<=400")

Wskazówka. Dowiedz się, jak używać COUNTIFS z kolorami w Google Sheets w tym artykule.

Liczenie unikatów w Arkuszach Google z wieloma kryteriami

Można pójść dalej i policzyć liczbę unikalnych produktów w przedziale od 200 do 400.

Nope, to nie jest to samo co powyżej! :) Powyższy COUNTIFS zlicza każde wystąpienie sprzedaży pomiędzy 200 a 400. To, co sugeruję, to spojrzenie również na produkt. Jeśli jego nazwa występuje więcej niż raz, nie zostanie uwzględniona w wyniku.

Jest do tego specjalna funkcja - COUNTUNIQUEIFS:

W porównaniu z COUNTIFS, to pierwszy argument robi różnicę. Count_unique_range to zakres, w którym funkcja będzie zliczać unikalne rekordy.

Oto jak będzie wyglądała formuła i jej wynik:

=COUNTUNIQUEIFS(D6:D16,F6:F16,">=200",F6:F16,"<=400")

Spójrz, są 3 wiersze, które spełniają moje kryteria: sprzedaż wynosi 200 i więcej, a jednocześnie wynosi 400 lub mniej.

Jednak 2 z nich należą do tego samego produktu -. Czekolada mleczna . COUNTUNIQUEIFS zlicza tylko pierwszą wzmiankę o produkcie.

Dzięki temu wiem, że są tylko 2 produkty, które spełniają moje kryteria.

Liczenie w arkuszach Google z wieloma kryteriami - logika OR

Gdy wystarczy tylko jedno ze wszystkich kryteriów, lepiej użyć kilku funkcji COUNTIF.

Przykład 1. COUNTIF + COUNTIF

Policzmy liczbę sprzedaży czarnej i białej czekolady. W tym celu wpiszmy w B4 następujący wzór:

=COUNTIF(D7:D17, "*Milk*") + COUNTIF(D7:D17, "*Dark*")

Wskazówka. Używam gwiazdki (*), aby zapewnić, że słowa "ciemny" i "mleko" zostaną policzone bez względu na to, w którym miejscu komórki się znajdują - na początku, w środku czy na końcu.

Wskazówka. zawsze możesz wprowadzić odwołania do komórek do swoich formuł. Zobacz, jak to wygląda na zrzucie ekranu poniżej w B3, wynik pozostaje taki sam:

Przykład 2. COUNTIF - COUNTIF

Teraz zamierzam policzyć liczbę całkowitych sprzedaży w przedziale od 200 do 400:

Biorę liczbę całkowitych sum poniżej 400 i odejmuję liczbę całkowitej sprzedaży poniżej 200 za pomocą następnego wzoru:

=C0UNTIF(F7:F17,"<=400") - COUNTIF(F7:F17,"<=200")

Formuła zwraca liczbę sprzedaży większą niż 200, ale mniejszą niż 400.

Jeśli zdecydujesz się odwołać do A3 i A4, które zawierają kryteria, formuła będzie nieco prostsza:

=COUNTIF(F7:F17, A4) - COUNTIF(F7:F17, A3)

Komórka A3 będzie miała kryterium "<=200", natomiast A4 - "<=400". Umieść obie formuły w B3 i B4 i sprawdź, czy wynik się nie zmieni - 3 sprzedaże w potrzebnym zakresie.

COUNTIF Google Sheets dla pustych i niepustych komórek

Za pomocą COUNTIF możemy również policzyć liczbę pustych lub niepustych komórek w jakimś zakresie.

Załóżmy, że z powodzeniem sprzedaliśmy produkt i oznaczyliśmy go jako "Zapłacony". Jeśli klient odmówił przyjęcia towaru, w komórce wpisujemy zero (0). Jeśli transakcja nie została zamknięta, komórka pozostaje pusta.

Do policzenia komórki niebędące komórkami pustymi z dowolną wartością, użyj następującego:

=COUNTIF(F7:F15,"")

lub

=COUNTIF(F7:F15,A3)

Aby policzyć liczbę puste komórki , pamiętaj, aby umieścić formułę COUNTIF w następujący sposób:

=COUNTIF(F7:F15,"")

lub

=COUNTIF(F7:F15,A4)

Liczba komórek z. wartość tekstowa jest liczony w ten sposób:

=COUNTIF(F7:F15, "*")

lub

=COUNTIF(F7:F15,A5)

Screenshot poniżej pokazuje, że komórki A3, A4 i A5 zawierają nasze kryteria:

Widzimy więc 4 zamknięte transakcje, z których 3 zostały opłacone, a 5 nie ma jeszcze żadnych oznaczeń i w związku z tym nie są zamknięte.

COUNTIF i formatowanie warunkowe

Jest jedna ciekawa możliwość, którą oferuje Google Sheets - do. zmienić format komórki (jak jego kolor) w zależności od jakichś kryteriów. Na przykład możemy wyróżnić na zielono wartości, które pojawiają się częściej.

Niewielką rolę może tu odegrać również funkcja COUNTIF.

Zaznacz zakres komórek, które chcesz sformatować w jakiś szczególny sposób.Kliknij Format -> Formatowanie warunkowe...

W Formatuj komórki, jeśli... z listy rozwijanej wybierz ostatnią opcję Wzór własny to. , a w pojawiające się pole wpisz następującą formułę:

=COUNTIF($B$10:$B$39,B10)/COUNTIF($B$10:$B$39,"*")>0.4

Oznacza to, że warunek zostanie spełniony, jeśli wartość z B10 pojawi się w obrębie B10:B39 w więcej niż 40% przypadków:

W podobny sposób dodajemy kolejne dwa kryteria reguły formatowania - jeśli wartość komórki pojawia się częściej niż w 25% przypadków oraz częściej niż w 15% przypadków:

=COUNTIF($B$10:$B$39,B10)/COUNTIF($B$10:$B$39,"*")>0.25

=COUNTIF($B$10:$B$39,B10)/COUNTIF($B$10:$B$39,"*")>0.15

Pamiętaj, że pierwsze kryterium zostanie sprawdzone wcześniej i jeśli zostanie spełnione, reszta nie będzie miała zastosowania. Dlatego lepiej zacząć od najbardziej unikalnych wartości przechodząc do tych najczęściej spotykanych. Jeśli wartość komórki nie spełnia żadnych kryteriów, jej format pozostanie nienaruszony.

Widać, że kolor komórek zmienił się zgodnie z naszymi kryteriami.

Dla pewności policzyliśmy również częstość występowania niektórych wartości w C3:C6 za pomocą funkcji COUNTIF. Wyniki potwierdzają, że COUNTIF w regule formatowania został zastosowany poprawnie.

Wskazówka. znajdź więcej przykładów, jak liczyć & zaznaczać duplikaty w Google Sheets.

Wszystkie te przykłady funkcji dają nam jasne zrozumienie, jak arkusz kalkulacyjny Google COUNTIF oferuje wiele możliwości pracy z danymi w najbardziej efektywny sposób.