Mục lục
Hướng dẫn xem xét cách sử dụng các hàm ISTEXT và ISNONTEXT trong Excel để kiểm tra xem một ô có chứa giá trị văn bản hay không.
Bất cứ khi nào bạn cần lấy thông tin về nội dung của một số ô trong Excel, bạn thường sử dụng cái gọi là hàm Thông tin. Cả ISTEXT và ISNONTEXT đều thuộc danh mục này. Hàm ISTEXT kiểm tra xem giá trị có phải là văn bản hay không và ISNONTEXT kiểm tra xem giá trị có phải là văn bản hay không. Bất kể khái niệm đơn giản là gì, thì các hàm này đều hữu ích một cách đáng ngạc nhiên để giải quyết nhiều tác vụ khác nhau trong Excel.
Hàm ISTEXT của Excel
Hàm ISTEXT trong Excel kiểm tra là một giá trị được chỉ định là văn bản hay không. Nếu giá trị là văn bản, hàm trả về TRUE. Đối với tất cả các loại dữ liệu khác (chẳng hạn như số, ngày, ô trống, lỗi, v.v.), nó trả về FALSE.
Cú pháp như sau:
ISTEXT(value)
Ở đâu giá trị là một giá trị, tham chiếu ô, biểu thức hoặc một hàm khác mà bạn muốn kiểm tra kết quả.
Ví dụ: để tìm hiểu xem một giá trị trong A2 có phải là văn bản hay không, hãy sử dụng công cụ đơn giản này công thức:
=ISTEXT(A2)
Hàm ISNONTEXT của Excel
Hàm ISNONTEXT trả về TRUE cho mọi giá trị không phải văn bản bao gồm số, ngày và giờ , khoảng trống và các công thức khác trả về kết quả hoặc lỗi không phải văn bản. Đối với các giá trị văn bản, nó trả về FALSE.
Cú pháp giống như cú pháp của hàm ISTEXT:
ISTEXT(value)
Ví dụ: để kiểm tra xem mộtgiá trị trong A2 không phải là văn bản, hãy sử dụng công thức sau:
=ISNONTEXT(A2)
Như minh họa trong ảnh chụp màn hình bên dưới, các công thức ISTEXT và ISNONTEXT trả về kết quả ngược lại:
Các hàm ISTEXT và ISNONTEXT trong Excel - lưu ý sử dụng
ISTEXT và ISNONTEXT là các hàm rất đơn giản và dễ sử dụng và bạn sẽ không gặp phải bất kỳ khó khăn nào với chúng. Tuy nhiên, có một số điểm chính cần lưu ý:
- Cả hai hàm đều thuộc nhóm hàm IS trả về giá trị logic (Boolean) là TRUE hoặc FALSE.
- Trong một trường hợp cụ thể khi số được lưu trữ dưới dạng văn bản , ISTEXT trả về TRUE và ISNONTEXT trả về FALSE.
- Cả hai hàm đều có sẵn trong tất cả các phiên bản Excel cho Office 365, Excel 2019, Excel 2016 , Excel 2013, Excel 2010, Excel 2007, Excel 2003, Excel XP và Excel 2000.
Sử dụng ISTEXT và ISNONTEXT trong Excel - ví dụ về công thức
Dưới đây, bạn sẽ tìm thấy ví dụ về cách sử dụng thực tế của các hàm ISTEXT và ISNONTEXT trong Excel, hy vọng sẽ giúp bạn làm cho trang tính của mình hiệu quả hơn.
Kiểm tra xem một giá trị có phải là văn bản không
Đôi khi khi bạn đang làm việc với nhiều giá trị, bạn có thể ngạc nhiên khi nhận thấy rằng đối với một số số, công thức của bạn trả về kết quả sai hoặc thậm chí có lỗi. Lý do rõ ràng nhất là các số có vấn đề được lưu trữ dưới dạng văn bản. Các công thức dưới đây sẽ cho bạn biết chắc chắn giá trị nào là văn bản từQuan điểm của Excel.
Công thức ISTEXT:
Trả về TRUE cho bất kỳ giá trị nào mà Excel coi là văn bản .
=ISTEXT(B2)
Công thức ISNONTEXT:
Trả về TRUE cho bất kỳ giá trị nào mà Excel coi là không phải văn bản .
=ISNONTEXT(B2)
ISTEXT để xác thực dữ liệu : chỉ cho phép nhập văn bản
Trong một số trường hợp, bạn có thể muốn cho phép người dùng chỉ nhập các giá trị văn bản vào một số ô nhất định. Để đạt được điều này, hãy tạo quy tắc xác thực dữ liệu dựa trên công thức ISTEXT. Dưới đây là cách thực hiện:
- Chọn một hoặc nhiều ô mà bạn muốn xác thực.
- Trên tab Dữ liệu , trong Công cụ dữ liệu nhóm, hãy nhấp vào nút Xác thực dữ liệu .
- Trên tab Cài đặt của hộp thoại Xác thực dữ liệu , hãy chọn Tùy chỉnh cho tiêu chí xác thực và nhập công thức ISTEXT của bạn vào hộp tương ứng.
- Nhấp vào OK để lưu quy tắc.
Đối với ví dụ này, chúng tôi đang xác thực các câu trả lời của bảng câu hỏi trong các ô B2 đến B4 với sự trợ giúp của công thức sau:
=ISTEXT(B2:B4)
Ngoài ra, bạn có thể định cấu hình thông báo Cảnh báo lỗi của riêng mình để giải thích cho người dùng của bạn loại dữ liệu nào được chấp nhận:
Kết quả là khi người dùng cố gắng nhập số hoặc ngày vào bất kỳ ô nào được xác thực, họ sẽ thấy thông tin sau cảnh báo:
Để biết thêm thông tin, vui lòng xem Sử dụng xác thực dữ liệu trong Excel.
Công thức Excel IF ISTEXT
Trong thực tế, ISTEXTvà ISNONTEXT thường được sử dụng cùng với hàm IF để đưa ra kết quả thân thiện với người dùng hơn so với TRUE và FALSE tiêu chuẩn.
Công thức 1. Nếu là văn bản thì
Lấy ví dụ đầu tiên của chúng tôi là a xa hơn một chút, giả sử bạn muốn trả về "Có" cho các giá trị văn bản và "Không" cho bất kỳ giá trị nào khác. Để hoàn thành, chỉ cần lồng hàm ISTEXT vào kiểm tra logic của IF và sử dụng "Có" và "Không" cho các đối số value_if_true và value_if_false tương ứng:
=IF(ISTEXT(A2), "Yes", "No")
Công thức 2. Kiểm tra đầu vào của ô
Trong một trong các ví dụ trước, chúng ta đã thảo luận về cách đảm bảo đầu vào hợp lệ của người dùng bằng cách sử dụng Xác thực dữ liệu . Điều này cũng có thể được thực hiện ở dạng "nhẹ nhàng hơn" với sự trợ giúp của công thức Excel IF ISTEXT.
Trong bảng câu hỏi, giả sử bạn muốn xác định câu trả lời nào hợp lệ (văn bản) và câu trả lời nào không (không phải văn bản). chữ). Đối với điều này, hãy sử dụng các câu lệnh IF lồng nhau với logic sau:
- Nếu ô được kiểm tra trống, không trả về gì, tức là một chuỗi trống ("").
- Nếu ô là văn bản, trả về "Câu trả lời hợp lệ".
- Nếu không có câu trả lời nào ở trên, hãy trả về "Câu trả lời không hợp lệ - vui lòng nhập văn bản."
Kết hợp tất cả những điều này lại với nhau, chúng tôi nhận được công thức sau , trong đó B2 là ô cần kiểm tra:
=IF(B2="", "", IF(ISTEXT(B2), "Valid answer", "Invalid answer - please enter text."))
Kiểm tra xem một dải ô có chứa bất kỳ văn bản nào không
Cho đến nay, chúng ta có đã kiểm tra từng tế bào riêng lẻ. Nhưng điều gì sẽ xảy ra nếu bạn cần biết liệu có bất kỳ ô nào trong một phạm vicó chứa văn bản không?
Để kiểm tra toàn bộ phạm vi, hãy kết hợp hàm ISTEXT với SUMPRODUCT theo cách sau:
SUMPRODUCT(ISTEXT( range)*1)>0 SUMPRODUCT(-- ISTEXT( range))>0Ví dụ: hãy kiểm tra từng hàng trong tập dữ liệu bên dưới để tìm giá trị văn bản, có thể thực hiện việc này bằng các công thức sau:
=SUMPRODUCT(ISTEXT(A2:C2)*1)>0
=SUMPRODUCT(--ISTEXT(A2:C2))>0
Một trong các công thức trên chuyển đến ô D2, sau đó bạn kéo công thức đó xuống ô D5.
Vì vậy, bây giờ bạn đã hiểu rõ hàng nào chứa một hoặc nhiều chuỗi văn bản (TRUE) và chỉ chứa số (FALSE).
Nếu bạn muốn trả về các kết quả khác, hãy nói "Có" hoặc "Không" trái ngược với TRUE và FALSE, hãy đính kèm công thức trên trong câu lệnh IF:
=IF(SUMPRODUCT(--ISTEXT(A2:C2))>0, "Yes", "No")
Cách hoạt động của công thức này
Công thức dựa trên khả năng của TÓM TẮT để xử lý các mảng nguyên bản. Hoạt động từ trong ra ngoài, đây là những gì nó thực hiện:
- Hàm ISTEXT trả về một mảng các giá trị TRUE và FALSE. Đối với A2:C2, chúng tôi nhận được mảng này:
{TRUE,TRUE,FALSE} - Tiếp theo, chúng tôi nhân từng phần tử của mảng trên với 1 để chuyển đổi các giá trị logic của TRUE và FALSE thành 1 và 0 tương ứng . Toán tử một ngôi kép (--) có thể được sử dụng cho cùng một mục đích. Sau khi chuyển đổi, công thức có dạng sau:
SUMPRODUCT({1,1,0})>0 - Hàm SUMPRODUCT cộng các giá trị 1 và 0, đồng thời bạn kiểm tra xem kết quả có lớn hơn 0 hay không. Nếu có, phạm vichứa ít nhất một giá trị văn bản và công thức trả về TRUE, nếu không trả về FALSE.
Kiểm tra xem một ô có chứa văn bản cụ thể hay không
Hàm ISTEXT của Excel chỉ có thể xác định xem một ô có chứa văn bản hay không , nghĩa là hoàn toàn bất kỳ văn bản nào. Để tìm hiểu xem một ô có chứa một chuỗi văn bản cụ thể hay không, hãy sử dụng công thức TÌM KIẾM SỐ IS hoặc COUNTIF với các ký tự đại diện.
Ví dụ: để xem liệu Id Mặt hàng trong A2 có chứa chuỗi văn bản được nhập trong ô D2 hay không, hãy sử dụng công thức bên dưới (vui lòng lưu ý tham chiếu tuyệt đối $D$2 để ngăn địa chỉ ô thay đổi khi công thức được sao chép sang các ô khác):
=ISNUMBER(SEARCH($D$2, A2))
Để thuận tiện, chúng tôi' sẽ đưa nó vào hàm IF:
=IF(ISNUMBER(SEARCH($D$2, A2)), "Yes", "No")
Và nhận được kết quả sau:
Kết quả tương tự có thể đạt được với COUNTIF :
=IF(COUNTIF(A2, "*"&$D$2&"*")>0, "Yes", "No")
Để biết thêm ví dụ, vui lòng xem Excel Nếu ô chứa công thức.
Đánh dấu các ô có chứa văn bản
Hàm ISTEXT cũng có thể được sử dụng với định dạng có điều kiện của Excel để đánh dấu các ô chứa giá trị văn bản. Dưới đây là cách thực hiện:
- Chọn tất cả các ô mà bạn muốn kiểm tra và đánh dấu (A2:C5 trong ví dụ này).
- Trên tab Trang chủ , trong nhóm Kiểu , nhấp vào Quy tắc mới > Sử dụng công thức để xác định các ô cần định dạng .
- Trong phần Định dạng giá trị nếu công thức này đúng , hãy nhập công thức bên dưới:
=ISTEXT(A2)Trong đó A2 làô ngoài cùng bên trái của phạm vi đã chọn.
- Nhấp vào nút Định dạng và chọn định dạng mong muốn.
- Nhấp OK hai lần để đóng cả hai hộp thoại và lưu quy tắc.
Để được giải thích chi tiết hơn về từng bước, vui lòng xem: Sử dụng công thức cho định dạng có điều kiện của Excel.
Kết quả là Excel đánh dấu tất cả các ô bằng bất kỳ chuỗi văn bản nào:
Đó là cách sử dụng hàm ISTEXT và ISNONTEXT trong Excel. Tôi cảm ơn bạn đã đọc và hy vọng sẽ gặp bạn trên blog của chúng tôi vào tuần tới!
Các bản tải xuống có sẵn
Ví dụ về công thức ISTEXT và ISNONTEXT của Excel
