Udžbenik govori o tome kako koristiti funkcije ISTEXT i ISNONTEXT u programu Excel za provjeru sadrži li ćelija tekstualnu vrijednost ili ne.

Kad god trebate dobiti informacije o sadržaju neke ćelije u Excelu, obično biste koristili takozvane informacijske funkcije. I ISTEXT i ISNONTEXT pripadaju ovoj kategoriji. Funkcija ISTEXT provjerava je li vrijednost tekst, a ISNONTEXT provjerava je li vrijednost tekst. Kakav god koncept bio jednostavan, funkcije su nevjerojatno korisne za rješavanje raznih zadataka u programu Excel.

Funkcija ISTEXT programa Excel

Funkcija ISTEXT u provjerama programa Excel je navedena vrijednost je tekst ili nije. Ako je vrijednost tekstualna, funkcija vraća TRUE. Za sve druge vrste podataka (kao što su brojevi, datumi, prazne ćelije, pogreške itd.) vraća FALSE.

Sintaksa je sljedeća:

ISTEXT(value)

Gdje vrijednost je vrijednost, referenca ćelije, izraz ili druga funkcija čiji rezultat želite testirati.

Na primjer, da biste saznali je li vrijednost u A2 tekst ili nije, upotrijebite ovaj jednostavan formula:

=ISTEXT(A2)

Funkcija ISNONTEXT programa Excel

Funkcija ISNONTEXT vraća TRUE za sve netekstualne vrijednosti uključujući brojeve, datume i vremena , praznine i druge formule koje vraćaju netekstualne rezultate ili pogreške. Za tekstualne vrijednosti vraća FALSE.

Sintaksa je ista kao kod funkcije ISTEXT:

ISTEXT(value)

Na primjer, da provjerite je livrijednost u A2 nije tekst, koristite ovu formulu:

=ISNONTEXT(A2)

Kao što je prikazano na slici ispod, formule ISTEXT i ISNONTEXT vraćaju suprotne rezultate:

Funkcije ISTEXT i ISNONTEXT u Excelu - napomene o korištenju

ISTEXT i ISNONTEXT su vrlo jednostavne funkcije koje se lako koriste i vjerojatno nećete naići na poteškoće s njima. Ipak, postoji nekoliko ključnih točaka na koje treba obratiti pozornost:

• Obje su funkcije dio grupe funkcija IS koje vraćaju logičke (Booleove) vrijednosti TRUE ili FALSE.
• U posebnom slučaju kada su brojevi pohranjeni kao tekst , ISTEXT vraća TRUE, a ISNONTEXT vraća FALSE.
• Obje funkcije dostupne su u svim verzijama programa Excel za Office 365, Excel 2019, Excel 2016 , Excel 2013, Excel 2010, Excel 2007, Excel 2003, Excel XP i Excel 2000.

Korištenje ISTEXT i ISNONTEXT u Excelu - primjeri formula

U nastavku ćete pronaći primjere praktične upotrebe funkcija ISTEXT i ISNONTEXT u Excelu koje će vam, nadamo se, pomoći da svoje radne listove učinite učinkovitijima.

Provjerite je li vrijednost tekst

Ponekad kada radite s hrpom vrijednosti, možda ćete se iznenaditi kada primijetite da za neke brojeve vaše formule vraćaju pogrešne rezultate ili čak pogreške. Najočitiji razlog je taj što su problematični brojevi pohranjeni kao tekst. Donje formule će vam sa sigurnošću reći iz kojih vrijednosti je tekstExcelovo gledište.

Formula ISTEXT:

Vraća TRUE za bilo koju vrijednost koju Excel smatra tekstom .

=ISTEXT(B2)

Formula ISNONTEXT:

Vraća TRUE za bilo koju vrijednost koju Excel smatra netekstualnom .

=ISNONTEXT(B2)

ISTEXT za provjeru valjanosti podataka : dopusti samo tekst

U nekim situacijama možda ćete htjeti dopustiti korisnicima unos samo tekstualnih vrijednosti u određene ćelije. Da biste to postigli, izradite pravilo za provjeru valjanosti podataka na temelju formule ISTEXT. Evo kako:

1. Odaberite jednu ili više ćelija koje želite potvrditi.
2. Na kartici Podaci , u Alatima za podatke kliknite gumb Provjera valjanosti podataka .
3. Na kartici Postavke dijaloškog okvira Provjera valjanosti podataka odaberite Prilagođeno za kriterije valjanosti i unesite svoju ISTEXT formulu u odgovarajući okvir.
4. Kliknite U redu za spremanje pravila.

Za ovaj primjer, provjeravamo odgovore na upitnik u ćelijama B2 kroz B4 uz pomoć ove formule:

=ISTEXT(B2:B4)

Osim toga, možete konfigurirati vlastitu poruku Upozorenje o pogrešci za objašnjenje vaši korisnici koje vrste podataka prihvaćaju:

Kao rezultat, kada korisnik pokuša unijeti broj ili datum u bilo koju od potvrđenih ćelija, vidjet će sljedeće upozorenje:

Za više informacija pogledajte Korištenje provjere valjanosti podataka u Excelu.

Excel IF ISTEXT formula

U praksi, ISTEXTi ISNONTEXT često se koriste zajedno s funkcijom IF za ispis rezultata koji je lakši za korištenje od standardnih TRUE i FALSE.

Formula 1. Ako je tekst, onda

Uzmimo naš prvi primjer a malo dalje, pretpostavimo da želite vratiti "Da" za tekstualne vrijednosti i "Ne" za bilo što drugo. Da biste to učinili, jednostavno ugniježdite funkciju ISTEXT u logički test IF i upotrijebite "Da" i "Ne" za argumente value_if_true odnosno value_if_false :

=IF(ISTEXT(A2), "Yes", "No")

Formula 2. Provjerite unos ćelije

U jednom od prethodnih primjera raspravljali smo o tome kako osigurati važeći korisnički unos pomoću provjere valjanosti podataka . To se također može učiniti u "blažem" obliku uz pomoć Excel IF ISTEXT formule.

Pretpostavimo da u upitniku želite odrediti koji su odgovori valjani (tekst), a koji nisu (ne- tekst). U tu svrhu upotrijebite ugniježđene IF naredbe sa sljedećom logikom:

• Ako je testirana ćelija prazna, ne vraća ništa, tj. prazan niz ("").
• Ako je ćelija je tekst, vratite "Valjani odgovor".
• Ako ništa od navedenog, vratite "Nevažeći odgovor - unesite tekst."

Stavljajući sve ovo zajedno, dobivamo sljedeću formulu , gdje je B2 ćelija koju treba provjeriti:

=IF(B2="", "", IF(ISTEXT(B2), "Valid answer", "Invalid answer - please enter text."))

Provjerite sadrži li raspon tekst

Do sada smo testirali svaku ćeliju pojedinačno. Ali što ako trebate znati postoji li neka ćelija u rasponusadrži tekst?

Da biste testirali cijeli raspon, kombinirajte funkciju ISTEXT sa SUMPRODUCT na ovaj način:

Kao primjer, provjerimo svaki redak u donjem skupu podataka za tekstualne vrijednosti, što se može učiniti pomoću sljedećih formula:

=SUMPRODUCT(ISTEXT(A2:C2)*1)>0

=SUMPRODUCT(--ISTEXT(A2:C2))>0

Jedna od gornjih formula ide u ćeliju D2, a zatim je povlačite prema dolje kroz ćeliju D5.

Dakle, sada jasno razumijete koji retci sadrže jedan ili više tekstualnih nizova (TRUE) i koji sadrže samo brojeve (FALSE).

Ako želite vratiti različite rezultate, recite "Da" ili "Ne" za razliku od TRUE i FALSE, priložite gornju formulu u IF izjavu:

=IF(SUMPRODUCT(--ISTEXT(A2:C2))>0, "Yes", "No")

Kako ova formula radi

Formula temelji se na sposobnosti SUMPRODUCT-a da nativno rukuje nizovima. Gledajući iznutra prema van, evo što radi:

• Funkcija ISTEXT vraća niz vrijednosti TRUE i FALSE. Za A2:C2 dobivamo ovaj niz:

  {TRUE,TRUE,FALSE}

• Dalje, svaki element gornjeg niza množimo s 1 kako bismo pretvorili logičke vrijednosti TRUE i FALSE u 1 odnosno 0 . Dvostruki unarni operator (--) može se koristiti za istu svrhu. Nakon transformacije, formula poprima ovaj oblik:

  SUMPRODUCT({1,1,0})>0

• Funkcija SUMPRODUCT zbraja 1 i 0, a vi provjeravate je li rezultat veći od nule. Ako jest, rasponsadrži barem jednu tekstualnu vrijednost i formula vraća TRUE, ako ne FALSE.

Provjerite sadrži li ćelija određeni tekst

Funkcija Excel ISTEXT može samo odrediti sadrži li ćelija tekst , što znači apsolutno bilo koji tekst. Kako biste saznali sadrži li ćelija određeni tekstualni niz, upotrijebite formulu ISBROJ PRETRAŽIVANJE ili COUNTIF sa zamjenskim znakovima.

Na primjer, da vidite sadrži li ID stavke u A2 unos tekstualnog niza u ćeliji D2, upotrijebite formulu u nastavku (imajte na umu apsolutnu referencu $D$2 koja sprječava promjenu adrese ćelije kada se formula kopira u druge ćelije):

=ISNUMBER(SEARCH($D$2, A2))

Radi praktičnosti, mi' zamotat ću ga u funkciju IF:

=IF(ISNUMBER(SEARCH($D$2, A2)), "Yes", "No")

I dobiti sljedeće rezultate:

Isti rezultat može se postići s COUNTIF :

=IF(COUNTIF(A2, "*"&$D$2&"*")>0, "Yes", "No")

Za više primjera pogledajte Excel Ako ćelija sadrži formule.

Označite ćelije koje sadrže tekst

Funkcija ISTEXT također se može koristiti s Excel uvjetnim oblikovanjem za označavanje ćelija koje sadrže tekstualne vrijednosti. Evo kako:

1. Odaberite sve ćelije koje želite provjeriti i označiti (A2:C5 u ovom primjeru).
2. Na kartici Početna , u grupi Stilovi kliknite Novo pravilo > Koristite formulu da odredite koje ćelije oblikovati .
3. U vrijednostima oblikovanja gdje je ova formula istinita okvir, unesite donju formulu:

   =ISTEXT(A2)

   Gdje je A2krajnja lijeva ćelija odabranog raspona.

4. Kliknite gumb Format i odaberite željeno oblikovanje.
5. Kliknite OK dvaput da biste zatvorili oba dijaloška okvira i spremili pravilo.

Za detaljnije objašnjenje svakog koraka pogledajte: Korištenje formula za Excel uvjetno oblikovanje.

Kao rezultat, Excel ističe sve ćelije s bilo kojim tekstualnim nizovima:

Tako se koriste funkcije ISTEXT i ISNONTEXT u programu Excel. Zahvaljujem vam na čitanju i nadam se da se vidimo na našem blogu sljedeći tjedan!

Dostupna preuzimanja

Excel ISTEXT i ISNONTEXT primjeri formula