I handledningen beskrivs hur du använder funktionerna ISTEXT och ISNONTEXT i Excel för att kontrollera om en cell innehåller ett textvärde eller inte.

När du behöver få information om innehållet i en cell i Excel använder du vanligtvis de så kallade informationsfunktionerna. Både ISTEXT och ISNONTEXT tillhör denna kategori. ISTEXT-funktionen kontrollerar om ett värde är text och ISNONTEXT kontrollerar om ett värde inte är text. Hur enkelt konceptet än är, är funktionerna otroligt användbara för att lösa en mängd olika uppgifter i Excel.

Excel ISTEXT-funktionen

ISTEXT-funktionen i Excel kontrollerar om ett angivet värde är text eller ej. Om värdet är text återger funktionen TRUE. För alla andra datatyper (t.ex. siffror, datum, tomma celler, fel osv.) återger den FALSE.

Syntaxen är följande:

ISTEXT(värde)

Var värde är ett värde, en cellreferens, ett uttryck eller en annan funktion vars resultat du vill testa.

Om du till exempel vill ta reda på om ett värde i A2 är text eller inte använder du den här enkla formeln:

=ISTEXT(A2)

Excel ISNONTEXT-funktionen

Funktionen ISNONTEXT returnerar TRUE för alla värden som inte är textvärden, t.ex. siffror, datum och tider, blanksteg och andra formler som returnerar icke-textuella resultat eller fel. För textvärden returnerar den FALSE.

Syntaxen är densamma som för ISTEXT-funktionen:

ISTEXT(värde)

Om du till exempel vill kontrollera om ett värde i A2 inte är text använder du den här formeln:

=ISNONTEXT(A2)

Som framgår av skärmbilden nedan ger formlerna ISTEXT och ISNONTEXT motsatta resultat:

ISTEXT- och ISNONTEXT-funktionerna i Excel - användningsanvisningar

ISTEXT och ISNONTEXT är mycket enkla och lättanvända funktioner, och det är inte troligt att du kommer att stöta på några svårigheter med dem. Det finns dock några viktiga punkter att ta hänsyn till:

• Båda funktionerna ingår i gruppen IS-funktioner och returnerar de logiska (booleska) värdena TRUE eller FALSE.
• I ett särskilt fall när nummer lagras som text ISTEXT returnerar TRUE och ISNONTEXT returnerar FALSE.
• Båda funktionerna finns i alla versioner av Excel för Office 365, Excel 2019, Excel 2016, Excel 2013, Excel 2010, Excel 2007, Excel 2003, Excel XP och Excel 2000.

Användning av ISTEXT och ISNONTEXT i Excel - exempel på formler

Nedan hittar du exempel på praktisk användning av funktionerna ISTEXT och ISNONTEXT i Excel som förhoppningsvis kan hjälpa dig att göra dina kalkylblad effektivare.

Kontrollera om ett värde är text

Ibland när du arbetar med en mängd värden kan du bli förvånad när du märker att formlerna för vissa tal ger fel resultat eller till och med fel. Den mest uppenbara orsaken är att problematiska tal lagras som text. Formlerna nedan visar dig säkert vilka värden som är text ur Excels synvinkel.

ISTEXT-formeln:

Återger TRUE för alla värden som Excel anser vara text .

=ISTEXT(B2)

Formeln ISNONTEXT:

Återger TRUE för alla värden som Excel anser vara Icke-text .

=ISNONTEXT(B2)

ISTEXT för datavalidering: endast text tillåts

I vissa situationer vill du kanske tillåta användare att endast skriva in textvärden i vissa celler. För att uppnå detta skapar du en regel för datavalidering som baseras på en ISTEXT-formel. Så här gör du:

1. Markera en eller flera celler som du vill validera.
2. På den Uppgifter på fliken Verktyg för data grupp, klickar du på Validering av data knapp.
3. På den Inställningar på fliken Validering av data dialogrutan, välj Anpassad för valideringskriterierna och ange din ISTEXT-formel i motsvarande ruta.
4. Klicka på OK för att spara regeln.

I det här exemplet validerar vi enkätsvaren i cellerna B2 till B4 med hjälp av den här formeln:

=ISTEXT(B2:B4)

Dessutom kan du konfigurera din egen Felvarning meddelande för att förklara för användarna vilken typ av data som accepteras:

När användaren försöker skriva in ett nummer eller ett datum i någon av de validerade cellerna visas följande varning:

Mer information finns i Användning av datavalidering i Excel.

Excel IF ISTEXT-formel

I praktiken används ISTEXT och ISNONTEXT ofta tillsammans med IF-funktionen för att ge ett mer användarvänligt resultat än standardvärdena TRUE och FALSE.

Formel 1. Om är text, då

Om vi tar vårt allra första exempel lite längre och antar att du vill returnera "Ja" för textvärden och "Nej" för allt annat. För att få det gjort är det bara att bädda in ISTEXT-funktionen i det logiska testet IF och använda "Ja" och "Nej" för value_if_true och value_if_false respektive argument:

=IF(ISTEXT(A2), "Ja", "Nej")

Formel 2. Kontrollera cellens inmatning

I ett av de tidigare exemplen diskuterade vi hur man säkerställer giltig användarinmatning med hjälp av datavalidering. Detta kan också göras i en "mildare" form med hjälp av en Excel IF ISTEXT-formel.

Antag att du vill avgöra vilka svar som är giltiga (text) och vilka som inte är giltiga (icke-text) i frågeformuläret genom att använda de inbäddade IF-satserna med följande logik:

• Om den testade cellen är tom returneras ingenting, dvs. en tom sträng ("").
• Om cellen är text, återges "Giltigt svar".
• Om inget av ovanstående anges, återges "ogiltigt svar - ange text".

Om vi lägger ihop allt detta får vi följande formel, där B2 är den cell som ska kontrolleras:

=IF(B2="", "", IF(ISTEXT(B2), "Giltigt svar", "Ogiltigt svar - ange text"))

Kontrollera om ett intervall innehåller någon text

Hittills har vi testat varje cell för sig. Men vad händer om du vill veta om någon cell i ett intervall innehåller text?

Om du vill testa hela intervallet kombinerar du ISTEXT-funktionen med SUMPRODUCT på detta sätt:

Som exempel kan vi kontrollera om varje rad i nedanstående datamängd innehåller textvärden, vilket kan göras med följande formler:

=SUMPRODUCT(ISTEXT(A2:C2)*1)>0

=SUMPRODUCT(--ISTEXT(A2:C2))>0

En av formlerna ovan går till cell D2, och sedan drar du den ner till cell D5.

Nu vet du tydligt vilka rader som innehåller en eller flera textsträngar (TRUE) och vilka som endast innehåller siffror (FALSE).

Om du vill returnera olika resultat, säga "Yes" eller "No" i stället för TRUE och FALSE, kan du inkludera ovanstående formel i IF-angivelsen:

=IF(SUMPRODUCT(--ISTEXT(A2:C2))>0, "Ja", "Nej")

Hur denna formel fungerar

Formeln är baserad på SUMPRODUCT:s förmåga att hantera matriser. Så här gör den från insidan och utåt:

• ISTEXT-funktionen returnerar en matris med värden TRUE och FALSE. För A2:C2 får vi denna matris:

  {TRUE,TRUE,FALSE}

• Därefter multiplicerar vi varje element i matrisen ovan med 1 för att omvandla de logiska värdena TRUE och FALSE till 1:or respektive 0:or. En dubbel unary operator (--) kan användas för samma ändamål. Efter omvandlingen har formeln följande form:

  SUMPRODUCT({1,1,0})>0

• Funktionen SUMPRODUCT adderar 1:or och 0:or och du kontrollerar om resultatet är större än noll. Om det är så innehåller intervallet minst ett textvärde och formeln returnerar TRUE, om inte FALSE.

Kontrollera om en cell innehåller specifik text

Excel-funktionen ISTEXT kan bara avgöra om en cell innehåller text, dvs. absolut vilken text som helst. Om du vill ta reda på om en cell innehåller en specifik textsträng använder du antingen formeln ISNUMBER SEARCH eller COUNTIF med jokertecken.

Om du till exempel vill se om artikelnummer i A2 innehåller textsträngen i cell D2 använder du nedanstående formel (tänk på den absoluta referensen $D$2 som förhindrar att celladressen ändras när formeln kopieras till andra celler):

=ISNUMBER(SEARCH($D$2, A2))

För enkelhetens skull lägger vi in den i IF-funktionen:

=IF(ISNUMBER(SEARCH($D$2, A2)), "Ja", "Nej")

Och får följande resultat:

Samma resultat kan uppnås med COUNTIF:

=IF(COUNTIF(A2, "*"&$D$2& "*")>0, "Ja", "Nej")

Fler exempel finns i Excel Om cellen innehåller formler.

Markera celler som innehåller text

ISTEXT-funktionen kan också användas med Excel villkorlig formatering för att markera celler som innehåller textvärden. Så här gör du:

1. Markera alla celler som du vill kontrollera och markera (A2:C5 i det här exemplet).
2. På den Hem på fliken Stilar grupp, klicka på Ny regel > Använd en formel för att bestämma vilka celler som ska formateras .
3. I Formatera värden där denna formel är sann och ange nedanstående formel:

   =ISTEXT(A2)

   Där A2 är den vänstra cellen i det valda intervallet.

4. Klicka på Format och välj önskad formatering.
5. Klicka på OK två gånger för att stänga båda dialogrutorna och spara regeln.

En mer detaljerad förklaring av varje steg finns i: Använda formler för villkorlig formatering i Excel.

Resultatet blir att Excel markerar alla celler med textsträngar:

Så här använder du funktionerna ISTEXT och ISNONTEXT i Excel. Tack för att du läste och vi ses på vår blogg nästa vecka!

Tillgängliga nedladdningar

Exempel på Excel-formlerna ISTEXT och ISNONTEXT