Tento kurz se zabývá použitím funkcí ISTEXT a ISNONTEXT v aplikaci Excel ke kontrole, zda buňka obsahuje textovou hodnotu, nebo ne.

Kdykoli potřebujete v Excelu získat informace o obsahu nějaké buňky, obvykle použijete takzvané informační funkce. Do této kategorie patří jak ISTEXT, tak ISNONTEXT. Funkce ISTEXT zjišťuje, zda je hodnota text, a ISNONTEXT testuje, zda hodnota není text. Ať už je koncept jakkoli jednoduchý, tyto funkce jsou úžasně užitečné pro řešení nejrůznějších úloh v Excelu.

Funkce Excel ISTEXT

Funkce ISTEXT v aplikaci Excel kontroluje, zda je zadaná hodnota textová nebo ne. Pokud je hodnota textová, funkce vrátí hodnotu TRUE. Pro všechny ostatní typy dat (například čísla, data, prázdné buňky, chyby atd.) vrátí hodnotu FALSE.

Syntaxe je následující:

ISTEXT(value)

Kde: hodnota je hodnota, odkaz na buňku, výraz nebo jiná funkce, jejíž výsledek chcete otestovat.

Chcete-li například zjistit, zda je hodnota v A2 textová, nebo ne, použijte tento jednoduchý vzorec:

=ISTEXT(A2)

Funkce ISNONTEXT aplikace Excel

Funkce ISNONTEXT vrací hodnotu TRUE pro všechny netextové hodnoty včetně čísel, dat a časů, prázdných míst a dalších vzorců, které vracejí netextové výsledky nebo chyby. Pro textové hodnoty vrací hodnotu FALSE.

Syntaxe je stejná jako u funkce ISTEXT:

ISTEXT(value)

Chcete-li například ověřit, zda hodnota v poli A2 není text, použijte tento vzorec:

=ISNONTEXT(A2)

Jak ukazuje obrázek níže, vzorce ISTEXT a ISNONTEXT vracejí opačné výsledky:

Funkce ISTEXT a ISNONTEXT v aplikaci Excel - poznámky k použití

Funkce ISTEXT a ISNONTEXT jsou velmi jednoduché a snadno použitelné a pravděpodobně s nimi nenarazíte na žádné potíže. Přesto je třeba věnovat pozornost několika klíčovým bodům:

• Obě funkce patří do skupiny funkcí IS, které vracejí logické (logické) hodnoty TRUE nebo FALSE.
• V konkrétním případě, kdy čísla jsou uložena jako text , ISTEXT vrací TRUE a ISNONTEXT vrací FALSE.
• Obě funkce jsou k dispozici ve všech verzích aplikace Excel pro Office 365, Excel 2019, Excel 2016, Excel 2013, Excel 2010, Excel 2007, Excel 2003, Excel XP a Excel 2000.

Použití ISTEXT a ISNONTEXT v aplikaci Excel - příklady vzorců

Níže najdete příklady praktického použití funkcí ISTEXT a ISNONTEXT v aplikaci Excel, které vám snad pomohou zefektivnit vaše pracovní listy.

Kontrola, zda je hodnota textová

Někdy, když pracujete s hromadou hodnot, můžete s překvapením zjistit, že pro některá čísla vaše vzorce vracejí nesprávné výsledky nebo dokonce chyby. Nejzřejmějším důvodem je, že problematická čísla jsou uložena jako text. Níže uvedené vzorce vám s jistotou prozradí, které hodnoty jsou z pohledu Excelu textové.

Vzorec ISTEXT:

Vrací hodnotu TRUE pro jakoukoli hodnotu, kterou Excel považuje za text .

=ISTEXT(B2)

Vzorec ISNONTEXT:

Vrací hodnotu TRUE pro jakoukoli hodnotu, kterou Excel považuje za netextové .

=ISNONTEXT(B2)

ISTEXT pro ověřování dat: povolit pouze text

V některých situacích můžete chtít uživatelům povolit zadávat do určitých buněk pouze textové hodnoty. Toho dosáhnete vytvořením pravidla pro ověřování dat na základě vzorce ISTEXT:

1. Vyberte jednu nebo více buněk, které chcete ověřit.
2. Na Data na kartě Datové nástroje klikněte na skupinu Ověřování dat tlačítko.
3. Na Nastavení na kartě Ověřování dat dialogového okna vyberte možnost Vlastní pro ověřovací kritéria a do příslušného pole zadejte vzorec ISTEXT.
4. Kliknutím na tlačítko OK pravidlo uložte.

V tomto příkladu ověřujeme odpovědi na dotazník v buňkách B2 až B4 pomocí tohoto vzorce:

=ISTEXT(B2:B4)

Kromě toho si můžete nakonfigurovat vlastní Upozornění na chybu vysvětlit uživatelům, jaký druh dat je přijímán:

Když se uživatel pokusí zadat číslo nebo datum do některé z ověřených buněk, zobrazí se následující upozornění:

Další informace naleznete v části Použití ověřování dat v aplikaci Excel.

Vzorec IF ISTEXT aplikace Excel

V praxi se ISTEXT a ISNONTEXT často používají společně s funkcí IF, aby byl výsledek uživatelsky přívětivější než standardní TRUE a FALSE.

Vzorec 1. Pokud je text, pak

Pokud náš první příklad posuneme o něco dále, předpokládejme, že chcete vracet hodnotu "Ano" pro textové hodnoty a "Ne" pro cokoli jiného. Chcete-li to provést, jednoduše vnořte funkci ISTEXT do logického testu IF a použijte "Ano" a "Ne" pro hodnoty value_if_true a value_if_false argumenty:

=IF(ISTEXT(A2), "Ano", "Ne")

Vzorec 2. Zkontrolujte vstup buňky

V jednom z předchozích příkladů jsme se zabývali tím, jak zajistit správnost uživatelského vstupu pomocí funkce Ověřování dat. To lze provést i v "mírnější" formě pomocí vzorce IF ISTEXT aplikace Excel.

Předpokládejme, že v dotazníku chcete určit, které odpovědi jsou platné (textové) a které ne (netextové). K tomu použijte vnořené příkazy IF s následující logikou:

• Pokud je testovaná buňka prázdná, nevrací nic, tj. prázdný řetězec ("").
• Pokud je buňka textová, vrátí se zpráva "Valid answer".
• Pokud není uvedena žádná z výše uvedených možností, vrátí se zpráva "Neplatná odpověď - zadejte prosím text.".

Když to všechno spojíme dohromady, dostaneme následující vzorec, kde B2 je buňka, která se má kontrolovat:

=IF(B2="", "", IF(ISTEXT(B2), "Platná odpověď", "Neplatná odpověď - zadejte prosím text."))

Zkontrolovat, zda rozsah obsahuje nějaký text

Dosud jsme testovali každou buňku zvlášť. Co když ale potřebujete zjistit, zda některá buňka v rozsahu obsahuje text?

Chcete-li otestovat celý rozsah, zkombinujte funkci ISTEXT s funkcí SUMPRODUCT tímto způsobem:

Jako příklad uveďme kontrolu textových hodnot v každém řádku níže uvedeného souboru dat, kterou lze provést pomocí následujících vzorců:

=SUMPRODUCT(ISTEXT(A2:C2)*1)>0

=SUMPRODUCT(--ISTEXT(A2:C2))>0

Jeden z výše uvedených vzorců přejde do buňky D2 a pak jej přetáhnete dolů přes buňku D5.

Nyní tedy víte, které řádky obsahují jeden nebo více textových řetězců (TRUE) a které pouze čísla (FALSE).

Pokud chcete vracet různé výsledky, například "Ano" nebo "Ne", a ne TRUE a FALSE, vložte výše uvedený vzorec do příkazu IF:

=IF(SUMPRODUCT(--ISTEXT(A2:C2))>0, "Ano", "Ne")

Jak tento vzorec funguje

Vzorec je založen na schopnosti funkce SUMPRODUCT nativně pracovat s poli. Když pracujeme zevnitř ven, uvedeme, co dělá:

• Funkce ISTEXT vrací pole hodnot TRUE a FALSE. Pro A2:C2 získáme toto pole:

  {TRUE,TRUE,FALSE}

• Dále každý prvek výše uvedeného pole vynásobíme jedničkou, abychom převedli logické hodnoty TRUE a FALSE na 1, resp. 0. Ke stejnému účelu lze použít dvojitý unární operátor (--). Po transformaci má vzorec tento tvar:

  SUMPRODUCT({1,1,0})>0

• Funkce SUMPRODUCT sčítá jedničky a nuly a kontroluje, zda je výsledek větší než nula. Pokud ano, rozsah obsahuje alespoň jednu textovou hodnotu a vzorec vrací TRUE, pokud ne, vrací FALSE.

Zkontrolovat, zda buňka obsahuje určitý text

Funkce ISTEXT aplikace Excel dokáže pouze zjistit, zda buňka obsahuje text, tedy naprosto libovolný text. Chcete-li zjistit, zda buňka obsahuje konkrétní textový řetězec, použijte vzorec ISNUMBER SEARCH nebo COUNTIF se zástupnými znaky.

Chcete-li například zjistit, zda položka Id v buňce A2 obsahuje textový řetězec zadaný v buňce D2, použijte následující vzorec (nezapomeňte na absolutní odkaz $D$2, který zabraňuje změně adresy buňky při kopírování vzorce do jiných buněk):

=ISNUMBER(SEARCH($D$2, A2))

Pro větší pohodlí ji zabalíme do funkce IF:

=IF(ISNUMBER(SEARCH($D$2, A2)), "Ano", "Ne")

A získáte následující výsledky:

Stejného výsledku lze dosáhnout pomocí COUNTIF:

=IF(COUNTIF(A2, "*"&$D$2& "*")>0, "Ano", "Ne")

Další příklady naleznete v části Excel Pokud buňka obsahuje vzorce.

Zvýraznění buněk, které obsahují text

Funkci ISTEXT lze také použít s podmíněným formátováním aplikace Excel ke zvýraznění buněk obsahujících textové hodnoty. Zde je uveden postup:

1. Vyberte všechny buňky, které chcete zkontrolovat, a zvýrazněte je (v tomto příkladu A2:C5).
2. Na Home na kartě Styly klikněte na tlačítko Nové pravidlo > Pomocí vzorce určete, které buňky se mají formátovat .
3. V Formátování hodnot, kde je tento vzorec pravdivý zadejte následující vzorec:

   =ISTEXT(A2)

   Kde A2 je nejlevější buňka vybraného rozsahu.

4. Klikněte na Formát a vyberte požadované formátování.
5. Dvakrát klikněte na tlačítko OK, abyste zavřeli obě dialogová okna a uložili pravidlo.

Podrobnější vysvětlení jednotlivých kroků naleznete v části: Použití vzorců pro podmíněné formátování aplikace Excel.

Výsledkem je, že Excel zvýrazní všechny buňky s libovolnými textovými řetězci:

To je návod, jak používat funkce ISTEXT a ISNONTEXT v aplikaci Excel. Děkuji vám za přečtení a doufám, že se uvidíme na našem blogu příští týden!

Dostupné soubory ke stažení

Příklady vzorců Excel ISTEXT a ISNONTEXT