Šioje pamokoje nagrinėjama, kaip naudoti "Excel" funkcijas ISTEXT ir ISNONTEXT, kad patikrintumėte, ar ląstelėje yra tekstinė reikšmė, ar ne.

Kai "Excel" programoje reikia gauti informacijos apie kurio nors langelio turinį, paprastai naudojate vadinamąsias informacijos funkcijas. Šiai kategorijai priklauso ir ISTEXT, ir ISNONTEXT. Funkcija ISTEXT tikrina, ar reikšmė yra tekstas, o ISNONTEXT tikrina, ar reikšmė nėra tekstas. Kad ir kokia paprasta būtų koncepcija, šios funkcijos yra nepaprastai naudingos sprendžiant įvairius "Excel" uždavinius.

"Excel" ISTEXT funkcija

"Excel" funkcija ISTEXT tikrina, ar nurodyta reikšmė yra tekstas, ar ne. Jei reikšmė yra tekstinė, funkcija grąžina TRUE. Visų kitų tipų duomenims (pvz., skaičiams, datoms, tuštiems langeliams, klaidoms ir t. t.) funkcija grąžina FALSE.

Sintaksė yra tokia:

ISTEXT(vertė)

Kur vertė yra reikšmė, ląstelės nuoroda, išraiška arba kita funkcija, kurios rezultatą norite patikrinti.

Pavyzdžiui, norėdami sužinoti, ar A2 reikšmė yra tekstas, ar ne, naudokite šią paprastą formulę:

=ISTEXT(A2)

"Excel" ISNONTEXT funkcija

Funkcija ISNONTEXT grąžina TRUE bet kokiai netekstinei vertei, įskaitant skaičius, datas ir laikus, tuščias vietas ir kitas formules, kurios grąžina netekstinius rezultatus arba klaidas. Teksto vertėms funkcija grąžina FALSE.

Sintaksė tokia pati kaip funkcijos ISTEXT:

ISTEXT(vertė)

Pavyzdžiui, norėdami patikrinti, ar A2 reikšmė nėra tekstas, naudokite šią formulę:

=ISNONTEXT(A2)

Kaip parodyta toliau pateiktoje ekrano kopijoje, formulės ISTEXT ir ISNONTEXT duoda priešingus rezultatus:

ISTEXT ir ISNONTEXT funkcijos "Excel" programoje - naudojimo pastabos

ISTEXT ir ISNONTEXT yra labai paprastos ir lengvai naudojamos funkcijos, todėl vargu ar su jomis susidursite su kokiais nors sunkumais. Vis dėlto reikia atkreipti dėmesį į keletą esminių dalykų:

• Abi funkcijos priklauso IS funkcijų grupei ir grąžina logines (logines) reikšmes TRUE arba FALSE.
• Konkrečiu atveju, kai skaičiai saugomi kaip tekstas , ISTEXT grąžina TRUE, o ISNONTEXT grąžina FALSE.
• Abi funkcijas galima naudoti visose "Office 365", "Excel 2019", "Excel 2019", "Excel 2016", "Excel 2013", "Excel 2010", "Excel 2007", "Excel 2003", "Excel XP" ir "Excel 2000" versijose.

ISTEXT ir ISNONTEXT naudojimas programoje "Excel" - formulių pavyzdžiai

Toliau rasite praktinių ISTEXT ir ISNONTEXT funkcijų naudojimo "Excel" programoje pavyzdžių, kurie, tikimės, padės jums efektyviau naudoti darbalapius.

Patikrinkite, ar reikšmė yra tekstas

Kartais, kai dirbate su keliomis reikšmėmis, galite nustebti pastebėję, kad kai kurių skaičių atveju formulės pateikia neteisingus rezultatus ar net klaidas. Akivaizdžiausia priežastis yra ta, kad probleminiai skaičiai saugomi kaip tekstas. Toliau pateiktos formulės jums tiksliai parodys, kurios reikšmės "Excel" požiūriu yra tekstas.

ISTEXT formulė:

Grąžinama TRUE bet kokiai vertei, kurią "Excel" laiko tekstas .

=ISTEXT(B2)

ISNONTEXT formulė:

Grąžinama TRUE bet kokiai vertei, kurią "Excel" laiko netekstinis .

=ISNONTEXT(B2)

ISTEXT duomenų patvirtinimui: leidžiama naudoti tik tekstą

Kai kuriais atvejais galite norėti leisti naudotojams tam tikrose ląstelėse įvesti tik teksto reikšmes. Kad tai pasiektumėte, sukurkite duomenų patvirtinimo taisyklę, pagrįstą ISTEXT formule:

1. Pasirinkite vieną ar daugiau langelių, kuriuos norite patvirtinti.
2. Dėl Duomenys skirtuke Duomenų įrankiai grupę, spustelėkite Duomenų patvirtinimas mygtuką.
3. Dėl Nustatymai skirtukas Duomenų patvirtinimas dialogo lange pasirinkite Pasirinktinis patvirtinimo kriterijų ir į atitinkamą langelį įrašykite ISTEXT formulę.
4. Norėdami išsaugoti taisyklę, spustelėkite Gerai.

Šiame pavyzdyje, naudodami šią formulę, patvirtiname B2-B4 langeliuose esančius klausimyno atsakymus:

=ISTEXT(B2:B4)

Be to, galite sukonfigūruoti savo Įspėjimas apie klaidą pranešimą, kuriame naudotojams paaiškinama, kokie duomenys priimami:

Todėl, kai naudotojas bandys įvesti skaičių arba datą į bet kurį iš patvirtintų langelių, jam bus rodomas toks įspėjimas:

Daugiau informacijos rasite skyriuje Duomenų patvirtinimas "Excel" programoje.

"Excel" IF ISTEXT formulė

Praktikoje ISTEXT ir ISNONTEXT dažnai naudojamos kartu su IF funkcija, kad būtų galima gauti patogesnį rezultatą nei standartiniai TRUE ir FALSE.

1 formulė Jei yra tekstas, tai

Jei mūsų pirmąjį pavyzdį panagrinėtume šiek tiek plačiau, tarkime, kad norite grąžinti "Taip" teksto reikšmėms ir "Ne" bet kokiai kitai reikšmei. Norėdami tai padaryti, tiesiog įkelkite funkciją ISTEXT į loginį testą IF ir naudokite "Taip" ir "Ne" kaip value_if_true ir value_if_false argumentai:

=IF(ISTEXT(A2), "Taip", "Ne")

Formulė 2. Patikrinkite ląstelės įvestį

Viename iš ankstesnių pavyzdžių aptarėme, kaip užtikrinti teisingą naudotojo įvestį naudojant duomenų patvirtinimą. Tai galima atlikti ir "švelnesne" forma, naudojant "Excel" IF ISTEXT formulę.

Tarkime, kad klausimyne norite nustatyti, kurie atsakymai yra teisingi (tekstiniai), o kurie ne (netekstiniai). Tam naudokite įterptinius IF teiginius su tokia logika:

• Jei tikrinamas langelis yra tuščias, negrąžinama nieko, t. y. tuščia eilutė ("").
• Jei langelis yra tekstas, grąžinama "Valid answer".
• Jei nė vienas iš šių atsakymų nepateiktas, grąžinama "Netinkamas atsakymas - įveskite tekstą".

Visa tai sudėjus gauname šią formulę, kurioje B2 yra tikrinama ląstelė:

=IF(B2="", "", IF(ISTEXT(B2), "Valid answer", "Invalid answer - please enter text."))

Patikrinkite, ar diapazone yra koks nors tekstas

Iki šiol tikrinome kiekvieną ląstelę atskirai. Tačiau ką daryti, jei norite sužinoti, ar bet kurioje diapazono ląstelėje yra teksto?

Jei norite patikrinti visą intervalą, tokiu būdu derinkite funkciją ISTEXT su SUMPRODUCT:

Pavyzdžiui, patikrinkime, ar kiekvienoje toliau pateikto duomenų rinkinio eilutėje yra teksto reikšmių, o tai galima padaryti naudojant šias formules:

=SUMPRODUCT(ISTEXT(A2:C2)*1)>0

=SUMPRODUCT(--ISTEXT(A2:C2))>0

Viena iš pirmiau pateiktų formulių patenka į langelį D2, tada ją vilkite žemyn per langelį D5.

Taigi dabar aiškiai suprantate, kuriose eilutėse yra viena ar daugiau teksto eilučių (TRUE), o kuriose - tik skaičiai (FALSE).

Jei norite grąžinti skirtingus rezultatus, t. y. "Taip" arba "Ne", o ne TRUE ir FALSE, pirmiau pateiktą formulę įtraukite į IF teiginį:

=IF(SUMPRODUCT(--ISTEXT(A2:C2))>0, "Taip", "Ne")

Kaip veikia ši formulė

Ši formulė pagrįsta SUMPRODUCT galimybe natūraliai tvarkyti masyvus. Dirbant iš vidaus į išorę, štai ką ji daro:

• Funkcija ISTEXT grąžina TRUE ir FALSE reikšmių masyvą. A2:C2 atveju gauname šį masyvą:

  {TRUE,TRUE,FALSE}

• Toliau kiekvieną minėto masyvo elementą padauginame iš 1, kad logines reikšmes TRUE ir FALSE paverstume atitinkamai 1 ir 0. Tam pačiam tikslui galima naudoti dvigubą vienaženklį operatorių (--). Po transformacijos formulė įgauna tokią formą:

  SUMPRODUCT({1,1,0})>0

• Funkcija SUMPRODUCT sudeda 1 ir 0 ir patikrina, ar rezultatas didesnis už nulį. Jei taip, diapazone yra bent viena teksto reikšmė, o formulė grąžina TRUE, jei ne - FALSE.

Patikrinkite, ar ląstelėje yra tam tikras tekstas

Excel funkcija ISTEXT gali nustatyti tik tai, ar ląstelėje yra teksto, t. y. absoliučiai bet kokio teksto. Norėdami sužinoti, ar ląstelėje yra konkreti teksto eilutė, naudokite formulę ISNUMBER SEARCH arba COUNTIF su pakaitiniais simboliais.

Pavyzdžiui, norėdami patikrinti, ar A2 ląstelėje esančiame elemento ID yra teksto eilutė, įvesta D2 ląstelėje, naudokite toliau pateiktą formulę (atkreipkite dėmesį į absoliučią nuorodą $D$2, kuri neleidžia pakeisti ląstelės adreso, kai formulė kopijuojama į kitas ląsteles):

=ISNUMBER(SEARCH($D$2, A2))

Patogumo dėlei ją įtrauksime į funkciją IF:

=IF(ISNUMBER(SEARCH($D$2, A2)), "Taip", "Ne")

Ir gausite šiuos rezultatus:

Tokį patį rezultatą galima pasiekti naudojant COUNTIF:

=IF(COUNTIF(A2, "*"&$D$2& "*")>0, "Taip", "Ne")

Daugiau pavyzdžių žr. "Excel" Jei ląstelėje yra formulių.

Paryškinkite ląsteles, kuriose yra teksto

Funkciją ISTEXT taip pat galima naudoti su "Excel" sąlyginiu formatavimu, kad paryškintumėte langelius, kuriuose yra teksto reikšmių. Štai kaip:

1. Pažymėkite ir paryškinkite visas ląsteles, kurias norite patikrinti (šiame pavyzdyje - A2:C5).
2. Dėl Pagrindinis skirtuke Stiliai grupę, spustelėkite Nauja taisyklė > Naudokite formulę, kad nustatytumėte, kurias ląsteles formatuoti .
3. Į Formuoti reikšmes, kai ši formulė yra teisinga įveskite toliau pateiktą formulę:

   =ISTEXT(A2)

   Kai A2 yra pasirinkto diapazono kairiausia ląstelė.

4. Spustelėkite Formatas mygtuką ir pasirinkite norimą formatavimą.
5. Du kartus spustelėkite OK, kad uždarytumėte abu dialogo langus ir išsaugotumėte taisyklę.

Išsamesnių kiekvieno žingsnio paaiškinimų rasite: "Excel" sąlyginio formatavimo formulių naudojimas.

Dėl to "Excel" išryškina visas ląsteles, kuriose yra bet kokių teksto eilučių:

Štai kaip naudoti ISTEXT ir ISNONTEXT funkcijas "Excel" programoje. Dėkoju, kad perskaitėte, ir tikiuosi, kad kitą savaitę susitiksime mūsų tinklaraštyje!

Galimi atsisiuntimai

"Excel" ISTEXT ir ISNONTEXT formulių pavyzdžiai