ٹیوٹوریل دیکھتا ہے کہ ایکسل میں ISTEXT اور ISNONTEXT فنکشنز کو کس طرح استعمال کیا جائے تاکہ یہ معلوم کیا جا سکے کہ آیا سیل میں ٹیکسٹول ویلیو ہے یا نہیں۔

جب بھی آپ کو مواد کے بارے میں معلومات حاصل کرنے کی ضرورت ہو ایکسل میں کچھ سیل میں، آپ عام طور پر نام نہاد انفارمیشن فنکشنز استعمال کریں گے۔ ISTEXT اور ISNONTEXT دونوں اس زمرے سے تعلق رکھتے ہیں۔ ISTEXT فنکشن چیک کرتا ہے کہ آیا کوئی قدر ٹیکسٹ ہے اور ISNONTEXT ٹیسٹ کرتا ہے اگر کوئی قدر ٹیکسٹ نہیں ہے۔ تصور جتنا بھی آسان ہو، فنکشنز ایکسل میں مختلف کاموں کی ایک قسم کو حل کرنے کے لیے حیرت انگیز طور پر مفید ہیں۔

Excel ISTEXT فنکشن

ایکسل چیک میں ISTEXT فنکشن ایک ہے مخصوص قیمت متن ہے یا نہیں؟ اگر قدر متنی ہے تو فنکشن TRUE لوٹاتا ہے۔ دیگر تمام ڈیٹا کی اقسام (جیسے نمبرز، تاریخیں، خالی سیل، غلطیاں وغیرہ) کے لیے یہ FALSE لوٹاتا ہے۔

نحو درج ذیل ہے:

ISTEXT(value)

کہاں 1 فارمولا:

=ISTEXT(A2)

Excel ISNONTEXT فنکشن

ISNONTEXT فنکشن نمبر، تاریخوں اور اوقات سمیت کسی بھی غیر متنی قدر کے لیے TRUE لوٹاتا ہے۔ ، خالی جگہیں، اور دوسرے فارمولے جو غیر متنی نتائج یا غلطیاں واپس کرتے ہیں۔ متن کی قدروں کے لیے، یہ FALSE لوٹاتا ہے۔

نحو ISTEXT فنکشن کی طرح ہے:

ISTEXT(value)

مثال کے طور پر، یہ چیک کرنے کے لیے کہ آیاA2 میں قدر ٹیکسٹ نہیں ہے، یہ فارمولہ استعمال کریں:

=ISNONTEXT(A2)

جیسا کہ نیچے اسکرین شاٹ میں دکھایا گیا ہے، ISTEXT اور ISNONTEXT فارمولے مخالف نتائج دیتے ہیں:

ایکسل میں ISTEXT اور ISNONTEXT فنکشنز - استعمال کے نوٹ

ISTEXT اور ISNONTEXT بہت سیدھے اور استعمال میں آسان فنکشنز ہیں، اور آپ کو ان کے ساتھ کسی قسم کی مشکلات کا سامنا کرنے کا امکان نہیں ہے۔ اس نے کہا، نوٹس لینے کے لیے چند اہم نکات ہیں:

• دونوں فنکشنز IS فنکشنز گروپ کا حصہ ہیں جو TRUE یا FALSE کی منطقی (بولین) اقدار واپس کرتے ہیں۔
• کسی مخصوص صورت میں جب نمبرز کو ٹیکسٹ کے طور پر محفوظ کیا جاتا ہے ، ISTEXT TRUE اور ISNONTEXT FALSE لوٹاتا ہے۔
• دونوں فنکشنز Excel کے تمام ورژن برائے Office 365, Excel 2019, Excel 2016 میں دستیاب ہیں۔ , Excel 2013, Excel 2010, Excel 2007, Excel 2003, Excel XP, اور Excel 2000.

ایکسل میں ISTEXT اور ISNONTEXT کا استعمال - فارمولہ مثالیں

ذیل میں آپ کو اس کی مثالیں ملیں گی ایکسل میں ISTEXT اور ISNONTEXT فنکشنز کے عملی استعمال جو امید ہے کہ آپ کی ورک شیٹس کو مزید موثر بنانے میں مدد کریں گے۔

چیک کریں کہ آیا کوئی قدر ٹیکسٹ ہے

بعض اوقات جب آپ قدروں کے ایک گروپ کے ساتھ کام کر رہے ہوتے ہیں، آپ کو یہ دیکھ کر حیرت ہو سکتی ہے کہ کچھ نمبروں کے لیے آپ کے فارمولے غلط نتائج یا غلطیاں بھی دیتے ہیں۔ سب سے واضح وجہ یہ ہے کہ مشکل نمبروں کو متن کے طور پر محفوظ کیا جاتا ہے۔ مندرجہ ذیل فارمولے آپ کو یقینی طور پر بتائیں گے کہ کن اقدار سے متن ہے۔ایکسل کا نقطہ نظر۔

ISTEXT فارمولا:

کسی بھی قدر کے لیے TRUE لوٹاتا ہے جسے Excel text سمجھتا ہے۔

=ISTEXT(B2)

ISNONTEXT فارمولا:

کسی بھی قدر کے لیے TRUE لوٹاتا ہے جسے Excel non-text سمجھتا ہے۔

=ISNONTEXT(B2)

ڈیٹا کی توثیق کے لیے ISTEXT : صرف متن کی اجازت دیں

کچھ حالات میں، آپ صارفین کو مخصوص سیلز میں صرف متن کی قدریں داخل کرنے کی اجازت دینا چاہتے ہیں۔ اسے حاصل کرنے کے لیے، ISTEXT فارمولے کی بنیاد پر ڈیٹا کی توثیق کا اصول بنائیں۔ یہاں طریقہ ہے:

1. ایک یا زیادہ سیلز کو منتخب کریں جن کی آپ تصدیق کرنا چاہتے ہیں۔
2. ڈیٹا ٹیب پر، ڈیٹا ٹولز میں گروپ میں، ڈیٹا کی توثیق بٹن پر کلک کریں۔
3. ڈیٹا کی توثیق ڈائیلاگ باکس کے سیٹنگز ٹیب پر، اپنی مرضی کے مطابق<15 کو منتخب کریں۔ توثیق کے معیار کے لیے اور متعلقہ باکس میں اپنا ISTEXT فارمولہ درج کریں۔
4. قاعدہ کو محفوظ کرنے کے لیے ٹھیک ہے پر کلک کریں۔

اس مثال کے لیے، ہم سیل B2 میں سوالنامے کے جوابات کی توثیق کر رہے ہیں۔ اس فارمولے کی مدد سے B4 کے ذریعے:

=ISTEXT(B2:B4)

اس کے علاوہ، آپ وضاحت کرنے کے لیے اپنا اپنا خرابی الرٹ پیغام ترتیب دے سکتے ہیں۔ آپ کے صارفین کس قسم کا ڈیٹا قبول کرتے ہیں:

نتیجے کے طور پر، جب صارف کسی بھی تصدیق شدہ سیل میں نمبر یا تاریخ درج کرنے کی کوشش کرتا ہے، تو وہ درج ذیل دیکھیں گے۔ الرٹ:

مزید معلومات کے لیے، براہ کرم Excel میں ڈیٹا کی توثیق کا استعمال دیکھیں۔

Excel IF ISTEXT فارمولا

عملی طور پر، ISTEXTاور ISNONTEXT کو اکثر IF فنکشن کے ساتھ استعمال کیا جاتا ہے تاکہ معیاری TRUE اور FALSE سے زیادہ صارف دوست نتیجہ نکل سکے۔

فارمولہ 1. اگر متن ہے، تو پھر

ہماری پہلی مثال کو لے کر تھوڑا آگے، فرض کریں کہ آپ متن کی قدروں کے لیے "ہاں" اور کسی اور چیز کے لیے "نہیں" واپس کرنا چاہتے ہیں۔ اسے مکمل کرنے کے لیے، ISTEXT فنکشن کو IF کے منطقی امتحان میں داخل کریں، اور بالترتیب value_if_true اور value_if_false دلائل کے لیے "Yes" اور "No" استعمال کریں:

=IF(ISTEXT(A2), "Yes", "No")

فارمولہ 2۔ سیل کا ان پٹ چیک کریں

پچھلی مثالوں میں سے ایک میں، ہم نے ڈیٹا کی توثیق کا استعمال کرکے درست صارف کے ان پٹ کو یقینی بنانے کے طریقہ پر تبادلہ خیال کیا . یہ ایکسل IF ISTEXT فارمولے کی مدد سے "ہلکی" شکل میں بھی کیا جا سکتا ہے۔

سوالنامے میں، فرض کریں کہ آپ یہ تعین کرنا چاہتے ہیں کہ کون سے جوابات درست ہیں (متن) اور کون سے نہیں (غیر- متن)۔ اس کے لیے، درج ذیل منطق کے ساتھ نیسٹڈ IF اسٹیٹمنٹس کا استعمال کریں:

• اگر ٹیسٹ شدہ سیل خالی ہے تو کچھ واپس نہ کریں، یعنی خالی سٹرنگ ("")۔
• اگر سیل متن ہے، "درست جواب" واپس کریں۔
• اگر مذکورہ بالا میں سے کوئی بھی نہیں ہے تو، "غلط جواب - براہ کرم متن درج کریں۔"

ان سب کو ایک ساتھ رکھنے سے، ہمیں درج ذیل فارمولہ ملتا ہے۔ ، جہاں B2 چیک کیا جانے والا سیل ہے:

=IF(B2="", "", IF(ISTEXT(B2), "Valid answer", "Invalid answer - please enter text."))

چیک کریں کہ آیا کسی رینج میں کوئی متن ہے

اب تک، ہمارے پاس ہر سیل کو انفرادی طور پر آزمایا۔ لیکن کیا ہوگا اگر آپ کو یہ جاننے کی ضرورت ہو کہ آیا ایک رینج میں کوئی سیل ہے۔متن پر مشتمل ہے؟

پوری رینج کو جانچنے کے لیے، ISTEXT فنکشن کو SUMPRODUCT کے ساتھ اس طرح جوڑیں:

مثال کے طور پر، آئیے ٹیکسٹ ویلیوز کے لیے نیچے دیے گئے ڈیٹا سیٹ میں ہر قطار کو چیک کریں، جو درج ذیل فارمولوں کے ساتھ کیا جا سکتا ہے:

=SUMPRODUCT(ISTEXT(A2:C2)*1)>0

=SUMPRODUCT(--ISTEXT(A2:C2))>0

اگر آپ مختلف نتائج واپس کرنا چاہتے ہیں تو "ہاں" یا "نہیں" کہیں۔ TRUE اور FALSE کے برعکس، اوپر والے فارمولے کو IF سٹیٹمنٹ میں بند کریں:

=IF(SUMPRODUCT(--ISTEXT(A2:C2))>0, "Yes", "No")

یہ فارمولہ کیسے کام کرتا ہے

فارمولہ مقامی طور پر صفوں کو ہینڈل کرنے کی SUMPRODUCT کی صلاحیت پر مبنی ہے۔ اندر سے کام کرتے ہوئے، یہ کیا کرتا ہے:

• ISTEXT فنکشن TRUE اور FALSE قدروں کی ایک صف لوٹاتا ہے۔ A2:C2 کے لیے، ہمیں یہ صف ملتی ہے:

  {TRUE,TRUE,FALSE}

• اس کے بعد، ہم TRUE اور FALSE کی منطقی قدروں کو بالترتیب 1's اور 0's میں تبدیل کرنے کے لیے مذکورہ صف کے ہر عنصر کو 1 سے ضرب دیتے ہیں۔ . ایک ڈبل یونری آپریٹر (--) اسی مقصد کے لیے استعمال کیا جا سکتا ہے۔ تبدیلی کے بعد، فارمولہ یہ شکل اختیار کرتا ہے:

  SUMPRODUCT({1,1,0})>0

• SUMPRODUCT فنکشن 1 اور 0 کا اضافہ کرتا ہے، اور آپ چیک کرتے ہیں کہ آیا نتیجہ صفر سے زیادہ ہے۔ اگر یہ ہے، رینجکم از کم ایک ٹیکسٹ ویلیو پر مشتمل ہے اور فارمولہ غلط نہیں تو TRUE لوٹاتا ہے۔

چیک کریں کہ آیا سیل میں مخصوص ٹیکسٹ ہے

ایکسل ISTEXT فنکشن صرف اس بات کا تعین کر سکتا ہے کہ آیا سیل متن پر مشتمل ہے ، مطلب بالکل کوئی متن۔ یہ معلوم کرنے کے لیے کہ آیا سیل میں مخصوص ٹیکسٹ اسٹرنگ ہے، یا تو ISNUMBER SEARCH فارمولہ یا COUNTIF وائلڈ کارڈز کے ساتھ استعمال کریں۔

مثال کے طور پر، یہ دیکھنے کے لیے کہ آیا A2 میں آئٹم آئی ڈی سیل D2 میں ٹیکسٹ سٹرنگ ان پٹ پر مشتمل ہے، استعمال کریں۔ مندرجہ ذیل فارمولہ (براہ کرم مطلق حوالہ $D$2 کو ذہن میں رکھیں جو سیل ایڈریس کو تبدیل کرنے سے روکتا ہے جب فارمولہ دوسرے سیلز میں کاپی کیا جاتا ہے):

=ISNUMBER(SEARCH($D$2, A2))

سہولت کے لیے، ہم' اسے IF فنکشن میں لپیٹیں گے:

=IF(ISNUMBER(SEARCH($D$2, A2)), "Yes", "No")

اور درج ذیل نتائج حاصل کریں:

28>

وہی نتیجہ COUNTIF کے ساتھ حاصل کیا جاسکتا ہے۔ :

=IF(COUNTIF(A2, "*"&$D$2&"*")>0, "Yes", "No")

مزید مثالوں کے لیے، براہ کرم Excel دیکھیں اگر سیل فارمولوں پر مشتمل ہے۔

ایسے سیلز کو نمایاں کریں جن میں ٹیکسٹ ہو

ISTEXT فنکشن کو ایکسل کنڈیشنل فارمیٹنگ کے ساتھ ٹیکسٹ ویلیوز والے سیلز کو ہائی لائٹ کرنے کے لیے بھی استعمال کیا جا سکتا ہے۔ یہ طریقہ ہے:

1. ان تمام سیلز کو منتخب کریں جنہیں آپ چیک کرنا چاہتے ہیں اور ہائی لائٹ کرنا چاہتے ہیں (اس مثال میں A2:C5)۔
2. ہوم ٹیب پر، میں اسٹائلز گروپ پر کلک کریں نیا اصول > ایک فارمولہ استعمال کریں اس بات کا تعین کرنے کے لیے کہ کن سیلز کو فارمیٹ کرنا ہے ۔
3. فارمیٹ ویلیوز میں جہاں یہ فارمولہ درست ہے باکس، ذیل کا فارمولا درج کریں:

   =ISTEXT(A2)

   جہاں A2 ہےمنتخب کردہ رینج کا سب سے بائیں سیل۔

4. فارمیٹ بٹن پر کلک کریں اور مطلوبہ فارمیٹنگ کا انتخاب کریں۔
5. دونوں ڈائیلاگ باکسز کو بند کرنے اور اصول کو محفوظ کرنے کے لیے دو بار ٹھیک ہے پر کلک کریں۔

ہر قدم کی مزید تفصیلی وضاحت کے لیے، براہ کرم دیکھیں: Excel مشروط فارمیٹنگ کے لیے فارمولے استعمال کرنا۔

نتیجے کے طور پر، Excel تمام سیلز کو کسی بھی ٹیکسٹ اسٹرنگ کے ساتھ ہائی لائٹ کرتا ہے:

اس طرح ایکسل میں ISTEXT اور ISNONTEXT فنکشنز کو استعمال کرنا ہے۔ میں پڑھنے کے لیے آپ کا شکریہ ادا کرتا ہوں اور امید کرتا ہوں کہ آپ کو اگلے ہفتے ہمارے بلاگ پر ملوں گا!

دستیاب ڈاؤن لوڈز

Excel ISTEXT اور ISNONTEXT فارمولے کی مثالیں