El tutorial muestra cómo utilizar las funciones ISTEXT e ISNONTEXT en Excel para comprobar si una celda contiene un valor textual o no.

Siempre que necesites obtener información sobre el contenido de alguna celda en Excel, lo normal es que utilices las llamadas funciones de Información. Tanto ISTEXT como ISNONTEXT pertenecen a esta categoría. La función ISTEXT comprueba si un valor es texto e ISNONTEXT comprueba si un valor no es texto. Por sencillo que sea el concepto, las funciones son asombrosamente útiles para resolver una gran variedad de tareas diferentes en Excel.

Función ISTEXT de Excel

La función ISTEXT de Excel comprueba si un valor especificado es texto o no. Si el valor es textual, la función devuelve TRUE. Para todos los demás tipos de datos (como números, fechas, celdas en blanco, errores, etc.) devuelve FALSE.

La sintaxis es la siguiente:

ISTEXT(valor)

Dónde valor es un valor, una referencia de celda, una expresión u otra función cuyo resultado desea comprobar.

Por ejemplo, para saber si un valor de A2 es texto o no, utilice esta sencilla fórmula:

=ISTEXT(A2)

Función ISNONTEXT de Excel

La función ISNONTEXT devuelve TRUE para cualquier valor no textual, incluidos números, fechas y horas, espacios en blanco y otras fórmulas que devuelven resultados no textuales o errores. Para valores de texto, devuelve FALSE.

La sintaxis es la misma que la de la función ISTEXT:

ISTEXT(valor)

Por ejemplo, para comprobar si un valor de A2 no es texto, utilice esta fórmula:

=ISNONTEXT(A2)

Como se muestra en la siguiente captura de pantalla, las fórmulas ISTEXT e ISNONTEXT devuelven resultados opuestos:

Funciones ISTEXT e ISNONTEXT en Excel - notas de uso

ISTEXT e ISNONTEXT son funciones muy sencillas y fáciles de usar, y es poco probable que encuentre dificultades con ellas. Dicho esto, hay algunos puntos clave que debe tener en cuenta:

• Ambas funciones forman parte del grupo de funciones IS que devuelven los valores lógicos (booleanos) de TRUE o FALSE.
• En un caso concreto, cuando los números se almacenan como texto ISTEXT devuelve TRUE e ISNONTEXT devuelve FALSE.
• Ambas funciones están disponibles en todas las versiones de Excel para Office 365, Excel 2019, Excel 2016, Excel 2013, Excel 2010, Excel 2007, Excel 2003, Excel XP y Excel 2000.

Uso de ISTEXT e ISNONTEXT en Excel - ejemplos de fórmulas

A continuación encontrará ejemplos de usos prácticos de las funciones ISTEXT e ISNONTEXT en Excel que esperamos le ayuden a hacer más eficientes sus hojas de cálculo.

Comprobar si un valor es texto

A veces, cuando estás trabajando con un montón de valores, puede que te sorprendas al notar que para algunos números tus fórmulas devuelven resultados erróneos o incluso errores. La razón más obvia es que los números problemáticos están almacenados como texto. Las siguientes fórmulas te dirán con seguridad qué valores son texto desde el punto de vista de Excel.

Fórmula ISTEXT:

Devuelve TRUE para cualquier valor que Excel considere texto .

=ISTEXT(B2)

Fórmula ISNONTEXT:

Devuelve TRUE para cualquier valor que Excel considere sin texto .

=ISNONTEXT(B2)

ISTEXT para la validación de datos: permitir sólo texto

En algunas situaciones, es posible que desee permitir que los usuarios introduzcan sólo valores de texto en determinadas celdas. Para ello, cree una regla de validación de datos basada en una fórmula ISTEXT. A continuación se explica cómo hacerlo:

1. Seleccione una o varias celdas que desee validar.
2. En el Datos en la pestaña Herramientas de datos haga clic en el botón Validación de datos botón.
3. En el Ajustes de la pestaña Validación de datos seleccione A medida para los criterios de validación e introduzca su fórmula ISTEXT en la casilla correspondiente.
4. Haga clic en Aceptar para guardar la regla.

Para este ejemplo, estamos validando las respuestas del cuestionario en las celdas B2 a B4 con la ayuda de esta fórmula:

=ISTEXT(B2:B4)

Además, puede configurar su propio Alerta de error para explicar a los usuarios qué tipo de datos se aceptan:

Como resultado, cuando el usuario intente introducir un número o una fecha en cualquiera de las celdas validadas, verá la siguiente alerta:

Para obtener más información, consulte Uso de la validación de datos en Excel.

Fórmula IF ISTEXT de Excel

En la práctica, ISTEXT e ISNONTEXT se utilizan a menudo junto con la función IF para obtener un resultado más fácil de usar que los estándares TRUE y FALSE.

Fórmula 1. Si es texto, entonces

Llevando nuestro primer ejemplo un poco más lejos, supongamos que desea devolver "Sí" para los valores de texto y "No" para cualquier otra cosa. Para ello, basta con anidar la función ISTEXT en la prueba lógica de IF, y utilizar "Sí" y "No" para la función value_if_true y value_if_false respectivamente:

=IF(ISTEXT(A2), "Sí", "No")

Fórmula 2. Comprobar la entrada de la celda

En uno de los ejemplos anteriores, explicamos cómo garantizar que la entrada del usuario es válida utilizando la Validación de Datos. Esto también se puede hacer de una forma más "suave" con la ayuda de una fórmula IF ISTEXT de Excel.

En el cuestionario, supongamos que desea determinar qué respuestas son válidas (texto) y cuáles no (no texto). Para ello, utilice las sentencias IF anidadas con la siguiente lógica:

• Si la celda analizada está vacía, no devuelve nada, es decir, una cadena vacía ("").
• Si la celda es texto, devuelve "Respuesta válida".
• Si ninguna de las anteriores, devuelva "Respuesta no válida - por favor, introduzca el texto".

Juntando todo esto, obtenemos la siguiente fórmula, donde B2 es la celda a comprobar:

=IF(B2="", "", IF(ISTEXT(B2), "Respuesta válida", "Respuesta no válida - introduzca un texto."))

Comprobar si un rango contiene algún texto

Hasta ahora, hemos comprobado cada celda individualmente. Pero, ¿qué ocurre si necesitas saber si alguna celda de un rango contiene texto?

Para comprobar todo el rango, combine la función ISTEXT con SUMPRODUCT de esta forma:

A modo de ejemplo, comprobemos cada fila del conjunto de datos siguiente en busca de valores de texto, lo que puede hacerse con las siguientes fórmulas:

=SUMPRODUCT(ISTEXT(A2:C2)*1)>0

=SUMPRODUCT(--ISTEXT(A2:C2))>0

Una de las fórmulas anteriores va a la celda D2, y luego la arrastras hacia abajo a través de la celda D5.

Así, ahora tiene claro qué filas contienen una o más cadenas de texto (TRUE) y cuáles contienen sólo números (FALSE).

Si desea obtener resultados diferentes, es decir, "Sí" o "No" en lugar de VERDADERO y FALSO, incluya la fórmula anterior en la sentencia IF:

=IF(SUMPRODUCT(--ISTEXT(A2:C2))>0, "Sí", "No")

Cómo funciona esta fórmula

La fórmula se basa en la capacidad de SUMPRODUCT para manejar matrices de forma nativa. Trabajando desde dentro hacia fuera, esto es lo que hace:

• La función ISTEXT devuelve una matriz de valores TRUE y FALSE. Para A2:C2, obtenemos esta matriz:

  {VERDADERO,VERDADERO,FALSO}

• A continuación, multiplicamos cada elemento de la matriz anterior por 1 para convertir los valores lógicos de VERDADERO y FALSO en 1 y 0, respectivamente. Se puede utilizar un operador unario doble (--) con el mismo propósito. Después de la transformación, la fórmula adopta esta forma:

  SUMPRODUCT({1,1,0})>0

• La función SUMPRODUCTO suma 1's y 0's, y comprueba si el resultado es mayor que cero. Si lo es, el rango contiene al menos un valor de texto y la fórmula devuelve VERDADERO, si no FALSO.

Comprobar si una celda contiene un texto específico

La función ISTEXT de Excel sólo puede determinar si una celda contiene texto, es decir, absolutamente cualquier texto. Para averiguar si una celda contiene una cadena de texto específica, utilice la fórmula BUSCAR ISNUMBER o COUNTIF con comodines.

Por ejemplo, para ver si el Id de elemento en A2 contiene la cadena de texto introducida en la celda D2, utilice la siguiente fórmula (tenga en cuenta la referencia absoluta $D$2 que impide que la dirección de la celda cambie cuando la fórmula se copia en otras celdas):

=ISNUMBER(SEARCH($D$2, A2))

Para mayor comodidad, lo envolveremos en la función IF:

=IF(ISNUMBER(SEARCH($D$2, A2)), "Sí", "No")

Y obtener los siguientes resultados:

El mismo resultado puede obtenerse con COUNTIF:

=IF(COUNTIF(A2, "*"&$D$2& "*")>0, "Sí", "No")

Para ver más ejemplos, consulte Excel Si la celda contiene fórmulas.

Resaltar las celdas que contienen texto

La función ISTEXT también puede utilizarse con el formato condicional de Excel para resaltar celdas que contengan valores de texto. A continuación se explica cómo:

1. Seleccione todas las celdas que desee comprobar y resáltelas (A2:C5 en este ejemplo).
2. En el Inicio en la pestaña Estilos grupo, haga clic en Nueva norma > Utilizar una fórmula para determinar qué celdas formatear .
3. En el Formatear los valores en los que esta fórmula es verdadera introduzca la siguiente fórmula:

   =ISTEXT(A2)

   Donde A2 es la celda situada más a la izquierda del rango seleccionado.

4. Haga clic en el botón Formato y elija el formato deseado.
5. Haga clic en Aceptar dos veces para cerrar ambos cuadros de diálogo y guardar la regla.

Para una explicación más detallada de cada paso, consulte: Uso de fórmulas para el formato condicional de Excel.

Como resultado, Excel resalta todas las celdas con cualquier cadena de texto:

Así es como se utilizan las funciones ISTEXT e ISNONTEXT en Excel. Te doy las gracias por leer y ¡espero verte en nuestro blog la semana que viene!

Descargas disponibles

Ejemplos de fórmulas ISTEXT e ISNONTEXT en Excel