يبحث البرنامج التعليمي في كيفية استخدام وظائف ISTEXT و ISNONTEXT في Excel للتحقق مما إذا كانت الخلية تحتوي على قيمة نصية أم لا.

كلما احتجت إلى الحصول على معلومات حول المحتويات في بعض الخلايا في Excel ، ستستخدم عادةً ما يسمى بوظائف المعلومات. ينتمي كل من ISTEXT و ISNONTEXT إلى هذه الفئة. تتحقق الدالة ISTEXT مما إذا كانت القيمة نصية ويختبر ISNONTEXT ما إذا كانت القيمة ليست نصًا. مهما كان المفهوم بسيطًا ، فإن الوظائف مفيدة بشكل مثير للدهشة لحل مجموعة متنوعة من المهام المختلفة في Excel.

وظيفة ISTEXT في Excel

وظيفة ISTEXT في Excel تدقيق هي القيمة المحددة نص أم لا. إذا كانت القيمة نصية ، ترجع الدالة TRUE. بالنسبة لجميع أنواع البيانات الأخرى (مثل الأرقام والتواريخ والخلايا الفارغة والأخطاء وما إلى ذلك) ، فإنها ترجع FALSE.

يكون بناء الجملة كما يلي:

ISTEXT(value)

أين القيمة هي قيمة أو مرجع خلية أو تعبير أو دالة أخرى تريد اختبار نتيجتها.

على سبيل المثال ، لمعرفة ما إذا كانت القيمة في A2 نصًا أم لا ، استخدم هذا البسيط الصيغة:

=ISTEXT(A2)

دالة ISNONTEXT في Excel

ترجع الدالة ISNONTEXT TRUE لأي قيمة غير نصية بما في ذلك الأرقام والتواريخ والأوقات والفراغات والصيغ الأخرى التي تعرض نتائج أو أخطاء غير نصية. بالنسبة للقيم النصية ، تقوم بإرجاع FALSE.

بناء الجملة هو نفسه صيغة الدالة ISTEXT:

ISTEXT(value)

على سبيل المثال ، للتحقق مما إذا كانالقيمة في A2 ليست نصًا ، استخدم هذه الصيغة:

=ISNONTEXT(A2)

كما هو موضح في لقطة الشاشة أدناه ، ترجع الصيغتان ISTEXT و ISNONTEXT النتائج المعاكسة:

وظائف ISTEXT و ISNONTEXT في Excel - ملاحظات الاستخدام

ISTEXT و ISNONTEXT هي وظائف مباشرة للغاية وسهلة الاستخدام ، ومن غير المحتمل أن تواجه أي صعوبات معها. ومع ذلك ، هناك بعض النقاط الرئيسية التي يجب الانتباه إليها:

• تعد كلتا الوظيفتين جزءًا من مجموعة وظائف IS التي تُرجع القيم المنطقية (المنطقية) للقيمة TRUE أو FALSE.
• في حالة معينة عندما يتم تخزين أرقام كنص ، تُرجع ISTEXT TRUE وتُرجع ISNONTEXT FALSE.
• تتوفر كلتا الوظيفتين في جميع إصدارات Excel لـ Office 365 و Excel 2019 و Excel 2016 و Excel 2013 و Excel 2010 و Excel 2007 و Excel 2003 و Excel XP و Excel 2000.

استخدام ISTEXT و ISNONTEXT في Excel - أمثلة على الصيغ

أدناه ستجد أمثلة على الاستخدامات العملية لوظائف ISTEXT و ISNONTEXT في Excel والتي نأمل أن تساعدك في جعل أوراق العمل الخاصة بك أكثر كفاءة.

تحقق مما إذا كانت القيمة هي نص

في بعض الأحيان عندما تعمل مع مجموعة من القيم ، قد تتفاجأ عندما تلاحظ أنه بالنسبة لبعض الأرقام ، تُرجع الصيغ نتائج خاطئة أو حتى أخطاء. السبب الأكثر وضوحًا هو أن الأرقام التي بها مشكلات يتم تخزينها كنص. سوف تخبرك الصيغ أدناه بالتأكيد أي القيم تأتي من النصوجهة نظر Excel.

صيغة ISTEXT:

إرجاع TRUE لأي قيمة يعتبرها Excel نص .

=ISTEXT(B2)

صيغة ISNONTEXT:

إرجاع TRUE لأي قيمة يعتبرها Excel غير نصية .

=ISNONTEXT(B2)

ISTEXT للتحقق من صحة البيانات : السماح بالنص فقط

في بعض المواقف ، قد ترغب في السماح للمستخدمين بإدخال قيم نصية فقط في خلايا معينة. لتحقيق ذلك ، قم بإنشاء قاعدة التحقق من صحة البيانات بناءً على صيغة ISTEXT. وإليك الطريقة:

1. حدد خلية واحدة أو أكثر تريد التحقق من صحتها.
2. في علامة التبويب البيانات ، في أدوات البيانات المجموعة ، انقر فوق الزر التحقق من صحة البيانات .
3. في علامة التبويب الإعدادات في علامة التبويب التحقق من صحة البيانات ، حدد مخصص لمعايير التحقق وأدخل صيغة ISTEXT في المربع المقابل.
4. انقر فوق "موافق" لحفظ القاعدة.

في هذا المثال ، نحن نتحقق من صحة إجابات الاستبيان في الخلايا B2 من خلال B4 بمساعدة هذه الصيغة:

=ISTEXT(B2:B4)

بالإضافة إلى ذلك ، يمكنك تكوين رسالة تنبيه الخطأ لشرحها المستخدمون نوع البيانات المقبولة:

ونتيجة لذلك ، عندما يحاول المستخدم إدخال رقم أو تاريخ في أي من الخلايا التي تم التحقق من صحتها ، سيرى ما يلي تنبيه:

لمزيد من المعلومات ، يرجى الاطلاع على استخدام التحقق من صحة البيانات في Excel.

صيغة Excel IF ISTEXT

عمليًا ، ISTEXTوغالبًا ما يتم استخدام ISNONTEXT مع الدالة IF لإخراج نتيجة أكثر سهولة في الاستخدام من النتيجة القياسية TRUE و FALSE.

الصيغة 1. إذا كانت نصًا ، فعندئذٍ

أبعد من ذلك بقليل ، لنفترض أنك تريد إرجاع "نعم" للقيم النصية و "لا" لأي شيء آخر. لإنجاز ذلك ، ما عليك سوى تضمين دالة ISTEXT في الاختبار المنطقي لـ IF ، واستخدام "نعم" و "لا" للوسيطتين value_if_true و value_if_false ، على التوالي:

=IF(ISTEXT(A2), "Yes", "No")

الصيغة 2. تحقق من إدخال الخلية

في أحد الأمثلة السابقة ، ناقشنا كيفية ضمان إدخال مستخدم صالح باستخدام التحقق من صحة البيانات . يمكن القيام بذلك أيضًا في نموذج "أكثر اعتدالًا" بمساعدة صيغة Excel IF ISTEXT.

في الاستبيان ، افترض أنك تريد تحديد الإجابات الصحيحة (نص) وأيها ليست (غير - نص). لهذا ، استخدم عبارات IF المتداخلة مع المنطق التالي:

• إذا كانت الخلية المختبرة فارغة ، لا تُرجع شيئًا ، أي سلسلة فارغة ("").
• إذا كانت الخلية عبارة عن نص ، قم بإرجاع "إجابة صالحة".
• إذا لم يكن أي من الخيارين أعلاه ، فقم بإرجاع "إجابة غير صالحة - الرجاء إدخال نص."

بتجميع كل هذا معًا ، نحصل على الصيغة التالية ، حيث B2 هي الخلية المطلوب التحقق منها:

=IF(B2="", "", IF(ISTEXT(B2), "Valid answer", "Invalid answer - please enter text."))

تحقق مما إذا كان النطاق يحتوي على أي نص

حتى الآن ، لدينا اختبرت كل خلية على حدة. ولكن ماذا لو كنت بحاجة إلى معرفة ما إذا كانت هناك أي خلية في النطاقيحتوي على نص؟

لاختبار النطاق بالكامل ، ادمج دالة ISTEXT مع SUMPRODUCT بهذه الطريقة:

كمثال ، دعنا نتحقق من كل صف في مجموعة البيانات أدناه للقيم النصية ، والتي يمكن إجراؤها باستخدام الصيغ التالية:

=SUMPRODUCT(ISTEXT(A2:C2)*1)>0

=SUMPRODUCT(--ISTEXT(A2:C2))>0

تنتقل إحدى الصيغ أعلاه إلى الخلية D2 ، ثم تسحبها لأسفل عبر الخلية D5.

لذلك ، لديك الآن فهم واضح للصفوف التي تحتوي على سلسلة نصية واحدة أو أكثر (TRUE) والتي تحتوي على أرقام فقط (FALSE).

إذا كنت ترغب في إرجاع نتائج مختلفة ، فقل "نعم" أو "لا" على عكس TRUE و FALSE ، أرفق الصيغة أعلاه في عبارة IF:

=IF(SUMPRODUCT(--ISTEXT(A2:C2))>0, "Yes", "No")

كيف تعمل هذه الصيغة

الصيغة يعتمد على قدرة SUMPRODUCT على التعامل مع المصفوفات محليًا. من الداخل إلى الخارج ، إليك ما تفعله:

• ترجع الدالة ISTEXT صفيفًا من قيم TRUE و FALSE. بالنسبة إلى A2: C2 ، نحصل على هذه المصفوفة:

  {TRUE,TRUE,FALSE}

• بعد ذلك ، نضاعف كل عنصر من المصفوفة أعلاه بمقدار 1 لتحويل القيم المنطقية لـ TRUE و FALSE إلى قيم 1 و 0 ، على التوالي . يمكن استخدام عامل تشغيل أحادي مزدوج (-) لنفس الغرض. بعد التحويل ، تأخذ الصيغة هذا الشكل:

  SUMPRODUCT({1,1,0})>0

• تضيف الدالة SUMPRODUCT قيم 1 و 0 ، وتتحقق مما إذا كانت النتيجة أكبر من الصفر. إذا كان كذلك ، فإن النطاقتحتوي على قيمة نصية واحدة على الأقل وتقوم الصيغة بإرجاع TRUE ، إن لم يكن FALSE.

تحقق مما إذا كانت الخلية تحتوي على نص معين

يمكن للدالة Excel ISTEXT فقط تحديد ما إذا كانت الخلية تحتوي على نص ، وهذا يعني أي نص على الإطلاق. لمعرفة ما إذا كانت الخلية تحتوي على سلسلة نصية معينة ، استخدم إما صيغة ISNUMBER SEARCH أو COUNTIF مع أحرف البدل.

على سبيل المثال ، لمعرفة ما إذا كان معرف العنصر في A2 يحتوي على إدخال سلسلة نصية في الخلية D2 ، استخدم الصيغة أدناه (يرجى مراعاة المرجع المطلق $ D $ 2 الذي يمنع عنوان الخلية من التغيير عند نسخ الصيغة إلى خلايا أخرى):

=ISNUMBER(SEARCH($D$2, A2))

من أجل الراحة ، نحن ' لفها في وظيفة IF:

=IF(ISNUMBER(SEARCH($D$2, A2)), "Yes", "No")

والحصول على النتائج التالية:

يمكن تحقيق نفس النتيجة باستخدام COUNTIF :

=IF(COUNTIF(A2, "*"&$D$2&"*")>0, "Yes", "No")

لمزيد من الأمثلة ، يرجى مراجعة Excel إذا كانت الخلية تحتوي على صيغ.

تمييز الخلايا التي تحتوي على نص

يمكن أيضًا استخدام وظيفة ISTEXT مع تنسيق Excel الشرطي لتمييز الخلايا التي تحتوي على قيم نصية. وإليك الطريقة:

1. حدد جميع الخلايا التي تريد التحقق منها وتمييزها (A2: C5 في هذا المثال).
2. في علامة التبويب الصفحة الرئيسية ، في المجموعة الأنماط ، انقر فوق قاعدة جديدة & gt؛ استخدم صيغة لتحديد الخلايا المراد تنسيقها .
3. في تنسيق القيم عندما تكون هذه الصيغة صحيحة في المربع ، أدخل الصيغة أدناه:

   =ISTEXT(A2)

   حيث يكون A2 هوالخلية الموجودة في أقصى اليسار من النطاق المحدد.

4. انقر فوق الزر تنسيق واختر التنسيق المطلوب.
5. انقر فوق موافق مرتين لإغلاق مربعي الحوار وحفظ القاعدة.

للحصول على شرح أكثر تفصيلاً لكل خطوة ، يرجى الاطلاع على: استخدام الصيغ للتنسيق الشرطي لـ Excel.

نتيجة لذلك ، يقوم Excel بتمييز جميع الخلايا التي تحتوي على أي سلاسل نصية:

هذه هي كيفية استخدام وظائف ISTEXT و ISNONTEXT في Excel. أشكرك على القراءة وآمل أن أراك على مدونتنا الأسبوع المقبل!

التنزيلات المتاحة

أمثلة على صيغ Excel ISTEXT و ISNONTEXT