В учебнике рассматривается, как использовать функции ISTEXT и ISNONTEXT в Excel, чтобы проверить, содержит ли ячейка текстовое значение или нет.

Если вам нужно получить информацию о содержимом какой-либо ячейки в Excel, вы обычно используете так называемые функции Информация. К этой категории относятся функции ISTEXT и ISNONTEXT. Функция ISTEXT проверяет, является ли значение текстом, а ISNONTEXT проверяет, не является ли значение текстом. Какой бы простой ни была концепция, эти функции удивительно полезны для решения множества различных задач в Excel.

Функция Excel ISTEXT

Функция ISTEXT в Excel проверяет, является ли указанное значение текстом или нет. Если значение текстовое, функция возвращает TRUE. Для всех других типов данных (таких как числа, даты, пустые ячейки, ошибки и т.д.) она возвращает FALSE.

Синтаксис следующий:

ISTEXT(значение)

Где значение это значение, ссылка на ячейку, выражение или другая функция, результат которой вы хотите проверить.

Например, чтобы узнать, является ли значение в A2 текстом или нет, используйте эту простую формулу:

=ISTEXT(A2)

Функция Excel ISNONTEXT

Функция ISNONTEXT возвращает TRUE для любого нетекстового значения, включая числа, даты и время, пробелы и другие формулы, которые возвращают нетекстовые результаты или ошибки. Для текстовых значений она возвращает FALSE.

Синтаксис такой же, как и у функции ISTEXT:

ISTEXT(значение)

Например, чтобы проверить, не является ли значение в A2 текстом, используйте эту формулу:

=ISNONTEXT(A2)

Как показано на скриншоте ниже, формулы ISTEXT и ISNONTEXT дают противоположные результаты:

Функции ISTEXT и ISNONTEXT в Excel - советы по использованию

ISTEXT и ISNONTEXT - очень простые и удобные в использовании функции, и вы вряд ли столкнетесь с какими-либо трудностями при работе с ними. Тем не менее, есть несколько ключевых моментов, на которые следует обратить внимание:

• Обе функции входят в группу функций IS, которые возвращают логические (булевы) значения TRUE или FALSE.
• В конкретном случае, когда числа хранятся в виде текста , ISTEXT возвращает TRUE, а ISNONTEXT возвращает FALSE.
• Обе функции доступны во всех версиях Excel для Office 365, Excel 2019, Excel 2016, Excel 2013, Excel 2010, Excel 2007, Excel 2003, Excel XP и Excel 2000.

Использование ISTEXT и ISNONTEXT в Excel - примеры формул

Ниже приведены примеры практического использования функций ISTEXT и ISNONTEXT в Excel, которые, надеемся, помогут вам сделать ваши рабочие листы более эффективными.

Проверьте, является ли значение текстом

Иногда, работая с кучей значений, вы можете с удивлением заметить, что для некоторых чисел ваши формулы возвращают неверные результаты или даже ошибки. Наиболее очевидная причина заключается в том, что проблемные числа хранятся как текст. Приведенные ниже формулы подскажут вам, какие значения являются текстовыми с точки зрения Excel.

Формула ISTEXT:

Возвращает TRUE для любого значения, которое Excel считает текст .

=ISTEXT(B2)

Формула ISNONTEXT:

Возвращает TRUE для любого значения, которое Excel считает нетекстовый .

=ISNONTEXT(B2)

ISTEXT для проверки данных: разрешить только текст

В некоторых ситуациях вы можете разрешить пользователям вводить в определенные ячейки только текстовые значения. Чтобы добиться этого, создайте правило проверки данных на основе формулы ISTEXT. Вот как это сделать:

1. Выберите одну или несколько ячеек, которые необходимо проверить.
2. На Данные во вкладке Инструменты данных группу, нажмите кнопку Валидация данных кнопка.
3. На Настройки вкладка Валидация данных в диалоговом окне выберите Пользовательский для критериев проверки и введите свою формулу ISTEXT в соответствующее поле.
4. Нажмите OK, чтобы сохранить правило.

В данном примере мы проверяем ответы на вопросы анкеты в ячейках с B2 по B4 с помощью этой формулы:

=ISTEXT(B2:B4)

Кроме того, вы можете настроить свои собственные Предупреждение об ошибке сообщение, чтобы объяснить пользователям, какого рода данные принимаются:

В результате, когда пользователь попытается ввести число или дату в любую из проверенных ячеек, он увидит следующее предупреждение:

Для получения дополнительной информации см. раздел Использование проверки данных в Excel.

Формула Excel ЕСЛИ ИСТЕКСТ

На практике ISTEXT и ISNONTEXT часто используются вместе с функцией IF для вывода более удобного для пользователя результата, чем стандартные TRUE и FALSE.

Формула 1. Если это текст, то

Если взять наш первый пример немного дальше, предположим, что вы хотите возвращать "Да" для текстовых значений и "Нет" для любых других. Чтобы сделать это, просто вложите функцию ISTEXT в логический тест IF, и используйте "Да" и "Нет" для значение_если_истина и значение_если_ложно аргументы, соответственно:

=IF(ISTEXT(A2), "Да", "Нет")

Формула 2. Проверка ввода ячейки

В одном из предыдущих примеров мы обсуждали, как обеспечить достоверный ввод данных пользователем с помощью валидации данных. Это можно сделать и в более "мягкой" форме с помощью формулы Excel IF ISTEXT.

В анкете, предположим, вы хотите определить, какие ответы являются валидными (текстовыми), а какие нет (нетекстовыми). Для этого используйте вложенные операторы IF со следующей логикой:

• Если проверяемая ячейка пуста, возвращает ничего, т.е. пустую строку ("").
• Если ячейка является текстом, возвращается "Действительный ответ".
• Если ни то, ни другое, верните "Неверный ответ - пожалуйста, введите текст".

Сложив все это вместе, мы получим следующую формулу, где B2 - проверяемая ячейка:

=IF(B2="", "", IF(ISTEXT(B2), "Верный ответ", "Неверный ответ - пожалуйста, введите текст."))

Проверьте, содержит ли диапазон какой-либо текст

До сих пор мы проверяли каждую ячейку в отдельности. Но что если вам нужно узнать, содержит ли любая ячейка в диапазоне текст?

Чтобы проверить весь диапазон, объедините функцию ISTEXT с SUMPRODUCT таким образом:

В качестве примера проверим каждую строку в приведенном ниже наборе данных на наличие текстовых значений, что можно сделать с помощью следующих формул:

=SUMPRODUCT(ISTEXT(A2:C2)*1)>0

=SUMPRODUCT(--ISTEXT(A2:C2))>0

Одна из приведенных выше формул попадает в ячейку D2, а затем вы перетаскиваете ее вниз через ячейку D5.

Итак, теперь вы четко понимаете, какие строки содержат одну или несколько текстовых строк (TRUE), а какие - только числа (FALSE).

Если вы хотите вернуть разные результаты, сказать "Да" или "Нет", а не TRUE и FALSE, заключите приведенную выше формулу в оператор IF:

=IF(SUMPRODUCT(--ISTEXT(A2:C2))>0, "Да", "Нет")

Как работает эта формула

Формула основана на способности SUMPRODUCT работать с массивами в естественном режиме. Работая изнутри наружу, вот что она делает:

• Функция ISTEXT возвращает массив значений TRUE и FALSE. Для A2:C2 мы получаем этот массив:

  {TRUE, TRUE, FALSE}

• Далее мы умножим каждый элемент вышеуказанного массива на 1, чтобы преобразовать логические значения TRUE и FALSE в 1 и 0 соответственно. Для этой же цели можно использовать двойной унарный оператор (--). После преобразования формула принимает следующий вид:

  SUMPRODUCT({1,1,0})>0

• Функция SUMPRODUCT складывает 1 и 0, и вы проверяете, больше ли результат нуля. Если да, то диапазон содержит хотя бы одно текстовое значение, и формула возвращает TRUE, если нет - FALSE.

Проверьте, содержит ли ячейка определенный текст

Функция Excel ISTEXT может только определить, содержит ли ячейка текст, то есть абсолютно любой текст. Чтобы узнать, содержит ли ячейка определенную текстовую строку, используйте либо формулу ПОИСК ПО ИМЯ, либо COUNTIF с подстановочными знаками.

Например, чтобы проверить, содержит ли Item Id в A2 текстовую строку, введенную в ячейку D2, используйте следующую формулу (пожалуйста, обратите внимание на абсолютную ссылку $D$2, которая предотвращает изменение адреса ячейки при копировании формулы в другие ячейки):

=ISNUMBER(SEARCH($D$2, A2))

Для удобства мы обернем его в функцию IF:

=IF(ISNUMBER(SEARCH($D$2, A2)), "Да", "Нет")

И получите следующие результаты:

Такого же результата можно достичь с помощью COUNTIF:

=IF(COUNTIF(A2, "*"&$D$2& "*")>0, "Да", "Нет")

Дополнительные примеры см. в разделе Excel Если ячейка содержит формулы.

Выделите ячейки, содержащие текст

Функцию ISTEXT можно также использовать с условным форматированием Excel для выделения ячеек, содержащих текстовые значения. Вот как это делается:

1. Выберите все ячейки, которые вы хотите проверить и выделить (A2:C5 в данном примере).
2. На Главная во вкладке Стили группу, нажмите Новое правило > Используйте формулу, чтобы определить, какие ячейки форматировать .
3. В Форматируйте значения, для которых эта формула истинна введите приведенную ниже формулу:

   =ISTEXT(A2)

   Где A2 - крайняя левая ячейка выбранного диапазона.

4. Нажмите кнопку Формат и выберите нужное форматирование.
5. Нажмите OK дважды, чтобы закрыть оба диалоговых окна и сохранить правило.

Более подробное объяснение каждого шага см. в разделе: Использование формул для условного форматирования Excel.

В результате Excel выделяет все ячейки с любыми текстовыми строками:

Вот как использовать функции ISTEXT и ISNONTEXT в Excel. Я благодарю вас за чтение и надеюсь увидеть вас в нашем блоге на следующей неделе!

Доступные загрузки

Примеры формул Excel ISTEXT и ISNONTEXT