Bu eğitimde, bir hücrenin metinsel bir değer içerip içermediğini kontrol etmek için Excel'de ISTEXT ve ISNONTEXT fonksiyonlarının nasıl kullanılacağı ele alınmaktadır.

Excel'de bir hücrenin içeriği hakkında bilgi almanız gerektiğinde, genellikle Bilgi işlevleri olarak adlandırılan işlevleri kullanırsınız. Hem ISTEXT hem de ISNONTEXT bu kategoriye aittir. ISTEXT işlevi bir değerin metin olup olmadığını kontrol eder ve ISNONTEXT bir değerin metin olup olmadığını test eder. Kavram ne kadar basit olursa olsun, işlevler Excel'de çeşitli farklı görevleri çözmek için inanılmaz derecede kullanışlıdır.

Excel ISTEXT işlevi

Excel'deki ISTEXT işlevi, belirtilen bir değerin metin olup olmadığını kontrol eder. Değer metinsel ise, işlev DOĞRU döndürür. Diğer tüm veri türleri için (sayılar, tarihler, boş hücreler, hatalar vb.) YANLIŞ döndürür.

Sözdizimi aşağıdaki gibidir:

ISTEXT(değer)

Nerede değer sonucunu test etmek istediğiniz bir değer, hücre başvurusu, ifade veya başka bir işlevdir.

Örneğin, A2'deki bir değerin metin olup olmadığını bulmak için şu basit formülü kullanın:

=ISTEXT(A2)

Excel ISNONTEXT işlevi

ISNONTEXT işlevi, sayılar, tarihler ve saatler, boşluklar ve metin dışı sonuçlar veya hatalar döndüren diğer formüller dahil olmak üzere metin olmayan tüm değerler için TRUE değerini döndürür. Metin değerleri için FALSE değerini döndürür.

Sözdizimi ISTEXT işlevinin sözdizimiyle aynıdır:

ISTEXT(değer)

Örneğin, A2'deki bir değerin metin olup olmadığını denetlemek için şu formülü kullanın:

=ISNONTEXT(A2)

Aşağıdaki ekran görüntüsünde gösterildiği gibi, ISTEXT ve ISNONTEXT formülleri zıt sonuçlar döndürür:

Excel'de ISTEXT ve ISNONTEXT işlevleri - kullanım notları

ISTEXT ve ISNONTEXT çok basit ve kullanımı kolay işlevlerdir ve bunlarla herhangi bir zorlukla karşılaşmanız pek olası değildir. Bununla birlikte, dikkat edilmesi gereken birkaç önemli nokta vardır:

• Her iki fonksiyon da TRUE veya FALSE mantıksal (Boolean) değerlerini döndüren IS fonksiyonları grubunun bir parçasıdır.
• Belirli bir durumda sayılar metin olarak saklanır , ISTEXT TRUE ve ISNONTEXT FALSE değerlerini döndürür.
• Her iki işlev de Office 365, Excel 2019, Excel 2016, Excel 2013, Excel 2010, Excel 2007, Excel 2003, Excel XP ve Excel 2000 için Excel'in tüm sürümlerinde mevcuttur.

Excel'de ISTEXT ve ISNONTEXT kullanma - formül örnekleri

Aşağıda, Excel'de ISTEXT ve ISNONTEXT işlevlerinin pratik kullanımlarına ilişkin örnekler bulacaksınız; bu işlevlerin çalışma sayfalarınızı daha verimli hale getirmenize yardımcı olacağını umuyoruz.

Bir değerin metin olup olmadığını kontrol edin

Bazen bir grup değerle çalışırken, bazı sayılar için formüllerinizin yanlış sonuçlar ve hatta hatalar döndürdüğünü fark ettiğinizde şaşırabilirsiniz. Bunun en belirgin nedeni, sorunlu sayıların metin olarak depolanmasıdır. Aşağıdaki formüller, Excel'in bakış açısından hangi değerlerin metin olduğunu size kesin olarak söyleyecektir.

ISTEXT formülü:

Excel'in dikkate aldığı herhangi bir değer için DOĞRU döndürür Metin .

=ISTEXT(B2)

ISNONTEXT formülü:

Excel'in dikkate aldığı herhangi bir değer için DOĞRU döndürür metin dışı .

=ISNONTEXT(B2)

Veri Doğrulama için ISTEXT: yalnızca metne izin ver

Bazı durumlarda, kullanıcıların belirli hücrelere yalnızca metin değerleri girmesine izin vermek isteyebilirsiniz. Bunu başarmak için, bir ISTEXT formülüne dayalı bir veri doğrulama kuralı oluşturun:

1. Doğrulamak istediğiniz bir veya daha fazla hücre seçin.
2. Üzerinde Veri sekmesinde Veri Araçları grubuna girmek için Veri Doğrulama Düğme.
3. Üzerinde Ayarlar sekmesinin Veri Doğrulama iletişim kutusunu seçin, ardından Özel doğrulama kriteri için ve ilgili kutuya ISTEXT formülünüzü girin.
4. Kuralı kaydetmek için Tamam'a tıklayın.

Bu örnekte, B2 ila B4 hücrelerindeki anket yanıtlarını bu formül yardımıyla doğruluyoruz:

=ISTEXT(B2:B4)

Ayrıca, kendi yapılandırmanızı da yapabilirsiniz Hata Uyarısı Kullanıcılarınıza ne tür verilerin kabul edildiğini açıklamak için mesaj:

Sonuç olarak, kullanıcı doğrulanan hücrelerden herhangi birine bir sayı veya tarih girmeye çalıştığında aşağıdaki uyarıyı görecektir:

Daha fazla bilgi için lütfen Excel'de Veri doğrulamayı kullanma bölümüne bakın.

Excel EĞER ISTEXT formülü

Uygulamada, ISTEXT ve ISNONTEXT genellikle standart TRUE ve FALSE'den daha kullanıcı dostu bir sonuç elde etmek için IF fonksiyonu ile birlikte kullanılır.

Formül 1. Eğer metin ise, o zaman

İlk örneğimizi biraz daha ileri götürerek, metin değerleri için "Evet" ve başka herhangi bir şey için "Hayır" döndürmek istediğinizi varsayalım. Bunu yapmak için, ISTEXT işlevini IF mantıksal testine yerleştirin ve "Evet" ve "Hayır" için value_if_true ve value_if_false sırasıyla argümanlar:

=IF(ISTEXT(A2), "Evet", "Hayır")

Formül 2. Hücrenin girişini kontrol edin

Önceki örneklerden birinde, Veri Doğrulama kullanarak geçerli kullanıcı girdisinin nasıl sağlanacağını tartışmıştık. Bu, bir Excel EĞER ISTEXT formülü yardımıyla "daha hafif" bir biçimde de yapılabilir.

Ankette, hangi cevapların geçerli (metin) hangilerinin geçerli olmadığını (metin olmayan) belirlemek istediğinizi varsayalım. Bunun için aşağıdaki mantıkla iç içe IF ifadelerini kullanın:

• Test edilen hücre boşsa, hiçbir şey döndürmez, yani boş bir dize ("") döndürür.
• Hücre metin ise, "Geçerli yanıt" döndürülür.
• Yukarıdakilerden hiçbiri değilse, "Geçersiz yanıt - lütfen metin girin" yanıtını döndürün.

Tüm bunları bir araya getirdiğimizde, B2'nin kontrol edilecek hücre olduğu aşağıdaki formülü elde ederiz:

=IF(B2="", "", IF(ISTEXT(B2), "Valid answer", "Invalid answer - please enter text."))

Bir aralığın herhangi bir metin içerip içermediğini kontrol edin

Şimdiye kadar her hücreyi tek tek test ettik. Peki ya bir aralıktaki herhangi bir hücrenin metin içerip içermediğini bilmeniz gerekiyorsa?

Tüm aralığı test etmek için, ISTEXT işlevini SUMPRODUCT ile bu şekilde birleştirin:

Örnek olarak, aşağıdaki veri kümesindeki her satırda metin değerleri olup olmadığını kontrol edelim; bunu aşağıdaki formüllerle yapabiliriz:

=SUMPRODUCT(ISTEXT(A2:C2)*1)>0

=SUMPRODUCT(--ISTEXT(A2:C2))>0

Yukarıdaki formüllerden biri D2 hücresine gider ve sonra onu D5 hücresine sürüklersiniz.

Artık hangi satırların bir veya daha fazla metin dizesi içerdiğini (DOĞRU) ve hangilerinin yalnızca sayı içerdiğini (YANLIŞ) net bir şekilde anlayabilirsiniz.

TRUE ve FALSE yerine "Yes" veya "No" gibi farklı sonuçlar döndürmek istiyorsanız, yukarıdaki formülü IF deyimine ekleyin:

=IF(SUMPRODUCT(--ISTEXT(A2:C2))>0, "Evet", "Hayır")

Bu formül nasıl çalışır?

Formül, SUMPRODUCT'un dizileri yerel olarak işleme yeteneğine dayanmaktadır. İçten dışa doğru çalışarak, işte ne yaptığı:

• ISTEXT fonksiyonu TRUE ve FALSE değerlerinden oluşan bir dizi döndürür. A2:C2 için bu diziyi elde ederiz:

  {TRUE,TRUE,FALSE}

• Daha sonra, TRUE ve FALSE mantıksal değerlerini sırasıyla 1'lere ve 0'lara dönüştürmek için yukarıdaki dizinin her bir öğesini 1 ile çarparız. Aynı amaç için çift tekli işleç (--) kullanılabilir. Dönüşümden sonra formül şu şekli alır:

  SUMPRODUCT({1,1,0})>0

• SUMPRODUCT işlevi 1'leri ve 0'ları toplar ve sonucun sıfırdan büyük olup olmadığını kontrol edersiniz. Eğer büyükse, aralık en az bir metin değeri içerir ve formül DOĞRU, değilse YANLIŞ döndürür.

Bir hücrenin belirli bir metin içerip içermediğini kontrol edin

Excel ISTEXT işlevi yalnızca bir hücrenin metin içerip içermediğini, yani kesinlikle herhangi bir metin içerip içermediğini belirleyebilir. Bir hücrenin belirli bir metin dizesi içerip içermediğini bulmak için, ISNUMBER SEARCH formülünü veya joker karakterlerle COUNTIF'i kullanın.

Örneğin, A2'deki Öğe Kimliğinin D2 hücresindeki metin dizesi girişini içerip içermediğini görmek için aşağıdaki formülü kullanın (formül diğer hücrelere kopyalandığında hücre adresinin değişmesini önleyen $D$2 mutlak başvurusuna lütfen dikkat edin):

=ISNUMBER(SEARCH($D$2, A2))

Kolaylık olması açısından, bunu IF fonksiyonunun içine saracağız:

=IF(ISNUMBER(SEARCH($D$2, A2)), "Evet", "Hayır")

Ve aşağıdaki sonuçları alın:

Aynı sonuç COUNTIF ile de elde edilebilir:

=IF(COUNTIF(A2, "*"&$D$2& "*")>0, "Evet", "Hayır")

Daha fazla örnek için lütfen Excel Hücre formül içeriyorsa bölümüne bakın.

Metin içeren hücreleri vurgulama

ISTEXT işlevi, metin değerleri içeren hücreleri vurgulamak için Excel koşullu biçimlendirmesiyle birlikte de kullanılabilir:

1. Kontrol etmek istediğiniz tüm hücreleri seçin ve vurgulayın (bu örnekte A2:C5).
2. Üzerinde Ev sekmesinde Stiller grubunu seçin, tıklayın Yeni Kural > Hangi hücrelerin biçimlendirileceğini belirlemek için bir formül kullanma .
3. İçinde Bu formülün doğru olduğu değerleri biçimlendirin kutusuna aşağıdaki formülü girin:

   =ISTEXT(A2)

   Burada A2, seçilen aralığın en soldaki hücresidir.

4. Tıklayınız Biçim düğmesine basın ve istediğiniz biçimlendirmeyi seçin.
5. Her iki iletişim kutusunu kapatmak ve kuralı kaydetmek için iki kez Tamam'a tıklayın.

Her adımın daha ayrıntılı açıklaması için lütfen bkz: Excel koşullu biçimlendirme için formülleri kullanma.

Sonuç olarak, Excel herhangi bir metin dizesi içeren tüm hücreleri vurgular:

Excel'de ISTEXT ve ISNONTEXT fonksiyonları bu şekilde kullanılır. Okuduğunuz için teşekkür ediyor ve gelecek hafta blogumuzda görüşmeyi umuyorum!

Mevcut indirmeler

Excel ISTEXT ve ISNONTEXT formül örnekleri