Водич говори о томе како да користите функције ИСТЕКСТ и ИСНОНТЕКСТ у Екцел-у да бисте проверили да ли ћелија садржи текстуалну вредност или не.

Увек када треба да добијете информације о садржају неке ћелије у Екцел-у, обично бисте користили такозване Информационе функције. И ИСТЕКСТ и ИСНОНТЕКСТ припадају овој категорији. Функција ИСТЕКСТ проверава да ли је вредност текст, а ИСНОНТЕКСТ тестира да ли вредност није текст. Колико год да је концепт једноставан, функције су невероватно корисне за решавање различитих задатака у Екцел-у.

Екцел функција ИСТЕКСТ

Функција ИСТЕКСТ у Екцел проверама је наведена вредност је текст или не. Ако је вредност текстуална, функција враћа ТРУЕ. За све друге типове података (као што су бројеви, датуми, празне ћелије, грешке итд.) враћа ФАЛСЕ.

Синтакса је следећа:

ISTEXT(value)

Где валуе је вредност, референца на ћелију, израз или друга функција чији резултат желите да тестирате.

На пример, да бисте сазнали да ли је вредност у А2 текст или не, користите ово једноставно формула:

=ISTEXT(A2)

Екцел функција ИСНОНТЕКСТ

Функција ИСНОНТЕКСТ враћа ТРУЕ за било коју вредност која није текстуална укључујући бројеве, датуме и времена , празнине и друге формуле које враћају нетекстуалне резултате или грешке. За текстуалне вредности, враћа ФАЛСЕ.

Синтакса је иста као код функције ИСТЕКСТ:

ISTEXT(value)

На пример, да проверите да ли јевредност у А2 није текст, користите ову формулу:

=ISNONTEXT(A2)

Као што је приказано на слици испод, формуле ИСТЕКСТ и ИСНОНТЕКСТ враћају супротне резултате:

ИСТЕКСТ и ИСНОНТЕКСТ функције у Екцел-у - напомене о употреби

ИСТЕКСТ и ИСНОНТЕКСТ су функције веома једноставне и једноставне за коришћење и мало је вероватно да ћете наићи на било какве потешкоће са њима. Уз то, постоји неколико кључних тачака на које треба обратити пажњу:

• Обе функције су део групе ИС функција које враћају логичке (Боолеан) вредности ТРУЕ или ФАЛСЕ.
• У одређеном случају када се бројеви чувају као текст , ИСТЕКСТ враћа ТРУЕ, а ИСНОНТЕКСТ враћа ФАЛСЕ.
• Обе функције су доступне у свим верзијама Екцел-а за Оффице 365, Екцел 2019, Екцел 2016 , Екцел 2013, Екцел 2010, Екцел 2007, Екцел 2003, Екцел КСП и Екцел 2000.

Коришћење ИСТЕКСТ и ИСНОНТЕКСТ у Екцелу – примери формула

У наставку ћете пронаћи примере практичне употребе функција ИСТЕКСТ и ИСНОНТЕКСТ у Екцел-у које ће вам, надамо се, помоћи да учините своје радне листове ефикаснијим.

Проверите да ли је вредност текст

Понекад када радите са гомилом вредности, можда ћете бити изненађени када приметите да за неке бројеве ваше формуле враћају погрешне резултате или чак грешке. Најочигледнији разлог је тај што се проблематични бројеви чувају као текст. Формуле у наставку ће вам са сигурношћу рећи које вредности потичу из текстаЕкцел-ова тачка гледишта.

ИСТЕКСТ формула:

Враћа ТРУЕ за било коју вредност коју Екцел сматра тект .

=ISTEXT(B2)

ИСНОНТЕКСТ формула:

Враћа ТРУЕ за било коју вредност коју Екцел сматра не-текстуалном .

=ISNONTEXT(B2)

ИСТЕКСТ за валидацију података : дозволи само текст

У неким ситуацијама, можда ћете желети да дозволите корисницима да уносе само текстуалне вредности у одређене ћелије. Да бисте то постигли, креирајте правило за валидацију података на основу формуле ИСТЕКСТ. Ево како:

1. Изаберите једну или више ћелија које желите да потврдите.
2. На картици Подаци , у Алатке за податке групи, кликните на дугме Провера ваљаности података .
3. На картици Подешавања дијалога Провера ваљаности података изаберите Прилагођено за критеријуме валидације и унесите своју ИСТЕКСТ формулу у одговарајуће поље.
4. Кликните на ОК да бисте сачували правило.

За овај пример, проверавамо одговоре на упитник у ћелијама Б2 кроз Б4 уз помоћ ове формуле:

=ISTEXT(B2:B4)

Поред тога, можете конфигурисати сопствену поруку Упозорење о грешци да бисте објаснили Ваши корисници која врста података је прихваћена:

Као резултат, када корисник покуша да унесе број или датум у било коју од потврђених ћелија, видеће следеће упозорење:

За више информација погледајте Коришћење валидације података у Екцел-у.

Екцел ИФ ИСТЕКСТ формула

У пракси, ИСТЕКСТи ИСНОНТЕКСТ се често користе заједно са функцијом ИФ за добијање кориснијег резултата од стандардних ТРУЕ и ФАЛСЕ.

Формула 1. Ако је текст, онда

Узећемо наш први пример а мало даље, под претпоставком да желите да вратите "Да" за текстуалне вредности и "Не" за било шта друго. Да бисте то урадили, једноставно угнездите функцију ИСТЕКСТ у логички тест ИФ и користите „Да“ и „Не“ за аргументе валуе_иф_труе и валуе_иф_фалсе , респективно:

=IF(ISTEXT(A2), "Yes", "No")

Формула 2. Проверите унос ћелије

У једном од претходних примера, разговарали смо о томе како да обезбедимо валидан кориснички унос коришћењем провере ваљаности података . Ово се такође може урадити у „блажем“ облику уз помоћ Екцел формуле ИФ ИСТЕКСТ.

У упитнику, претпоставимо да желите да утврдите који су одговори валидни (текст), а који нису (не- текст). За ово користите угнежђене ИФ изјаве са следећом логиком:

• Ако је тестирана ћелија празна, не враћа ништа, тј. празан стринг ("").
• Ако је ћелија је текст, вратите "Ваљани одговор".
• Ако ништа од горе наведеног, вратите "Неважећи одговор - унесите текст."

Стављајући све ово заједно, добијамо следећу формулу , где је Б2 ћелија коју треба проверити:

=IF(B2="", "", IF(ISTEXT(B2), "Valid answer", "Invalid answer - please enter text."))

Провери да ли опсег садржи текст

До сада смо тестирали сваку ћелију појединачно. Али шта ако треба да знате да ли постоји нека ћелија у опсегусадржи текст?

Да бисте тестирали цео опсег, комбинујте функцију ИСТЕКСТ са СУМПРОДУЦТ на овај начин:

Као пример, хајде да проверимо сваки ред у доњем скупу података за текстуалне вредности, што се може урадити помоћу следећих формула:

=SUMPRODUCT(ISTEXT(A2:C2)*1)>0

=SUMPRODUCT(--ISTEXT(A2:C2))>0

Једна од горњих формула иде у ћелију Д2, а затим је превлачите надоле кроз ћелију Д5.

Дакле, сада имате јасно разумевање који редови садрже један или више текстуалних низова (ТРУЕ) и који садрже само бројеве (ФАЛСЕ).

Ако желите да вратите различите резултате, реците „Да“ или „Не“ за разлику од ТРУЕ и ФАЛСЕ, приложите горњу формулу у ИФ наредбу:

=IF(SUMPRODUCT(--ISTEXT(A2:C2))>0, "Yes", "No")

Како ова формула функционише

Формула заснива се на способности СУМПРОДУЦТ-а да нативно рукује низовима. Радећи изнутра ка споља, ево шта ради:

• Функција ИСТЕКСТ враћа низ вредности ТРУЕ и ФАЛСЕ. За А2:Ц2, добијамо овај низ:

  {TRUE,TRUE,FALSE}

• Даље, сваки елемент горњег низа множимо са 1 да бисмо логичке вредности ТРУЕ и ФАЛСЕ претворили у 1 и 0, респективно . За исту сврху може се користити двоструки унарни оператор (--). Након трансформације, формула поприма овај облик:

  SUMPRODUCT({1,1,0})>0

• Функција СУМПРОДУЦТ сабира 1 и 0, а ви проверавате да ли је резултат већи од нуле. Ако јесте, опсегсадржи најмање једну текстуалну вредност и формула враћа ТРУЕ, ако не и ФАЛСЕ.

Проверите да ли ћелија садржи одређени текст

Екцел функција ИСТЕКСТ може само да утврди да ли ћелија садржи текст , што значи апсолутно сваки текст. Да бисте сазнали да ли ћелија садржи одређени текстуални низ, користите формулу ИСНУМБЕР СЕАРЦХ или ЦОУНТИФ са џокер знаковима.

На пример, да бисте видели да ли ИД ставке у А2 садржи текстуални низ који је унет у ћелију Д2, користите следећу формулу (имајте на уму апсолутну референцу $Д$2 која спречава да се адреса ћелије промени када се формула копира у друге ћелије):

=ISNUMBER(SEARCH($D$2, A2))

Ради погодности, ми смо Умотаћу га у функцију ИФ:

=IF(ISNUMBER(SEARCH($D$2, A2)), "Yes", "No")

И добити следеће резултате:

Исти резултат се може постићи са ЦОУНТИФ :

=IF(COUNTIF(A2, "*"&$D$2&"*")>0, "Yes", "No")

За више примера погледајте Екцел Ако ћелија садржи формуле.

Означите ћелије које садрже текст

Функција ИСТЕКСТ се такође може користити са Екцел условним форматирањем за истицање ћелија које садрже текстуалне вредности. Ево како:

1. Изаберите све ћелије које желите да проверите и означите (А2:Ц5 у овом примеру).
2. На картици Почетна , у у групи Стилови , кликните на Ново правило &гт; Користите формулу да одредите које ћелије да форматирате .
3. У Формат вредности где је ова формула тачна поље, унесите следећу формулу:

   =ISTEXT(A2)

   где је А2крајња лева ћелија изабраног опсега.

4. Кликните на дугме Формат и изаберите жељено форматирање.
5. Кликните двапут на ОК да бисте затворили оба дијалога и сачували правило.

За детаљније објашњење сваког корака погледајте: Коришћење формула за Екцел условно форматирање.

Као резултат, Екцел истиче све ћелије са било којим текстуалним низовима:

Тако се користе функције ИСТЕКСТ и ИСНОНТЕКСТ у Екцел-у. Захваљујем вам што сте читали и надам се да се видимо на нашем блогу следеће недеље!

Доступна преузимања

Екцел ИСТЕКСТ и ИСНОНТЕКСТ примери формуле