Sa huling ilang artikulo, tinalakay namin ang iba't ibang function ng Text - ang mga ginagamit upang manipulahin ang mga string ng text. Ngayon ang aming focus ay sa RIGHT function, na idinisenyo upang ibalik ang isang tinukoy na bilang ng mga character mula sa pinakakanang bahagi ng isang string. Tulad ng iba pang mga function ng Excel Text, ang RIGHT ay napaka-simple at prangka, gayunpaman, mayroon itong ilang hindi halatang paggamit na maaaring patunayang kapaki-pakinabang sa iyong trabaho.

Excel RIGHT function syntax

Ibinabalik ng RIGHT function sa Excel ang tinukoy na bilang ng mga character mula sa dulo ng isang text string.

Ang syntax ng RIGHT function ay ang sumusunod:

Kung saan :

• Text (kinakailangan) - ang text string kung saan mo gustong kunin ang mga character.
• Num_chars (opsyonal) - ang bilang ng mga character na i-extract, simula sa pinakakanang character.
  • Kung ang num_chars ay tinanggal, 1 huling character ng string ang ibabalik (default).
  • Kung ang num_chars ay mas malaki kaysa sa kabuuang bilang ng character sa string, ibinabalik ang lahat ng character.
  • Kung ang num_chars ay negatibong numero, ibabalik ng Tamang formula ang #VALUE! error.

Halimbawa, para i-extract ang huling 3 character mula sa string sa cell A2, gamitin ang formula na ito:

=RIGHT(A2, 3)

Ang resulta ay maaaring magmukhang katulad nito:

Mahalagang tala! Ang Excel RIGHT function ay palaging nagbabalik ng textstring , kahit na ang orihinal na halaga ay isang numero. Upang pilitin ang isang Tamang formula na mag-output ng isang numero, gamitin ito kasama ng VALUE function tulad ng ipinakita sa halimbawang ito.

Paano gamitin ang RIGHT function sa Excel - mga halimbawa ng formula

Sa totoong buhay worksheet, ang Excel RIGHT function ay bihirang gamitin sa sarili nitong. Sa karamihan ng mga kaso, gagamitin mo ito kasama ng iba pang mga function ng Excel bilang bahagi ng mas kumplikadong mga formula.

Paano makakuha ng substring na kasunod ng isang partikular na character

Kung sakaling gusto mong i-extract isang substring na sumusunod sa isang partikular na character, gamitin ang alinman sa SEARCH o FIND function upang matukoy ang posisyon ng character na iyon, ibawas ang posisyon mula sa kabuuang haba ng string na ibinalik ng LEN function, at hilahin ang maraming character mula sa pinakakanang bahagi ng orihinal na string.

Sabihin natin, cell Ang A2 ay naglalaman ng una at apelyido na pinaghihiwalay ng isang puwang, at nilalayon mong hilahin ang apelyido sa isa pang cell. Kunin lang ang generic na formula sa itaas at ilagay mo ang A2 sa halip na string , at " " (space) sa bilis ng character:

=RIGHT(A2,LEN(A2)-SEARCH(" ",A2))

Ang formula ay magbubunga ng sumusunod na resulta:

Sa katulad na paraan, maaari kang makakuha ng substring na sumusunod sa anumang iba pang character, hal. isang kuwit, tuldok-kuwit, gitling, atbp. Halimbawa, upang kunin ang isang substring na kasunod ng isang gitling,gamitin ang formula na ito:

=RIGHT(A2,LEN(A2)-SEARCH("-",A2))

Magiging katulad nito ang resulta:

Paano mag-extract ng substring pagkatapos ng huling paglitaw ng delimiter

Kailan pagharap sa mga kumplikadong string na naglalaman ng ilang mga paglitaw ng parehong delimiter, maaaring kailanganin mong kunin ang teksto sa kanan ng huling paglitaw ng delimiter. Upang gawing mas madaling maunawaan ang mga bagay, tingnan ang sumusunod na pinagmumulan ng data at ninanais na resulta:

Tulad ng makikita mo sa screenshot sa itaas, ang Column A ay naglalaman ng isang listahan ng mga error. Ang iyong layunin ay hilahin ang paglalarawan ng error na darating pagkatapos ng huling colon sa bawat string. Ang isang karagdagang komplikasyon ay ang orihinal na mga string ay maaaring maglaman ng iba't ibang bilang ng mga instance ng delimiter, hal. Ang A3 ay naglalaman ng 3 colon habang ang A5 ay isa lang.

Ang susi sa paghahanap ng solusyon ay ang pagtukoy sa posisyon ng huling delimiter sa source string (ang huling paglitaw ng colon sa halimbawang ito). Upang gawin ito, kakailanganin mong gumamit ng ilang iba't ibang function:

1. Kunin ang bilang ng mga delimiter sa orihinal na string. Ito ay isang madaling bahagi:
   • Una, kinakalkula mo ang kabuuang haba ng string gamit ang function na LEN: LEN(A2)
   • Pangalawa, kino-compute mo ang haba ng string nang walang mga delimiter sa pamamagitan ng paggamit ng SUBSTITUTE function na pumapalit sa lahat ng paglitaw ng isang colon ng wala: LEN(SUBSTITUTE(A2,":",""))
   • Sa wakas, ibawas mo ang haba ng orihinal na stringwalang mga delimiter mula sa kabuuang haba ng string: LEN(A2)-LEN(SUBSTITUTE(A2,":",""))

   Para matiyak na gumagana nang tama ang formula, maaari mo itong ilagay sa isang hiwalay na cell, at ang magiging resulta ay 2, na ang bilang ng mga colon sa cell A2.

2. Palitan ang huling delimiter ng ilang natatanging karakter. Upang ma-extract ang text na kasunod ng huling delimiter sa string, kailangan nating "markahan" ang huling paglitaw ng delimiter sa ilang paraan. Para dito, palitan natin ang huling paglitaw ng isang colon ng isang character na hindi lumilitaw saanman sa orihinal na mga string, halimbawa ng isang pound sign (#).

   Kung pamilyar ka sa syntax ng Excel SUBSTITUTE function, maaari mong tandaan na mayroon itong ika-4 na opsyonal na argumento (instance_num) na nagpapahintulot na palitan lamang ang isang partikular na pangyayari ng tinukoy na character. At dahil nakalkula na namin ang bilang ng mga delimiter sa string, ibigay lang ang function sa itaas sa ikaapat na argumento ng isa pang SUBSTITUTE function:

   =SUBSTITUTE(A2,":","#",LEN(A2)-LEN(SUBSTITUTE(A2,":","")))

   Kung ilalagay mo ang formula na ito sa isang hiwalay na cell , ibabalik nito ang string na ito: ERROR:432#Connection timed out

3. Kunin ang posisyon ng huling delimiter sa string. Depende sa kung anong character ang pinalitan mo sa huling delimiter, gamitin ang alinman sa case-insensitive na SEARCH o case-sensitive FIND upang matukoy ang posisyon ng character na iyon sa string. Pinalitan namin ang huling colonna may # sign, kaya ginagamit namin ang sumusunod na formula upang malaman ang posisyon nito:

   =SEARCH("#", SUBSTITUTE(A2,":","#",LEN(A2)-LEN(SUBSTITUTE(A2,":",""))))

   Sa halimbawang ito, ang formula ay nagbabalik ng 10, na siyang posisyon ng # sa pinalitan na string.

4. Magbalik ng substring sa kanan ng huling delimiter. Ngayong alam mo na ang posisyon ng huling delimiter sa isang string, ang kailangan mo lang gawin ay ibawas ang numerong iyon mula sa kabuuang haba ng string, at kunin ang RIGHT function upang ibalik ang maraming character mula sa dulo ng orihinal na string:

   =RIGHT(A2,LEN(A2)-SEARCH("$",SUBSTITUTE(A2,":","$",LEN(A2)-LEN(SUBSTITUTE(A2,":","")))))

Tulad ng ipinapakita sa screenshot sa ibaba, gumagana nang perpekto ang formula:

Kung nagtatrabaho ka sa isang malaking dataset kung saan maaaring maglaman ng iba't ibang mga delimiter ang iba't ibang mga cell, maaaring gusto mo upang ilakip ang formula sa itaas sa function na IFERROR upang maiwasan ang mga posibleng error:

=IFERROR(RIGHT(A2,LEN(A2)-SEARCH("$",SUBSTITUTE(A2,":","$",LEN(A2)-LEN(SUBSTITUTE(A2,":",""))))), A2)

Kung sakaling ang isang partikular na string ay hindi naglalaman ng isang paglitaw ng tinukoy na delimiter, ibabalik ang orihinal na string, tulad ng sa row 6 sa screenshot sa ibaba:

Paano alisin ang unang N character mula sa isang string

Bukod sa pag-extract ng substring mula sa dulo ng isang string, madaling gamitin ang Excel RIGHT function. sa mga sitwasyon kung kailan mo gustong mag-alis ng ilang partikular na bilang ng mga character mula sa simula ng string.

Sa dataset na ginamit sa nakaraan Halimbawa, maaaring gusto mong alisin ang salitang "ERROR" na lumalabas sa simula ng bawat string at iwanan lamang ang numero ng error at paglalarawan. Upang magkaroon nitotapos na, ibawas ang bilang ng mga character na aalisin sa kabuuang haba ng string, at ibigay ang numerong iyon sa num_chars argument ng Excel RIGHT function:

Sa halimbawang ito, inaalis namin ang unang 6 na character (5 letra at tutuldok) mula sa text string sa A2, kaya ang aming formula ay napupunta bilang sumusunod:

=RIGHT(A2, LEN(A2)-6)

Maaari bang magbalik ng numero ang Excel RIGHT function?

Tulad ng nabanggit sa simula ng tutorial na ito, palaging nagbabalik ng text string ang RIGHT function sa Excel kahit kung ang orihinal na halaga ay isang numero. Ngunit paano kung nagtatrabaho ka sa isang numeric na dataset at nais na ang output ay numeric din? Ang isang madaling solusyon ay ang paglalagay ng Tamang formula sa VALUE function, na espesyal na idinisenyo upang i-convert ang isang string na kumakatawan sa isang numero sa isang numero.

Halimbawa, upang hilahin ang huling 5 character (zip code) mula sa string sa A2 at i-convert ang mga na-extract na character sa isang numero, gamitin ang formula na ito:

=VALUE(RIGHT(A2, 5))

Ipinapakita ng screenshot sa ibaba ang resulta - pakipansin ang mga numerong naka-align sa kanan sa column B, kumpara sa kaliwa -aligned text strings sa column A:

Bakit hindi gumagana ang RIGHT function sa mga petsa?

Dahil ang Excel RIGHT function ay idinisenyo upang gumana sa mga text string samantalang ang mga petsa ay kinakatawan ng mga numero sa ang panloob na sistema ng Excel, ang isang Tamang formula ay hindi mabawi ang isang indibidwalbahagi ng isang petsa tulad ng araw, buwan o taon. Kung susubukan mong gawin ito, ang makukuha mo lang ay ilang huling digit ng numerong kumakatawan sa isang petsa.

Kumbaga, mayroon kang petsang 18-Ene-2017 sa cell A1. Kung susubukan mong kunin ang taon gamit ang formula na RIGHT(A1,4), ang magiging resulta ay 2753, na siyang huling 4 na digit ng numero 42753 na kumakatawan sa Enero 18, 2017 sa Excel system.

"Kung gayon, paano ko kukunin ang isang partikular na bahagi ng isang petsa?", maaari mong itanong sa akin. Sa pamamagitan ng paggamit ng isa sa mga sumusunod na function:

• DAY function para kunin ang isang araw: =DAY(A1)
• MONTH function para makakuha ng buwan: =MONTH(A1)
• YEAR function to pull a year: =YEAR(A1)

Ipinapakita ng sumusunod na screenshot ang mga resulta:

Kung ang iyong mga petsa ay kinakatawan ng mga string ng text , na kadalasang nangyayari kapag nag-export ka ng data mula sa isang panlabas na pinagmulan, walang pumipigil sa iyong gamitin ang RIGHT function upang hilahin ang huling ilang character sa string na kumakatawan sa isang partikular na bahagi ng petsa:

Excel RIGHT hindi gumagana ang function - mga dahilan at solusyon

Kung ang isang Tamang formula ay hindi gumagana nang tama sa iyong worksheet, malamang na ito ay dahil sa isa sa mga sumusunod na dahilan:

1. May isa o higit pa mga trailing space sa orihinal na data. Upang mabilis na mag-alis ng mga dagdag na espasyo sa mga cell, gamitin ang Excel TRIM function o ang add-in ng Cell Cleaner.
2. Ang argument na num_chars ay mas mababa sa zero . NgSiyempre, hindi mo gustong maglagay ng negatibong numero sa iyong formula nang kusa, ngunit kung ang num_chars na argumento ay kinakalkula ng isa pang Excel function o kumbinasyon ng iba't ibang function at ang iyong Right formula ay nagbabalik ng #VALUE! error, tiyaking suriin ang (mga) nested function para sa mga error.
3. Ang orihinal na value ay isang petsa . Kung sinunod mo nang mabuti ang tutorial na ito, alam mo na kung bakit hindi gumagana ang RIGHT function sa mga petsa. Kung may lumaktaw sa nakaraang seksyon, mahahanap mo ang buong detalye sa Bakit hindi gumagana ang Excel RIGHT function sa mga petsa.

Ganito mo ginagamit ang RIGHT function sa Excel. Upang mas masusing tingnan ang mga formula na tinalakay sa tutorial na ito, malugod kang malugod na i-download ang aming sample na workbook sa ibaba. Salamat sa pagbabasa at umaasa akong makita ka sa aming blog sa susunod na linggo.

Mga available na download

Excel RIGHT function - mga halimbawa (.xlsx file)