Opplæringen viser forskjellige måter å få alder fra bursdag i Excel. Du vil lære en håndfull formler for å beregne alder som et antall hele år, få nøyaktig alder i år, måneder og dager på dagens dato eller en bestemt dato.

Det er ingen spesiell funksjon å beregne alder i Excel, men det finnes noen forskjellige måter å konvertere fødselsdato til alder. Denne opplæringen vil forklare fordelene og ulempene ved hver vei, viser hvordan du lager en perfekt aldersberegningsformel i Excel og tilpasser den for å løse noen spesifikke oppgaver.

Hvordan beregne alder fra dato fødsel i Excel

I hverdagen innebærer spørsmålet « Hvor gammel er du? » vanligvis et svar som angir hvor mange år du har vært i live. I Microsoft Excel kan du lage en formel for å beregne en nøyaktig alder i måneder, dager, timer og til og med minutter. Men la oss være tradisjonelle, og lære å beregne alder fra DOB i år først.

Grunnleggende Excel-formel for alder i år

Hvordan finner du vanligvis ut noens alder? Ganske enkelt ved å trekke fødselsdatoen fra gjeldende dato. Denne konvensjonelle aldersformelen kan også brukes i Excel.

Forutsatt at en fødselsdato er i celle B2, går formelen for å beregne alder i år som følger:

=(TODAY()-B2)/365

første del av formelen (TODAY()-B2) returnerer forskjellen mellom gjeldende dato og fødselsdato er dager, og deretter deler du detcellereferanse eller en dato i formatet mm/dd/åååå.

Ferdig!

Formelen settes inn i den valgte cellen et øyeblikk, og du dobbeltklikker på fyllhåndtaket for å kopiere den ned i kolonnen.

Som du kanskje har lagt merke til, er formelen laget av vår Excel-alderkalkulator mer kompleks enn de vi har diskutert så langt, men den tar hensyn til entall og flertall av tidsenheter som "dag" og "dager".

Hvis du vil bli kvitt nullenheter som "0 dager", merk av for Ikke vis nullenheter :

Hvis du er nysgjerrig på å teste denne alderskalkulatoren samt å oppdage 60 flere tidsbesparende tillegg for Excel, er du velkommen til å laste ned en prøveversjon av Ultimate Suite på slutten av dette innlegget.

Hvordan fremheve visse aldre (under eller over en spesifikk alder)

I noen situasjoner må du kanskje ikke bare beregne alder i Excel, men også utheve celler som inneholder aldre som er under eller over en bestemt alder.

Hvis aldersberegningsformelen din returnerer antall hele år, så kan du lage en vanlig betinget formateringsregel basert på en enkel formel som disse:

• For å fremheve aldre lik eller større enn18: =$C2>=18
• For å fremheve aldre under 18 år: =$C2<18

Hvor C2 er den øverste cellen i Alder-kolonnen (ikke inkludert kolonneoverskrift).

Men hva om formelen din viser alder i år og måneder, eller i år, måneder og dager? I dette tilfellet må du lage en regel basert på en DATEDIF-formel som beregner alder fra fødselsdato i år.

Forutsatt at fødselsdatoene er i kolonne B som begynner med rad 2, er formlene som følger:

• For å fremheve alder under 18 (gul): =DATEDIF($B2, TODAY(),"Y")<18
• For å fremheve alder mellom 18 og 65 (grønn): =AND(DATEDIF($B2, TODAY(),"Y")>=18, DATEDIF($B2, TODAY(),"Y")<=65)
• For å fremheve aldre over 65 (blå): =DATEDIF($B2, TODAY(),"Y")>65

For å lage regler basert på formlene ovenfor, velg cellene eller hele radene du vil fremheve , gå til Hjem -fanen > Stiler -gruppen, og klikk Betinget formatering > Ny regel... > Bruk en formel for å bestemme hvilke celler som skal formateres .

De detaljerte trinnene finner du her: Hvordan lage en betinget formateringsregel basert på formel.

Slik beregner du alder i Excel. Jeg håper formlene var enkle for deg å lære, og du vil prøve dem i regnearkene dine. Takk for at du leste og håper å se deg på bloggen vår neste uke!

Tilgjengelige nedlastinger

Eksempler på Excel-alderberegning (.xlsx-fil)

Ultimate Suite 14-dagers fullstendig -funksjonell versjon (.exe-fil)

Formelen er åpenbar og lett å huske, men det er et lite problem. I de fleste tilfeller returnerer den et desimaltall som vist i skjermbildet nedenfor.

For å vise antall komplette år, bruk INT-funksjonen til å runde en desimal ned til nærmeste heltall:

=INT((TODAY()-B2)/365)

Ulemper: Bruk av denne aldersformelen i Excel gir ganske nøyaktige resultater, men ikke feilfrie. Å dele på gjennomsnittlig antall dager i et år fungerer fint mesteparten av tiden, men noen ganger blir det feil med alderen. For eksempel, hvis noen ble født 29. februar og i dag er 28. februar, vil formelen gjøre en person én dag eldre.

Som et alternativ kan du dele på 365,25 i stedet for 365 siden hvert fjerde år har 366 dager. Denne tilnærmingen er imidlertid heller ikke perfekt. Hvis du for eksempel beregner alderen til et barn som ennå ikke har gjennomlevd et skuddår, gir deling på 365,25 et feil resultat.

Samlet sett fungerer det utmerket å trekke fødselsdatoen fra gjeldende dato. normalt liv, men er ikke den ideelle tilnærmingen i Excel. Videre i denne opplæringen vil du lære et par spesialfunksjoner som beregner alder feilfritt uavhengig av år.

Beregn alder fra fødselsdato med funksjonen YEARFRAC

En mer pålitelig måte å konvertere DOB to age i Excel bruker YEARFRAC-funksjonen somreturnerer brøkdelen av året, dvs. antall hele dager mellom to datoer.

Syntaksen til ÅRFRAK-funksjonen er som følger:

De to første argumentene er åpenbare og krever knapt noen ytterligere forklaring. Basis er et valgfritt argument som definerer dagtellingsgrunnlaget som skal brukes.

For å lage en helt sann aldersformel, oppgi følgende verdier til YEARFRAC-funksjonen:

• Start_date - fødselsdato.
• End_date - TODAY() funksjon for å returnere dagens dato.
• Basis - bruk grunnlag 1 som forteller Excel å dele det faktiske antallet dager per måned med det faktiske antallet dager per år.

Tatt i betraktning ovenstående, en Excel-formel å beregne alder fra fødselsdato er som følger:

Forutsatt at fødselsdatoen er i celle B2, har formelen følgende form:

=YEARFRAC(B2, TODAY(), 1)

Som i forrige eksempel, er resultatet av ÅRFRAK-funksjonen også et desimaltall. For å fikse dette, bruk RUNDDOWN-funksjonen med 0 i det siste argumentet fordi du ikke vil ha noen desimaler.

Så, her er en forbedret ÅRFRAC-formel for å beregne alder i Excel:

=ROUNDDOWN(YEARFRAC(B2, TODAY(), 1), 0)

Beregn alder i Excel med DATEDIF

En annen måte å konvertere fødselsdato til alder i Excel er å bruke DATEDIF-funksjonen:

Denne funksjonen kan returnere forskjellen mellom to datoer i forskjellige tidsenheter som år, måneder og dager, avhengig av verdien du oppgir i enhet -argumentet:

• Y - returnerer antall fullstendige år mellom start- og sluttdatoen.
• M - returnerer antall fullstendige måneder mellom datoene.
• D - returnerer antall dager mellom de to datoene.
• YM - returnerer måneder , ignorerer dager og år.
• MD - returnerer forskjellen i dager , ignorerer måneder og år.
• YD - returnerer forskjellen i dager , ignorerer år.

Siden vi tar sikte på å beregne alder i år , bruker vi "y"-enheten:

I dette eksemplet er DOB i celle B2, og du refererer til denne cellen i aldersformelen din:

=DATEDIF(B2, TODAY(), "y")

Ingen ekstra avrundingsfunksjon er nødvendig i dette tilfellet fordi en DATEDIF-formel med t "y"-enheten beregner antall hele år:

Hvordan få alder fra bursdag i år, måneder og dager

Som du nettopp har sett , å beregne alder som antall hele år som personen har levd er enkelt, men det er ikke alltid tilstrekkelig. Hvis du vil vite nøyaktig alder, dvs. hvor mange år, måneder og dager det er mellom noens fødselsdato og nåværende dato, skriv 3forskjellige DATEDIF-funksjoner:

1. For å få antall år: =DATEDIF(B2, TODAY(), "Y")
2. For å få antall måneder: =DATEDIF(B2, TODAY(), "YM")
3. For å få antall dager: =DATEDIF(B2,TODAY(),"MD")

Hvor B2 er fødselsdatoen.

Og deretter, slå sammen funksjonene ovenfor i en enkelt formel, slik:

=DATEDIF(B2,TODAY(),"Y") & DATEDIF(B2,TODAY(),"YM") & DATEDIF(B2,TODAY(),"MD")

Formelen ovenfor returnerer 3 tall (år, måneder og dager) sammenkoblet i en enkelt tekststreng, som vist på skjermbildet nedenfor:

Gir ikke mye mening, eh ? For å gjøre resultatene mer meningsfulle, separer tallene med komma og definer hva hver verdi betyr:

=DATEDIF(B2,TODAY(),"Y") & " Years, " & DATEDIF(B2,TODAY(),"YM") & " Months, " & DATEDIF(B2,TODAY(),"MD") & " Days"

Resultatet ser mye bedre ut nå:

Formelen fungerer utmerket, men du kan forbedre den ytterligere ved å skjule nullverdier. For dette, legg til 3 IF-setninger som sjekker for 0-er, en for hver DATEDIF:

=IF(DATEDIF(B2, TODAY(),"y")=0,"",DATEDIF(B2, TODAY(),"y")&" years, ")& IF(DATEDIF(B2, TODAY(),"ym")=0,"",DATEDIF(B2, TODAY(),"ym")&" months, ")& IF(DATEDIF(B2, TODAY(),"md")=0,"",DATEDIF(B2, TODAY(),"md")&" days")

Følgende skjermbilde viser den endelige Excel-alderformelen i aksjon - den returnerer alder i år, måneder, og dager, viser bare ikke-null verdier:

Tips. Hvis du leter etter en Excel-formel for å beregne alder i år og måneder , ta formelen ovenfor og fjern den siste IF(DATEDIF())-blokken som beregner dager.

Spesifikke formler til beregne alder i Excel

De generiske aldersberegningsformlene diskutert ovenfor fungerer utmerket i de fleste tilfeller. I noen situasjoner kan du imidlertid trenge noe veldig spesifikt. Selvfølgelig er det ikke mulig å dekke alleog hvert scenario, men de følgende eksemplene vil gi deg noen ideer om hvordan du kan justere en aldersformel avhengig av din spesifikke oppgave.

Hvordan beregne alder på en bestemt dato i Excel

Hvis du vil vite noens alder på en bestemt dato, bruk DATEDIF aldersformelen diskutert ovenfor, men bytt ut TODAY()-funksjonen i det andre argumentet med den spesifikke datoen.

Forutsatt at fødselsdatoen er i B1, følgende formel vil returnere alder fra 1. januar 2020:

=DATEDIF(B1, "1/1/2020","Y") & " Years, " & DATEDIF(B1, "1/1/2020","YM") & " Months, " & DATEDIF(B1, "1/1/2020", "MD") & " Days"

For å gjøre aldersformelen mer fleksibel, kan du skrive inn datoen i en celle og referere til den cellen i formelen din:

=DATEDIF(B1, B2,"Y") & " Years, "& DATEDIF(B1,B2,"YM") & " Months, "&DATEDIF(B1,B2, "MD") & " Days"

Hvor B1 er DOB, og B2 er datoen du vil beregne alder.

Beregn alder i en bestemt år

Denne formelen kommer godt med i situasjoner der den fullstendige datoen for å beregne på ikke er definert, og du vet bare året.

La oss si at du jobber med en medisinsk database, og din Målet er å finne ut pasientenes alder på den tiden de er under gikk siste fullstendige medisinske undersøkelse.

Forutsatt at fødselsdatoene er i kolonne B som begynner med rad 3, og året for siste medisinske undersøkelse er i kolonne C, går aldersberegningsformelen som følger:

=DATEDIF(B3,DATE(C3, 1, 1),"y")

Fordi den eksakte datoen for medisinsk undersøkelse ikke er definert, bruker du DATE-funksjonen med et vilkårlig dato- og månedsargument, f.eks. DATO(C3, 1, 1).

DenDATE-funksjonen trekker ut året fra celle B3, lager en fullstendig dato ved å bruke måneds- og dagtallene du oppga (1-Jan i dette eksemplet), og overfører denne datoen til DATEDIF. Som et resultat får du pasientens alder per 1. januar i et bestemt år:

Finn ut en dato når en person fyller N år

Anta at vennen din ble født 8. mars 1978. Hvordan vet du på hvilken dato han fyller 50 år? Vanligvis vil du ganske enkelt legge til 50 år til personens fødselsdato. I Excel gjør du det samme ved å bruke DATO-funksjonen:

=DATE(YEAR(B2) + 50, MONTH(B2), DAY(B2))

Hvor B2 er fødselsdatoen.

I stedet for å hardkode antall år i formel, kan du referere til en bestemt celle der brukerne dine kan legge inn et hvilket som helst antall år (F1 i skjermbildet nedenfor):

Beregn alder fra dag, måned og år i forskjellige celler

Når en fødselsdato er delt inn i 3 forskjellige celler (f.eks. år er i B3, måned i C3 og dag i D3), kan du beregne alder på denne måten:

• Få fødselsdatoen ved å bruke funksjonene DATO og DATOVERDI:

  DATE(B3,MONTH(DATEVALUE(C3&"1")),D3)

• Legg inn formelen ovenfor i DATEDIF for å beregne alder fra fødselsdato i år, måneder og dager: =DATEDIF(DATE(B3, MONTH(DATEVALUE(C3&"1")), D3), TODAY(), "y") & " Years, "& DATEDIF(DATE(B3, MONTH(DATEVALUE(C3&"1")), D3),TODAY(), "ym") & " Months, "& DATEDIF(DATE(B3, MONTH(DATEVALUE(C3&"1")), D3), TODAY(), "md") & " Days"

  

For flere eksempler på beregning av antall dager før/etter en dato, se Hvordan beregne dager siden eller til dato i Excel.

Alder kalkulator i Excel

Hvis du vil ha din egenalderskalkulator i Excel, kan du lage en ved å bruke noen forskjellige DATEDIF-formler forklart nedenfor. Hvis du heller ikke vil finne opp hjulet på nytt, kan du bruke alderskalkulatoren laget av våre Excel-eksperter.

Hvordan lage en alderskalkulator i Excel

Nå som du vet hvordan du lager en aldersformel i Excel, kan du bygge en egendefinert alderskalkulator, for eksempel denne:

Merk. For å se den innebygde arbeidsboken, vennligst tillat markedsføringskapsler.

Det du ser ovenfor er et innebygd Excel Online-ark, så skriv gjerne inn fødselsdatoen din i den tilsvarende cellen, så får du alderen din om et øyeblikk.

Kalkulatoren bruker følgende formler for å beregne alder basert på fødselsdatoen i celle A3 og dagens dato.

• Formel i B5 beregner alder i år, måneder og dager: =DATEDIF(B2,TODAY(),"Y") & " Years, " & DATEDIF(B2,TODAY(),"YM") & " Months, " & DATEDIF(B2,TODAY(),"MD") & " Days"
• Formel i B6 beregner alder i måneder: =DATEDIF($B$3,TODAY(),"m")
• Formel i B7 beregner alder i dager: =DATEDIF($B$3,TODAY(),"d")

Hvis du har litt erfaring med Excel-skjemakontroller, du kan legge til et alternativ for å beregne alder på en bestemt dato, som vist i følgende skjermbilde:

For dette, legg til et par alternativknapper ( Utvikler-fanen > Sett inn > Skjemakontroller > Alternativknapp ), og koble dem til en celle. Og skriv deretter en IF/DATEDIF-formel for å få alder enten på dagens dato eller på datoen spesifisert av brukeren.

Formelen fungerer med følgendelogikk:

• Hvis alternativboksen Dagens dato er valgt, vises verdi 1 i den koblede cellen (I5 i dette eksemplet), og aldersformelen beregnes basert på dagens dato : IF($I$5=1, DATEDIF($B$3,TODAY(),"Y") & " Years, " & DATEDIF($B$3,TODAY(), "YM") & " Months, " & DATEDIF($B$3, TODAY(), "MD") & " Days")
• Hvis alternativknappen Spesifikk dato er valgt OG en dato legges inn i celle B7, beregnes alder på den angitte datoen: IF(ISNUMBER($B$7), DATEDIF($B$3, $B$7,"Y") & " Years, " & DATEDIF($B$3, $B$7,"YM") & " Months, " & DATEDIF($B$3, $B$7,"MD") & " Days", ""))

Til slutt , nester funksjonene ovenfor inn i hverandre, så får du den komplette aldersberegningsformelen (i B9):

=IF($I$5=1, DATEDIF($B$3, TODAY(), "Y") & " Years, " & DATEDIF($B$3, TODAY(), "YM") & " Months, " & DATEDIF($B$3, TODAY(), "MD") & " Days", IF(ISNUMBER($B$7), DATEDIF($B$3, $B$7,"Y") & " Years, " & DATEDIF($B$3, $B$7,"YM") & " Months, " & DATEDIF($B$3, $B$7,"MD") & " Days", ""))

Formlene i B10 og B11 fungerer med samme logikk. Selvfølgelig er de mye enklere fordi de inkluderer bare én DATEDIF-funksjon for å returnere alder som henholdsvis antall komplette måneder eller dager.

For å lære detaljene, inviterer jeg deg til å laste ned denne Excel-alderkalkulatoren og undersøke formlene i cellene B9:B11.

Last ned alderskalkulator for Excel

Klar til bruk alderskalkulator for Excel

Brukerne av Ultimate Suite har ikke å bry seg om å lage sin egen alderskalkulator i Excel - det er bare et par klikk unna:

1. Velg en celle der du vil sette inn en aldersformel, gå til Ablebits Tools -fanen > Dato & Tid -gruppen, og klikk på Dato & Tidsveiviser -knapp.

   

2. Datoen & Tidsveiviseren starter, og du går direkte til Alder -fanen.
3. På Alder -fanen er det 3 ting du må spesifisere:
   • Fødselsdata som en