ટ્યુટોરીયલ એક્સેલમાં જન્મદિવસથી વય મેળવવાની વિવિધ રીતો બતાવે છે. તમે કેટલાંક પૂર્ણ વર્ષોની સંખ્યા તરીકે ઉંમરની ગણતરી કરવા માટે મુઠ્ઠીભર સૂત્રો શીખી શકશો, આજની તારીખે અથવા ચોક્કસ તારીખે વર્ષો, મહિનાઓ અને દિવસોમાં ચોક્કસ ઉંમર મેળવો.

ગણતરી કરવા માટે કોઈ વિશેષ કાર્ય નથી એક્સેલમાં ઉંમર, જો કે જન્મ તારીખને ઉંમરમાં રૂપાંતરિત કરવાની કેટલીક અલગ અલગ રીતો છે. આ ટ્યુટોરીયલ દરેક રીતના ફાયદા અને ખામીઓ સમજાવશે, એક્સેલમાં સંપૂર્ણ વય ગણતરી ફોર્મ્યુલા કેવી રીતે બનાવવી અને અમુક ચોક્કસ કાર્યોને ઉકેલવા માટે તેમાં ફેરફાર કેવી રીતે કરવો તે બતાવશે.

તારીખથી ઉંમરની ગણતરી કેવી રીતે કરવી એક્સેલમાં જન્મનું

રોજિંદા જીવનમાં, પ્રશ્ન " તમારી ઉંમર કેટલી છે? " સામાન્ય રીતે જવાબ સૂચવે છે કે તમે કેટલા વર્ષોથી જીવિત છો. માઈક્રોસોફ્ટ એક્સેલમાં, તમે મહિનાઓ, દિવસો, કલાકો અને મિનિટોમાં ચોક્કસ ઉંમરની ગણતરી કરવા માટે એક સૂત્ર બનાવી શકો છો. પરંતુ ચાલો પરંપરાગત બનીએ, અને પહેલા DOB થી વર્ષોમાં ઉંમરની ગણતરી કેવી રીતે કરવી તે શીખીએ.

વર્ષોમાં ઉંમર માટે મૂળભૂત એક્સેલ ફોર્મ્યુલા

તમે સામાન્ય રીતે કોઈની ઉંમર કેવી રીતે આંકડો છો? ફક્ત વર્તમાન તારીખમાંથી જન્મ તારીખ બાદ કરીને. આ પરંપરાગત વય સૂત્રનો એક્સેલમાં પણ ઉપયોગ કરી શકાય છે.

જન્મતારીખ સેલ B2 માં છે એમ માનીને, વર્ષોમાં વયની ગણતરી કરવા માટેનું સૂત્ર નીચે મુજબ છે:

=(TODAY()-B2)/365

આ ફોર્મ્યુલાનો પ્રથમ ભાગ (TODAY()-B2) વર્તમાન તારીખ અને જન્મ તારીખ વચ્ચેનો તફાવત દિવસો છે અને પછી તમે તેને વિભાજિત કરો છોકોષ સંદર્ભ અથવા તારીખ mm/dd/yyyy ફોર્મેટમાં.

પૂર્ણ!

સૂત્રને પસંદ કરેલ કોષમાં ક્ષણવારમાં દાખલ કરવામાં આવે છે, અને તમે તેને કૉલમ નીચે કૉપિ કરવા માટે ફિલ હેન્ડલ પર ડબલ-ક્લિક કરો છો.

તમે નોંધ્યું હશે કે, અમારા એક્સેલ એજ કેલ્ક્યુલેટર દ્વારા બનાવેલ ફોર્મ્યુલા અમે અત્યાર સુધી ચર્ચા કરેલ ફોર્મ્યુલા કરતાં વધુ જટિલ છે, પરંતુ તે "દિવસ" અને "દિવસો" જેવા સમય એકમોના એકવચન અને બહુવચનને પૂર્ણ કરે છે.

જો તમે "0 દિવસ" જેવા શૂન્ય એકમોમાંથી છૂટકારો મેળવવા માંગતા હો, તો નહીં શૂન્ય એકમો બતાવો ચેક બોક્સ પસંદ કરો:

જો તમે આ વય કેલ્ક્યુલેટરનું પરીક્ષણ કરવા તેમજ એક્સેલ માટે વધુ 60 સમય-બચત એડ-ઇન્સ શોધવા માટે ઉત્સુક છો, તો તમે અમારા અલ્ટીમેટ સ્યુટનું ટ્રાયલ વર્ઝન ડાઉનલોડ કરવા માટે આવકાર્ય છે. આ પોસ્ટ.

કેવી રીતે અમુક વયને હાઇલાઇટ કરવી (a. હેઠળ કે તેથી વધુ ચોક્કસ ઉંમર)

કેટલીક પરિસ્થિતિઓમાં, તમારે માત્ર Excel માં ઉંમરની ગણતરી કરવાની જરૂર નથી, પરંતુ ચોક્કસ વયથી ઓછી અથવા તેથી વધુ ઉંમર ધરાવતા કોષોને પણ પ્રકાશિત કરવાની જરૂર પડી શકે છે.

જો તમારી ઉંમરની ગણતરી સૂત્ર પૂર્ણ વર્ષોની સંખ્યા પરત કરે છે, તો પછી તમે આના જેવા સરળ સૂત્રના આધારે નિયમિત શરતી ફોર્મેટિંગ નિયમ બનાવી શકો છો:

• તેની સમાન અથવા તેથી વધુ ઉંમરને પ્રકાશિત કરવા માટે18: =$C2>=18
• 18 વર્ષથી ઓછી ઉંમરના લોકોને હાઇલાઇટ કરવા માટે: =$C2<18

જ્યાં C2 એ એજ કૉલમમાં સૌથી ટોચનો કોષ છે (જેનો સમાવેશ થતો નથી કૉલમ હેડર).

પરંતુ જો તમારું ફોર્મ્યુલા વર્ષો અને મહિનાઓમાં અથવા વર્ષો, મહિનાઓ અને દિવસોમાં વય દર્શાવે છે તો શું? આ કિસ્સામાં, તમારે DATEDIF ફોર્મ્યુલાના આધારે એક નિયમ બનાવવો પડશે જે જન્મ તારીખથી વર્ષોમાં વયની ગણતરી કરે છે.

ધારો કે જન્મતારીખ પંક્તિ 2 થી શરૂ થતી કૉલમ B માં છે, સૂત્રો નીચે મુજબ છે:

• ની નીચે 18 (પીળો): =DATEDIF($B2, TODAY(),"Y")<18
• ઉમરોને હાઇલાઇટ કરવા 18 અને 65 (લીલો): =AND(DATEDIF($B2, TODAY(),"Y")>=18, DATEDIF($B2, TODAY(),"Y")<=65)
• ઉમર થી વધુ 65 (વાદળી): =DATEDIF($B2, TODAY(),"Y")>65

ઉપરોક્ત સૂત્રોના આધારે નિયમો બનાવવા માટે, તમે હાઇલાઇટ કરવા માંગો છો તે કોષો અથવા સમગ્ર પંક્તિઓ પસંદ કરો , હોમ ટેબ > શૈલીઓ જૂથ પર જાઓ, અને શરતી ફોર્મેટિંગ > નવો નિયમ… > ઉપયોગ પર ક્લિક કરો કયા કોષોને ફોર્મેટ કરવા તે નક્કી કરવા માટેનું એક સૂત્ર .

વિગતવાર પગલાં અહીં મળી શકે છે: ફોર્મ્યુલાના આધારે શરતી ફોર્મેટિંગ નિયમ કેવી રીતે બનાવવો.

આ રીતે તમે Excel માં ઉંમરની ગણતરી કરો છો. હું આશા રાખું છું કે ફોર્મ્યુલા તમારા માટે શીખવા માટે સરળ હતા અને તમે તેને તમારી વર્કશીટ્સમાં અજમાવી જુઓ. વાંચવા બદલ આભાર અને આશા છે કે આવતા અઠવાડિયે તમને અમારા બ્લોગ પર જોવા મળશે!

ઉપલબ્ધ ડાઉનલોડ્સ

Excel ઉંમર ગણતરીના ઉદાહરણો (.xlsx ફાઇલ)

અંતિમ સ્યુટ 14-દિવસ પૂર્ણપણે -ફંક્શનલ વર્ઝન (.exe ફાઇલ)

સૂત્ર સ્પષ્ટ અને યાદ રાખવામાં સરળ છે, જો કે, એક નાની સમસ્યા છે. મોટા ભાગના કિસ્સાઓમાં, તે નીચે આપેલા સ્ક્રીનશૉટમાં દર્શાવ્યા મુજબ દશાંશ નંબર આપે છે.

સંપૂર્ણ વર્ષોની સંખ્યા દર્શાવવા માટે, INT ફંક્શનનો ઉપયોગ કરીને દશાંશને નીચેની તરફ ગોળાકાર કરવા માટે નજીકના પૂર્ણાંક:

=INT((TODAY()-B2)/365)

ખામીઓ: એક્સેલમાં આ વય સૂત્રનો ઉપયોગ કરવાથી ખૂબ સચોટ પરિણામો મળે છે, પરંતુ દોષરહિત નથી. વર્ષમાં સરેરાશ દિવસોની સંખ્યા વડે ભાગાકાર કરવો એ મોટાભાગે સારું કામ કરે છે, પરંતુ કેટલીકવાર તે ઉંમરને ખોટી પાડે છે. ઉદાહરણ તરીકે, જો કોઈ વ્યક્તિનો જન્મ 29 ફેબ્રુઆરીએ થયો હોય અને આજે 28 ફેબ્રુઆરી છે, તો સૂત્ર વ્યક્તિને એક દિવસ મોટી બનાવશે.

વિકલ્પ તરીકે, તમે 365ને બદલે 365.25 વડે ભાગી શકો છો કારણ કે દરેક ચોથા વર્ષે 366 હોય છે. દિવસ. જો કે, આ અભિગમ પણ સંપૂર્ણ નથી. ઉદાહરણ તરીકે, જો તમે એવા બાળકની ઉંમરની ગણતરી કરી રહ્યા છો જે હજુ સુધી લીપ વર્ષ સુધી જીવ્યા નથી, તો 365.25 વડે ભાગવાથી ખોટું પરિણામ આવે છે.

એકંદરે, વર્તમાન તારીખમાંથી જન્મતારીખ બાદ કરવાથી આમાં સારું કામ થાય છે. સામાન્ય જીવન, પરંતુ Excel માં આદર્શ અભિગમ નથી. આ ટ્યુટોરીયલમાં આગળ, તમે કેટલાક વિશિષ્ટ કાર્યો શીખી શકશો જે વર્ષને ધ્યાનમાં લીધા વિના ભૂલ વગર વયની ગણતરી કરે છે.

YEARFRAC કાર્ય સાથે જન્મ તારીખથી ઉંમરની ગણતરી કરો

રૂપાંતર કરવાની વધુ વિશ્વસનીય રીત એક્સેલમાં DOB થી ઉંમર એ YEARFRAC ફંક્શનનો ઉપયોગ કરે છે જેવર્ષનો અપૂર્ણાંક પરત કરે છે, એટલે કે બે તારીખો વચ્ચેના સંપૂર્ણ દિવસોની સંખ્યા.

YEARFRAC કાર્યનું વાક્યરચના નીચે મુજબ છે:

The પ્રથમ બે દલીલો સ્પષ્ટ છે અને ભાગ્યે જ કોઈ વધારાના સમજૂતીની જરૂર છે. આધાર એ એક વૈકલ્પિક દલીલ છે જે ઉપયોગ કરવા માટેના દિવસની ગણતરીના આધારને વ્યાખ્યાયિત કરે છે.

એક સંપૂર્ણ સાચી વય સૂત્ર બનાવવા માટે, YEARFRAC ફંક્શનને નીચેના મૂલ્યો આપો:

• Start_date - જન્મ તારીખ.
• End_date - આજની તારીખ પરત કરવા માટે TODAY() ફંક્શન.
• આધાર - આધારનો ઉપયોગ કરો 1 કે જે એક્સેલને દર મહિને દિવસોની વાસ્તવિક સંખ્યાને દર વર્ષે દિવસોની વાસ્તવિક સંખ્યા દ્વારા વિભાજિત કરવાનું કહે છે.

ઉપરોક્તને ધ્યાનમાં લેતા, ગણતરી કરવા માટે એક એક્સેલ સૂત્ર જન્મ તારીખથી ઉંમર નીચે મુજબ છે:

જન્મતારીખ સેલ B2 માં છે એમ માનીને, સૂત્ર નીચેનો આકાર લે છે:

=YEARFRAC(B2, TODAY(), 1)

પહેલાના ઉદાહરણની જેમ, YEARFRAC ફંક્શનનું પરિણામ પણ દશાંશ સંખ્યા છે. આને ઠીક કરવા માટે, છેલ્લી દલીલમાં 0 સાથે ROUNDDOWN ફંક્શનનો ઉપયોગ કરો કારણ કે તમને કોઈ દશાંશ સ્થાન જોઈતું નથી.

તેથી, Excel માં ઉંમરની ગણતરી કરવા માટે અહીં એક સુધારેલ YEARFRAC ફોર્મ્યુલા છે:

=ROUNDDOWN(YEARFRAC(B2, TODAY(), 1), 0)

DATEDIF સાથે એક્સેલમાં ઉંમરની ગણતરી કરો

એક્સેલમાં જન્મતારીખને ઉંમરમાં કન્વર્ટ કરવાની એક વધુ રીત DATEDIF ફંક્શનનો ઉપયોગ કરી રહી છે:

આ ફંક્શન તમે એકમ દલીલમાં સપ્લાય કરો છો તેના આધારે વિવિધ સમય એકમો જેમ કે વર્ષ, મહિના અને દિવસોની બે તારીખો વચ્ચેનો તફાવત પરત કરી શકે છે:

• Y - શરૂઆત અને સમાપ્તિ તારીખો વચ્ચેના પૂર્ણ વર્ષ ની સંખ્યા પરત કરે છે.
• M - વચ્ચેના પૂર્ણ મહિનાઓ ની સંખ્યા પરત કરે છે. તારીખો.
• D - બે તારીખો વચ્ચેના દિવસો ની સંખ્યા પરત કરે છે.
• YM - દિવસો અને વર્ષોને અવગણીને મહિના પરત કરે છે.
• MD - મહિનાઓ અને વર્ષોને અવગણીને દિવસો માં તફાવત પરત કરે છે.
• YD - વર્ષોને અવગણીને દિવસો માં તફાવત પરત કરે છે.

અમે વય વર્ષ માં ગણતરી કરવાનું લક્ષ્ય રાખ્યું હોવાથી, અમે "y" એકમનો ઉપયોગ કરી રહ્યા છીએ:

આ ઉદાહરણમાં, DOB સેલ B2 માં છે, અને તમે આ કોષને તમારા વય સૂત્રમાં સંદર્ભિત કરો છો:

=DATEDIF(B2, TODAY(), "y")

આ કિસ્સામાં કોઈ વધારાના રાઉન્ડિંગ ફંક્શનની જરૂર નથી કારણ કે t સાથે DATEDIF ફોર્મ્યુલા he "y" એકમ સંપૂર્ણ વર્ષોની સંખ્યાની ગણતરી કરે છે:

વર્ષ, મહિના અને દિવસોમાં જન્મદિવસથી ઉંમર કેવી રીતે મેળવવી

જેમ તમે હમણાં જ જોયું છે , વ્યક્તિ જીવે છે તે સંપૂર્ણ વર્ષોની સંખ્યા તરીકે ઉંમરની ગણતરી કરવી સરળ છે, પરંતુ તે હંમેશા પર્યાપ્ત નથી. જો તમારે ચોક્કસ ઉંમર જાણવી હોય, એટલે કે કોઈની જન્મ તારીખ અને વર્તમાન તારીખ વચ્ચે કેટલા વર્ષ, મહિના અને દિવસો છે, તો 3 લખો.વિવિધ DATEDIF ફંક્શન્સ:

1. વર્ષની સંખ્યા મેળવવા માટે: =DATEDIF(B2, TODAY(), "Y")
2. મહિનાઓની સંખ્યા મેળવવા માટે: =DATEDIF(B2, TODAY(), "YM")
3. દિવસોની સંખ્યા મેળવવા માટે: =DATEDIF(B2,TODAY(),"MD")

જ્યાં B2 એ જન્મ તારીખ છે.

અને પછી, ઉપરોક્ત કાર્યોને એક સૂત્રમાં જોડો, જેમ કે:

=DATEDIF(B2,TODAY(),"Y") & DATEDIF(B2,TODAY(),"YM") & DATEDIF(B2,TODAY(),"MD")

ઉપરોક્ત સૂત્ર 3 નંબરો (વર્ષ, મહિના અને દિવસો) આપે છે જે એક જ ટેક્સ્ટ સ્ટ્રિંગમાં સંકલિત છે, જેમ કે નીચેના સ્ક્રીનશોટમાં બતાવ્યા પ્રમાણે:

તેનો કોઈ અર્થ નથી, ઉહ ? પરિણામોને વધુ અર્થપૂર્ણ બનાવવા માટે, સંખ્યાઓને અલ્પવિરામથી અલગ કરો અને દરેક મૂલ્યનો અર્થ શું છે તે વ્યાખ્યાયિત કરો:

=DATEDIF(B2,TODAY(),"Y") & " Years, " & DATEDIF(B2,TODAY(),"YM") & " Months, " & DATEDIF(B2,TODAY(),"MD") & " Days"

પરિણામ હવે વધુ સારું લાગે છે:

સૂત્ર સરસ કામ કરે છે, પરંતુ તમે શૂન્ય મૂલ્યોને છુપાવીને તેને વધુ સુધારી શકો છો. આ માટે, 3 IF સ્ટેટમેન્ટ્સ ઉમેરો જે 0 માટે તપાસે છે, દરેક DATEDIF દીઠ એક:

=IF(DATEDIF(B2, TODAY(),"y")=0,"",DATEDIF(B2, TODAY(),"y")&" years, ")& IF(DATEDIF(B2, TODAY(),"ym")=0,"",DATEDIF(B2, TODAY(),"ym")&" months, ")& IF(DATEDIF(B2, TODAY(),"md")=0,"",DATEDIF(B2, TODAY(),"md")&" days")

નીચેનો સ્ક્રીનશોટ અંતિમ એક્સેલ વય સૂત્રને કાર્યમાં દર્શાવે છે - તે વર્ષો, મહિનાઓમાં વય પરત કરે છે. અને દિવસો, માત્ર નૉન-શૂન્ય મૂલ્યો પ્રદર્શિત કરે છે:

ટીપ. જો તમે વર્ષ અને મહિનાઓ માં ઉંમરની ગણતરી કરવા માટે એક્સેલ ફોર્મ્યુલા શોધી રહ્યાં છો, તો ઉપરોક્ત સૂત્ર લો અને છેલ્લા IF(DATEDIF()) બ્લોકને દૂર કરો જે દિવસોની ગણતરી કરે છે.

વિશિષ્ટ ફોર્મ્યુલા એક્સેલમાં ઉંમરની ગણતરી કરો

ઉપર ચર્ચા કરાયેલ સામાન્ય વય ગણતરી ફોર્મ્યુલા મોટા ભાગના કિસ્સાઓમાં સરસ કામ કરે છે. કેટલીક પરિસ્થિતિઓમાં, જો કે, તમારે ખૂબ ચોક્કસ કંઈકની જરૂર પડી શકે છે. અલબત્ત, દરેકને આવરી લેવું શક્ય નથીઅને દરેક દૃશ્ય, પરંતુ નીચેના ઉદાહરણો તમને તમારા ચોક્કસ કાર્યના આધારે વય સૂત્રમાં કેવી રીતે ફેરફાર કરી શકે તે અંગેના કેટલાક વિચારો આપશે.

એક્સેલમાં ચોક્કસ તારીખે ઉંમરની ગણતરી કેવી રીતે કરવી

જો તમે ચોક્કસ તારીખે કોઈની ઉંમર જાણવા માગો છો, ઉપર ચર્ચા કરેલ DATEDIF વય સૂત્રનો ઉપયોગ કરો, પરંતુ 2જી દલીલમાં TODAY() ફંક્શનને ચોક્કસ તારીખથી બદલો.

જન્મ તારીખ B1 માં છે એમ ધારીને, નીચે આપેલ ફોર્મ્યુલા 1 જાન્યુઆરી 2020 થી ઉંમર પરત કરશે:

=DATEDIF(B1, "1/1/2020","Y") & " Years, " & DATEDIF(B1, "1/1/2020","YM") & " Months, " & DATEDIF(B1, "1/1/2020", "MD") & " Days"

તમારી ઉંમર ફોર્મ્યુલાને વધુ લવચીક બનાવવા માટે, તમે અમુક સેલમાં તારીખ દાખલ કરી શકો છો અને તમારા ફોર્મ્યુલામાં તે કોષનો સંદર્ભ આપી શકો છો:<3

=DATEDIF(B1, B2,"Y") & " Years, "& DATEDIF(B1,B2,"YM") & " Months, "&DATEDIF(B1,B2, "MD") & " Days"

જ્યાં B1 એ DOB છે, અને B2 એ તારીખ છે કે જેના પર તમે ઉંમરની ગણતરી કરવા માંગો છો.

એક ચોક્કસ રીતે ઉંમરની ગણતરી કરો વર્ષ

આ સૂત્ર એવા સંજોગોમાં કામ આવે છે જ્યારે ગણતરી કરવાની સંપૂર્ણ તારીખ નિર્ધારિત ન હોય અને તમે માત્ર વર્ષ જાણો છો.

ચાલો કહીએ કે તમે તબીબી ડેટાબેઝ સાથે કામ કરી રહ્યા છો, અને તમારા ધ્યેય એ છે કે દર્દીઓની ઉંમર તેઓની નીચે હોય તે સમયે શોધવાનું છેલ્લી સંપૂર્ણ તબીબી તપાસ કરી.

ધારી લઈએ કે જન્મ તારીખો કૉલમ B માં પંક્તિ 3 થી શરૂ થાય છે, અને છેલ્લી તબીબી પરીક્ષાનું વર્ષ કૉલમ C માં છે, વય ગણતરી સૂત્ર નીચે મુજબ છે:

=DATEDIF(B3,DATE(C3, 1, 1),"y")

તબીબી પરીક્ષાની ચોક્કસ તારીખ નિર્ધારિત ન હોવાથી, તમે DATE ફંક્શનનો ઉપયોગ મનસ્વી તારીખ અને મહિનાની દલીલ સાથે કરો છો, દા.ત. તારીખ(C3, 1, 1).

TheDATE ફંક્શન સેલ B3 માંથી વર્ષ કાઢે છે, તમે પૂરા પાડેલા મહિના અને દિવસની સંખ્યાનો ઉપયોગ કરીને સંપૂર્ણ તારીખ બનાવે છે (આ ઉદાહરણમાં 1-જાન્યુઆરી), અને તે તારીખને DATEDIF માં પસાર કરે છે. પરિણામ સ્વરૂપે, તમને દર્દીની ઉંમર ચોક્કસ વર્ષની 1 જાન્યુઆરીથી મળે છે:

એક તારીખ શોધો જ્યારે વ્યક્તિ N વર્ષની ઉંમરે પહોંચે

ધારો કે તમારા મિત્રનો જન્મ 8 માર્ચ 1978 ના રોજ થયો હતો. તમે કેવી રીતે જાણો છો કે તે કઈ તારીખે તેની 50 વર્ષ પૂર્ણ કરે છે? સામાન્ય રીતે, તમે વ્યક્તિની જન્મતારીખમાં ફક્ત 50 વર્ષ ઉમેરશો. એક્સેલમાં, તમે DATE ફંક્શનનો ઉપયોગ કરીને તે જ કરો છો:

=DATE(YEAR(B2) + 50, MONTH(B2), DAY(B2))

જ્યાં B2 જન્મ તારીખ છે.

માં વર્ષોની સંખ્યાને સખત કોડિંગ કરવાને બદલે ફોર્મ્યુલા, તમે ચોક્કસ કોષનો સંદર્ભ લઈ શકો છો જ્યાં તમારા વપરાશકર્તાઓ ગમે તેટલા વર્ષો ઇનપુટ કરી શકે છે (નીચેના સ્ક્રીનશૉટમાં F1):

દિવસ, મહિનો અને વર્ષમાંથી અલગ અલગ રીતે ઉંમરની ગણતરી કરો કોષો

જ્યારે જન્મતારીખ 3 અલગ અલગ કોષોમાં વિભાજિત કરવામાં આવે છે (દા.ત. વર્ષ B3 માં, મહિનો C3 માં અને દિવસ D3 માં), તમે આ રીતે ઉંમરની ગણતરી કરી શકો છો:

• મેળવો DATE અને DATEVALUE ફંક્શનનો ઉપયોગ કરીને જન્મ તારીખ:

  DATE(B3,MONTH(DATEVALUE(C3&"1")),D3)

• ઉપરોક્ત સૂત્રને DATEDIF માં એમ્બેડ કરો અને વર્ષ, મહિના અને દિવસોમાં જન્મ તારીખથી ઉંમરની ગણતરી કરો: =DATEDIF(DATE(B3, MONTH(DATEVALUE(C3&"1")), D3), TODAY(), "y") & " Years, "& DATEDIF(DATE(B3, MONTH(DATEVALUE(C3&"1")), D3),TODAY(), "ym") & " Months, "& DATEDIF(DATE(B3, MONTH(DATEVALUE(C3&"1")), D3), TODAY(), "md") & " Days"

  

તારીખ પહેલા/પછીના દિવસોની ગણતરી કરવાના વધુ ઉદાહરણો માટે, કૃપા કરીને Excel માં ત્યારથી કે તારીખ સુધીના દિવસોની ગણતરી કેવી રીતે કરવી તે જુઓ.

ઉંમર Excel માં કેલ્ક્યુલેટર

જો તમે તમારું પોતાનું રાખવા માંગતા હોExcel માં ઉંમર કેલ્ક્યુલેટર, તમે નીચે સમજાવેલ થોડા અલગ DATEDIF ફોર્મ્યુલાનો ઉપયોગ કરીને એક બનાવી શકો છો. જો તમે વ્હીલને પુનઃશોધ ન કરવા માંગતા હો, તો તમે અમારા એક્સેલ પ્રોફેશનલ્સ દ્વારા બનાવેલ વય કેલ્ક્યુલેટરનો ઉપયોગ કરી શકો છો.

એક્સેલમાં વય કેલ્ક્યુલેટર કેવી રીતે બનાવવું

હવે તમે જાણો છો કે કેવી રીતે એક્સેલમાં ઉંમર સૂત્ર, તમે કસ્ટમ વય કેલ્ક્યુલેટર બનાવી શકો છો, ઉદાહરણ તરીકે આ:

નોંધ. એમ્બેડેડ વર્કબુક જોવા માટે, કૃપા કરીને માર્કેટિંગ કૂકીઝને મંજૂરી આપો.

તમે ઉપર જે જુઓ છો તે એમ્બેડેડ એક્સેલ ઓનલાઈન શીટ છે, તેથી અનુરૂપ કોષમાં તમારી જન્મતારીખ દાખલ કરવા માટે નિઃસંકોચ કરો, અને તમને તમારી ઉંમર એક ક્ષણમાં મળી જશે.

કેલ્ક્યુલેટર સેલ A3 માં જન્મ તારીખ અને આજની તારીખના આધારે ઉંમરની ગણતરી કરવા માટે નીચેના સૂત્રોનો ઉપયોગ કરે છે.

• B5 માં ફોર્મ્યુલા વર્ષ, મહિના અને દિવસોમાં ઉંમરની ગણતરી કરે છે: =DATEDIF(B2,TODAY(),"Y") & " Years, " & DATEDIF(B2,TODAY(),"YM") & " Months, " & DATEDIF(B2,TODAY(),"MD") & " Days"
• B6 માં ફોર્મ્યુલા મહિનાઓમાં ઉંમરની ગણતરી કરે છે: =DATEDIF($B$3,TODAY(),"m")
• B7 માં ફોર્મ્યુલા દિવસોમાં ઉંમરની ગણતરી કરે છે: =DATEDIF($B$3,TODAY(),"d")

જો તમને એક્સેલ ફોર્મ નિયંત્રણોનો થોડો અનુભવ હોય, તમે ચોક્કસ તારીખે ઉંમરની ગણતરી કરવાનો વિકલ્પ ઉમેરી શકો છો, જેમ કે નીચેના સ્ક્રીનશૉટમાં બતાવેલ છે:

આ માટે, થોડા વિકલ્પ બટનો ઉમેરો ( વિકાસકર્તા ટેબ > શામેલ કરો > ફોર્મ નિયંત્રણો > વિકલ્પ બટન ), અને તેમને અમુક સેલ સાથે લિંક કરો. અને પછી, આજની તારીખે અથવા વપરાશકર્તા દ્વારા ઉલ્લેખિત તારીખે ઉંમર મેળવવા માટે IF/DATEDIF ફોર્મ્યુલા લખો.

સૂત્ર નીચેના સાથે કામ કરે છે.તર્ક:

• જો આજની તારીખ વિકલ્પ બોક્સ પસંદ કરેલ હોય, તો લિંક કરેલ કોષમાં મૂલ્ય 1 દેખાય છે (આ ઉદાહરણમાં I5), અને વય સૂત્ર આજની તારીખના આધારે ગણતરી કરે છે. : IF($I$5=1, DATEDIF($B$3,TODAY(),"Y") & " Years, " & DATEDIF($B$3,TODAY(), "YM") & " Months, " & DATEDIF($B$3, TODAY(), "MD") & " Days")
• જો ચોક્કસ તારીખ વિકલ્પ બટન પસંદ કરેલ છે અને સેલ B7 માં તારીખ દાખલ કરવામાં આવી છે, તો વય નિર્દિષ્ટ તારીખે ગણવામાં આવે છે: IF(ISNUMBER($B$7), DATEDIF($B$3, $B$7,"Y") & " Years, " & DATEDIF($B$3, $B$7,"YM") & " Months, " & DATEDIF($B$3, $B$7,"MD") & " Days", ""))

આખરે , ઉપરોક્ત કાર્યોને એકબીજામાં બાંધો, અને તમને સંપૂર્ણ વય ગણતરી સૂત્ર (B9 માં) મળશે:

=IF($I$5=1, DATEDIF($B$3, TODAY(), "Y") & " Years, " & DATEDIF($B$3, TODAY(), "YM") & " Months, " & DATEDIF($B$3, TODAY(), "MD") & " Days", IF(ISNUMBER($B$7), DATEDIF($B$3, $B$7,"Y") & " Years, " & DATEDIF($B$3, $B$7,"YM") & " Months, " & DATEDIF($B$3, $B$7,"MD") & " Days", ""))

B10 અને B11 માંના સૂત્રો સમાન તર્ક સાથે કામ કરે છે. અલબત્ત, તે વધુ સરળ છે કારણ કે તેમાં અનુક્રમે પૂર્ણ મહિનાઓ અથવા દિવસોની સંખ્યા તરીકે વય પરત કરવા માટે માત્ર એક DATEDIF ફંક્શનનો સમાવેશ થાય છે.

વિગતો જાણવા માટે, હું તમને આ એક્સેલ એજ કેલ્ક્યુલેટર ડાઉનલોડ કરવા અને તપાસ કરવા આમંત્રણ આપું છું. કોષો B9:B11 માં સૂત્રો.

એક્સેલ માટે ઉંમર કેલ્ક્યુલેટર ડાઉનલોડ કરો

એક્સેલ માટે ઉપયોગમાં લેવા માટે તૈયાર ઉંમર કેલ્ક્યુલેટર

અમારા અલ્ટીમેટ સ્યુટના વપરાશકર્તાઓ પાસે નથી એક્સેલમાં પોતાનું વય કેલ્ક્યુલેટર બનાવવા વિશે ચિંતા કરવા માટે - તે માત્ર થોડા ક્લિક્સ દૂર છે:

1. એક કોષ પસંદ કરો જ્યાં તમે વય સૂત્ર દાખલ કરવા માંગો છો, Ablebits Tools<પર જાઓ 2> ટેબ > તારીખ & સમય જૂથ, અને ક્લિક કરો તારીખ & સમય વિઝાર્ડ બટન.

   

2. તારીખ & સમય વિઝાર્ડ શરૂ થશે, અને તમે સીધા જ ઉંમર ટેબ પર જશો.
3. ઉંમર ટેબ પર, તમારે સ્પષ્ટ કરવા માટે 3 વસ્તુઓ છે:
   • જન્મનો ડેટા એ