Õpetus näitab erinevaid viise, kuidas saada vanus sünnipäevast Excelis. Saate teada käputäie valemeid, et arvutada vanus täielike aastate arvuna, saada täpne vanus aastates, kuudes ja päevades tänase kuupäeva või konkreetse kuupäeva seisuga.

Vanuse arvutamiseks Excelis ei ole spetsiaalset funktsiooni, kuid on olemas mõned erinevad viisid sünnikuupäeva vanuseks teisendamiseks. Selles õpetuses selgitatakse iga viisi eeliseid ja puudusi, näidatakse, kuidas teha Excelis täiuslik vanuse arvutamise valem ja kohandada seda mõne konkreetse ülesande lahendamiseks.

Kuidas arvutada vanust sünnikuupäevast Excelis

Igapäevaelus on küsimus " Kui vana sa oled? " tähendab tavaliselt vastust, mis näitab, mitu aastat te olete elanud. Microsoft Excelis saate teha valemi, et arvutada täpne vanus kuudes, päevades, tundides ja isegi minutites. Kuid olgem traditsioonilised ja õppigem kõigepealt, kuidas arvutada vanust DOB-st aastates.

Exceli põhivalem vanuse kohta aastates

Kuidas te tavaliselt kellegi vanuse välja selgitate? Lihtsalt lahutades sünnikuupäeva praegusest kuupäevast. Seda tavapärast vanuse valemit saab kasutada ka Excelis.

Eeldades, et sünniaeg on lahtris B2, on valem vanuse arvutamiseks aastates järgmine:

=(TÄNA()-B2)/365

Valemi esimene osa (TODAY()-B2) annab praeguse kuupäeva ja sünnikuupäeva erinevuse päevades, seejärel jagate selle arvu 365-ga, et saada aastate arv.

Valem on ilmne ja kergesti meeldejääv, kuid on üks pisike probleem. Enamikul juhtudel annab see tagasi kümnendarvu, nagu on näidatud alloleval ekraanipildil.

Täielike aastate arvu kuvamiseks kasutage funktsiooni INT, et ümardada kümnendarv lähima täisarvuni:

=INT((TODAY()-B2)/365)

Puudused: Selle vanuse valemi kasutamine Excelis annab üsna täpseid tulemusi, kuid mitte veatuid. Jagamine aasta keskmise päevade arvuga töötab enamasti hästi, kuid mõnikord annab see vanuse valesti. Näiteks kui keegi on sündinud 29. veebruaril ja täna on 28. veebruar, teeb valem inimese ühe päeva võrra vanemaks.

Alternatiivina võib 365 asemel jagada 365,25-ga, kuna igal neljandal aastal on 366 päeva. Kuid ka see lähenemine ei ole täiuslik. Näiteks kui arvutate lapse vanust, kes ei ole veel kariaastat läbi elanud, annab 365,25-ga jagamine vale tulemuse.

Üldiselt töötab sünnikuupäeva lahutamine praegusest kuupäevast suurepäraselt tavalises elus, kuid Excelis ei ole see ideaalne lähenemine. Edasi selles õpetuses õpid tundma paari erifunktsiooni, mis arvutavad vanuse veatult sõltumata aastaarvust.

Vanuse arvutamine sünnikuupäevast funktsiooniga YEARFRAC

Usaldusväärsem viis DOB vanuseks konverteerimiseks Excelis on kasutada funktsiooni YEARFRAC, mis tagastab aastaosa, st kahe kuupäeva vaheliste tervete päevade arvu.

Funktsiooni YEARFRAC süntaks on järgmine:

Esimesed kaks argumenti on ilmselged ja vaevalt, et need vajavad täiendavaid selgitusi. Alus on valikuline argument, mis määrab kasutatava päevade arvu aluse.

Täiesti tõese vanuse valemi saamiseks sisestage funktsioonile YEARFRAC järgmised väärtused:

• Start_date - sünniaeg.
• End_date - TODAY() funktsioon, et tagastada tänane kuupäev.
• Alus - kasutamise alus 1 mis ütleb Excelile, et jagada tegelik päevade arv kuus tegeliku päevade arvuga aastas.

Võttes arvesse ülaltoodut, on Exceli valem vanuse arvutamiseks sünnikuupäevast järgmine:

Eeldades, et sünnikuupäev on lahtris B2, võtab valem järgmise kuju:

=YEARFRAC(B2, TODAY(), 1)

Nagu eelmises näites, on ka funktsiooni YEARFRAC tulemus kümnendarv. Selle parandamiseks kasutage funktsiooni ROUNDDOWN, mille viimaseks argumendiks on 0, sest te ei soovi kümnendkohti.

Nii et siin on täiustatud valem YEARFRAC vanuse arvutamiseks Excelis:

=ROUNDDOWN(YEARFRAC(B2, TODAY(), 1), 0)

Vanuse arvutamine Excelis DATEDIF-i abil

Veel üks võimalus sünniaegade konverteerimiseks vanuseks Excelis on kasutada funktsiooni DATEDIF:

See funktsioon võib tagastada kahe kuupäeva vahe erinevates ajaühikutes, näiteks aastates, kuudes ja päevades, sõltuvalt väärtusest, mille annate parameetris üksus argument:

• Y - tagastab arvu täielikud aastad algus- ja lõppkuupäevade vahel.
• M - tagastab arvu täielikud kuud kuupäevade vahel.
• D - tagastab arvu päevad kahe kuupäeva vahel.
• YM - naaseb kuud , ignoreerides päevi ja aastaid.
• MD - tagastab erinevuse päevad , ignoreerides kuid ja aastaid.
• YD - tagastab erinevuse päevad , ignoreerides aastaid.

Kuna meie eesmärk on arvutada vanus aastal aastat , me kasutame "y" ühikut:

Selles näites on DOB lahtris B2 ja te viitate sellele lahtrisse oma vanuse valemis:

=DATEDIF(B2, TODAY(), "y")

Sellisel juhul ei ole vaja täiendavat ümardamisfunktsiooni, sest DATEDIF-vormel koos ühikuga "y" arvutab täielike aastate arvu:

Kuidas saada vanus sünnipäevast aastate, kuude ja päevade kaupa

Nagu äsja nägite, on vanuse arvutamine täisaastate arvuna lihtne, kuid see ei ole alati piisav. Kui soovite teada täpset vanust, st mitu aastat, kuud ja päeva on kellegi sünnikuupäeva ja praeguse kuupäeva vahel, kirjutage 3 erinevat DATEDIF-funktsiooni:

1. Aastate arvu saamiseks: =DATEDIF(B2, TODAY(), "Y")
2. Kuude arvu saamiseks: =DATEDIF(B2, TODAY(), "YM")
3. Päevade arvu saamiseks: =DATEDIF(B2,TODAY(), "MD")

Kus B2 on sünniaeg.

Ja siis ühendage ülaltoodud funktsioonid üheks valemiks, näiteks nii:

=DATEDIF(B2,TODAY(), "Y") & DATEDIF(B2,TODAY(), "YM") & DATEDIF(B2,TODAY(), "MD")

Ülaltoodud valem tagastab 3 numbrit (aastad, kuud ja päevad), mis on liidetud ühte tekstisõnumisse, nagu on näidatud alloleval ekraanipildil:

Ei ole palju mõtet, mis? Et tulemused oleksid sisukamad, eraldage numbrid komadega ja määratlege, mida iga väärtus tähendab:

=DATEDIF(B2,TODAY(), "Y") & " Aastad, " & DATEDIF(B2,TODAY(), "YM") & " kuud, " & DATEDIF(B2,TODAY(), "MD") & " päevad"

Tulemus näeb nüüd palju parem välja:

Valem töötab suurepäraselt, kuid te saate seda veelgi parandada, varjates nullväärtused. Selleks lisage 3 IF avaldust, mis kontrollivad 0-d, üks iga DATEDIF-i kohta:

=IF(DATEDIF(B2, TODAY(), "y")=0,"",DATEDIF(B2, TODAY(), "y")&" aastat, ")& IF(DATEDIF(B2, TODAY(), "ym")=0,"",DATEDIF(B2, TODAY(), "ym")&" kuud, ")& IF(DATEDIF(B2, TODAY(), "md")=0,"",DATEDIF(B2, TODAY(), "md")&" päeva")

Järgmine ekraanipilt näitab Exceli lõplikku vanuse valemit - see annab vanuse aastate, kuude ja päevade kaupa tagasi, näidates ainult mittenulli väärtused:

Vihje. Kui otsite Exceli valemit, et arvutada vanust aastal aastad ja kuud võtke ülaltoodud valem ja eemaldage viimane IF(DATEDIF()) plokk, mis arvutab päevi.

Konkreetsed valemid vanuse arvutamiseks Excelis

Eespool käsitletud üldised vanuse arvutamise valemid toimivad enamikul juhtudel suurepäraselt. Mõnes olukorras võib aga olla vaja midagi väga spetsiifilist. Loomulikult ei ole võimalik katta kõiki ja kõiki stsenaariume, kuid järgmised näited annavad teile mõned ideed, kuidas te saate vanuse arvutamise valemit vastavalt teie konkreetsele ülesandele kohandada.

Kuidas arvutada vanust konkreetsel kuupäeval Excelis

Kui soovite teada kellegi vanust teatud kuupäeval, kasutage eespool käsitletud DATEDIF vanuse valemit, kuid asendage funktsiooni TODAY() 2. argumendis konkreetse kuupäevaga.

Eeldades, et sünnikuupäev on B1, annab järgmine valem vanuse 1. jaanuari 2020. aasta seisuga:

=DATEDIF(B1, "1/1/2020", "Y") & " Aastad, " & DATEDIF(B1, "1/1/2020", "YM") & " kuud, " & DATEDIF(B1, "1/1/2020", "MD") & " päevad"

Et muuta oma vanuse valemit paindlikumaks, võite sisestada kuupäeva mõnda lahtrisse ja viidata sellele lahtrisse oma valemis:

=DATEDIF(B1, B2, "Y") & " Aastad, "& DATEDIF(B1,B2, "YM") & " kuud, "&DATEDIF(B1,B2, "MD") & " päevad"

Kus B1 on sünniaeg ja B2 on kuupäev, mille kohta soovite vanust arvutada.

Vanuse arvutamine teatud aastal

See valem tuleb kasuks olukordades, kus täielik kuupäev, mille kohta arvutusi teha, ei ole määratletud ja te teate ainult aastaarvu.

Oletame, et töötate meditsiinilise andmebaasiga ja teie eesmärk on leida patsientide vanus ajal, mil nad läbisid viimase täieliku arstliku läbivaatuse.

Eeldades, et sünniaeg on veerus B alates reast 3 ja viimase arstliku läbivaatuse aasta on veerus C, on vanuse arvutamise valem järgmine:

=DATEDIF(B3,DATE(C3, 1, 1), "y")

Kuna arstliku läbivaatuse täpne kuupäev ei ole määratletud, kasutate funktsiooni DATE koos suvalise kuupäeva ja kuu argumendiga, nt DATE(C3, 1, 1, 1).

Funktsioon DATE võtab lahtrist B3 välja aastaarvu, koostab täieliku kuupäeva, kasutades teie poolt esitatud kuu ja päeva numbreid (antud näites 1-Jan), ja edastab selle kuupäeva funktsioonile DATEDIF. Tulemusena saate patsiendi vanuse konkreetse aasta 1. jaanuari seisuga:

Leia välja kuupäev, millal isik saab N-aastaseks.

Oletame, et teie sõber on sündinud 8. märtsil 1978. Kuidas te saate teada, millisel kuupäeval ta täidab oma 50-aastaseks saamist? Tavaliselt lisate lihtsalt 50 aastat isiku sünnikuupäevale. Excelis teete sama, kasutades funktsiooni DATE:

=DATE(AASTA(B2) + 50, KUU(B2), PÄEV(B2))

Kus B2 on sünniaeg.

Selle asemel, et valemisse aastate arvu kõvasti sisestada, saate viidata teatud lahtrisse, kuhu kasutajad saavad sisestada mis tahes arvu aastaid (F1 alloleval ekraanipildil):

Vanuse arvutamine päevast, kuust ja aastast erinevates lahtrites

Kui sünnikuupäev on jagatud 3 erinevasse lahtrisse (nt aasta on B3-s, kuu C3-s ja päev D3-s), saate vanuse arvutada sel viisil:

• Sünnikuupäeva saamine funktsioonide DATE ja DATEVALUE abil:

  DATE(B3,MONTH(DATEVALUE(C3& "1")),D3)

• Sisestage ülaltoodud valem DATEDIF-i, et arvutada vanus sünnikuupäevast aastate, kuude ja päevadega: =DATEDIF(DATE(B3, MONTH(DATEVALUE(C3& "1")), D3), TODAY(), "y") & " Years, "& DATEDIF(DATE(B3, MONTH(DATEVALUE(C3& "1")), D3),TODAY(), "ym") & " Months, "& DATEDIF(DATE(B3, MONTH(DATEVALUE(C3& "1")), D3), TODAY(), "md") & " Days"

  

Rohkem näiteid kuupäevale eelnevate/järgsete päevade arvu arvutamise kohta leiate jaotisest Kuidas arvutada päevi alates kuupäevast või kuni kuupäevani Excelis.

Vanuse kalkulaator Excelis

Kui soovite omaenda vanusekalkulaatorit Excelis, saate selle teha, kasutades mõnda erinevat DATEDIF-vormelit, mida selgitatakse allpool. Kui te ei soovi ratast uuesti leiutada, võite kasutada meie Exceli spetsialistide loodud vanusekalkulaatorit.

Kuidas luua vanuse kalkulaator Excelis

Nüüd, kui te teate, kuidas Excelis vanuse valemit koostada, saate luua kohandatud vanusekalkulaatori, näiteks selle:

Märkus. Sisseehitatud töövihiku vaatamiseks lubage turundusküpsiseid.

See, mida näete eespool, on sisseehitatud Excel Online'i leht, nii et sisestage julgelt oma sünniaeg vastavasse lahtrisse ja saate oma vanuse kohe kätte.

Kalkulaator kasutab järgmisi valemeid, et arvutada vanus lahtris A3 oleva sünnikuupäeva ja tänase kuupäeva põhjal.

• Valem B5 arvutab vanuse aastates, kuudes ja päevades: =DATEDIF(B2,TODAY(), "Y") & " Aastad, " & DATEDIF(B2,TODAY(), "YM") & " kuud, " & DATEDIF(B2,TODAY(), "MD") & " päevad"
• Valem B6 arvutab vanuse kuudes: =DATEDIF($B$3,TODAY(), "m")
• Valem B7 arvutab vanuse päevades: =DATEDIF($B$3,TODAY(), "d")

Kui teil on kogemusi Exceli vormikontrollidega, saate lisada võimaluse vanuse arvutamiseks konkreetsel kuupäeval, nagu on näidatud järgmisel ekraanipildil:

Selleks lisage paar valikunuppu ( Arendaja vahekaart > Sisesta > Vormi kontroll > Valiku nupp ) ja seosta need mõne lahtriga. Ja siis kirjuta IF/DATEDIF valem, et saada vanus kas tänase kuupäeva või kasutaja poolt määratud kuupäeva seisuga.

Valem töötab järgmise loogika alusel:

• Kui Tänane kuupäev valikukast on valitud, ilmub seotud lahtrisse (antud näites I5) väärtus 1 ja vanuse valem arvutatakse tänase kuupäeva alusel: IF($I$5=1, DATEDIF($B$3,TODAY(), "Y") & " Years, " & DATEDIF($B$3,TODAY(), "YM") & " Months, " & DATEDIF($B$3, TODAY(), "MD") & " Days")
• Kui Konkreetne kuupäev nupp on valitud JA lahtrisse B7 on sisestatud kuupäev, arvutatakse vanus määratud kuupäeval: IF(ISNUMBER($B$7), DATEDIF($B$3, $B$7, "Y") & " Aastad, " & DATEDIF($B$3, $B$7, "YM") & " kuud, " & DATEDIF($B$3, $B$7, "MD") & " päevad", ""))

Lõpuks ühendage ülaltoodud funktsioonid omavahel ja saate täieliku vanuse arvutamise valemi (B9):

=IF($I$5=1, DATEDIF($B$3, TODAY(), "Y") & " Aastad, " & DATEDIF($B$3, TODAY(), "YM") & " kuud, " & DATEDIF($B$3, TODAY(), "MD") & " päevad", IF(ISNUMBER($B$7), DATEDIF($B$3, $B$7, "Y") & " aastad, " & DATEDIF($B$3, $B$7, "YM") & " kuud, " & DATEDIF($B$3, $B$7, "MD") & " päevad", ""))

Valemid B10 ja B11 töötavad sama loogika järgi. Muidugi on need palju lihtsamad, sest need sisaldavad ainult ühte DATEDIF-funktsiooni, mis tagastab vanuse vastavalt täielike kuude või päevade arvuna.

Üksikasjadega tutvumiseks kutsun teid üles laadima alla selle Exceli vanusekalkulaatori ja uurima lahtrites B9:B11 olevaid valemeid.

Lae alla Exceli vanusekalkulaator

Valmis vanusekalkulaator Exceli jaoks

Meie Ultimate Suite'i kasutajad ei pea vaeva nägema oma vanusekalkulaatori tegemisega Excelis - see on vaid paari kliki kaugusel:

1. Valige lahter, kuhu soovite sisestada vanuse valemi, minge lahtrisse Ablebits tööriistad tab> Kuupäev & Kellaaeg gruppi ja klõpsake nuppu Kuupäev & Aeg Wizard nuppu.

   

2. Date & Time Wizard käivitub, ja te lähete otse Vanus vahekaart.
3. On Vanus vahekaardil on 3 asja, mida peate täpsustama:
   • Sünniandmed kui lahtriviide või kuupäev vormingus mm/dd/yyyyyy.
   • Vanus kell tänane kuupäev või konkreetne kuupäev .
   • Valige, kas arvutada vanus päevades, kuudes, aastates või täpne vanus.
4. Klõpsake nuppu Sisesta valem nupp.

Valmis!

Valem sisestatakse valitud lahtrisse hetkeks ja te topeltklõpsate täitekäepidemel, et kopeerida see veerus alla.

Nagu olete ehk märganud, on meie Exceli vanusekalkulaatori poolt loodud valem keerulisem kui need, mida oleme seni arutanud, kuid see arvestab ajaühikute, nagu "päev" ja "päevad", ainsuses ja mitmuses.

Kui soovite vabaneda nullühikutest, nagu "0 päeva", valige valik Ärge näidata null ühikut märkeruut:

Kui olete huvitatud selle vanusekalkulaatori testimisest ja veel 60 Exceli ajasäästu lisavõimaluse avastamisest, võite selle postituse lõpus alla laadida meie Ultimate Suite'i prooviversiooni.

Kuidas tõsta esile teatud vanuseid (alla või üle teatud vanuse)

Mõnes olukorras võib olla vaja mitte ainult vanuse arvutamist Excelis, vaid ka selliste lahtrite esiletõstmist, mis sisaldavad alla või üle teatud vanuse jäävat vanust.

Kui teie vanuse arvutamise valem tagastab täielike aastate arvu, siis saate luua tavalise tingimusliku vormindamise reegli, mis põhineb lihtsal valemil, nagu need:

• 18-aastaste või suuremate vanuste esiletõstmiseks: =$C2>=18
• Alla 18-aastaste vanuse esiletõstmiseks: =$C2<18

Kus C2 on vanuse veeru kõige ülemine lahter (välja arvatud veeru päis).

Aga mis siis, kui teie valem näitab vanust aastates ja kuudes või aastates, kuudes ja päevades? Sellisel juhul peate looma reegli, mis põhineb DATEDIF-valemil, mis arvutab vanuse sünniaastast aastates.

Oletame, et sünnikuupäevad on veerus B alates reast 2, siis on valemid järgmised:

• Eakate esiletõstmiseks aadressil 18 (kollane): =DATEDIF($B2, TODAY(), "Y")<18
• Eakate esiletõstmiseks vahel. 18 ja 65 (roheline): =AND(DATEDIF($B2, TODAY(), "Y")>=18, DATEDIF($B2, TODAY(), "Y")<=65)
• Eakate esiletõstmiseks üle 65 (sinine): =DATEDIF($B2, TODAY(), "Y")>65

Et luua reegleid ülaltoodud valemite alusel, valige rakud või terved read, mida soovite esile tõsta, minge valikusse Kodu tab> Stiilid rühma ja klõpsake Tingimuslik vormindamine > Uus reegel... > Kasutage valemit, et määrata, millised lahtrid tuleb vormindada .

Üksikasjalikud sammud leiate siit: Kuidas teha valemil põhinev tingimuslik vormindamise reegel.

Nii arvutatakse Excelis vanust. Loodan, et need valemid olid teile hõlpsasti selgeks õppida ja te proovite neid oma töölehtedel. Tänan teid lugemise eest ja loodan, et näeme teid järgmisel nädalal meie blogis!

Saadaolevad allalaadimised

Exceli vanuse arvutamise näited (.xlsx fail)

Ultimate Suite 14-päevane täisfunktsionaalne versioon (.exe fail)