Ang tutorial ay nagpapakita ng iba't ibang paraan upang makakuha ng edad mula sa kaarawan sa Excel. Matututo ka ng ilang mga formula upang kalkulahin ang edad bilang isang bilang ng mga kumpletong taon, makakuha ng eksaktong edad sa mga taon, buwan at araw sa petsa ngayon o isang partikular na petsa.

Walang espesyal na function upang kalkulahin edad sa Excel, gayunpaman mayroong ilang iba't ibang paraan upang i-convert ang petsa ng kapanganakan sa edad. Ipapaliwanag ng tutorial na ito ang mga pakinabang at disbentaha ng bawat paraan, ipinapakita kung paano gumawa ng perpektong formula ng pagkalkula ng edad sa Excel at i-tweak ito para sa paglutas ng ilang partikular na gawain.

Paano kalkulahin ang edad mula sa petsa ng kapanganakan sa Excel

Sa pang-araw-araw na buhay, ang tanong na " Ilang taon ka na? " ay karaniwang nagpapahiwatig ng sagot na nagsasaad kung ilang taon ka nang nabubuhay. Sa Microsoft Excel, maaari kang gumawa ng pormula upang makalkula ang eksaktong edad sa mga buwan, araw, oras at kahit minuto. Ngunit maging tradisyonal tayo, at alamin kung paano kalkulahin ang edad mula sa DOB sa mga taon muna.

Basic Excel formula para sa edad sa mga taon

Paano mo karaniwang nalaman ang edad ng isang tao? Sa pamamagitan lamang ng pagbabawas ng petsa ng kapanganakan mula sa kasalukuyang petsa. Ang conventional age formula na ito ay maaari ding gamitin sa Excel.

Ipagpalagay na ang petsa ng kapanganakan ay nasa cell B2, ang formula para kalkulahin ang edad sa mga taon ay sumusunod:

=(TODAY()-B2)/365

Ang ibinabalik ng unang bahagi ng formula (TODAY()-B2) ang pagkakaiba sa pagitan ng kasalukuyang petsa at petsa ng kapanganakan ay mga araw, at pagkatapos ay hahatiin mo iyoncell reference o isang petsa sa mm/dd/yyyy na format.

Tapos na!

Ang formula ay ipinasok sa napiling cell saglit, at i-double click mo ang fill handle upang kopyahin ito pababa sa column.

Tulad ng maaaring napansin mo, ang formula na ginawa ng aming Excel age calculator ay mas kumplikado kaysa sa mga napag-usapan natin sa ngayon, ngunit ito ay tumutugon sa isahan at maramihan ng mga yunit ng oras gaya ng "araw" at "mga araw".

Kung gusto mong alisin ang mga zero unit tulad ng "0 araw", piliin ang check box na Huwag magpakita ng zero units :

Kung gusto mong subukan ang calculator ng edad na ito pati na rin ang pagtuklas ng 60 pang nakakatipid sa oras na add-in para sa Excel, maaari kang mag-download ng trial na bersyon ng aming Ultimate Suite sa pagtatapos ng ang post na ito.

Paano i-highlight ang ilang partikular na edad (sa ilalim o higit sa isang partikular na edad)

Sa ilang sitwasyon, maaaring kailanganin mong hindi lamang kalkulahin ang edad sa Excel, ngunit i-highlight din ang mga cell na naglalaman ng mga edad na wala pa o higit sa isang partikular na edad.

Kung ang iyong formula sa pagkalkula ng edad ibinabalik ang bilang ng mga kumpletong taon, pagkatapos ay maaari kang lumikha ng isang regular na tuntunin sa pag-format ng kondisyon batay sa isang simpleng formula tulad ng mga ito:

• Upang i-highlight ang mga edad na katumbas ng o higit pa sa18: =$C2>=18
• Upang i-highlight ang mga edad na wala pang 18: =$C2<18

Kung saan ang C2 ang pinakanangungunang cell sa column na Edad (hindi kasama ang header ng column).

Ngunit paano kung ang iyong formula ay nagpapakita ng edad sa mga taon at buwan, o sa mga taon, buwan at araw? Sa kasong ito, kakailanganin mong gumawa ng panuntunan batay sa isang DATEDIF formula na kinakalkula ang edad mula sa petsa ng kapanganakan sa mga taon.

Ipagpalagay na ang mga petsa ng kapanganakan ay nasa column B simula sa row 2, ang mga formula ay ang mga sumusunod:

• Upang i-highlight ang mga edad sa ilalim ng 18 (dilaw): =DATEDIF($B2, TODAY(),"Y")<18
• Upang i-highlight ang mga edad sa pagitan ng 18 at 65 (berde): =AND(DATEDIF($B2, TODAY(),"Y")>=18, DATEDIF($B2, TODAY(),"Y")<=65)
• Upang i-highlight ang mga edad higit sa 65 (asul): =DATEDIF($B2, TODAY(),"Y")>65

Upang gumawa ng mga panuntunan batay sa mga formula sa itaas, piliin ang mga cell o buong row na gusto mong i-highlight , pumunta sa tab na Home > Mga Estilo , at i-click ang Conditional Formatting > Bagong Panuntunan... > Gamitin isang formula upang matukoy kung aling mga cell ang ipo-format .

Matatagpuan dito ang mga detalyadong hakbang: Paano gumawa ng tuntunin sa pag-format ng kondisyon batay sa formula.

Ganito mo kinakalkula ang edad sa Excel. Sana naging madali para sa iyo na matutunan ang mga formula at susubukan mo ang mga ito sa iyong mga worksheet. Salamat sa pagbabasa at sana ay makita ka sa aming blog sa susunod na linggo!

Mga available na download

Mga halimbawa ng Excel Age Calculation (.xlsx file)

Ultimate Suite 14 na araw nang buo -functional na bersyon (.exe file)

Ang formula ay malinaw at madaling tandaan, gayunpaman, mayroong isang maliit na problema. Sa karamihan ng mga kaso, nagbabalik ito ng decimal na numero gaya ng ipinakita sa screenshot sa ibaba.

Upang ipakita ang bilang ng mga kumpletong taon, gamitin ang INT function upang i-round ang isang decimal hanggang sa pinakamalapit na integer:

=INT((TODAY()-B2)/365)

Mga Sagabal: Ang paggamit sa formula ng edad na ito sa Excel ay nagbubunga ng medyo tumpak na mga resulta, ngunit hindi walang kamali-mali. Ang paghahati sa average na bilang ng mga araw sa isang taon ay gumagana nang maayos sa halos lahat ng oras, ngunit kung minsan ay nagkakamali ito sa edad. Halimbawa, kung may ipinanganak noong Pebrero 29 at ngayon ay Pebrero 28, ang formula ay magpapatanda sa isang tao isang araw.

Bilang alternatibo, maaari mong hatiin sa 365.25 sa halip na 365 dahil bawat ikaapat na taon ay mayroong 366 araw. Gayunpaman, ang diskarte na ito ay hindi rin perpekto. Halimbawa, kung kinakalkula mo ang edad ng isang bata na hindi pa nabubuhay sa isang leap year, ang paghahati sa 365.25 ay magbubunga ng maling resulta.

Sa pangkalahatan, ang pagbabawas ng petsa ng kapanganakan mula sa kasalukuyang petsa ay gumagana nang mahusay sa normal na buhay, ngunit hindi ito ang perpektong diskarte sa Excel. Higit pa sa tutorial na ito, matututo ka ng ilang espesyal na function na walang kamaliang kinakalkula ang edad anuman ang taon.

Kalkulahin ang edad mula sa petsa ng kapanganakan gamit ang YEARFRAC function

Isang mas maaasahang paraan ng pag-convert DOB sa edad sa Excel ay gumagamit ng YEARFRAC function naibinabalik ang fraction ng taon, ibig sabihin, ang bilang ng buong araw sa pagitan ng dalawang petsa.

Ang syntax ng YEARFRAC function ay ang sumusunod:

The ang unang dalawang argumento ay halata at halos hindi nangangailangan ng anumang karagdagang paliwanag. Ang Basis ay isang opsyonal na argumento na tumutukoy sa batayan ng bilang ng araw na gagamitin.

Upang gumawa ng perpektong formula ng edad, ibigay ang mga sumusunod na value sa YEARFRAC function:

• Start_date - petsa ng kapanganakan.
• End_date - TODAY() function para ibalik ang petsa ngayon.
• Basis - gamitin ang batayan 1 na nagsasabi sa Excel na hatiin ang aktwal na bilang ng mga araw bawat buwan sa aktwal na bilang ng mga araw bawat taon.

Isinasaalang-alang ang nasa itaas, isang formula ng Excel upang kalkulahin ang edad mula sa petsa ng kapanganakan ay ang mga sumusunod:

Ipagpalagay na ang petsa ng kapanganakan ay nasa cell B2, ang formula ay may sumusunod na hugis:

=YEARFRAC(B2, TODAY(), 1)

Tulad sa nakaraang halimbawa, ang resulta ng YEARFRAC function ay isang decimal na numero din. Para ayusin ito, gamitin ang ROUNDDOWN function na may 0 sa huling argumento dahil ayaw mo ng anumang decimal na lugar.

Kaya, narito ang isang pinahusay na formula ng YEARFRAC para kalkulahin ang edad sa Excel:

=ROUNDDOWN(YEARFRAC(B2, TODAY(), 1), 0)

Kalkulahin ang edad sa Excel gamit ang DATEDIF

Isa pang paraan para i-convert ang petsa ng kapanganakan sa edad sa Excel ay ang paggamit ng DATEDIF function:

Maaaring ibalik ng function na ito ang pagkakaiba sa pagitan ng dalawang petsa sa iba't ibang unit ng oras gaya ng mga taon, buwan at araw, depende sa value na ibinibigay mo sa unit argument:

• Y - ibinabalik ang bilang ng kumpletong taon sa pagitan ng mga petsa ng pagsisimula at pagtatapos.
• M - ibinabalik ang bilang ng kumpletong buwan sa pagitan ang mga petsa.
• D - ibinabalik ang bilang ng araw sa pagitan ng dalawang petsa.
• YM - ibinabalik ang buwan , hindi pinapansin ang mga araw at taon.
• MD - ibinabalik ang pagkakaiba sa araw , binabalewala ang mga buwan at taon.
• YD - ibinabalik ang pagkakaiba sa araw , binabalewala ang mga taon.

Dahil nilalayon naming kalkulahin ang edad sa taon , ginagamit namin ang "y" unit:

Sa halimbawang ito, ang DOB ay nasa cell B2, at tinutukoy mo ang cell na ito sa iyong formula ng edad:

=DATEDIF(B2, TODAY(), "y")

Walang karagdagang function ng rounding ang kailangan sa kasong ito dahil ang isang DATEDIF formula na may t kinakalkula ng "y" unit ang bilang ng buong taon:

Paano makakuha ng edad mula sa kaarawan sa mga taon, buwan at araw

Gaya ng nakita mo , ang pagkalkula ng edad bilang ang bilang ng buong taon na nabuhay ang tao ay madali, ngunit hindi ito palaging sapat. Kung gusto mong malaman ang eksaktong edad, ibig sabihin, ilang taon, buwan at araw ang pagitan ng petsa ng kapanganakan ng isang tao at ng kasalukuyang petsa, isulat ang 3iba't ibang function ng DATEDIF:

1. Upang makuha ang bilang ng mga taon: =DATEDIF(B2, TODAY(), "Y")
2. Upang makuha ang bilang ng mga buwan: =DATEDIF(B2, TODAY(), "YM")
3. Upang makuha ang bilang ng mga araw: =DATEDIF(B2,TODAY(),"MD")

Kung saan ang B2 ay ang petsa ng kapanganakan.

At pagkatapos, pagsamahin ang mga function sa itaas sa isang formula, tulad nito:

=DATEDIF(B2,TODAY(),"Y") & DATEDIF(B2,TODAY(),"YM") & DATEDIF(B2,TODAY(),"MD")

Ang formula sa itaas ay nagbabalik ng 3 numero (mga taon, buwan, at araw) na pinagsama-sama sa iisang text string, tulad ng ipinapakita sa screenshot sa ibaba:

Hindi gaanong makatuwiran, uh ? Upang gawing mas makabuluhan ang mga resulta, paghiwalayin ang mga numero gamit ang mga kuwit at tukuyin kung ano ang ibig sabihin ng bawat value:

=DATEDIF(B2,TODAY(),"Y") & " Years, " & DATEDIF(B2,TODAY(),"YM") & " Months, " & DATEDIF(B2,TODAY(),"MD") & " Days"

Mukhang mas maganda ngayon ang resulta:

Mahusay na gumagana ang formula, ngunit mapapabuti mo pa ito sa pamamagitan ng pagtatago ng mga zero na halaga. Para dito, magdagdag ng 3 IF statement na tumitingin ng 0, isa sa bawat DATEDIF:

=IF(DATEDIF(B2, TODAY(),"y")=0,"",DATEDIF(B2, TODAY(),"y")&" years, ")& IF(DATEDIF(B2, TODAY(),"ym")=0,"",DATEDIF(B2, TODAY(),"ym")&" months, ")& IF(DATEDIF(B2, TODAY(),"md")=0,"",DATEDIF(B2, TODAY(),"md")&" days")

Ipinapakita ng sumusunod na screenshot ang panghuling formula ng edad ng Excel sa pagkilos - ibinabalik nito ang edad sa mga taon, buwan, at mga araw, ipinapakita lang ang non-zero na mga value:

Tip. Kung naghahanap ka ng formula ng Excel para kalkulahin ang edad sa mga taon at buwan , kunin ang formula sa itaas at alisin ang huling IF(DATEDIF()) block na kumukwenta ng mga araw.

Mga partikular na formula sa kalkulahin ang edad sa Excel

Ang mga generic na formula ng pagkalkula ng edad na tinalakay sa itaas ay mahusay sa karamihan ng mga kaso. Sa ilang mga sitwasyon, gayunpaman, maaaring kailangan mo ng isang bagay na napaka-espesipiko. Siyempre, hindi posible na masakop ang bawat isaat bawat senaryo, ngunit ang mga sumusunod na halimbawa ay magbibigay sa iyo ng ilang ideya kung paano ka makakapag-tweak ng formula ng edad depende sa iyong partikular na gawain.

Paano kalkulahin ang edad sa isang partikular na petsa sa Excel

Kung gusto mong malaman ang edad ng isang tao sa isang partikular na petsa, gamitin ang DATEDIF age formula na tinalakay sa itaas, ngunit palitan ang TODAY() function sa 2nd argument ng partikular na petsa.

Ipagpalagay na ang petsa ng kapanganakan ay nasa B1, ang ang sumusunod na formula ay magbabalik ng edad simula Enero 1, 2020:

=DATEDIF(B1, "1/1/2020","Y") & " Years, " & DATEDIF(B1, "1/1/2020","YM") & " Months, " & DATEDIF(B1, "1/1/2020", "MD") & " Days"

Upang gawing mas flexible ang formula ng iyong edad, maaari mong ipasok ang petsa sa ilang cell at i-reference ang cell na iyon sa iyong formula:

=DATEDIF(B1, B2,"Y") & " Years, "& DATEDIF(B1,B2,"YM") & " Months, "&DATEDIF(B1,B2, "MD") & " Days"

Kung saan ang B1 ay ang DOB, at ang B2 ay ang petsa kung saan mo gustong kalkulahin ang edad.

Kalkulahin ang edad sa isang partikular na taon

Magagamit ang formula na ito sa mga sitwasyon kung kailan hindi tinukoy ang kumpletong petsa ng pagkalkula, at taon lang ang alam mo.

Ipagpalagay nating nagtatrabaho ka sa isang medikal na database, at ang iyong layunin ay upang malaman ang edad ng mga pasyente sa oras na sila ay nasa ilalim pumunta sa huling buong medikal na pagsusuri.

Ipagpalagay na ang mga petsa ng kapanganakan ay nasa column B simula sa row 3, at ang taon ng huling medikal na pagsusuri ay nasa column C, ang formula ng pagkalkula ng edad ay napupunta sa sumusunod:

=DATEDIF(B3,DATE(C3, 1, 1),"y")

Dahil hindi tinukoy ang eksaktong petsa ng medikal na eksaminasyon, ginagamit mo ang function na DATE na may arbitrary na argumento ng petsa at buwan, hal. DATE(C3, 1, 1).

AngKinukuha ng function ng DATE ang taon mula sa cell B3, gumagawa ng kumpletong petsa gamit ang mga numero ng buwan at araw na iyong ibinigay (1-Ene sa halimbawang ito), at ipinapasa ang petsang iyon sa DATEDIF. Bilang resulta, makukuha mo ang edad ng pasyente simula Enero 1 ng isang partikular na taon:

Alamin ang petsa kung kailan umabot ang isang tao ng N taong gulang

Ipagpalagay na ang iyong kaibigan ay ipinanganak noong ika-8 ng Marso 1978. Paano mo malalaman kung anong petsa siya nakumpleto ang kanyang 50 taong gulang? Karaniwan, magdadagdag ka lang ng 50 taon sa petsa ng kapanganakan ng tao. Sa Excel, ganoon din ang ginagawa mo gamit ang DATE function:

=DATE(YEAR(B2) + 50, MONTH(B2), DAY(B2))

Kung saan ang B2 ay ang petsa ng kapanganakan.

Sa halip na hard-coding ang bilang ng mga taon sa formula, maaari kang sumangguni sa isang partikular na cell kung saan maaaring mag-input ang iyong mga user ng anumang bilang ng mga taon (F1 sa screenshot sa ibaba):

Kalkulahin ang edad mula sa araw, buwan at taon sa magkaibang mga cell

Kapag ang petsa ng kapanganakan ay nahati sa 3 magkaibang mga cell (hal. taon ay nasa B3, buwan sa C3 at araw sa D3), maaari mong kalkulahin ang edad sa ganitong paraan:

• Kunin ang petsa ng kapanganakan sa pamamagitan ng paggamit ng DATE at DATEVALUE function:

  DATE(B3,MONTH(DATEVALUE(C3&"1")),D3)

• I-embed ang formula sa itaas sa DATEDIF upang kalkulahin ang edad mula sa petsa ng kapanganakan sa mga taon, buwan, at araw: =DATEDIF(DATE(B3, MONTH(DATEVALUE(C3&"1")), D3), TODAY(), "y") & " Years, "& DATEDIF(DATE(B3, MONTH(DATEVALUE(C3&"1")), D3),TODAY(), "ym") & " Months, "& DATEDIF(DATE(B3, MONTH(DATEVALUE(C3&"1")), D3), TODAY(), "md") & " Days"

  

Para sa higit pang mga halimbawa ng pagkalkula ng bilang ng mga araw bago/pagkatapos ng isang petsa, pakitingnan ang Paano kalkulahin ang mga araw mula o hanggang petsa sa Excel.

Edad calculator sa Excel

Kung gusto mong magkaroon ng sarili mocalculator ng edad sa Excel, maaari kang gumawa ng isa sa pamamagitan ng paggamit ng ilang iba't ibang mga formula ng DATEDIF na ipinaliwanag sa ibaba. Kung mas gugustuhin mong hindi muling likhain ang gulong, maaari mong gamitin ang calculator ng edad na ginawa ng aming mga propesyonal sa Excel.

Paano gumawa ng calculator ng edad sa Excel

Ngayong alam mo na kung paano gumawa ng age formula sa Excel, maaari kang bumuo ng custom na calculator ng edad, halimbawa ang isang ito:

Tandaan. Upang tingnan ang naka-embed na workbook, mangyaring payagan ang cookies sa marketing.

Ang nakikita mo sa itaas ay isang naka-embed na Excel Online sheet, kaya huwag mag-atubiling ilagay ang iyong petsa ng kapanganakan sa kaukulang cell, at makukuha mo ang iyong edad sa isang sandali.

Ginagamit ng calculator ang mga sumusunod na formula upang kalkulahin ang edad batay sa petsa ng kapanganakan sa cell A3 at petsa ngayon.

• Kinakalkula ng formula sa B5 ang edad sa mga taon, buwan, at araw: =DATEDIF(B2,TODAY(),"Y") & " Years, " & DATEDIF(B2,TODAY(),"YM") & " Months, " & DATEDIF(B2,TODAY(),"MD") & " Days"
• Kinakalkula ng Formula sa B6 ang edad sa mga buwan: =DATEDIF($B$3,TODAY(),"m")
• Kinakalkula ng Formula sa B7 ang edad sa mga araw: =DATEDIF($B$3,TODAY(),"d")

Kung mayroon kang karanasan sa mga kontrol ng Excel Form, maaari kang magdagdag ng opsyon upang makalkula ang edad sa isang partikular na petsa, tulad ng ipinapakita sa sumusunod na screenshot:

Para dito, magdagdag ng ilang button ng opsyon ( Tab ng developer > Ipasok > Mga kontrol sa form > Option Button ), at i-link ang mga ito sa ilang cell. At pagkatapos, magsulat ng IF/DATEDIF formula para makakuha ng edad sa petsa ngayon o sa petsang tinukoy ng user.

Gumagana ang formula sa sumusunodlogic:

• Kung pinili ang Petsa ngayong araw na kahon ng opsyon, lalabas ang value 1 sa naka-link na cell (I5 sa halimbawang ito), at ang formula ng edad ay kinakalkula batay sa petsa ng araw : IF($I$5=1, DATEDIF($B$3,TODAY(),"Y") & " Years, " & DATEDIF($B$3,TODAY(), "YM") & " Months, " & DATEDIF($B$3, TODAY(), "MD") & " Days")
• Kung pinili ang button na opsyon na Tiyak na petsa AT may ipinasok na petsa sa cell B7, kinakalkula ang edad sa tinukoy na petsa: IF(ISNUMBER($B$7), DATEDIF($B$3, $B$7,"Y") & " Years, " & DATEDIF($B$3, $B$7,"YM") & " Months, " & DATEDIF($B$3, $B$7,"MD") & " Days", ""))

Sa wakas , ilagay ang mga function sa itaas sa isa't isa, at makukuha mo ang kumpletong formula ng pagkalkula ng edad (sa B9):

=IF($I$5=1, DATEDIF($B$3, TODAY(), "Y") & " Years, " & DATEDIF($B$3, TODAY(), "YM") & " Months, " & DATEDIF($B$3, TODAY(), "MD") & " Days", IF(ISNUMBER($B$7), DATEDIF($B$3, $B$7,"Y") & " Years, " & DATEDIF($B$3, $B$7,"YM") & " Months, " & DATEDIF($B$3, $B$7,"MD") & " Days", ""))

Ang mga formula sa B10 at B11 ay gumagana sa parehong lohika. Siyempre, mas simple ang mga ito dahil may kasama lang silang isang function na DATEDIF para ibalik ang edad bilang bilang ng mga kumpletong buwan o araw, ayon sa pagkakabanggit.

Upang matutunan ang mga detalye, iniimbitahan kitang i-download itong Excel Age Calculator at imbestigahan ang mga formula sa mga cell B9:B11.

I-download ang Age Calculator para sa Excel

Handa nang gamitin na calculator ng edad para sa Excel

Ang mga user ng aming Ultimate Suite ay walang para mag-abala tungkol sa paggawa ng sarili nilang calculator ng edad sa Excel - ilang pag-click lang ang layo:

1. Pumili ng cell kung saan mo gustong maglagay ng formula ng edad, pumunta sa Ablebits Tools tab > Petsa & Oras pangkat, at i-click ang Petsa & Button ng Time Wizard .

   

2. Ang Petsa & Magsisimula ang Time Wizard, at direktang pupunta ka sa tab na Edad .
3. Sa tab na Edad , mayroong 3 bagay na dapat mong tukuyin:
   • Data ng kapanganakan bilang a