De handleiding toont verschillende manieren om leeftijd te berekenen uit de verjaardag in Excel. U leert een handvol formules om leeftijd te berekenen als een aantal volledige jaren, de exacte leeftijd in jaren, maanden en dagen op de datum van vandaag of een bepaalde datum.

Er is geen speciale functie om de leeftijd te berekenen in Excel, maar er bestaan wel een paar verschillende manieren om de geboortedatum om te rekenen naar leeftijd. Deze handleiding legt de voor- en nadelen van elke manier uit, laat zien hoe u een perfecte leeftijdsberekeningsformule in Excel kunt maken en deze kunt aanpassen voor het oplossen van enkele specifieke taken.

Hoe de leeftijd berekenen uit de geboortedatum in Excel

In het dagelijks leven is de vraag " Hoe oud ben je? "In Microsoft Excel kunt u een formule maken om een exacte leeftijd te berekenen in maanden, dagen, uren en zelfs minuten. Maar laten we traditioneel zijn, en eerst leren hoe u de leeftijd van uw DOB in jaren berekent.

Basis Excel-formule voor leeftijd in jaren

Hoe kom je normaal gesproken achter iemands leeftijd? Gewoon door de geboortedatum af te trekken van de huidige datum. Deze conventionele leeftijdsformule kan ook in Excel worden gebruikt.

Ervan uitgaande dat een geboortedatum in cel B2 staat, gaat de formule om de leeftijd in jaren te berekenen als volgt:

=(VANDAAG()-B2)/365

Het eerste deel van de formule (TODAY()-B2) geeft het verschil tussen de huidige datum en de geboortedatum in dagen, en dan deel je dat getal door 365 om het aantal jaren te krijgen.

De formule is duidelijk en gemakkelijk te onthouden, maar er is een klein probleem. In de meeste gevallen levert het een decimaal getal op, zoals in de schermafbeelding hieronder.

Om het aantal volledige jaren weer te geven, gebruikt u de functie INT om een decimaal naar beneden af te ronden op het dichtstbijzijnde gehele getal:

=INT((VANDAAG()-B2)/365)

Nadelen: Deze leeftijdsformule in Excel geeft vrij nauwkeurige resultaten, maar niet foutloos. Delen door het gemiddelde aantal dagen in een jaar werkt meestal prima, maar soms wordt de leeftijd verkeerd weergegeven. Als iemand bijvoorbeeld op 29 februari is geboren en vandaag is het 28 februari, dan maakt de formule iemand één dag ouder.

Als alternatief kunt u delen door 365,25 in plaats van 365, omdat elk vierde jaar 366 dagen heeft. Deze aanpak is echter ook niet perfect. Als u bijvoorbeeld de leeftijd berekent van een kind dat nog geen schrikkeljaar heeft meegemaakt, levert delen door 365,25 een verkeerd resultaat op.

Het aftrekken van de geboortedatum van de huidige datum werkt prima in het normale leven, maar is niet de ideale aanpak in Excel. Verderop in deze tutorial leert u een paar speciale functies die de leeftijd feilloos berekenen, ongeacht het jaar.

Bereken leeftijd uit geboortedatum met de functie YEARFRAC

Een meer betrouwbare manier om DOB om te zetten in leeftijd in Excel is het gebruik van de functie YEARFRAC, die de fractie van het jaar geeft, d.w.z. het aantal hele dagen tussen twee datums.

De syntaxis van de functie YEARFRAC is als volgt:

De eerste twee argumenten liggen voor de hand en behoeven nauwelijks nadere uitleg. Basis is een optioneel argument dat de te gebruiken dagtellingsbasis bepaalt.

Om een perfecte leeftijdsformule te maken, geeft u de volgende waarden aan de functie YEARFRAC:

• Begin_datum - geboortedatum.
• Einddatum - TODAY() functie om de datum van vandaag terug te geven.
• Basis - gebruiksbasis 1 die Excel vertelt het werkelijke aantal dagen per maand te delen door het werkelijke aantal dagen per jaar.

Gezien het bovenstaande is een Excel-formule om de leeftijd uit de geboortedatum te berekenen als volgt:

Ervan uitgaande dat de geboortedatum in cel B2 staat, krijgt de formule de volgende vorm:

=YEARFRAC(B2, TODAY(), 1)

Zoals in het vorige voorbeeld is het resultaat van de functie YEARFRAC ook een decimaal getal. Om dit op te lossen gebruikt u de functie ROUNDDOWN met 0 in het laatste argument omdat u geen decimalen wilt.

Dus, hier is een verbeterde YEARFRAC formule om leeftijd te berekenen in Excel:

=ROUNDDOWN(YEARFRAC(B2, TODAY(), 1), 0)

Leeftijd berekenen in Excel met DATEDIF

Een andere manier om geboortedatum om te zetten in leeftijd in Excel is met behulp van de functie DATEDIF:

Deze functie kan het verschil tussen twee datums teruggeven in verschillende tijdseenheden zoals jaren, maanden en dagen, afhankelijk van de waarde die u opgeeft in de eenheid argument:

• Y - geeft het aantal volledige jaren tussen de begin- en einddatum.
• M - geeft het aantal volledige maanden tussen de data.
• D - geeft het aantal dagen tussen de twee data.
• YM - keert terug maanden en negeert dagen en jaren.
• MD - geeft het verschil in dagen en negeert maanden en jaren.
• YD - geeft het verschil in dagen , het negeren van jaren.

Aangezien wij streven naar de berekening van leeftijd in jaren gebruiken we de "y" eenheid:

In dit voorbeeld staat de DOB in cel B2, en u verwijst naar deze cel in uw leeftijdsformule:

=DATEDIF(B2, TODAY(), "y")

In dit geval is geen extra afrondingsfunctie nodig omdat een DATEDIF-formule met de eenheid "y" het aantal volledige jaren berekent:

Hoe krijg je de leeftijd van je verjaardag in jaren, maanden en dagen?

Zoals u zojuist hebt gezien, is het berekenen van de leeftijd als het aantal volle jaren dat de persoon heeft geleefd eenvoudig, maar niet altijd voldoende. Als u de exacte leeftijd wilt weten, d.w.z. hoeveel jaren, maanden en dagen er liggen tussen iemands geboortedatum en de huidige datum, schrijft u 3 verschillende DATEDIF-functies:

1. Om het aantal jaren te krijgen: =DATEDIF(B2, TODAY(), "Y")
2. Om het aantal maanden te krijgen: =DATEDIF(B2, TODAY(), "YM")
3. Om het aantal dagen te krijgen: =DATEDIF(B2,TODAY(),"MD")

Waarbij B2 de geboortedatum is.

En voeg dan de bovenstaande functies samen in één formule, zoals dit:

=DATEDIF(B2,TODAY(),"Y") & DATEDIF(B2,TODAY(),"YM") & DATEDIF(B2,TODAY(),"MD")

De bovenstaande formule geeft 3 getallen (jaren, maanden en dagen) samengevoegd in een enkele tekststring, zoals in de onderstaande schermafbeelding:

Heeft niet veel zin, hè? Om de resultaten zinvoller te maken, scheidt u de getallen met komma's en definieert u wat elke waarde betekent:

=DATEDIF(B2,TODAY(),"Y") & " Jaren, " & DATEDIF(B2,TODAY(),"YM") & " Maanden, " & DATEDIF(B2,TODAY(),"MD") & " Dagen".

Het resultaat ziet er nu veel beter uit:

De formule werkt prima, maar u kunt hem nog verbeteren door nulwaarden te verbergen. Voeg daarvoor 3 IF statements toe die controleren op 0's, één per elke DATEDIF:

=IF(DATEDIF(B2, TODAY(),"y")=0,"",DATEDIF(B2, TODAY(),"y")&" jaren, ")& IF(DATEDIF(B2, TODAY(),"ym")=0,"",DATEDIF(B2, TODAY(),"ym")&" maanden, ")& IF(DATEDIF(B2, TODAY(),"md")=0,"",DATEDIF(B2, TODAY(),"md")&" dagen")

De volgende schermafbeelding toont de uiteindelijke Excel-leeftijdsformule in actie - deze geeft de leeftijd in jaren, maanden en dagen, met alleen de volgende weergave niet-nul waarden:

Tip. Als u op zoek bent naar een Excel formule om de leeftijd te berekenen in jaren en maanden Neem de bovenstaande formule en verwijder het laatste IF(DATEDIF()) blok dat dagen berekent.

Specifieke formules om leeftijd te berekenen in Excel

De hierboven besproken algemene leeftijdsberekeningsformules werken in de meeste gevallen goed. In sommige situaties hebt u echter iets heel specifieks nodig. Natuurlijk is het niet mogelijk om elk scenario te behandelen, maar de volgende voorbeelden geven u enkele ideeën over hoe u een leeftijdsformule kunt aanpassen aan uw specifieke taak.

Hoe leeftijd op een specifieke datum berekenen in Excel

Als u iemands leeftijd op een bepaalde datum wilt weten, gebruikt u de hierboven besproken formule DATEDIF age, maar vervangt u de functie TODAY() in het 2e argument door de specifieke datum.

Ervan uitgaande dat de geboortedatum in B1 ligt, geeft de volgende formule de leeftijd per 1 januari 2020:

=DATEDIF(B1, "1/1/2020","Y") & " Jaren, " & DATEDIF(B1, "1/1/2020","YM") & " Maanden, " & DATEDIF(B1, "1/1/2020", "MD") & " Dagen".

Om uw leeftijdsformule flexibeler te maken, kunt u de datum invoeren in een cel en naar die cel verwijzen in uw formule:

=DATEDIF(B1, B2,"Y") & " Jaren, "& DATEDIF(B1,B2,"YM") & " Maanden, "&DATEDIF(B1,B2,"MD") & " Dagen"

Waarbij B1 de DOB is, en B2 de datum waarop u de leeftijd wilt berekenen.

Bereken de leeftijd in een bepaald jaar

Deze formule komt van pas in situaties waarin de volledige datum waarop moet worden gerekend niet is gedefinieerd, en u alleen het jaartal kent.

Stel, u werkt met een medische database, en uw doel is de leeftijd van de patiënten te achterhalen op het moment dat zij het laatste volledige medische onderzoek ondergingen.

Ervan uitgaande dat de geboortedata in kolom B staan, te beginnen met rij 3, en het jaar van het laatste medisch onderzoek in kolom C, gaat de formule voor het berekenen van de leeftijd als volgt:

=DATEDIF(B3,DATE(C3, 1, 1),"y")

Omdat de exacte datum van het medisch onderzoek niet gedefinieerd is, gebruikt u de functie DATUM met een willekeurig datum- en maandargument, bijvoorbeeld DATUM(C3, 1, 1).

De functie DATUM haalt het jaar uit cel B3, maakt een volledige datum met behulp van de maand- en dagnummers die u hebt opgegeven (1-Jan in dit voorbeeld), en geeft die datum door aan DATEDIF. Als resultaat krijgt u de leeftijd van de patiënt per 1 januari van een bepaald jaar:

Zoek een datum waarop een persoon N jaar wordt.

Stel dat uw vriend is geboren op 8 maart 1978. Hoe weet u dan op welke datum hij 50 jaar wordt? Gewoonlijk telt u gewoon 50 jaar op bij de geboortedatum van de persoon. In Excel doet u hetzelfde met de functie DATUM:

=DATUM(JAAR(B2) + 50, MAAND(B2), DAG(B2))

Waarbij B2 de geboortedatum is.

In plaats van het aantal jaren vast te leggen in de formule, kunt u verwijzen naar een bepaalde cel waar uw gebruikers een willekeurig aantal jaren kunnen invoeren (F1 in de onderstaande schermafbeelding):

Bereken leeftijd uit dag, maand en jaar in verschillende cellen

Wanneer een geboortedatum is opgesplitst in 3 verschillende cellen (bv. jaar staat in B3, maand in C3 en dag in D3), kunt u de leeftijd op deze manier berekenen:

• Verkrijg de geboortedatum met behulp van de functies DATE en DATEVALUE:

  DATE(B3,MONTH(DATEVALUE(C3&"1")),D3)

• Neem de bovenstaande formule op in DATEDIF om de leeftijd te berekenen op basis van de geboortedatum in jaren, maanden en dagen: =DATEDIF(DATE(B3, MONTH(DATEVALUE(C3&"1")), D3), TODAY(), "y") & " Jaren, "& DATEDIF(DATE(B3, MONTH(DATEVALUE(C3&"1")), D3),TODAY(), "ym") & " Maanden, "& DATEDIF(DATE(B3, MONTH(DATEVALUE(C3&"1")), D3), TODAY(), "md") & " Dagen".

  

Voor meer voorbeelden van het berekenen van het aantal dagen voor/na een datum, zie Hoe dagen sinds of tot datum berekenen in Excel.

Leeftijdsberekening in Excel

Als u uw eigen leeftijdsberekening in Excel wilt hebben, kunt u er een maken met behulp van een paar verschillende DATEDIF-formules die hieronder worden uitgelegd. Als u het wiel liever niet opnieuw uitvindt, kunt u de leeftijdsberekening gebruiken die onze Excel-professionals hebben gemaakt.

Hoe maak je een leeftijdsberekening in Excel

Nu u weet hoe u een leeftijdsformule in Excel maakt, kunt u een aangepaste leeftijdsberekening maken, bijvoorbeeld deze:

Opmerking: om de ingesloten werkmap te bekijken, moet u marketingcookies toestaan.

Wat je hierboven ziet is een ingebed Excel Online blad, dus voel je vrij om je geboortedatum in te voeren in de overeenkomstige cel, en je krijgt zo je leeftijd.

De rekenmachine gebruikt de volgende formules om de leeftijd te berekenen op basis van de geboortedatum in cel A3 en de datum van vandaag.

• De formule in B5 berekent de leeftijd in jaren, maanden en dagen: =DATEDIF(B2,TODAY(),"Y") & " Jaren, " & DATEDIF(B2,TODAY(),"YM") & " Maanden, " & DATEDIF(B2,TODAY(),"MD") & " Dagen".
• De formule in B6 berekent de leeftijd in maanden: =DATEDIF($B$3,TODAY(),"m")
• De formule in B7 berekent de leeftijd in dagen: =DATEDIF($B$3,TODAY(),"d")

Als u enige ervaring heeft met Excel Formulier besturingselementen, kunt u een optie toevoegen om de leeftijd op een specifieke datum te berekenen, zoals in de volgende schermafbeelding:

Voeg hiervoor een paar optieknoppen toe ( Tabblad Ontwikkelaar > Plaats > Formulier controles > Optie knop ), en koppel ze aan een cel. En schrijf dan een IF/DATEDIF-formule om de leeftijd te krijgen op de datum van vandaag of op de door de gebruiker opgegeven datum.

De formule werkt met de volgende logica:

• Als de De datum van vandaag optievak is geselecteerd, verschijnt waarde 1 in de gekoppelde cel (I5 in dit voorbeeld), en berekent de leeftijdsformule op basis van de datum van vandaag: IF($I$5=1, DATEDIF($B$3,TODAY(),"Y") & " Jaren, " & DATEDIF($B$3,TODAY(), "YM") & " Maanden, " & DATEDIF($B$3, TODAY(), "MD") & " Dagen")
• Als de Specifieke datum optieknop is geselecteerd EN een datum is ingevoerd in cel B7, wordt de leeftijd berekend op de gespecificeerde datum: IF(ISNUMBER($B$7), DATEDIF($B$3, $B$7,"Y") & " Jaren, " & DATEDIF($B$3, $B$7,"YM") & " Maanden, " & DATEDIF($B$3, $B$7,"MD") & " Dagen", ""))

Tenslotte nestelt u de bovenstaande functies in elkaar, en u krijgt de volledige formule voor het berekenen van de leeftijd (in B9):

=IF($I$5=1, DATEDIF($B$3, TODAY(), "Y") & " Jaren, " & DATEDIF($B$3, TODAY(), "YM") & " Maanden, " & DATEDIF($B$3, TODAY(), "MD") & " Dagen", IF(ISNUMBER($B$7), DATEDIF($B$3, $B$7,"Y") & " Jaren, " & DATEDIF($B$3, $B$7,"YM") & " Maanden, " & DATEDIF($B$3, $B$7,"MD") & " Dagen", "").

De formules in B10 en B11 werken met dezelfde logica. Natuurlijk zijn ze veel eenvoudiger omdat ze slechts één DATEDIF-functie bevatten om de leeftijd terug te geven als het aantal volledige maanden, respectievelijk dagen.

Om de details te leren kennen, nodig ik u uit deze Excel Leeftijdsberekening te downloaden en de formules in de cellen B9:B11 te onderzoeken.

Download Leeftijdsberekening voor Excel

Gebruiksklare leeftijdsberekening voor Excel

De gebruikers van onze Ultimate Suite hoeven geen moeite te doen om hun eigen leeftijdsberekening in Excel te maken - het is slechts een paar klikken verwijderd:

1. Selecteer een cel waar u een leeftijdsformule wilt invoegen, ga naar de Ablebits Gereedschap tab> Datum en tijd groep, en klik op de Datum & Tijd Wizard knop.

   

2. De Date & Time Wizard start, en u gaat direct naar de Leeftijd tab.
3. Op de Leeftijd tabblad, er zijn 3 dingen voor u om te specificeren:
   • Geboortegegevens als een celverwijzing of een datum in de notatie mm/dd/jjjj.
   • Leeftijd bij de datum van vandaag of specifieke datum .
   • Kies of u de leeftijd wilt berekenen in dagen, maanden, jaren, of de exacte leeftijd.
4. Klik op de Formule invoegen knop.

Klaar!

De formule wordt even ingevoegd in de geselecteerde cel, en u dubbelklikt op de vulgreep om deze naar beneden in de kolom te kopiëren.

Zoals u wellicht hebt gemerkt, is de formule van onze Excel-leeftijdscalculator complexer dan de formules die we tot nu toe hebben besproken, maar ze is geschikt voor enkelvoud en meervoud van tijdseenheden zoals "dag" en "dagen".

Als u nul eenheden zoals "0 dagen" wilt weglaten, selecteert u de optie Niet doen. toon nul eenheden check box:

Als u nieuwsgierig bent naar deze leeftijdscalculator en naar 60 andere tijdbesparende add-ins voor Excel, kunt u aan het eind van dit bericht een proefversie van onze Ultimate Suite downloaden.

Hoe bepaalde leeftijden te markeren (onder of boven een bepaalde leeftijd)

In sommige situaties moet u niet alleen de leeftijd in Excel berekenen, maar ook cellen markeren die leeftijden bevatten die onder of boven een bepaalde leeftijd liggen.

Als uw formule voor het berekenen van de leeftijd het aantal volledige jaren oplevert, dan kunt u een gewone regel voor voorwaardelijke opmaak maken op basis van een eenvoudige formule zoals deze:

• Om leeftijden gelijk aan of groter dan 18 jaar te markeren: =$C2>=18
• Om de leeftijd onder 18 jaar te benadrukken: =$C2<18

Waarbij C2 de bovenste cel in de kolom Leeftijd is (de kolomkop niet meegerekend).

Maar wat als uw formule de leeftijd weergeeft in jaren en maanden, of in jaren, maanden en dagen? In dat geval moet u een regel maken op basis van een DATEDIF-formule die de leeftijd berekent op basis van de geboortedatum in jaren.

Stel dat de geboortedata in kolom B staan, beginnend met rij 2, dan zijn de formules als volgt:

• Leeftijden markeren onder 18 (geel): =DATEDIF($B2, TODAY(),"Y")<18
• Leeftijden markeren tussen 18 en 65 (groen): =AND(DATEDIF($B2, TODAY(),"Y")>=18, DATEDIF($B2, TODAY(),"Y")<=65)
• Leeftijden markeren over 65 (blauw): =DATEDIF($B2, TODAY(),"Y")>65

Om regels te maken op basis van bovenstaande formules, selecteert u de cellen of hele rijen die u wilt markeren, gaat u naar het menu Home tab> Styles groep, en klik op Voorwaardelijke opmaak > Nieuwe regel... > Gebruik een formule om te bepalen welke cellen moeten worden opgemaakt .

De gedetailleerde stappen vindt u hier: Hoe maak je een voorwaardelijke opmaakregel op basis van een formule?

Dit is hoe je leeftijd berekent in Excel. Ik hoop dat de formules gemakkelijk te leren waren voor je en dat je ze gaat uitproberen in je werkbladen. Bedankt voor het lezen en hopelijk tot volgende week op onze blog!

Beschikbare downloads

Excel Leeftijdsberekening voorbeelden (.xlsx bestand)

Ultimate Suite 14 dagen volledig functionele versie (.exe bestand)