Vodič pokazuje različite načine da dobijete starost od rođendana u Excelu. Naučit ćete pregršt formula za izračunavanje starosti kao broja punih godina, dobiti tačnu starost u godinama, mjesecima i danima na današnji datum ili određeni datum.

Ne postoji posebna funkcija za izračunavanje starost u Excelu, međutim, postoji nekoliko različitih načina za pretvaranje datuma rođenja u godine. Ovaj vodič će objasniti prednosti i nedostatke svakog načina, pokazati kako napraviti savršenu formulu za izračunavanje starosti u Excelu i podesiti je za rješavanje nekih specifičnih zadataka.

Kako izračunati starost od datuma rođenja u Excelu

U svakodnevnom životu, pitanje " Koliko imaš godina? " obično podrazumijeva odgovor koji pokazuje koliko si godina živi. U programu Microsoft Excel možete napraviti formulu za izračunavanje tačne starosti u mjesecima, danima, satima, pa čak i minutama. Ali budimo tradicionalni i prvo naučimo kako izračunati starost iz DOB-a u godinama.

Osnovna Excel formula za starost u godinama

Kako obično izračunati nečiju dob? Jednostavno oduzimanjem datuma rođenja od trenutnog datuma. Ova konvencionalna formula starosti se također može koristiti u Excelu.

Pod pretpostavkom da je datum rođenja u ćeliji B2, formula za izračunavanje starosti u godinama glasi kako slijedi:

=(TODAY()-B2)/365

prvi dio formule (TODAY()-B2) vraća razliku između trenutnog datuma i datuma rođenja su dani, a zatim to podijelitereferenca ćelije ili datum u formatu mm/dd/gggg.

Gotovo!

Formula se trenutno ubacuje u odabranu ćeliju, a vi dvaput kliknite na ručicu za popunjavanje da biste je kopirali niz kolonu.

Kao što ste možda primijetili, formula koju je kreirao naš Excel kalkulator starosti je složenija od onih o kojima smo do sada raspravljali, ali se brine za jednine i množinu vremenskih jedinica kao što su "dan" i "dani".

Ako se želite riješiti nula jedinica kao što je "0 dana", potvrdite okvir Ne prikaži nula jedinica :

Ako ste radoznali da testirate ovaj kalkulator starosti, kao i da otkrijete još 60 dodataka za Excel koji štede vrijeme, dobrodošli ste da preuzmete probnu verziju našeg Ultimate Suite-a na kraju ovaj post.

Kako istaknuti određene dobi (ispod ili više od a određena dob)

U nekim situacijama možda ćete morati ne samo izračunati dob u Excelu, već i istaknuti ćelije koje sadrže uzrast ispod ili više od određene dobi.

Ako vaša formula za izračunavanje starosti vraća broj punih godina, tada možete kreirati redovno pravilo uslovnog oblikovanja na osnovu jednostavne formule poput ovih:

• Da biste istakli starosti jednake ili veće od18: =$C2>=18
• Da biste istakli uzrast ispod 18 godina: =$C2<18

Gdje je C2 najviša ćelija u stupcu Dob (ne uključujući zaglavlje stupca).

Ali šta ako vaša formula prikazuje starost u godinama i mjesecima, ili u godinama, mjesecima i danima? U ovom slučaju, morat ćete kreirati pravilo zasnovano na formuli DATEDIF koja računa starost od datuma rođenja u godinama.

Pretpostavimo da su datumi rođenja u koloni B koji počinje sa redom 2, formule su sljedeće:

• Da biste istakli uzrast ispod 18 (žuto): =DATEDIF($B2, TODAY(),"Y")<18
• Da biste istakli uzrast između 18 i 65 godina (zeleno): =AND(DATEDIF($B2, TODAY(),"Y")>=18, DATEDIF($B2, TODAY(),"Y")<=65)
• Da biste istakli uzrast preko 65 (plavo): =DATEDIF($B2, TODAY(),"Y")>65

Da biste kreirali pravila na osnovu gornjih formula, izaberite ćelije ili čitave redove koje želite da istaknete , idite na karticu Početna grupa > Stilovi i kliknite na Uslovno oblikovanje > Novo pravilo… > Koristi formulu za određivanje koje ćelije treba formatirati .

Detaljne korake možete pronaći ovdje: Kako napraviti pravilo uvjetnog oblikovanja na osnovu formule.

Ovako izračunavate starost u Excel-u. Nadam se da su vam formule bile lake za učenje i da ćete ih isprobati u svojim radnim listovima. Hvala vam što čitate i nadamo se da se vidimo na našem blogu sljedeće sedmice!

Dostupna preuzimanja

Primjeri izračunavanja starosti u Excelu (.xlsx datoteka)

Ultimate Suite 14 dana u potpunosti -funkcionalna verzija (.exe fajl)

Formula je očigledna i lako pamtljiva, međutim, postoji mali problem. U većini slučajeva vraća decimalni broj kao što je prikazano na snimku ekrana ispod.

Da biste prikazali broj kompletnih godina, koristite funkciju INT da zaokružite decimalni naniže na najbliži cijeli broj:

=INT((TODAY()-B2)/365)

Nedostaci: Upotreba ove formule starosti u Excelu daje prilično točne rezultate, ali ne i besprijekorne. Podjela sa prosječnim brojem dana u godini funkcionira dobro većinu vremena, ali ponekad se pogrešno izračunava starost. Na primjer, ako je neko rođen 29. februara, a danas je 28. februar, formula će učiniti osobu starijom za jedan dan.

Kao alternativu, možete podijeliti sa 365,25 umjesto sa 365 jer svaka četvrta godina ima 366 dana. Međutim, ni ovaj pristup nije savršen. Na primjer, ako izračunavate starost djeteta koje još nije proživjelo prijestupnu godinu, dijeljenje sa 365,25 daje pogrešan rezultat.

Sve u svemu, oduzimanje datuma rođenja od trenutnog datuma odlično funkcionira u normalan život, ali nije idealan pristup u Excelu. Dalje u ovom tutorijalu naučit ćete nekoliko posebnih funkcija koje besprijekorno izračunavaju dob bez obzira na godinu.

Izračunajte starost od datuma rođenja pomoću funkcije YEARFRAC

Pouzdaniji način pretvaranja DOB do starosti u Excelu koristi funkciju YEARFRAC kojavraća dio godine, tj. broj cijelih dana između dva datuma.

Sintaksa funkcije YEARFRAC je sljedeća:

prva dva argumenta su očigledna i teško da zahtevaju dodatno objašnjenje. Osnova je neobavezni argument koji definira osnovu za brojanje dana koju treba koristiti.

Da biste napravili savršeno istinitu formulu starosti, dostavite sljedeće vrijednosti funkciji YEARFRAC:

• Datum_početka - datum rođenja.
• Završni_datum - DANAS() funkcija za vraćanje današnjeg datuma.
• Osnova - koristite osnovu 1 koja govori Excelu da podijeli stvarni broj dana u mjesecu sa stvarnim brojem dana u godini.

S obzirom na gore navedeno, Excel formula za izračunavanje starost od datuma rođenja je kako slijedi:

Pod pretpostavkom da je datum rođenja u ćeliji B2, formula poprima sljedeći oblik:

=YEARFRAC(B2, TODAY(), 1)

Kao i u prethodnom primjeru, rezultat funkcije YEARFRAC je također decimalni broj. Da biste ovo popravili, koristite funkciju ROUNDDOWN sa 0 u zadnjem argumentu jer ne želite decimalna mjesta.

Dakle, evo poboljšane formule YEARFRAC za izračunavanje starosti u Excelu:

=ROUNDDOWN(YEARFRAC(B2, TODAY(), 1), 0)

Izračunajte dob u Excelu pomoću DATEDIF

Još jedan način za pretvaranje datuma rođenja u dob u Excelu je korištenje funkcije DATEDIF:

Ova funkcija može vratiti razliku između dva datuma u različitim vremenskim jedinicama kao što su godine, mjeseci i dani, ovisno o vrijednosti koju unesete u argument unit :

• Y - vraća broj potpunih godina između datuma početka i završetka.
• M - vraća broj potpunih mjeseci između datume.
• D - vraća broj dana između dva datuma.
• YM - vraća mjeseci , zanemarujući dane i godine.
• MD - vraća razliku u dana , zanemarujući mjesece i godine.
• YD - vraća razliku u dana , zanemarujući godine.

Budući da nam je cilj izračunati starost za godina , koristimo jedinicu "y":

U ovom primjeru, DOB je u ćeliji B2, a vi referencirate ovu ćeliju u svojoj formuli starosti:

=DATEDIF(B2, TODAY(), "y")

U ovom slučaju nije potrebna dodatna funkcija zaokruživanja jer DATEDIF formula sa t jedinica "y" izračunava broj punih godina:

Kako izračunati starost od rođendana u godinama, mjesecima i danima

Kao što ste upravo vidjeli , izračunavanje starosti kao broja punih godina koje je osoba proživjela je lako, ali nije uvijek dovoljno. Ako želite da znate tačnu starost, tj. koliko godina, meseci i dana ima između nečijeg datuma rođenja i trenutnog datuma, napišite 3različite funkcije DATEDIF:

1. Da biste dobili broj godina: =DATEDIF(B2, TODAY(), "Y")
2. Da biste dobili broj mjeseci: =DATEDIF(B2, TODAY(), "YM")
3. Da biste dobili broj dana: =DATEDIF(B2,TODAY(),"MD")

Gdje je B2 datum rođenja.

I onda, spojite gornje funkcije u jednu formulu, ovako:

=DATEDIF(B2,TODAY(),"Y") & DATEDIF(B2,TODAY(),"YM") & DATEDIF(B2,TODAY(),"MD")

Gornja formula vraća 3 broja (godine, mjesece i dane) spojena u jedan tekstualni niz, kao što je prikazano na slici ispod:

Nema puno smisla, uh ? Da bi rezultati bili smisleniji, razdvojite brojeve zarezima i definirajte šta svaka vrijednost znači:

=DATEDIF(B2,TODAY(),"Y") & " Years, " & DATEDIF(B2,TODAY(),"YM") & " Months, " & DATEDIF(B2,TODAY(),"MD") & " Days"

Rezultat sada izgleda mnogo bolje:

Formula radi odlično, ali možete je još više poboljšati skrivanjem nultih vrijednosti. Za ovo dodajte 3 IF izraza koji provjeravaju 0, po jedan za svaki DATEDIF:

=IF(DATEDIF(B2, TODAY(),"y")=0,"",DATEDIF(B2, TODAY(),"y")&" years, ")& IF(DATEDIF(B2, TODAY(),"ym")=0,"",DATEDIF(B2, TODAY(),"ym")&" months, ")& IF(DATEDIF(B2, TODAY(),"md")=0,"",DATEDIF(B2, TODAY(),"md")&" days")

Sljedeći snimak ekrana prikazuje konačnu Excel formulu starosti u akciji - vraća starost u godinama, mjesecima, i dane, prikazujući samo vrijednosti ne-nula :

Savjet. Ako tražite Excel formulu za izračunavanje starosti u godina i mjeseci , uzmite gornju formulu i uklonite posljednji IF(DATEDIF()) blok koji izračunava dane.

Specifične formule za izračunaj starost u Excel-u

Generičke formule za izračunavanje starosti o kojima smo gore govorili rade odlično u većini slučajeva. U nekim situacijama, međutim, možda će vam trebati nešto vrlo specifično. Naravno, nije moguće pokriti svei svaki scenario, ali sljedeći primjeri će vam dati neke ideje o tome kako možete podesiti formulu starosti ovisno o vašem konkretnom zadatku.

Kako izračunati starost na određeni datum u Excelu

Ako želite da saznate nečiju starost na određeni datum, koristite formulu starosti DATEDIF o kojoj smo gore govorili, ali zamijenite funkciju TODAY() u 2. argumentu sa određenim datumom.

Pod pretpostavkom da je datum rođenja u B1, sljedeća formula će vratiti starost od 1. januara 2020.:

=DATEDIF(B1, "1/1/2020","Y") & " Years, " & DATEDIF(B1, "1/1/2020","YM") & " Months, " & DATEDIF(B1, "1/1/2020", "MD") & " Days"

Da biste svoju formulu starosti učinili fleksibilnijom, možete unijeti datum u neku ćeliju i referencirati tu ćeliju u formuli:

=DATEDIF(B1, B2,"Y") & " Years, "& DATEDIF(B1,B2,"YM") & " Months, "&DATEDIF(B1,B2, "MD") & " Days"

Gdje je B1 DOB, a B2 datum na koji želite izračunati godine.

Izračunajte starost u određenom godina

Ova formula je korisna u situacijama kada potpuni datum za izračunavanje nije definiran, a vi znate samo godinu.

Recimo da radite s medicinskom bazom podataka i cilj je saznati starost pacijenata u vrijeme kada su oni mlađi prošao zadnji potpuni ljekarski pregled.

Pod pretpostavkom da su datumi rođenja u koloni B počevši od reda 3, a godina posljednjeg ljekarskog pregleda u koloni C, formula za obračun starosti je sljedeća:

=DATEDIF(B3,DATE(C3, 1, 1),"y")

Pošto tačan datum medicinskog pregleda nije definiran, koristite funkciju DATE sa proizvoljnim argumentom datuma i mjeseca, npr. DATUM(C3, 1, 1).

TheFunkcija DATE izdvaja godinu iz ćelije B3, pravi potpuni datum koristeći brojeve mjeseca i dana koje ste unijeli (1-jan u ovom primjeru) i prosljeđuje taj datum u DATEDIF. Kao rezultat, dobijate starost pacijenta od 1. januara određene godine:

Pronađite datum kada osoba navrši N godina starosti

Pretpostavimo da je vaš prijatelj rođen 8. marta 1978. Kako znate kog datuma navršava 50 godina života? Obično biste jednostavno dodali 50 godina na datum rođenja osobe. U Excelu isto radite koristeći funkciju DATE:

=DATE(YEAR(B2) + 50, MONTH(B2), DAY(B2))

Gdje je B2 datum rođenja.

Umjesto čvrstog kodiranja broja godina u formule, možete referencirati određenu ćeliju u koju vaši korisnici mogu unijeti bilo koji broj godina (F1 na slici ispod):

Izračunajte starost iz dana, mjeseca i godine u različitim ćelije

Kada je datum rođenja podijeljen u 3 različite ćelije (npr. godina je u B3, mjesec u C3 i dan u D3), možete izračunati starost na ovaj način:

• Nabavite datum rođenja koristeći funkcije DATE i DATEVALUE:

  DATE(B3,MONTH(DATEVALUE(C3&"1")),D3)

• Ugradite gornju formulu u DATEDIF da izračunate starost od datuma rođenja u godinama, mjesecima i danima: =DATEDIF(DATE(B3, MONTH(DATEVALUE(C3&"1")), D3), TODAY(), "y") & " Years, "& DATEDIF(DATE(B3, MONTH(DATEVALUE(C3&"1")), D3),TODAY(), "ym") & " Months, "& DATEDIF(DATE(B3, MONTH(DATEVALUE(C3&"1")), D3), TODAY(), "md") & " Days"

  

Za više primjera izračunavanja broja dana prije/poslije datuma, pogledajte Kako izračunati dane od ili do datuma u Excelu.

Starost kalkulator u Excelu

Ako želite imati svojkalkulator starosti u Excelu, možete ga napraviti koristeći nekoliko različitih formula DATEDIF objašnjenih u nastavku. Ako ne biste radije izmislili točak, možete koristiti kalkulator starosti koji su kreirali naši Excel profesionalci.

Kako napraviti kalkulator starosti u Excelu

Sada kada znate kako napraviti Formula starosti u Excelu, možete napraviti prilagođeni kalkulator starosti, na primjer ovaj:

Napomena. Da vidite ugrađenu radnu svesku, dozvolite marketinške kolačiće.

Ono što vidite iznad je ugrađeni Excel Online list, pa slobodno unesite datum rođenja u odgovarajuću ćeliju i za trenutak ćete dobiti svoje godine.

Kalkulator koristi sljedeće formule za izračunavanje starosti na osnovu datuma rođenja u ćeliji A3 i današnjeg datuma.

• Formula u B5 izračunava starost u godinama, mjesecima i danima: =DATEDIF(B2,TODAY(),"Y") & " Years, " & DATEDIF(B2,TODAY(),"YM") & " Months, " & DATEDIF(B2,TODAY(),"MD") & " Days"
• Formula u B6 izračunava starost u mjesecima: =DATEDIF($B$3,TODAY(),"m")
• Formula u B7 izračunava starost u danima: =DATEDIF($B$3,TODAY(),"d")

Ako imate iskustva s kontrolama Excel obrasca, možete dodati opciju za izračunavanje starosti na određeni datum, kao što je prikazano na sljedećem snimku ekrana:

Za ovo dodajte nekoliko gumba opcija ( kartica za programere > Insert > Kontrole obrasca > Dugme opcija ), i povežite ih s nekom ćelijom. A zatim napišite formulu IF/DATEDIF da dobijete starost ili na današnji datum ili na datum koji je odredio korisnik.

Formula radi sa sljedećimlogika:

• Ako je odabran okvir za opciju Današnji datum , vrijednost 1 se pojavljuje u povezanoj ćeliji (I5 u ovom primjeru), a formula dobi izračunava se na osnovu današnjeg datuma : IF($I$5=1, DATEDIF($B$3,TODAY(),"Y") & " Years, " & DATEDIF($B$3,TODAY(), "YM") & " Months, " & DATEDIF($B$3, TODAY(), "MD") & " Days")
• Ako je odabrano dugme opcije Određeni datum I datum se unese u ćeliju B7, starost se izračunava na navedeni datum: IF(ISNUMBER($B$7), DATEDIF($B$3, $B$7,"Y") & " Years, " & DATEDIF($B$3, $B$7,"YM") & " Months, " & DATEDIF($B$3, $B$7,"MD") & " Days", ""))

Konačno , ugnijezdite gore navedene funkcije jednu u drugu i dobićete kompletnu formulu za izračunavanje starosti (u B9):

=IF($I$5=1, DATEDIF($B$3, TODAY(), "Y") & " Years, " & DATEDIF($B$3, TODAY(), "YM") & " Months, " & DATEDIF($B$3, TODAY(), "MD") & " Days", IF(ISNUMBER($B$7), DATEDIF($B$3, $B$7,"Y") & " Years, " & DATEDIF($B$3, $B$7,"YM") & " Months, " & DATEDIF($B$3, $B$7,"MD") & " Days", ""))

Formule u B10 i B11 rade sa istom logikom. Naravno, oni su mnogo jednostavniji jer uključuju samo jednu funkciju DATEDIF za vraćanje starosti kao broja punih mjeseci ili dana, respektivno.

Da biste saznali detalje, pozivam vas da preuzmete ovaj Excel kalkulator starosti i istražite formule u ćelijama B9:B11.

Preuzmite kalkulator starosti za Excel

Kalkulator starosti spreman za upotrebu za Excel

Korisnici našeg Ultimate Suite-a nemaju da se mučite oko izrade vlastitog kalkulatora starosti u Excelu - udaljen je samo nekoliko klikova:

1. Odaberite ćeliju u koju želite da umetnete formulu starosti, idite na Alatke Ablebits kartica > Datum & Vrijeme grupu i kliknite na Datum & Dugme Time Wizard .

   

2. Datum & Čarobnjak za vrijeme će se pokrenuti i vi idete direktno na karticu Dob .
3. Na kartici Dob postoje 3 stvari koje možete odrediti:
   • Podaci rođenja kao a