Excel හි උපන් දින සිට වයස ලබා ගැනීමට නිබන්ධනය විවිධ ක්‍රම පෙන්වයි. ඔබ වයස සම්පූර්ණ වසර ගණනක් ලෙස ගණනය කිරීමට සූත්‍ර අතලොස්සක් ඉගෙන ගනු ඇත, අද දින හෝ නිශ්චිත දිනයක නිශ්චිත වයස අවුරුදු, මාස සහ දින ලබා ගන්න.

ගණනය කිරීමට විශේෂ කාර්යයක් නොමැත. Excel හි වයස, කෙසේ වෙතත් උපන් දිනය වයස බවට පරිවර්තනය කිරීමට විවිධ ක්‍රම කිහිපයක් තිබේ. මෙම නිබන්ධනය එක් එක් ක්‍රමයේ වාසි සහ අවාසි පැහැදිලි කරනු ඇත, Excel හි පරිපූර්ණ වයස් ගණනය කිරීමේ සූත්‍රයක් සාදා එය යම් නිශ්චිත කාර්යයන් විසඳීම සඳහා එය වෙනස් කරන්නේ කෙසේද යන්න පෙන්වයි.

දින සිට වයස ගණනය කරන්නේ කෙසේද Excel හි උපත

එදිනෙදා ජීවිතයේදී, " ඔබේ වයස කීයද? " යන ප්‍රශ්නය සාමාන්‍යයෙන් අදහස් කරන්නේ ඔබ කොපමණ වසරක් ජීවත්ව සිටියාද යන්න දැක්වෙන පිළිතුරකි. Microsoft Excel හි, ඔබට නිශ්චිත වයස මාස, දින, පැය සහ මිනිත්තු වලින් ගණනය කිරීමට සූත්‍රයක් සෑදිය හැක. නමුත් අපි සාම්ප්‍රදායික වෙමු, පළමුව DOB වලින් වයස අවුරුදු වලින් ගණනය කරන්නේ කෙසේදැයි ඉගෙන ගනිමු.

වයස අවුරුදු වල මූලික Excel සූත්‍රය

ඔබ සාමාන්‍යයෙන් කෙනෙකුගේ වයස සොයා ගන්නේ කෙසේද? සරලව උපන් දිනය වත්මන් දිනයෙන් අඩු කිරීමෙන්. මෙම සාම්ප්‍රදායික වයස් සූත්‍රය Excel හි ද භාවිතා කළ හැක.

උපන්දිනයක් B2 කොටුවේ ඇතැයි උපකල්පනය කළහොත්, වසර වලින් වයස ගණනය කිරීමේ සූත්‍රය පහත පරිදි වේ:

=(TODAY()-B2)/365

සූත්‍රයේ පළමු කොටස (TODAY()-B2) වත්මන් දිනය සහ උපන් දිනය අතර වෙනස දින වේ, ඉන්පසු ඔබ එය බෙදන්නසෛල යොමුව හෝ mm/dd/yyyy ආකෘතියේ දිනයක්.

නිමයි!

සූත්‍රය තෝරන ලද කොටුව තුළ ක්ෂණිකව ඇතුළු කරනු ලබන අතර, තීරුවේ පහළට පිටපත් කිරීමට ඔබ පිරවුම් හසුරුව මත දෙවරක් ක්ලික් කරන්න.

ඔබට "දින 0" වැනි ශුන්‍ය ඒකක ඉවත් කිරීමට අවශ්‍ය නම්, එපා ශුන්‍ය ඒකක පෙන්වන්න සලකුණු කොටුව තෝරන්න:

ඔබට මෙම වයස් කැල්කියුලේටරය පරීක්ෂා කිරීමට මෙන්ම Excel සඳහා තවත් කාලය ඉතිරි කරන ඇඩෝන 60ක් සොයා ගැනීමට කුතුහලයක් ඇත්නම්, අවසානයේ අපගේ Ultimate Suite හි අත්හදා බැලීමේ අනුවාදයක් බාගැනීමට ඔබව සාදරයෙන් පිළිගනිමු. මෙම සටහන.

ඇතැම් වයස් උද්දීපනය කරන්නේ කෙසේද (අට අඩු හෝ වැඩි නිශ්චිත වයස)

සමහර අවස්ථා වලදී, ඔබට Excel හි වයස ගණනය කිරීම පමණක් නොව, යම් වයසකට අඩු හෝ ඊට වැඩි වයස් අඩංගු සෛල ඉස්මතු කිරීමටද අවශ්‍ය විය හැක.

ඔබේ වයස ගණනය කිරීමේ සූත්‍රය නම් සම්පූර්ණ වසර ගණන ආපසු ලබා දෙයි, එවිට ඔබට මෙවැනි සරල සූත්‍රයක් මත පදනම්ව සාමාන්‍ය කොන්දේසි සහිත හැඩතල ගැන්වීමේ රීතියක් සෑදිය හැක:

• වයසට සමාන හෝ ඊට වැඩි වයස් ඉස්මතු කිරීමට18: =$C2>=18
• වයස අවුරුදු 18ට අඩු වයස් උද්දීපනය කිරීමට: =$C2<18

C2 යනු වයස් තීරුවේ ඉහළම සෛලය වන (ඇතුළත් නොවේ තීරු ශීර්ෂකය).

නමුත් ඔබේ සූත්‍රය වයස අවුරුදු සහ මාසවලින් හෝ අවුරුදු, මාස සහ දිනවලින් පෙන්වන්නේ නම් කුමක් කළ යුතුද? මෙම අවස්ථාවේදී, ඔබට DATEDIF සූත්‍රයක් මත පදනම්ව රීතියක් නිර්මාණය කිරීමට සිදුවනු ඇත, එය උපන්දිනයේ සිට අවුරුදු වලින් වයස ගණනය කරයි.

උපන්දිනයන් 2 පේළියෙන් ආරම්භ වන B තීරුවේ ඇතැයි සිතමු, සූත්‍ර පහත පරිදි වේ:

• වයස ට අඩු 18 (කහ): =DATEDIF($B2, TODAY(),"Y")<18
• උද්දීපනය කිරීමට වයස 18 සහ 65 අතර (කොළ): =AND(DATEDIF($B2, TODAY(),"Y")>=18, DATEDIF($B2, TODAY(),"Y")<=65)
• වයස ට වැඩි 65 (නිල්) ඉස්මතු කිරීමට (නිල්): =DATEDIF($B2, TODAY(),"Y")>65

ඉහත සූත්‍ර මත පදනම්ව නීති නිර්මාණය කිරීමට, ඔබට උද්දීපනය කිරීමට අවශ්‍ය කොටු හෝ සම්පූර්ණ පේළි තෝරන්න . කුමන සෛල සංයුති කළ යුතුද යන්න තීරණය කිරීමට සූත්‍රයක් .

සවිස්තරාත්මක පියවර මෙතැනින් සොයා ගත හැක: සූත්‍රය මත පදනම්ව කොන්දේසි සහිත හැඩතල ගැන්වීමේ රීතියක් සාදා ගන්නේ කෙසේද.

ලබාගත හැකි බාගැනීම්

Excel වයස ගණනය කිරීමේ උදාහරණ (.xlsx ගොනුව)

Ultimate Suite-දින 14 සම්පූර්ණයෙන් -ක්‍රියාකාරී අනුවාදය (.exe ගොනුව)

සූත්‍රය පැහැදිලි සහ මතක තබා ගැනීමට පහසුය, කෙසේ වෙතත්, කුඩා ගැටලුවක් තිබේ. බොහෝ අවස්ථා වලදී, එය පහත තිර රුවෙහි පෙන්වා ඇති පරිදි දශම සංඛ්‍යාවක් ලබා දෙයි.

සම්පූර්ණ වසර ගණන සංදර්ශන කිරීමට, INT ශ්‍රිතය භාවිතා කර දශමයක් පහළට වට කරන්න. ආසන්නතම පූර්ණ සංඛ්‍යාව:

=INT((TODAY()-B2)/365)

අඩුපාඩු අවුරුද්දක සාමාන්‍ය දින ගණනින් බෙදීම බොහෝ විට හොඳින් ක්‍රියා කරයි, නමුත් සමහර විට එය වයස වැරදියි. නිදසුනක් වශයෙන්, යමෙකු උපත ලැබුවේ පෙබරවාරි 29 සහ අද පෙබරවාරි 28 නම්, සූත්‍රය පුද්ගලයෙකු දිනක් වැඩිහිටියෙකු බවට පත් කරයි.

විකල්පයක් ලෙස, සෑම සිව්වන වසරකම 366 ක් ඇති බැවින් ඔබට 365 වෙනුවට 365.25 න් බෙදිය හැකිය. දින. කෙසේ වෙතත්, මෙම ප්රවේශය ද පරිපූර්ණ නොවේ. උදාහරණයක් ලෙස, ඔබ තවමත් අධික වසරක් ජීවත් වී නැති දරුවෙකුගේ වයස ගණනය කරන්නේ නම්, 365.25 න් බෙදීම වැරදි ප්‍රතිඵලයක් ලබා දෙයි.

සමස්තයක් වශයෙන්, වර්තමාන දිනයෙන් උපන් දිනය අඩු කිරීම ඉතා හොඳින් ක්‍රියා කරයි. සාමාන්‍ය ජීවිතය, නමුත් එය Excel හි කදිම ප්‍රවේශය නොවේ. මෙම නිබන්ධනය තුළ තව දුරටත්, ඔබ වසර කුමක් වුවත් වයස නොසැලකිලිමත් ලෙස ගණනය කරන විශේෂ කාර්යයන් කිහිපයක් ඉගෙන ගනු ඇත.

YEARFRAC ශ්‍රිතය සමඟ උපන් දින සිට වයස ගණනය කරන්න

පරිවර්තනය කිරීමට වඩා විශ්වාසදායක ක්‍රමයක් එක්සෙල් හි වයසට යාමට DOB YEARFRAC ශ්‍රිතය භාවිතා කරයිවර්ෂයේ භාගය ආපසු ලබා දෙයි, එනම් දින දෙකක් අතර සම්පූර්ණ දින ගණන.

YEARFRAC ශ්‍රිතයේ වාක්‍ය ඛණ්ඩය පහත පරිදි වේ:

පළමු තර්ක දෙක පැහැදිලි වන අතර අමතර පැහැදිලි කිරීමක් අවශ්‍ය නොවේ. පදනම යනු භාවිතා කිරීමට දින ගණන් කිරීමේ පදනම නිර්වචනය කරන විකල්ප තර්කයකි.

සම්පූර්ණ සත්‍ය වයස් සූත්‍රයක් සෑදීමට, YEARFRAC ශ්‍රිතයට පහත අගයන් සපයන්න:

14> ආරම්භක_දිනය - උපන් දිනය.
• අවසන්_දිනය - අද දිනය ආපසු ලබා දීමට අද() ශ්‍රිතය.
• පදනම් - භාවිතා කරන්න පදනම 1 Excel හට මසකට සැබෑ දින ගණන වසරකට සැබෑ දින ගණනින් බෙදන්න.

ඉහත සලකා බැලීමේදී, ගණනය කිරීමට එක්සෙල් සූත්‍රයක් උපන් දින සිට වයස පහත පරිදි වේ:

උපන් දිනය B2 කොටුවේ ඇතැයි උපකල්පනය කළහොත්, සූත්‍රය පහත හැඩය ගනී:

=YEARFRAC(B2, TODAY(), 1)

පෙර උදාහරණයේ මෙන්, YEARFRAC ශ්‍රිතයේ ප්‍රතිඵලය ද දශම සංඛ්‍යාවකි. මෙය නිවැරදි කිරීමට, ඔබට දශම ස්ථාන කිසිවක් අවශ්‍ය නොවන නිසා අවසාන තර්කයේ 0 සමඟ ROUNDDOWN ශ්‍රිතය භාවිතා කරන්න.

එබැවින්, Excel හි වයස ගණනය කිරීමට වැඩි දියුණු කළ YEARFRAC සූත්‍රයක් මෙන්න:

=ROUNDDOWN(YEARFRAC(B2, TODAY(), 1), 0)

DATEDIF සමඟ Excel හි වයස ගණනය කරන්න

Excel හි උපන් දිනය වයස බවට පරිවර්තනය කිරීමට තවත් එක් ක්‍රමයක් වන්නේ DATEDIF ශ්‍රිතය භාවිතා කිරීමයි:

මෙම ශ්‍රිතයට ඔබ ඒකකය තර්කය තුළ සපයන අගය මත පදනම්ව, වසර, මාස සහ දින වැනි විවිධ කාල ඒකකවල දින දෙකක් අතර වෙනස ලබා දිය හැක:

• Y - ආරම්භක සහ අවසන් දිනයන් අතර සම්පූර්ණ අවුරුදු ගණන ලබා දෙයි.
• M - සම්පූර්ණ මාස අතර සංඛ්‍යාව ලබා දෙයි. දිනයන්.
• D - දින දෙක අතර දින ගණන ලබා දෙයි.
• YM - දින සහ වර්ෂ නොසලකා හැර මාස ලබා දෙයි.
• MD - මාස සහ අවුරුදු නොසලකා හරිමින් දින වෙනස ලබා දෙයි.
• YD - වසර නොසලකා හරිමින් දින වෙනස ලබා දෙයි.

අපි වයස වසර ගණනය කිරීමට ඉලක්ක කරන බැවින්, අපි "y" ඒකකය භාවිතා කරන්නෙමු:

මෙම උදාහරණයේ, DOB සෛලය B2 හි ඇති අතර, ඔබ මෙම කොටුව ඔබේ වයස් සූත්‍රයේ සඳහන් කරයි:

=DATEDIF(B2, TODAY(), "y")

t සමඟ DATEDIF සූත්‍රයක් නිසා මෙම අවස්ථාවේදී අමතර වටකුරු ශ්‍රිතයක් අවශ්‍ය නොවේ ඔහු "y" ඒකකය සම්පූර්ණ වසර ගණන ගණනය කරයි:

උපන් දින සිට අවුරුදු, මාස සහ දින වලින් වයස ලබා ගන්නේ කෙසේද

ඔබ දැන් දැක ඇති පරිදි , පුද්ගලයා ජීවත් වූ සම්පූර්ණ වසර ගණන ලෙස වයස ගණනය කිරීම පහසු ය, නමුත් එය සෑම විටම ප්රමාණවත් නොවේ. ඔබට නිශ්චිත වයස දැන ගැනීමට අවශ්‍ය නම්, එනම් කෙනෙකුගේ උපන් දිනය සහ වර්තමාන දිනය අතර කොපමණ වසර, මාස සහ දින තිබේද යන්න, 3 ලියන්න.විවිධ DATEDIF කාර්යයන්:

1. වසර ගණන ලබා ගැනීමට: =DATEDIF(B2, TODAY(), "Y")
2. මාස ගණන ලබා ගැනීමට: =DATEDIF(B2, TODAY(), "YM")
3. දින ගණන ලබා ගැනීමට: =DATEDIF(B2,TODAY(),"MD")

B2 යනු උපන් දිනය වේ.

ඉන්පසු, ඉහත ශ්‍රිත තනි සූත්‍රයකින් සංගත කරන්න, මේ වගේ:

=DATEDIF(B2,TODAY(),"Y") & DATEDIF(B2,TODAY(),"YM") & DATEDIF(B2,TODAY(),"MD")

ඉහත සූත්‍රය පහත තිර රුවෙහි පෙන්වා ඇති පරිදි, තනි පෙළ තන්තුවකින් සංක්‍රමණය කර ඇති සංඛ්‍යා 3ක් (වසර, මාස සහ දින) ලබා දෙයි:

වැඩි තේරුමක් නැහැ, අහ් ? ප්‍රතිඵල වඩාත් අර්ථවත් කිරීමට, කොමාවලින් සංඛ්‍යා වෙන් කර එක් එක් අගයෙන් අදහස් කරන්නේ කුමක්ද යන්න නිර්වචනය කරන්න:

=DATEDIF(B2,TODAY(),"Y") & " Years, " & DATEDIF(B2,TODAY(),"YM") & " Months, " & DATEDIF(B2,TODAY(),"MD") & " Days"

ප්‍රතිඵලය දැන් වඩා හොඳින් පෙනේ:

සූත්‍රය විශිෂ්ට ලෙස ක්‍රියා කරයි, නමුත් ඔබට ශුන්‍ය අගයන් සඟවා එය තව දුරටත් වැඩිදියුණු කළ හැක. මේ සඳහා, 0 සඳහා පරීක්ෂා කරන IF ප්‍රකාශ 3ක් එක් කරන්න, එක් එක් DATEDIF එකකට එකක්:

=IF(DATEDIF(B2, TODAY(),"y")=0,"",DATEDIF(B2, TODAY(),"y")&" years, ")& IF(DATEDIF(B2, TODAY(),"ym")=0,"",DATEDIF(B2, TODAY(),"ym")&" months, ")& IF(DATEDIF(B2, TODAY(),"md")=0,"",DATEDIF(B2, TODAY(),"md")&" days")

පහත තිර රුවක් මඟින් ක්‍රියාත්මක වන අවසාන Excel වයස් සූත්‍රය පෙන්නුම් කරයි - එය වයස අවුරුදු, මාස, සහ දින, ශුන්‍ය නොවන අගයන් පමණක් ප්‍රදර්ශනය කරමින්:

ඉඟිය. ඔබ වයස අවුරුදු සහ මාස කින් ගණනය කිරීමට Excel සූත්‍රයක් සොයන්නේ නම්, ඉහත සූත්‍රය ගෙන දින ගණනය කරන අවසාන IF(DATEDIF()) අවහිරය ඉවත් කරන්න.

විශේෂිත සූත්‍ර Excel හි වයස ගණනය කරන්න

ඉහත සාකච්ඡා කර ඇති සාමාන්‍ය වයස් ගණනය කිරීමේ සූත්‍ර බොහෝ අවස්ථාවලදී විශිෂ්ට ලෙස ක්‍රියා කරයි. කෙසේ වෙතත්, සමහර අවස්ථාවලදී, ඔබට ඉතා නිශ්චිත දෙයක් අවශ්ය විය හැකිය. ඇත්ත වශයෙන්ම, සෑම එකක්ම ආවරණය කළ නොහැකසහ එක් එක් සිද්ධිය, නමුත් පහත උදාහරණ මඟින් ඔබට ඔබේ විශේෂිත කාර්යය අනුව වයස් සූත්‍රයක් වෙනස් කළ හැකි ආකාරය පිළිබඳ අදහස් කිහිපයක් ලබා දෙනු ඇත.

Excel හි නිශ්චිත දිනයක වයස ගණනය කරන්නේ කෙසේද

නම් ඔබට යම් දිනයක කෙනෙකුගේ වයස දැන ගැනීමට අවශ්‍ය වේ, ඉහත සාකච්ඡා කර ඇති DATEDIF වයස් සූත්‍රය භාවිතා කරන්න, නමුත් 2වන තර්කයේ TODAY() ශ්‍රිතය නිශ්චිත දිනය සමඟ ප්‍රතිස්ථාපනය කරන්න.

උපන් දිනය B1 හි ඇතැයි උපකල්පනය කිරීම, පහත සූත්‍රය 2020 ජනවාරි 1 දිනට වයස ලබා දෙනු ඇත:

=DATEDIF(B1, "1/1/2020","Y") & " Years, " & DATEDIF(B1, "1/1/2020","YM") & " Months, " & DATEDIF(B1, "1/1/2020", "MD") & " Days"

ඔබේ වයස් සූත්‍රය වඩාත් නම්‍යශීලී කිරීමට, ඔබට යම් කොටුවක දිනය ඇතුළත් කර එම කොටුව ඔබේ සූත්‍රයේ සඳහන් කළ හැක:

=DATEDIF(B1, B2,"Y") & " Years, "& DATEDIF(B1,B2,"YM") & " Months, "&DATEDIF(B1,B2, "MD") & " Days"

B1 යනු DOB වන අතර B2 යනු ඔබට වයස ගණනය කිරීමට අවශ්‍ය දිනයයි.

නිශ්චිතව වයස ගණනය කරන්න. වර්ෂය

මෙම සූත්‍රය ප්‍රයෝජනවත් වන්නේ ගණනය කළ යුතු සම්පූර්ණ දිනය නිර්වචනය කර නොමැති අවස්ථාවන්හිදී සහ ඔබ දන්නේ වර්ෂය පමණි.

ඔබ වෛද්‍ය දත්ත ගබඩාවක් සමඟ වැඩ කරන බව කියමු, සහ ඔබේ ඉලක්කය වන්නේ ඔවුන් යටතේ සිටින රෝගීන්ගේ වයස සොයා ගැනීමයි අවසාන සම්පූර්ණ වෛද්‍ය පරීක්‍ෂණයට ගියේය.

උපන් දිනයන් 3 පේළියෙන් ආරම්භ වන B තීරුවේ සහ අවසාන වෛද්‍ය පරීක්ෂණයේ වර්ෂය C තීරුවේ ඇතැයි උපකල්පනය කළහොත්, වයස් ගණනය කිරීමේ සූත්‍රය පහත පරිදි වේ:

=DATEDIF(B3,DATE(C3, 1, 1),"y")

වෛද්‍ය පරීක්ෂණයේ නිශ්චිත දිනය නිර්වචනය කර නොමැති නිසා, ඔබ DATE ශ්‍රිතය අත්තනෝමතික දිනයක් සහ මාසික තර්කයක් සමඟ භාවිතා කරයි, උදා. DATE(C3, 1, 1).

දDATE ශ්‍රිතය B3 කොටුවෙන් වර්ෂය උපුටා ගනී, ඔබ සැපයූ මාසය සහ දින අංක භාවිතයෙන් සම්පූර්ණ දිනයක් සාදා (මෙම උදාහරණයේ ජනවාරි 1), සහ එම දිනය DATEDIF වෙත සම්මත කරයි. එහි ප්‍රතිඵලයක් වශයෙන්, යම් වර්ෂයක ජනවාරි 1 වන දිනට රෝගියාගේ වයස ඔබට ලැබේ:

පුද්ගලයෙකු වයස අවුරුදු N වන දිනයක් සොයා ගන්න

ඔබේ මිතුරා ඉපදුණේ 1978 මාර්තු 8 වැනිදා යැයි සිතමු. ඔහුගේ වයස අවුරුදු 50 සම්පූර්ණ වන්නේ කුමන දිනයකදැයි ඔබ දන්නේ කෙසේද? සාමාන්‍යයෙන්, ඔබ පුද්ගලයාගේ උපන්දිනයට වසර 50ක් එකතු කරයි. Excel හි, ඔබ DATE ශ්‍රිතය භාවිතයෙන් එයම කරයි:

=DATE(YEAR(B2) + 50, MONTH(B2), DAY(B2))

B2 යනු උපන් දිනය වේ.

ඒ වෙනුවට වසර ගණන තද කේත කිරීම වෙනුවට සූත්‍රය, ඔබට ඔබේ පරිශීලකයින්ට ඕනෑම වසර ගණනක් ඇතුළත් කළ හැකි යම් කොටුවක් සඳහන් කළ හැකිය (පහත තිර රුවෙහි F1):

දින, මාසය සහ අවුරුද්දේ සිට වයස වෙනස් ලෙස ගණනය කරන්න සෛල

උත්පත්ති දිනයක් විවිධ සෛල 3කට බෙදූ විට (උදා: වර්ෂය B3, මාසය C3 සහ දිනය D3), ඔබට මේ ආකාරයට වයස ගණනය කළ හැක:

• ලබා ගන්න DATE සහ DATEVALUE ශ්‍රිත භාවිතයෙන් උපන් දිනය:

  DATE(B3,MONTH(DATEVALUE(C3&"1")),D3)

• උපන් සූත්‍රය DATEDIF වෙත කාවැද්දීමෙන් උපන්දිනයේ සිට අවුරුදු, මාස සහ දින වලින් වයස ගණනය කරන්න: =DATEDIF(DATE(B3, MONTH(DATEVALUE(C3&"1")), D3), TODAY(), "y") & " Years, "& DATEDIF(DATE(B3, MONTH(DATEVALUE(C3&"1")), D3),TODAY(), "ym") & " Months, "& DATEDIF(DATE(B3, MONTH(DATEVALUE(C3&"1")), D3), TODAY(), "md") & " Days"

  

දිනකට පෙර/පසු දින ගණන ගණනය කිරීමේ තවත් උදාහරණ සඳහා, Excel හි සිට හෝ දිනය දක්වා දින ගණනය කරන්නේ කෙසේදැයි බලන්න.

වයස Excel හි කැල්කියුලේටරය

ඔබට ඔබේම එකක් ලබා ගැනීමට අවශ්‍ය නම්Excel හි වයස් කැල්කියුලේටරය, පහත විස්තර කර ඇති විවිධ DATEDIF සූත්‍ර කිහිපයක් භාවිතා කිරීමෙන් ඔබට එකක් සෑදිය හැක. ඔබ රෝදය ප්‍රතිනිර්මාණය නොකිරීමට කැමති නම්, ඔබට අපගේ Excel වෘත්තිකයන් විසින් නිර්මාණය කරන ලද වයස් කැල්කියුලේටරය භාවිතා කළ හැක.

Excel හි වයස් කැල්කියුලේටරයක් ​​සාදා ගන්නේ කෙසේද

දැන් ඔබ දන්නවා ඇති ආකාරය Excel හි වයස් සූත්‍රය, ඔබට අභිරුචි වයස් කැල්කියුලේටරයක් ​​සෑදිය හැක, උදාහරණයක් ලෙස මෙය:

සටහන. කාවැද්දූ වැඩපොත බැලීමට, කරුණාකර අලෙවිකරණ කුකීස් වලට ඉඩ දෙන්න.

ඔබ ඉහත දකින්නේ කාවැද්දූ Excel ඔන්ලයින් පත්‍රයකි, එබැවින් ඔබගේ උපන්දිනය අදාල කොටුවේ ඇතුලත් කිරීමට නිදහස් වන්න, එවිට ඔබට මොහොතකින් ඔබගේ වයස ලැබෙනු ඇත.

A3 කොටුවේ උපන් දිනය සහ අද දිනය මත පදනම්ව වයස ගණනය කිරීමට කැල්කියුලේටරය පහත සූත්‍ර භාවිතා කරයි.

• B5 හි සූත්‍රය අවුරුදු, මාස සහ දින වලින් වයස ගණනය කරයි: =DATEDIF(B2,TODAY(),"Y") & " Years, " & DATEDIF(B2,TODAY(),"YM") & " Months, " & DATEDIF(B2,TODAY(),"MD") & " Days"
• B6 හි සූත්‍රය මාස වලින් වයස ගණනය කරයි: =DATEDIF($B$3,TODAY(),"m")
• B7 හි සූත්‍රය දින වලින් වයස ගණනය කරයි: =DATEDIF($B$3,TODAY(),"d")

ඔබට Excel පෝරම පාලනය පිළිබඳ යම් අත්දැකීමක් තිබේ නම්, පහත තිර පිටුවේ පෙන්වා ඇති පරිදි, ඔබට නිශ්චිත දිනයකදී වයස ගණනය කිරීමට විකල්පයක් එක් කළ හැක:

මේ සඳහා විකල්ප බොත්තම් කිහිපයක් එක් කරන්න ( සංවර්ධක පටිත්ත > ඇතුළු කරන්න > පෝරම පාලන > විකල්ප බොත්තම ), සහ ඒවා යම් කොටුවකට සම්බන්ධ කරන්න. ඉන්පසුව, අද දිනයේ හෝ පරිශීලකයා විසින් සඳහන් කරන ලද දිනයට වයස ලබා ගැනීමට IF/DATEDIF සූත්‍රයක් ලියන්න.

පහත සඳහන් දේ සමඟ සූත්‍රය ක්‍රියා කරයිතර්කනය:

• අද දිනය විකල්ප පෙට්ටිය තේරුවහොත්, සම්බන්ධිත කොටුවේ 1 අගය දිස්වේ (මෙම උදාහරණයේ I5), සහ අද දිනය මත පදනම්ව වයස් සූත්‍රය ගණනය කරයි : IF($I$5=1, DATEDIF($B$3,TODAY(),"Y") & " Years, " & DATEDIF($B$3,TODAY(), "YM") & " Months, " & DATEDIF($B$3, TODAY(), "MD") & " Days")
• නිශ්චිත දිනය විකල්ප බොත්තම තෝරාගෙන B7 කොටුවේ දිනයක් ඇතුළත් කළහොත්, වයස නිශ්චිත දිනයට ගණනය කෙරේ: IF(ISNUMBER($B$7), DATEDIF($B$3, $B$7,"Y") & " Years, " & DATEDIF($B$3, $B$7,"YM") & " Months, " & DATEDIF($B$3, $B$7,"MD") & " Days", ""))

අවසානය , ඉහත ශ්‍රිත එකිනෙක කැදවන්න, එවිට ඔබට සම්පූර්ණ වයස් ගණනය කිරීමේ සූත්‍රය ලැබෙනු ඇත (B9 හි):

=IF($I$5=1, DATEDIF($B$3, TODAY(), "Y") & " Years, " & DATEDIF($B$3, TODAY(), "YM") & " Months, " & DATEDIF($B$3, TODAY(), "MD") & " Days", IF(ISNUMBER($B$7), DATEDIF($B$3, $B$7,"Y") & " Years, " & DATEDIF($B$3, $B$7,"YM") & " Months, " & DATEDIF($B$3, $B$7,"MD") & " Days", ""))

B10 සහ B11 හි සූත්‍ර එකම තර්කනය සමඟ ක්‍රියා කරයි. ඇත්ත වශයෙන්ම, ඒවා වඩාත් සරල වන්නේ ඒවා පිළිවෙලින් සම්පූර්ණ මාස හෝ දින ගණන ලෙස වයස ආපසු ලබා දීම සඳහා එක් DATEDIF ශ්‍රිතයක් පමණක් ඇතුළත් වන බැවිනි.

විස්තර දැන ගැනීමට, මෙම Excel වයස් කැල්කියුලේටරය බාගත කර විමර්ශනය කිරීමට මම ඔබට ආරාධනා කරමි. සෛල B9:B11 හි ඇති සූත්‍ර.

Excel සඳහා වයස් කැල්කියුලේටරය බාගන්න

Excel සඳහා භාවිත කිරීමට සූදානම් වයස් කැල්කියුලේටරය

අපගේ Ultimate Suite භාවිතා කරන්නන් සතුව නොමැත Excel හි තමන්ගේම වයස් කැල්කියුලේටරය සෑදීම ගැන කරදර වීමට - එය ක්ලික් කිරීම් කිහිපයක් පමණි:

1. ඔබට වයස් සූත්‍රයක් ඇතුළු කිරීමට අවශ්‍ය කොටුවක් තෝරන්න, Ablebits මෙවලම්<වෙත යන්න 2> ටැබ් > දිනය & වේලාව සමූහය, සහ දිනය & කාල විශාරද ​​බොත්තම.

   

2. දිනය & කාල විශාරද ආරම්භ වනු ඇත, ඔබ කෙලින්ම Age ටැබය වෙත යන්න.
3. Age ටැබය මත, ඔබට සඳහන් කිරීමට කරුණු 3ක් ඇත:
   14> උපතේ දත්ත ලෙස a