Bu eğitimde Excel'de doğum gününden yaş almanın farklı yolları gösterilmektedir. Yaşı tam yıl sayısı olarak hesaplamak, bugünün tarihinde veya belirli bir tarihte yıl, ay ve gün cinsinden tam yaşı almak için birkaç formül öğreneceksiniz.

Excel'de yaş hesaplamak için özel bir işlev yoktur, ancak doğum tarihini yaşa dönüştürmenin birkaç farklı yolu vardır. Bu eğitim, her bir yolun avantajlarını ve dezavantajlarını açıklayacak, Excel'de mükemmel bir yaş hesaplama formülünün nasıl oluşturulacağını ve bazı özel görevleri çözmek için nasıl değiştirileceğini gösterecektir.

Excel'de doğum tarihinden yaş nasıl hesaplanır

Günlük yaşamda, " Kaç yaşındasın sen? " genellikle kaç yıldır hayatta olduğunuzu gösteren bir cevap anlamına gelir. Microsoft Excel'de ay, gün, saat ve hatta dakika cinsinden tam bir yaş hesaplamak için bir formül oluşturabilirsiniz. Ancak geleneksel olalım ve önce DOB'dan yıl cinsinden yaşı nasıl hesaplayacağımızı öğrenelim.

Yıl cinsinden yaş için temel Excel formülü

Normalde birinin yaşını nasıl bulursunuz? Basitçe doğum tarihini geçerli tarihten çıkararak. Bu geleneksel yaş formülü Excel'de de kullanılabilir.

B2 hücresinde bir doğum tarihi olduğunu varsayarsak, yaşı yıl cinsinden hesaplamak için formül aşağıdaki gibidir:

=(BUGÜN()-B2)/365

Formülün ilk kısmı (TODAY()-B2) geçerli tarih ile doğum tarihi arasındaki farkı gün olarak verir ve ardından yıl sayısını elde etmek için bu sayıyı 365'e bölersiniz.

Formül açıktır ve hatırlanması kolaydır, ancak küçük bir sorun vardır. Çoğu durumda, aşağıdaki ekran görüntüsünde gösterildiği gibi ondalık bir sayı döndürür.

Tam yıl sayısını görüntülemek için, ondalık sayıyı en yakın tam sayıya yuvarlamak üzere INT işlevini kullanın:

=INT((TODAY()-B2)/365)

Dezavantajları: Excel'de bu yaş formülünü kullanmak oldukça doğru sonuçlar verir, ancak kusursuz değildir. Bir yıldaki ortalama gün sayısına bölmek çoğu zaman işe yarar, ancak bazen yaşı yanlış hesaplar. Örneğin, biri 29 Şubat'ta doğmuşsa ve bugün 28 Şubat ise, formül kişiyi bir gün daha yaşlı yapacaktır.

Alternatif olarak, her dört yılda bir 366 gün olduğu için 365 yerine 365,25'e bölebilirsiniz. Ancak bu yaklaşım da mükemmel değildir. Örneğin, henüz artık yıl yaşamamış bir çocuğun yaşını hesaplıyorsanız, 365,25'e bölmek yanlış bir sonuç üretir.

Genel olarak, doğum tarihini geçerli tarihten çıkarmak normal hayatta harika çalışır, ancak Excel'de ideal bir yaklaşım değildir. Bu eğitimin ilerleyen bölümlerinde, yıldan bağımsız olarak yaşı hatasız bir şekilde hesaplayan birkaç özel işlev öğreneceksiniz.

YEARFRAC fonksiyonu ile doğum tarihinden yaş hesaplama

Excel'de DOB'u yaşa dönüştürmenin daha güvenilir bir yolu, yılın kesirini, yani iki tarih arasındaki tam gün sayısını döndüren YEARFRAC işlevini kullanmaktır.

YEARFRAC fonksiyonunun söz dizimi aşağıdaki gibidir:

İlk iki argüman açıktır ve ek bir açıklama gerektirmez. Temel kullanılacak gün sayısı temelini tanımlayan isteğe bağlı bir bağımsız değişkendir.

Tamamen doğru bir yaş formülü oluşturmak için YEARFRAC işlevine aşağıdaki değerleri verin:

• Başlangıç_tarihi - Doğum tarihi.
• Bitiş_tarihi - Bugünün tarihini döndürmek için TODAY() işlevini kullanın.
• Temel - kullanım esası 1 Excel'e ay başına gerçek gün sayısını yıl başına gerçek gün sayısına bölmesini söyler.

Yukarıdakileri göz önünde bulundurarak, doğum tarihinden yaşı hesaplamak için bir Excel formülü aşağıdaki gibidir:

Doğum tarihinin B2 hücresinde olduğunu varsayarsak, formül aşağıdaki şekli alır:

=YEARFRAC(B2, TODAY(), 1)

Önceki örnekte olduğu gibi, YEARFRAC fonksiyonunun sonucu da ondalıklı bir sayıdır. Bunu düzeltmek için ROUNDDOWN fonksiyonunu son bağımsız değişkende 0 ile kullanın çünkü ondalık basamak istemezsiniz.

İşte Excel'de yaşı hesaplamak için geliştirilmiş YEARFRAC formülü:

=ROUNDDOWN(YEARFRAC(B2, TODAY(), 1), 0)

Excel'de DATEDIF ile yaş hesaplama

Excel'de doğum tarihini yaşa dönüştürmenin bir başka yolu da DATEDIF işlevini kullanmaktır:

Bu fonksiyon, iki tarih arasındaki farkı yıl, ay ve gün gibi çeşitli zaman birimlerinde döndürebilir. birim Tartışma:

• Y - aşağıdakilerin sayısını döndürür tam yıllar başlangıç ve bitiş tarihleri arasında.
• M - aşağıdakilerin sayısını döndürür tam aylar tarihler arasında.
• D - aşağıdakilerin sayısını döndürür günler iki tarih arasında.
• YM - geri döner aylar Günleri ve yılları göz ardı ederek.
• MD - şu değerdeki farkı döndürür günler Ayları ve yılları göz ardı ederek.
• YD - şu değerdeki farkı döndürür günler Yılları görmezden gelerek.

Hesaplamayı hedeflediğimiz için yaş içinde yıllar "y" birimini kullanıyoruz:

Bu örnekte, DOB B2 hücresindedir ve yaş formülünüzde bu hücreye başvurursunuz:

=DATEDIF(B2, BUGÜN(), "y")

Bu durumda ek bir yuvarlama işlevine gerek yoktur çünkü "y" birimine sahip bir DATEDIF formülü tam yıl sayısını hesaplar:

Doğum gününden yıl, ay ve gün olarak yaş nasıl alınır

Az önce gördüğünüz gibi, yaşı kişinin yaşadığı tam yıl sayısı olarak hesaplamak kolaydır, ancak her zaman yeterli değildir. Tam yaşı, yani birinin doğum tarihi ile geçerli tarih arasında kaç yıl, ay ve gün olduğunu bilmek istiyorsanız, 3 farklı DATEDIF fonksiyonu yazın:

1. Yıl sayısını elde etmek için: =DATEDIF(B2, TODAY(), "Y")
2. Ay sayısını almak için: =DATEDIF(B2, TODAY(), "YM")
3. Gün sayısını almak için: =DATEDIF(B2,TODAY(), "MD")

Burada B2 doğum tarihidir.

Ardından, yukarıdaki işlevleri aşağıdaki gibi tek bir formülde birleştirin:

=DATEDIF(B2,TODAY(), "Y") & DATEDIF(B2,TODAY(), "YM") & DATEDIF(B2,TODAY(), "MD")

Yukarıdaki formül, aşağıdaki ekran görüntüsünde gösterildiği gibi, tek bir metin dizesinde birleştirilmiş 3 sayı (yıl, ay ve gün) döndürür:

Sonuçları daha anlamlı hale getirmek için sayıları virgülle ayırın ve her bir değerin ne anlama geldiğini tanımlayın:

=DATEDIF(B2,TODAY(), "Y") & " Yıl, " & DATEDIF(B2,TODAY(), "YM") & " Ay, " & DATEDIF(B2,TODAY(), "MD") & " Gün"

Sonuç şimdi çok daha iyi görünüyor:

Formül harika çalışıyor, ancak sıfır değerlerini gizleyerek daha da geliştirebilirsiniz. Bunun için, her DATEDIF başına bir tane olmak üzere 0'ları kontrol eden 3 IF deyimi ekleyin:

=IF(DATEDIF(B2, BUGÜN(), "y")=0,"",DATEDIF(B2, BUGÜN(), "y")&" yıl, ")& IF(DATEDIF(B2, BUGÜN(), "ym")=0,"",DATEDIF(B2, BUGÜN(), "ym")&" ay, ")& IF(DATEDIF(B2, BUGÜN(), "md")=0,"",DATEDIF(B2, BUGÜN(), "md")&" gün")

Aşağıdaki ekran görüntüsü son Excel yaş formülünü iş başında göstermektedir - yaşı yıl, ay ve gün olarak döndürür ve yalnızca sıfır olmayan değerler:

İpucu: Yaşı hesaplamak için bir Excel formülü arıyorsanız yıllar ve aylar yukarıdaki formülü alın ve günleri hesaplayan son IF(DATEDIF()) bloğunu kaldırın.

Excel'de yaş hesaplamak için özel formüller

Yukarıda tartışılan genel yaş hesaplama formülleri çoğu durumda harika çalışır. Ancak bazı durumlarda çok özel bir şeye ihtiyacınız olabilir. Elbette her bir senaryoyu ele almak mümkün değildir, ancak aşağıdaki örnekler size özel görevinize bağlı olarak bir yaş formülünü nasıl değiştirebileceğiniz konusunda bazı fikirler verecektir.

Excel'de belirli bir tarihte yaş nasıl hesaplanır

Birinin belirli bir tarihteki yaşını öğrenmek istiyorsanız, yukarıda tartışılan DATEDIF yaş formülünü kullanın, ancak 2. bağımsız değişkendeki TODAY() işlevini belirli bir tarihle değiştirin.

Doğum tarihinin B1'de olduğu varsayıldığında, aşağıdaki formül 1 Ocak 2020 itibariyle yaşı verecektir:

=DATEDIF(B1, "1/1/2020", "Y") & " Yıl, " & DATEDIF(B1, "1/1/2020", "YM") & " Ay, " & DATEDIF(B1, "1/1/2020", "MD") & " Gün"

Yaş formülünüzü daha esnek hale getirmek için, tarihi bir hücreye girebilir ve formülünüzde bu hücreye başvurabilirsiniz:

=DATEDIF(B1, B2, "Y") & "Yıl,"& DATEDIF(B1,B2, "YM") & "Ay,"&DATEDIF(B1,B2, "MD") & "Gün"

Burada B1 DOB ve B2 yaşı hesaplamak istediğiniz tarihtir.

Belirli bir yıldaki yaşı hesaplama

Bu formül, hesaplanacak tam tarihin tanımlanmadığı ve yalnızca yılın bilindiği durumlarda kullanışlıdır.

Diyelim ki bir tıbbi veritabanıyla çalışıyorsunuz ve amacınız hastaların son tam tıbbi muayeneden geçtikleri andaki yaşlarını bulmak.

Doğum tarihlerinin 3. satırdan itibaren B sütununda ve son tıbbi muayene yılının C sütununda olduğu varsayıldığında, yaş hesaplama formülü aşağıdaki gibidir:

=DATEDIF(B3,DATE(C3, 1, 1), "y")

Tıbbi muayenenin kesin tarihi tanımlanmadığından, DATE işlevini rastgele bir tarih ve ay bağımsız değişkeniyle kullanırsınız, örneğin DATE(C3, 1, 1).

DATE işlevi B3 hücresinden yılı alır, sağladığınız ay ve gün sayılarını kullanarak tam bir tarih oluşturur (bu örnekte 1-Ocak) ve bu tarihi DATEDIF işlevine aktarır. Sonuç olarak, hastanın belirli bir yılın 1 Ocak tarihi itibariyle yaşını elde edersiniz:

Bir kişinin N yaşına ulaştığı tarihi bulun

Diyelim ki arkadaşınız 8 Mart 1978'de doğdu. 50 yaşını hangi tarihte tamamladığını nasıl bileceksiniz? Genellikle kişinin doğum tarihine 50 yıl eklersiniz. Excel'de de aynı işlemi DATE işlevini kullanarak yaparsınız:

=TARIH(YIL(B2) + 50, AY(B2), GÜN(B2))

Burada B2 doğum tarihidir.

Formüldeki yıl sayısını sabit kodlamak yerine, kullanıcılarınızın herhangi bir yıl sayısını girebileceği belirli bir hücreye başvurabilirsiniz (aşağıdaki ekran görüntüsünde F1):

Farklı hücrelerdeki gün, ay ve yıldan yaşı hesaplama

Bir doğum tarihi 3 farklı hücreye bölündüğünde (örneğin yıl B3'te, ay C3'te ve gün D3'te), yaşı bu şekilde hesaplayabilirsiniz:

• DATE ve DATEVALUE fonksiyonlarını kullanarak doğum tarihini alın:

  DATE(B3,MONTH(DATEVALUE(C3& "1")),D3)

• Yıl, ay ve gün cinsinden doğum tarihinden yaşı hesaplamak için yukarıdaki formülü DATEDIF içine yerleştirin: =DATEDIF(DATE(B3, MONTH(DATEVALUE(C3& "1")), D3), TODAY(), "y") & " Yıl, "& DATEDIF(DATE(B3, MONTH(DATEVALUE(C3& "1")), D3),TODAY(), "ym") & " Ay, "& DATEDIF(DATE(B3, MONTH(DATEVALUE(C3& "1")), D3), TODAY(), "md") & " Gün"

  

Bir tarihten önceki/sonraki gün sayısını hesaplamaya ilişkin daha fazla örnek için lütfen Excel'de tarihten bu yana veya tarihe kadar olan günleri hesaplama bölümüne bakın.

Excel'de yaş hesaplayıcı

Excel'de kendi yaş hesaplayıcınıza sahip olmak istiyorsanız, aşağıda açıklanan birkaç farklı DATEDIF formülünü kullanarak bir tane yapabilirsiniz. Tekerleği yeniden icat etmek istemiyorsanız, Excel uzmanlarımız tarafından oluşturulan yaş hesaplayıcısını kullanabilirsiniz.

Excel'de yaş hesaplayıcısı nasıl oluşturulur

Artık Excel'de bir yaş formülünün nasıl oluşturulacağını bildiğinize göre, örneğin bu gibi özel bir yaş hesaplayıcısı oluşturabilirsiniz:

Not: Yerleşik çalışma kitabını görüntülemek için lütfen pazarlama çerezlerine izin verin.

Yukarıda gördüğünüz, gömülü bir Excel Online sayfasıdır, bu nedenle doğum tarihinizi ilgili hücreye girmekten çekinmeyin ve yaşınızı bir dakika içinde alacaksınız.

Hesap makinesi, A3 hücresindeki doğum tarihine ve bugünün tarihine göre yaşı hesaplamak için aşağıdaki formülleri kullanır.

• B5'teki formül yaşı yıl, ay ve gün olarak hesaplar: =DATEDIF(B2,TODAY(), "Y") & " Yıl, " & DATEDIF(B2,TODAY(), "YM") & " Ay, " & DATEDIF(B2,TODAY(), "MD") & " Gün"
• B6'daki formül ay cinsinden yaşı hesaplar: =DATEDIF($B$3,TODAY(), "m")
• B7'deki formül yaşı gün cinsinden hesaplar: =DATEDIF($B$3,TODAY(), "d")

Excel Form denetimleri konusunda biraz deneyiminiz varsa, aşağıdaki ekran görüntüsünde gösterildiği gibi belirli bir tarihteki yaşı hesaplamak için bir seçenek ekleyebilirsiniz:

Bunun için birkaç seçenek düğmesi ekleyin ( Geliştirici sekmesi > Ekleme > Form kontrolleri > Seçenek Düğmesi ) ve bunları bir hücreye bağlayın. Ardından, yaşı ya bugünün tarihinde ya da kullanıcı tarafından belirtilen tarihte almak için bir EĞER/TARİHIF formülü yazın.

Formül aşağıdaki mantıkla çalışır:

• Eğer Bugünün tarihi seçenek kutusu seçildiğinde, bağlantılı hücrede (bu örnekte I5) 1 değeri görünür ve yaş formülü bugün tarihine göre hesaplanır: IF($I$5=1, DATEDIF($B$3,TODAY(), "Y") & " Years, " & DATEDIF($B$3,TODAY(), "YM") & " Months, " & DATEDIF($B$3, TODAY(), "MD") & " Days")
• Eğer Belirli tarih seçenek düğmesi seçilir VE B7 hücresine bir tarih girilirse, yaş belirtilen tarihte hesaplanır: IF(ISNUMBER($B$7), DATEDIF($B$3, $B$7, "Y") & " Years, " & DATEDIF($B$3, $B$7, "YM") & " Months, " & DATEDIF($B$3, $B$7, "MD") & " Days", "")

Son olarak, yukarıdaki fonksiyonları birbirinin içine yerleştirin ve tam yaş hesaplama formülünü (B9'da) elde edeceksiniz:

=IF($I$5=1, DATEDIF($B$3, TODAY(), "Y") & " Years, " & DATEDIF($B$3, TODAY(), "YM") & " Months, " & DATEDIF($B$3, TODAY(), "MD") & " Days", IF(ISNUMBER($B$7), DATEDIF($B$3, $B$7, "Y") & " Years, " & DATEDIF($B$3, $B$7, "YM") & " Months, " & DATEDIF($B$3, $B$7, "MD") & " Days", "")

B10 ve B11'deki formüller de aynı mantıkla çalışır. Elbette bunlar çok daha basittir çünkü yaşı sırasıyla tam ay veya gün sayısı olarak döndürmek için yalnızca bir DATEDIF işlevi içerirler.

Ayrıntıları öğrenmek için sizi bu Excel Yaş Hesaplayıcısını indirmeye ve B9:B11 hücrelerindeki formülleri incelemeye davet ediyorum.

Excel için Yaş Hesaplayıcısını İndirin

Excel için kullanıma hazır yaş hesaplayıcı

Ultimate Suite'imizin kullanıcıları Excel'de kendi yaş hesaplayıcılarını yapmakla uğraşmak zorunda değiller - sadece birkaç tık ötede:

1. Yaş formülü eklemek istediğiniz hücreyi seçin ve Ablebits Araçları tab> Tarih & amp; Saat grubunu seçin ve Tarih ve Saat Sihirbazı Düğme.

   

2. Tarih ve Saat Sihirbazı başlayacak ve doğrudan Yaş sekmesi.
3. Üzerinde Yaş sekmesinde belirtmeniz gereken 3 şey vardır:
   • Doğum bilgileri bir hücre referansı veya aa/gg/yyyy biçiminde bir tarih olarak.
   • Yaş bugünün tarihi veya belirli tarih .
   • Yaşın gün, ay, yıl veya tam yaş olarak hesaplanıp hesaplanmayacağını seçin.
4. Tıklayınız Formül ekle Düğme.

Tamamdır!

Formül, seçili hücreye anlık olarak eklenir ve sütundan aşağı kopyalamak için doldurma tutamacına çift tıklarsınız.

Fark etmiş olabileceğiniz gibi, Excel yaş hesaplayıcımız tarafından oluşturulan formül şimdiye kadar tartıştıklarımızdan daha karmaşıktır, ancak "gün" ve "günler" gibi tekil ve çoğul zaman birimlerine hitap eder.

"0 gün" gibi sıfır birimlerden kurtulmak istiyorsanız Yapmayın. sıfır birim göster onay kutusu:

Bu yaş hesaplayıcısını test etmek ve Excel için zaman kazandıran 60 eklentiyi daha keşfetmek istiyorsanız, bu yazının sonunda Ultimate Suite'imizin deneme sürümünü indirebilirsiniz.

Belirli yaşlar nasıl vurgulanır (belirli bir yaşın altında veya üstünde)

Bazı durumlarda, Excel'de yalnızca yaşı hesaplamanız değil, aynı zamanda belirli bir yaşın altında veya üstünde olan yaşları içeren hücreleri vurgulamanız gerekebilir.

Yaş hesaplama formülünüz tam yıl sayısını döndürüyorsa, bunlar gibi basit bir formüle dayalı normal bir koşullu biçimlendirme kuralı oluşturabilirsiniz:

• 18'e eşit veya 18'den büyük yaşları vurgulamak için: =$C2>=18
• 18'in altındaki yaşları vurgulamak için: =$C2<18

Burada C2, Yaş sütunundaki en üst hücredir (sütun başlığı dahil değildir).

Peki ya formülünüz yaşı yıl ve ay olarak ya da yıl, ay ve gün olarak gösteriyorsa? Bu durumda, yaşı doğum tarihinden yıl olarak hesaplayan bir DATEDIF formülüne dayalı bir kural oluşturmanız gerekecektir.

Doğum tarihlerinin 2. satırdan başlayarak B sütununda yer aldığını varsayarsak, formüller aşağıdaki gibidir:

• Yaşları vurgulamak için altında 18 (sarı): =DATEDIF($B2, TODAY(), "Y")<18
• Yaşları vurgulamak için arasında 18 ve 65 (yeşil): =AND(DATEDIF($B2, TODAY(), "Y")>=18, DATEDIF($B2, TODAY(), "Y")<=65)
• Yaşları vurgulamak için üzerinde 65 (mavi): =DATEDIF($B2, TODAY(), "Y")>65

Yukarıdaki formüllere dayalı kurallar oluşturmak için, vurgulamak istediğiniz hücreleri veya tüm satırları seçin ve Ev tab> Stiller grubunu seçin ve Koşullu Biçimlendirme > Yeni kural. > Hangi hücrelerin biçimlendirileceğini belirlemek için bir formül kullanma .

Ayrıntılı adımları burada bulabilirsiniz: Formüle dayalı koşullu biçimlendirme kuralı nasıl oluşturulur?

Excel'de yaş hesaplaması bu şekilde yapılır. Umarım formülleri öğrenmek sizin için kolay olmuştur ve çalışma sayfalarınızda bunları denersiniz. Okuduğunuz için teşekkürler ve gelecek hafta blogumuzda görüşmek dileğiyle!

Mevcut indirmeler

Excel Yaş Hesaplama örnekleri (.xlsx dosyası)

Ultimate Suite 14 günlük tam işlevli sürüm (.exe dosyası)