ਵਿਸ਼ਾ - ਸੂਚੀ
ਟਿਊਟੋਰਿਅਲ ਐਕਸਲ ਵਿੱਚ ਜਨਮਦਿਨ ਤੋਂ ਉਮਰ ਪ੍ਰਾਪਤ ਕਰਨ ਦੇ ਵੱਖ-ਵੱਖ ਤਰੀਕੇ ਦਿਖਾਉਂਦਾ ਹੈ। ਤੁਸੀਂ ਪੂਰੇ ਸਾਲਾਂ ਦੀ ਗਿਣਤੀ ਵਜੋਂ ਉਮਰ ਦੀ ਗਣਨਾ ਕਰਨ ਲਈ ਕੁਝ ਮੁੱਠੀ ਭਰ ਫਾਰਮੂਲੇ ਸਿੱਖੋਗੇ, ਅੱਜ ਦੀ ਮਿਤੀ ਜਾਂ ਕਿਸੇ ਖਾਸ ਮਿਤੀ 'ਤੇ ਸਾਲਾਂ, ਮਹੀਨਿਆਂ ਅਤੇ ਦਿਨਾਂ ਵਿੱਚ ਸਹੀ ਉਮਰ ਪ੍ਰਾਪਤ ਕਰੋਗੇ।
ਗਣਨਾ ਕਰਨ ਲਈ ਕੋਈ ਵਿਸ਼ੇਸ਼ ਫੰਕਸ਼ਨ ਨਹੀਂ ਹੈ। ਐਕਸਲ ਵਿੱਚ ਉਮਰ, ਹਾਲਾਂਕਿ ਜਨਮ ਮਿਤੀ ਨੂੰ ਉਮਰ ਵਿੱਚ ਬਦਲਣ ਦੇ ਕੁਝ ਵੱਖਰੇ ਤਰੀਕੇ ਮੌਜੂਦ ਹਨ। ਇਹ ਟਿਊਟੋਰਿਅਲ ਹਰੇਕ ਤਰੀਕੇ ਦੇ ਫਾਇਦਿਆਂ ਅਤੇ ਕਮੀਆਂ ਦੀ ਵਿਆਖਿਆ ਕਰੇਗਾ, ਇਹ ਦਿਖਾਉਂਦਾ ਹੈ ਕਿ ਐਕਸਲ ਵਿੱਚ ਇੱਕ ਸੰਪੂਰਣ ਉਮਰ ਗਣਨਾ ਫਾਰਮੂਲਾ ਕਿਵੇਂ ਬਣਾਇਆ ਜਾਵੇ ਅਤੇ ਕੁਝ ਖਾਸ ਕੰਮਾਂ ਨੂੰ ਹੱਲ ਕਰਨ ਲਈ ਇਸਨੂੰ ਬਦਲਿਆ ਜਾਵੇ।
ਤਾਰੀਖ ਤੋਂ ਉਮਰ ਦੀ ਗਣਨਾ ਕਿਵੇਂ ਕਰੀਏ ਐਕਸਲ ਵਿੱਚ ਜਨਮ ਦਾ
ਰੋਜ਼ਾਨਾ ਜੀਵਨ ਵਿੱਚ, ਸਵਾਲ " ਤੁਹਾਡੀ ਉਮਰ ਕਿੰਨੀ ਹੈ? " ਆਮ ਤੌਰ 'ਤੇ ਇਹ ਦਰਸਾਉਂਦਾ ਹੈ ਕਿ ਤੁਸੀਂ ਕਿੰਨੇ ਸਾਲ ਜੀਵਿਤ ਹੋ। Microsoft Excel ਵਿੱਚ, ਤੁਸੀਂ ਮਹੀਨਿਆਂ, ਦਿਨਾਂ, ਘੰਟਿਆਂ ਅਤੇ ਇੱਥੋਂ ਤੱਕ ਕਿ ਮਿੰਟਾਂ ਵਿੱਚ ਇੱਕ ਸਹੀ ਉਮਰ ਦੀ ਗਣਨਾ ਕਰਨ ਲਈ ਇੱਕ ਫਾਰਮੂਲਾ ਬਣਾ ਸਕਦੇ ਹੋ। ਪਰ ਆਓ ਪਰੰਪਰਾਗਤ ਬਣੀਏ, ਅਤੇ ਸਿੱਖੀਏ ਕਿ DOB ਤੋਂ ਪਹਿਲਾਂ ਸਾਲਾਂ ਵਿੱਚ ਉਮਰ ਦੀ ਗਣਨਾ ਕਿਵੇਂ ਕਰਨੀ ਹੈ।
ਸਾਲਾਂ ਵਿੱਚ ਉਮਰ ਲਈ ਮੂਲ ਐਕਸਲ ਫਾਰਮੂਲਾ
ਤੁਸੀਂ ਆਮ ਤੌਰ 'ਤੇ ਕਿਸੇ ਦੀ ਉਮਰ ਦਾ ਪਤਾ ਕਿਵੇਂ ਲਗਾਉਂਦੇ ਹੋ? ਬਸ ਮੌਜੂਦਾ ਮਿਤੀ ਤੋਂ ਜਨਮ ਮਿਤੀ ਨੂੰ ਘਟਾ ਕੇ। ਇਹ ਰਵਾਇਤੀ ਉਮਰ ਫਾਰਮੂਲਾ ਐਕਸਲ ਵਿੱਚ ਵੀ ਵਰਤਿਆ ਜਾ ਸਕਦਾ ਹੈ।
ਇਹ ਮੰਨ ਕੇ ਕਿ ਇੱਕ ਜਨਮ ਮਿਤੀ ਸੈੱਲ B2 ਵਿੱਚ ਹੈ, ਸਾਲਾਂ ਵਿੱਚ ਉਮਰ ਦੀ ਗਣਨਾ ਕਰਨ ਲਈ ਫਾਰਮੂਲਾ ਇਸ ਤਰ੍ਹਾਂ ਹੈ:
=(TODAY()-B2)/365
ਦ ਫਾਰਮੂਲੇ ਦਾ ਪਹਿਲਾ ਹਿੱਸਾ (TODAY()-B2) ਵਰਤਮਾਨ ਮਿਤੀ ਅਤੇ ਜਨਮ ਮਿਤੀ ਦੇ ਵਿਚਕਾਰ ਅੰਤਰ ਦਿਨ ਹੈ, ਅਤੇ ਫਿਰ ਤੁਸੀਂ ਉਸ ਨੂੰ ਵੰਡਦੇ ਹੋਸੈੱਲ ਸੰਦਰਭ ਜਾਂ mm/dd/yyyy ਫਾਰਮੈਟ ਵਿੱਚ ਇੱਕ ਮਿਤੀ।
ਹੋ ਗਿਆ!
ਫਾਰਮੂਲਾ ਚੁਣੇ ਹੋਏ ਸੈੱਲ ਵਿੱਚ ਪਲ ਭਰ ਵਿੱਚ ਪਾ ਦਿੱਤਾ ਜਾਂਦਾ ਹੈ, ਅਤੇ ਤੁਸੀਂ ਕਾਲਮ ਦੇ ਹੇਠਾਂ ਕਾਪੀ ਕਰਨ ਲਈ ਫਿਲ ਹੈਂਡਲ 'ਤੇ ਦੋ ਵਾਰ ਕਲਿੱਕ ਕਰੋ।
ਜਿਵੇਂ ਕਿ ਤੁਸੀਂ ਦੇਖਿਆ ਹੋਵੇਗਾ, ਸਾਡੇ ਐਕਸਲ ਉਮਰ ਕੈਲਕੁਲੇਟਰ ਦੁਆਰਾ ਬਣਾਇਆ ਗਿਆ ਫਾਰਮੂਲਾ ਉਹਨਾਂ ਨਾਲੋਂ ਵਧੇਰੇ ਗੁੰਝਲਦਾਰ ਹੈ ਜਿਸ ਬਾਰੇ ਅਸੀਂ ਹੁਣ ਤੱਕ ਚਰਚਾ ਕੀਤੀ ਹੈ, ਪਰ ਇਹ "ਦਿਨ" ਅਤੇ "ਦਿਨ" ਵਰਗੀਆਂ ਸਮਾਂ ਇਕਾਈਆਂ ਦੇ ਇਕਵਚਨ ਅਤੇ ਬਹੁਵਚਨ ਨੂੰ ਪੂਰਾ ਕਰਦਾ ਹੈ।
ਜੇਕਰ ਤੁਸੀਂ "0 ਦਿਨ" ਵਰਗੀਆਂ ਜ਼ੀਰੋ ਯੂਨਿਟਾਂ ਤੋਂ ਛੁਟਕਾਰਾ ਪਾਉਣਾ ਚਾਹੁੰਦੇ ਹੋ, ਤਾਂ ਨਹੀਂ ਜ਼ੀਰੋ ਯੂਨਿਟਸ ਨਾ ਦਿਖਾਓ ਚੈੱਕ ਬਾਕਸ ਨੂੰ ਚੁਣੋ:
ਜੇਕਰ ਤੁਸੀਂ ਇਸ ਉਮਰ ਕੈਲਕੁਲੇਟਰ ਦੀ ਜਾਂਚ ਕਰਨ ਦੇ ਨਾਲ-ਨਾਲ ਐਕਸਲ ਲਈ 60 ਹੋਰ ਸਮਾਂ ਬਚਾਉਣ ਵਾਲੇ ਐਡ-ਇਨਾਂ ਨੂੰ ਖੋਜਣ ਲਈ ਉਤਸੁਕ ਹੋ, ਤਾਂ ਤੁਹਾਡਾ ਸਾਡੇ ਅਲਟੀਮੇਟ ਸੂਟ ਦੇ ਅਜ਼ਮਾਇਸ਼ ਸੰਸਕਰਣ ਨੂੰ ਡਾਊਨਲੋਡ ਕਰਨ ਲਈ ਸਵਾਗਤ ਹੈ। ਇਹ ਪੋਸਟ।
ਕੁਝ ਉਮਰਾਂ ਨੂੰ ਕਿਵੇਂ ਉਜਾਗਰ ਕਰਨਾ ਹੈ (a ਤੋਂ ਘੱਟ ਜਾਂ ਵੱਧ ਖਾਸ ਉਮਰ)
ਕੁਝ ਸਥਿਤੀਆਂ ਵਿੱਚ, ਤੁਹਾਨੂੰ ਨਾ ਸਿਰਫ਼ Excel ਵਿੱਚ ਉਮਰ ਦੀ ਗਣਨਾ ਕਰਨ ਦੀ ਲੋੜ ਹੋ ਸਕਦੀ ਹੈ, ਸਗੋਂ ਉਹਨਾਂ ਸੈੱਲਾਂ ਨੂੰ ਵੀ ਉਜਾਗਰ ਕਰਨ ਦੀ ਲੋੜ ਹੋ ਸਕਦੀ ਹੈ ਜਿਨ੍ਹਾਂ ਵਿੱਚ ਕਿਸੇ ਖਾਸ ਉਮਰ ਤੋਂ ਘੱਟ ਜਾਂ ਵੱਧ ਉਮਰ ਦੇ ਹੁੰਦੇ ਹਨ।
ਜੇ ਤੁਹਾਡੀ ਉਮਰ ਦੀ ਗਣਨਾ ਦਾ ਫਾਰਮੂਲਾ ਪੂਰੇ ਸਾਲਾਂ ਦੀ ਸੰਖਿਆ ਵਾਪਸ ਕਰਦਾ ਹੈ, ਫਿਰ ਤੁਸੀਂ ਇਹਨਾਂ ਵਰਗੇ ਸਧਾਰਨ ਫਾਰਮੂਲੇ ਦੇ ਆਧਾਰ 'ਤੇ ਨਿਯਮਤ ਸ਼ਰਤੀਆ ਫਾਰਮੈਟਿੰਗ ਨਿਯਮ ਬਣਾ ਸਕਦੇ ਹੋ:
- ਉਮਰਾਂ ਦੇ ਬਰਾਬਰ ਜਾਂ ਇਸ ਤੋਂ ਵੱਧ ਨੂੰ ਉਜਾਗਰ ਕਰਨ ਲਈ18: =$C2>=18
- 18 ਸਾਲ ਤੋਂ ਘੱਟ ਉਮਰ ਨੂੰ ਉਜਾਗਰ ਕਰਨ ਲਈ: =$C2<18
ਜਿੱਥੇ C2 ਉਮਰ ਕਾਲਮ ਵਿੱਚ ਸਭ ਤੋਂ ਉੱਚਾ ਸੈੱਲ ਹੈ (ਇਸ ਵਿੱਚ ਸ਼ਾਮਲ ਨਹੀਂ ਕਾਲਮ ਹੈਡਰ)।
ਪਰ ਕੀ ਜੇ ਤੁਹਾਡਾ ਫਾਰਮੂਲਾ ਸਾਲਾਂ ਅਤੇ ਮਹੀਨਿਆਂ ਵਿੱਚ, ਜਾਂ ਸਾਲਾਂ, ਮਹੀਨਿਆਂ ਅਤੇ ਦਿਨਾਂ ਵਿੱਚ ਉਮਰ ਦਰਸਾਉਂਦਾ ਹੈ? ਇਸ ਸਥਿਤੀ ਵਿੱਚ, ਤੁਹਾਨੂੰ ਇੱਕ DATEDIF ਫਾਰਮੂਲੇ ਦੇ ਅਧਾਰ 'ਤੇ ਇੱਕ ਨਿਯਮ ਬਣਾਉਣਾ ਹੋਵੇਗਾ ਜੋ ਜਨਮ ਮਿਤੀ ਤੋਂ ਸਾਲਾਂ ਵਿੱਚ ਉਮਰ ਦੀ ਗਣਨਾ ਕਰਦਾ ਹੈ।
ਮੰਨ ਲਓ ਕਿ ਜਨਮ ਮਿਤੀਆਂ ਕਤਾਰ 2 ਨਾਲ ਸ਼ੁਰੂ ਹੋਣ ਵਾਲੇ ਕਾਲਮ B ਵਿੱਚ ਹਨ, ਫਾਰਮੂਲੇ ਇਸ ਤਰ੍ਹਾਂ ਹਨ:
- ਉਮਰਾਂ ਨੂੰ ਉਜਾਗਰ ਕਰਨ ਲਈ ਘੱਟ 18 (ਪੀਲਾ):
=DATEDIF($B2, TODAY(),"Y")<18 - ਉਮਰਾਂ ਨੂੰ ਉਜਾਗਰ ਕਰਨ ਲਈ 18 ਅਤੇ 65 (ਹਰਾ):
=AND(DATEDIF($B2, TODAY(),"Y")>=18, DATEDIF($B2, TODAY(),"Y")<=65) - ਉਮਰ ਵੱਧ 65 (ਨੀਲਾ):
=DATEDIF($B2, TODAY(),"Y")>65
ਉਪਰੋਕਤ ਫਾਰਮੂਲੇ ਦੇ ਆਧਾਰ 'ਤੇ ਨਿਯਮ ਬਣਾਉਣ ਲਈ, ਉਹਨਾਂ ਸੈੱਲਾਂ ਜਾਂ ਪੂਰੀਆਂ ਕਤਾਰਾਂ ਨੂੰ ਚੁਣੋ ਜਿਨ੍ਹਾਂ ਨੂੰ ਤੁਸੀਂ ਹਾਈਲਾਈਟ ਕਰਨਾ ਚਾਹੁੰਦੇ ਹੋ। , ਹੋਮ ਟੈਬ > ਸ਼ੈਲੀ ਗਰੁੱਪ 'ਤੇ ਜਾਓ, ਅਤੇ ਕੰਡੀਸ਼ਨਲ ਫਾਰਮੈਟਿੰਗ > ਨਵਾਂ ਨਿਯਮ… > ਵਰਤਣ 'ਤੇ ਕਲਿੱਕ ਕਰੋ। ਇਹ ਨਿਰਧਾਰਤ ਕਰਨ ਲਈ ਇੱਕ ਫਾਰਮੂਲਾ ਕਿ ਕਿਹੜੇ ਸੈੱਲਾਂ ਨੂੰ ਫਾਰਮੈਟ ਕਰਨਾ ਹੈ ।
ਵਿਸਤ੍ਰਿਤ ਪੜਾਅ ਇੱਥੇ ਲੱਭੇ ਜਾ ਸਕਦੇ ਹਨ: ਫਾਰਮੂਲੇ ਦੇ ਆਧਾਰ 'ਤੇ ਸ਼ਰਤੀਆ ਫਾਰਮੈਟਿੰਗ ਨਿਯਮ ਕਿਵੇਂ ਬਣਾਇਆ ਜਾਵੇ।
ਇਸ ਤਰ੍ਹਾਂ ਤੁਸੀਂ ਐਕਸਲ ਵਿੱਚ ਉਮਰ ਦੀ ਗਣਨਾ ਕਰਦੇ ਹੋ। ਮੈਨੂੰ ਉਮੀਦ ਹੈ ਕਿ ਫਾਰਮੂਲੇ ਤੁਹਾਡੇ ਲਈ ਸਿੱਖਣ ਵਿੱਚ ਆਸਾਨ ਸਨ ਅਤੇ ਤੁਸੀਂ ਉਹਨਾਂ ਨੂੰ ਆਪਣੀਆਂ ਵਰਕਸ਼ੀਟਾਂ ਵਿੱਚ ਅਜ਼ਮਾਓਗੇ। ਪੜ੍ਹਨ ਲਈ ਤੁਹਾਡਾ ਧੰਨਵਾਦ ਅਤੇ ਅਗਲੇ ਹਫ਼ਤੇ ਤੁਹਾਨੂੰ ਸਾਡੇ ਬਲੌਗ 'ਤੇ ਮਿਲਣ ਦੀ ਉਮੀਦ ਹੈ!
ਉਪਲੱਬਧ ਡਾਊਨਲੋਡ
Excel ਉਮਰ ਗਣਨਾ ਦੀਆਂ ਉਦਾਹਰਣਾਂ (.xlsx ਫਾਈਲ)
ਅੰਤਮ ਸੂਟ 14-ਦਿਨ ਪੂਰੀ ਤਰ੍ਹਾਂ -ਫੰਕਸ਼ਨਲ ਸੰਸਕਰਣ (.exe ਫਾਈਲ)
ਸਾਲਾਂ ਦੀ ਸੰਖਿਆ ਪ੍ਰਾਪਤ ਕਰਨ ਲਈ 365 ਦੁਆਰਾ ਸੰਖਿਆ।ਫਾਰਮੂਲਾ ਸਪੱਸ਼ਟ ਅਤੇ ਯਾਦ ਰੱਖਣ ਵਿੱਚ ਆਸਾਨ ਹੈ, ਹਾਲਾਂਕਿ, ਇੱਕ ਛੋਟੀ ਜਿਹੀ ਸਮੱਸਿਆ ਹੈ। ਜ਼ਿਆਦਾਤਰ ਮਾਮਲਿਆਂ ਵਿੱਚ, ਇਹ ਹੇਠਾਂ ਦਿੱਤੇ ਸਕ੍ਰੀਨਸ਼ੌਟ ਵਿੱਚ ਦਰਸਾਏ ਗਏ ਇੱਕ ਦਸ਼ਮਲਵ ਸੰਖਿਆ ਨੂੰ ਵਾਪਸ ਕਰਦਾ ਹੈ।
ਪੂਰੇ ਸਾਲਾਂ ਦੀ ਸੰਖਿਆ ਨੂੰ ਪ੍ਰਦਰਸ਼ਿਤ ਕਰਨ ਲਈ, INT ਫੰਕਸ਼ਨ ਦੀ ਵਰਤੋਂ ਦਸ਼ਮਲਵ ਨੂੰ ਹੇਠਾਂ ਦਸ਼ਮਲਵ ਵਿੱਚ ਕਰਨ ਲਈ ਕਰੋ। ਨਜ਼ਦੀਕੀ ਪੂਰਨ ਅੰਕ:
=INT((TODAY()-B2)/365)
ਨੁਕਸਾਨ: ਐਕਸਲ ਵਿੱਚ ਇਸ ਉਮਰ ਫਾਰਮੂਲੇ ਦੀ ਵਰਤੋਂ ਕਰਨ ਨਾਲ ਬਹੁਤ ਸਟੀਕ ਨਤੀਜੇ ਨਿਕਲਦੇ ਹਨ, ਪਰ ਨਿਰਦੋਸ਼ ਨਹੀਂ। ਇੱਕ ਸਾਲ ਵਿੱਚ ਦਿਨਾਂ ਦੀ ਔਸਤ ਸੰਖਿਆ ਨਾਲ ਵੰਡਣਾ ਜ਼ਿਆਦਾਤਰ ਸਮਾਂ ਵਧੀਆ ਕੰਮ ਕਰਦਾ ਹੈ, ਪਰ ਕਈ ਵਾਰ ਇਹ ਉਮਰ ਗਲਤ ਹੋ ਜਾਂਦੀ ਹੈ। ਉਦਾਹਰਨ ਲਈ, ਜੇਕਰ ਕਿਸੇ ਦਾ ਜਨਮ 29 ਫਰਵਰੀ ਨੂੰ ਹੋਇਆ ਸੀ ਅਤੇ ਅੱਜ 28 ਫਰਵਰੀ ਹੈ, ਤਾਂ ਫਾਰਮੂਲਾ ਇੱਕ ਵਿਅਕਤੀ ਨੂੰ ਇੱਕ ਦਿਨ ਵੱਡਾ ਬਣਾ ਦੇਵੇਗਾ।
ਇੱਕ ਵਿਕਲਪ ਵਜੋਂ, ਤੁਸੀਂ 365 ਦੀ ਬਜਾਏ 365.25 ਨਾਲ ਭਾਗ ਕਰ ਸਕਦੇ ਹੋ ਕਿਉਂਕਿ ਹਰ ਚੌਥੇ ਸਾਲ ਵਿੱਚ 366 ਹੁੰਦੇ ਹਨ। ਦਿਨ ਹਾਲਾਂਕਿ, ਇਹ ਪਹੁੰਚ ਵੀ ਸੰਪੂਰਨ ਨਹੀਂ ਹੈ. ਉਦਾਹਰਨ ਲਈ, ਜੇਕਰ ਤੁਸੀਂ ਇੱਕ ਬੱਚੇ ਦੀ ਉਮਰ ਦੀ ਗਣਨਾ ਕਰ ਰਹੇ ਹੋ ਜੋ ਅਜੇ ਤੱਕ ਇੱਕ ਲੀਪ ਸਾਲ ਵਿੱਚ ਨਹੀਂ ਗੁਜ਼ਰਿਆ ਹੈ, ਤਾਂ 365.25 ਨਾਲ ਭਾਗ ਕਰਨ ਨਾਲ ਇੱਕ ਗਲਤ ਨਤੀਜਾ ਨਿਕਲਦਾ ਹੈ।
ਕੁੱਲ ਮਿਲਾ ਕੇ, ਮੌਜੂਦਾ ਮਿਤੀ ਤੋਂ ਜਨਮ ਮਿਤੀ ਨੂੰ ਘਟਾਉਣਾ ਬਹੁਤ ਵਧੀਆ ਕੰਮ ਕਰਦਾ ਹੈ। ਆਮ ਜੀਵਨ, ਪਰ ਐਕਸਲ ਵਿੱਚ ਆਦਰਸ਼ ਪਹੁੰਚ ਨਹੀਂ ਹੈ। ਇਸ ਟਿਊਟੋਰਿਅਲ ਵਿੱਚ ਅੱਗੇ, ਤੁਸੀਂ ਕੁਝ ਖਾਸ ਫੰਕਸ਼ਨ ਸਿੱਖੋਗੇ ਜੋ ਸਾਲ ਦੀ ਪਰਵਾਹ ਕੀਤੇ ਬਿਨਾਂ ਉਮਰ ਦੀ ਗਣਨਾ ਕਰਦੇ ਹਨ।
YEARFRAC ਫੰਕਸ਼ਨ ਨਾਲ ਜਨਮ ਮਿਤੀ ਤੋਂ ਉਮਰ ਦੀ ਗਣਨਾ ਕਰੋ
ਕਨਵਰਟ ਕਰਨ ਦਾ ਇੱਕ ਹੋਰ ਭਰੋਸੇਯੋਗ ਤਰੀਕਾ ਐਕਸਲ ਵਿੱਚ ਉਮਰ ਤੋਂ DOB YEARFRAC ਫੰਕਸ਼ਨ ਦੀ ਵਰਤੋਂ ਕਰ ਰਿਹਾ ਹੈ ਜੋਸਾਲ ਦਾ ਅੰਸ਼ ਵਾਪਸ ਕਰਦਾ ਹੈ, ਅਰਥਾਤ ਦੋ ਤਾਰੀਖਾਂ ਦੇ ਵਿਚਕਾਰ ਪੂਰੇ ਦਿਨਾਂ ਦੀ ਸੰਖਿਆ।
YEARFRAC ਫੰਕਸ਼ਨ ਦਾ ਸੰਟੈਕਸ ਇਸ ਤਰ੍ਹਾਂ ਹੈ:
YEARFRAC(start_date, end_date, [basis])The ਪਹਿਲੀਆਂ ਦੋ ਦਲੀਲਾਂ ਸਪੱਸ਼ਟ ਹਨ ਅਤੇ ਸ਼ਾਇਦ ਹੀ ਕਿਸੇ ਵਾਧੂ ਵਿਆਖਿਆ ਦੀ ਲੋੜ ਹੋਵੇ। ਬੇਸਿਸ ਇੱਕ ਵਿਕਲਪਿਕ ਆਰਗੂਮੈਂਟ ਹੈ ਜੋ ਵਰਤੋਂ ਲਈ ਦਿਨ ਦੀ ਗਿਣਤੀ ਦੇ ਆਧਾਰ ਨੂੰ ਪਰਿਭਾਸ਼ਿਤ ਕਰਦਾ ਹੈ।
ਬਿਲਕੁਲ ਸਹੀ ਉਮਰ ਫਾਰਮੂਲਾ ਬਣਾਉਣ ਲਈ, YEARFRAC ਫੰਕਸ਼ਨ ਨੂੰ ਹੇਠਾਂ ਦਿੱਤੇ ਮੁੱਲਾਂ ਦੀ ਸਪਲਾਈ ਕਰੋ:
- Start_date - ਜਨਮ ਮਿਤੀ।
- End_date - ਅੱਜ ਦੀ ਤਾਰੀਖ ਵਾਪਸ ਕਰਨ ਲਈ TODAY() ਫੰਕਸ਼ਨ।
- ਆਧਾਰ - ਆਧਾਰ ਦੀ ਵਰਤੋਂ ਕਰੋ 1 ਜੋ ਕਿ ਐਕਸਲ ਨੂੰ ਪ੍ਰਤੀ ਮਹੀਨਾ ਦਿਨਾਂ ਦੀ ਅਸਲ ਸੰਖਿਆ ਨੂੰ ਪ੍ਰਤੀ ਸਾਲ ਦਿਨਾਂ ਦੀ ਅਸਲ ਸੰਖਿਆ ਨਾਲ ਵੰਡਣ ਲਈ ਦੱਸਦਾ ਹੈ।
ਉਪਰੋਕਤ ਨੂੰ ਧਿਆਨ ਵਿੱਚ ਰੱਖਦੇ ਹੋਏ, ਗਣਨਾ ਕਰਨ ਲਈ ਇੱਕ ਐਕਸਲ ਫਾਰਮੂਲਾ। ਜਨਮ ਮਿਤੀ ਤੋਂ ਉਮਰ ਇਸ ਤਰ੍ਹਾਂ ਹੈ:
YEARFRAC( ਜਨਮ ਦੀ ਮਿਤੀ, TODAY(), 1)ਇਹ ਮੰਨ ਕੇ ਕਿ ਜਨਮ ਮਿਤੀ ਸੈੱਲ B2 ਵਿੱਚ ਹੈ, ਫਾਰਮੂਲਾ ਹੇਠ ਦਿੱਤੀ ਸ਼ਕਲ ਲੈਂਦਾ ਹੈ:
=YEARFRAC(B2, TODAY(), 1)
ਪਿਛਲੀ ਉਦਾਹਰਨ ਦੀ ਤਰ੍ਹਾਂ, YEARFRAC ਫੰਕਸ਼ਨ ਦਾ ਨਤੀਜਾ ਵੀ ਇੱਕ ਦਸ਼ਮਲਵ ਸੰਖਿਆ ਹੈ। ਇਸਨੂੰ ਠੀਕ ਕਰਨ ਲਈ, ਆਖਰੀ ਆਰਗੂਮੈਂਟ ਵਿੱਚ 0 ਨਾਲ ROUNDDOWN ਫੰਕਸ਼ਨ ਦੀ ਵਰਤੋਂ ਕਰੋ ਕਿਉਂਕਿ ਤੁਸੀਂ ਕੋਈ ਦਸ਼ਮਲਵ ਸਥਾਨ ਨਹੀਂ ਚਾਹੁੰਦੇ ਹੋ।
ਇਸ ਲਈ, Excel ਵਿੱਚ ਉਮਰ ਦੀ ਗਣਨਾ ਕਰਨ ਲਈ ਇੱਥੇ ਇੱਕ ਸੁਧਾਰਿਆ YEARFRAC ਫਾਰਮੂਲਾ ਹੈ:
=ROUNDDOWN(YEARFRAC(B2, TODAY(), 1), 0)
DATEDIF ਨਾਲ ਐਕਸਲ ਵਿੱਚ ਉਮਰ ਦੀ ਗਣਨਾ ਕਰੋ
ਐਕਸਲ ਵਿੱਚ ਜਨਮ ਮਿਤੀ ਨੂੰ ਉਮਰ ਵਿੱਚ ਬਦਲਣ ਦਾ ਇੱਕ ਹੋਰ ਤਰੀਕਾ DATEDIF ਫੰਕਸ਼ਨ ਦੀ ਵਰਤੋਂ ਕਰਨਾ ਹੈ:
DATEDIF(start_date, end_date, unit)ਇਹ ਫੰਕਸ਼ਨ ਵੱਖ-ਵੱਖ ਸਮੇਂ ਦੀਆਂ ਇਕਾਈਆਂ ਜਿਵੇਂ ਕਿ ਸਾਲ, ਮਹੀਨਿਆਂ ਅਤੇ ਦਿਨਾਂ ਵਿੱਚ ਦੋ ਮਿਤੀਆਂ ਵਿਚਕਾਰ ਅੰਤਰ ਨੂੰ ਵਾਪਸ ਕਰ ਸਕਦਾ ਹੈ, ਜੋ ਤੁਸੀਂ ਯੂਨਿਟ ਆਰਗੂਮੈਂਟ ਵਿੱਚ ਸਪਲਾਈ ਕਰਦੇ ਹੋ:
- Y - ਸ਼ੁਰੂਆਤੀ ਅਤੇ ਸਮਾਪਤੀ ਮਿਤੀਆਂ ਦੇ ਵਿਚਕਾਰ ਪੂਰੇ ਸਾਲਾਂ ਦੀ ਸੰਖਿਆ ਵਾਪਸ ਕਰਦਾ ਹੈ।
- M - ਵਿਚਕਾਰ ਪੂਰੇ ਮਹੀਨਿਆਂ ਦੀ ਸੰਖਿਆ ਵਾਪਸ ਕਰਦਾ ਹੈ ਮਿਤੀਆਂ।
- D - ਦੋ ਤਾਰੀਖਾਂ ਵਿਚਕਾਰ ਦਿਨਾਂ ਦੀ ਸੰਖਿਆ ਵਾਪਸ ਕਰਦਾ ਹੈ।
- YM - ਦਿਨਾਂ ਅਤੇ ਸਾਲਾਂ ਨੂੰ ਨਜ਼ਰਅੰਦਾਜ਼ ਕਰਦੇ ਹੋਏ, ਮਹੀਨੇ ਵਾਪਸ ਕਰਦਾ ਹੈ।
- MD - ਮਹੀਨਿਆਂ ਅਤੇ ਸਾਲਾਂ ਨੂੰ ਨਜ਼ਰਅੰਦਾਜ਼ ਕਰਦੇ ਹੋਏ, ਦਿਨਾਂ ਵਿੱਚ ਅੰਤਰ ਵਾਪਸ ਕਰਦਾ ਹੈ।
- YD - ਸਾਲਾਂ ਨੂੰ ਅਣਡਿੱਠ ਕਰਦੇ ਹੋਏ ਦਿਨਾਂ ਵਿੱਚ ਅੰਤਰ ਵਾਪਸ ਕਰਦਾ ਹੈ।
ਕਿਉਂਕਿ ਸਾਡਾ ਉਦੇਸ਼ ਉਮਰ ਸਾਲਾਂ ਵਿੱਚ ਗਣਨਾ ਕਰਨਾ ਹੈ, ਅਸੀਂ "y" ਯੂਨਿਟ ਦੀ ਵਰਤੋਂ ਕਰ ਰਹੇ ਹਾਂ:
DATEDIF( ਜਨਮ ਦੀ ਮਿਤੀ, TODAY(), "y")ਇਸ ਉਦਾਹਰਨ ਵਿੱਚ, DOB ਸੈੱਲ B2 ਵਿੱਚ ਹੈ, ਅਤੇ ਤੁਸੀਂ ਆਪਣੇ ਉਮਰ ਫਾਰਮੂਲੇ ਵਿੱਚ ਇਸ ਸੈੱਲ ਦਾ ਹਵਾਲਾ ਦਿੰਦੇ ਹੋ:
=DATEDIF(B2, TODAY(), "y")
ਇਸ ਕੇਸ ਵਿੱਚ ਕਿਸੇ ਵਾਧੂ ਰਾਊਂਡਿੰਗ ਫੰਕਸ਼ਨ ਦੀ ਲੋੜ ਨਹੀਂ ਹੈ ਕਿਉਂਕਿ t ਨਾਲ ਇੱਕ DATEDIF ਫਾਰਮੂਲਾ he "y" ਯੂਨਿਟ ਪੂਰੇ ਸਾਲਾਂ ਦੀ ਸੰਖਿਆ ਦੀ ਗਣਨਾ ਕਰਦਾ ਹੈ:
ਜਨਮ ਦਿਨ ਤੋਂ ਸਾਲ, ਮਹੀਨਿਆਂ ਅਤੇ ਦਿਨਾਂ ਵਿੱਚ ਉਮਰ ਕਿਵੇਂ ਪ੍ਰਾਪਤ ਕੀਤੀ ਜਾਵੇ
ਜਿਵੇਂ ਕਿ ਤੁਸੀਂ ਹੁਣੇ ਦੇਖਿਆ ਹੈ , ਵਿਅਕਤੀ ਦੁਆਰਾ ਜਿਉਣ ਵਾਲੇ ਪੂਰੇ ਸਾਲਾਂ ਦੀ ਗਿਣਤੀ ਵਜੋਂ ਉਮਰ ਦੀ ਗਣਨਾ ਕਰਨਾ ਆਸਾਨ ਹੈ, ਪਰ ਇਹ ਹਮੇਸ਼ਾ ਕਾਫ਼ੀ ਨਹੀਂ ਹੁੰਦਾ ਹੈ। ਜੇਕਰ ਤੁਸੀਂ ਸਹੀ ਉਮਰ ਜਾਣਨਾ ਚਾਹੁੰਦੇ ਹੋ, ਜਿਵੇਂ ਕਿ ਕਿਸੇ ਦੀ ਜਨਮ ਮਿਤੀ ਅਤੇ ਮੌਜੂਦਾ ਮਿਤੀ ਵਿਚਕਾਰ ਕਿੰਨੇ ਸਾਲ, ਮਹੀਨੇ ਅਤੇ ਦਿਨ ਹਨ, ਤਾਂ 3 ਲਿਖੋ।ਵੱਖ-ਵੱਖ DATEDIF ਫੰਕਸ਼ਨ:
- ਸਾਲਾਂ ਦੀ ਸੰਖਿਆ ਪ੍ਰਾਪਤ ਕਰਨ ਲਈ:
=DATEDIF(B2, TODAY(), "Y") - ਮਹੀਨਿਆਂ ਦੀ ਸੰਖਿਆ ਪ੍ਰਾਪਤ ਕਰਨ ਲਈ:
=DATEDIF(B2, TODAY(), "YM") - ਦਿਨਾਂ ਦੀ ਸੰਖਿਆ ਪ੍ਰਾਪਤ ਕਰਨ ਲਈ:
=DATEDIF(B2,TODAY(),"MD")
ਜਿੱਥੇ B2 ਜਨਮ ਮਿਤੀ ਹੈ।
ਅਤੇ ਫਿਰ, ਉਪਰੋਕਤ ਫੰਕਸ਼ਨਾਂ ਨੂੰ ਇੱਕ ਫਾਰਮੂਲੇ ਵਿੱਚ ਜੋੜੋ, ਇਸ ਤਰ੍ਹਾਂ:
=DATEDIF(B2,TODAY(),"Y") & DATEDIF(B2,TODAY(),"YM") & DATEDIF(B2,TODAY(),"MD")
ਉਪਰੋਕਤ ਫਾਰਮੂਲਾ 3 ਨੰਬਰਾਂ (ਸਾਲ, ਮਹੀਨੇ ਅਤੇ ਦਿਨ) ਨੂੰ ਇੱਕ ਸਿੰਗਲ ਟੈਕਸਟ ਸਤਰ ਵਿੱਚ ਜੋੜਦਾ ਹੈ, ਜਿਵੇਂ ਕਿ ਹੇਠਾਂ ਦਿੱਤੇ ਸਕ੍ਰੀਨਸ਼ੌਟ ਵਿੱਚ ਦਿਖਾਇਆ ਗਿਆ ਹੈ:
ਇਸਦਾ ਕੋਈ ਮਤਲਬ ਨਹੀਂ ਹੈ, ਓਹ ? ਨਤੀਜਿਆਂ ਨੂੰ ਵਧੇਰੇ ਅਰਥਪੂਰਨ ਬਣਾਉਣ ਲਈ, ਸੰਖਿਆਵਾਂ ਨੂੰ ਕਾਮਿਆਂ ਨਾਲ ਵੱਖ ਕਰੋ ਅਤੇ ਪਰਿਭਾਸ਼ਿਤ ਕਰੋ ਕਿ ਹਰੇਕ ਮੁੱਲ ਦਾ ਕੀ ਅਰਥ ਹੈ:
=DATEDIF(B2,TODAY(),"Y") & " Years, " & DATEDIF(B2,TODAY(),"YM") & " Months, " & DATEDIF(B2,TODAY(),"MD") & " Days"
ਨਤੀਜਾ ਹੁਣ ਬਹੁਤ ਵਧੀਆ ਦਿਖਾਈ ਦਿੰਦਾ ਹੈ:
ਫਾਰਮੂਲਾ ਵਧੀਆ ਕੰਮ ਕਰਦਾ ਹੈ, ਪਰ ਤੁਸੀਂ ਜ਼ੀਰੋ ਮੁੱਲਾਂ ਨੂੰ ਲੁਕਾ ਕੇ ਇਸ ਨੂੰ ਹੋਰ ਵੀ ਸੁਧਾਰ ਸਕਦੇ ਹੋ। ਇਸਦੇ ਲਈ, 3 IF ਸਟੇਟਮੈਂਟਾਂ ਜੋੜੋ ਜੋ 0 ਦੀ ਜਾਂਚ ਕਰਦੇ ਹਨ, ਹਰੇਕ DATEDIF ਲਈ ਇੱਕ:
=IF(DATEDIF(B2, TODAY(),"y")=0,"",DATEDIF(B2, TODAY(),"y")&" years, ")& IF(DATEDIF(B2, TODAY(),"ym")=0,"",DATEDIF(B2, TODAY(),"ym")&" months, ")& IF(DATEDIF(B2, TODAY(),"md")=0,"",DATEDIF(B2, TODAY(),"md")&" days")
ਹੇਠਾਂ ਦਿੱਤਾ ਸਕ੍ਰੀਨਸ਼ੌਟ ਅੰਤਮ ਐਕਸਲ ਉਮਰ ਫਾਰਮੂਲੇ ਨੂੰ ਅਮਲ ਵਿੱਚ ਦਰਸਾਉਂਦਾ ਹੈ - ਇਹ ਸਾਲਾਂ, ਮਹੀਨਿਆਂ ਵਿੱਚ ਉਮਰ ਵਾਪਸ ਕਰਦਾ ਹੈ, ਅਤੇ ਦਿਨ, ਸਿਰਫ ਗੈਰ-ਜ਼ੀਰੋ ਮੁੱਲ ਪ੍ਰਦਰਸ਼ਿਤ ਕਰਦੇ ਹੋਏ:
ਟਿਪ। ਜੇਕਰ ਤੁਸੀਂ ਸਾਲ ਅਤੇ ਮਹੀਨਿਆਂ ਵਿੱਚ ਉਮਰ ਦੀ ਗਣਨਾ ਕਰਨ ਲਈ ਇੱਕ ਐਕਸਲ ਫਾਰਮੂਲਾ ਲੱਭ ਰਹੇ ਹੋ, ਤਾਂ ਉਪਰੋਕਤ ਫਾਰਮੂਲਾ ਲਓ ਅਤੇ ਆਖਰੀ IF(DATEDIF()) ਬਲਾਕ ਨੂੰ ਹਟਾਓ ਜੋ ਦਿਨਾਂ ਦੀ ਗਣਨਾ ਕਰਦਾ ਹੈ।
ਵਿਸ਼ਿਸ਼ਟ ਫਾਰਮੂਲੇ ਐਕਸਲ ਵਿੱਚ ਉਮਰ ਦੀ ਗਣਨਾ ਕਰੋ
ਉੱਪਰ ਦੱਸੇ ਗਏ ਆਮ ਉਮਰ ਗਣਨਾ ਫਾਰਮੂਲੇ ਜ਼ਿਆਦਾਤਰ ਮਾਮਲਿਆਂ ਵਿੱਚ ਵਧੀਆ ਕੰਮ ਕਰਦੇ ਹਨ। ਕੁਝ ਸਥਿਤੀਆਂ ਵਿੱਚ, ਹਾਲਾਂਕਿ, ਤੁਹਾਨੂੰ ਕਿਸੇ ਖਾਸ ਚੀਜ਼ ਦੀ ਲੋੜ ਹੋ ਸਕਦੀ ਹੈ। ਬੇਸ਼ੱਕ, ਹਰ ਇੱਕ ਨੂੰ ਕਵਰ ਕਰਨਾ ਸੰਭਵ ਨਹੀਂ ਹੈਅਤੇ ਹਰੇਕ ਦ੍ਰਿਸ਼, ਪਰ ਹੇਠਾਂ ਦਿੱਤੀਆਂ ਉਦਾਹਰਨਾਂ ਤੁਹਾਨੂੰ ਇਸ ਬਾਰੇ ਕੁਝ ਵਿਚਾਰ ਦੇਣਗੀਆਂ ਕਿ ਤੁਸੀਂ ਆਪਣੇ ਖਾਸ ਕੰਮ ਦੇ ਆਧਾਰ 'ਤੇ ਉਮਰ ਦੇ ਫਾਰਮੂਲੇ ਨੂੰ ਕਿਵੇਂ ਬਦਲ ਸਕਦੇ ਹੋ।
ਐਕਸਲ ਵਿੱਚ ਕਿਸੇ ਖਾਸ ਮਿਤੀ 'ਤੇ ਉਮਰ ਦੀ ਗਣਨਾ ਕਿਵੇਂ ਕੀਤੀ ਜਾਵੇ
ਜੇ ਤੁਸੀਂ ਕਿਸੇ ਖਾਸ ਮਿਤੀ 'ਤੇ ਕਿਸੇ ਦੀ ਉਮਰ ਜਾਣਨਾ ਚਾਹੁੰਦੇ ਹੋ, ਉੱਪਰ ਦੱਸੇ DATEDIF ਉਮਰ ਫਾਰਮੂਲੇ ਦੀ ਵਰਤੋਂ ਕਰੋ, ਪਰ ਦੂਜੇ ਆਰਗੂਮੈਂਟ ਵਿੱਚ TODAY() ਫੰਕਸ਼ਨ ਨੂੰ ਖਾਸ ਮਿਤੀ ਨਾਲ ਬਦਲੋ।
ਇਹ ਮੰਨ ਕੇ ਕਿ ਜਨਮ ਮਿਤੀ B1 ਵਿੱਚ ਹੈ, ਨਿਮਨਲਿਖਤ ਫਾਰਮੂਲਾ 1 ਜਨਵਰੀ 2020 ਤੋਂ ਉਮਰ ਵਾਪਸ ਕਰੇਗਾ:
=DATEDIF(B1, "1/1/2020","Y") & " Years, " & DATEDIF(B1, "1/1/2020","YM") & " Months, " & DATEDIF(B1, "1/1/2020", "MD") & " Days"
ਤੁਹਾਡੇ ਉਮਰ ਫਾਰਮੂਲੇ ਨੂੰ ਵਧੇਰੇ ਲਚਕਦਾਰ ਬਣਾਉਣ ਲਈ, ਤੁਸੀਂ ਕਿਸੇ ਸੈੱਲ ਵਿੱਚ ਮਿਤੀ ਦਾਖਲ ਕਰ ਸਕਦੇ ਹੋ ਅਤੇ ਆਪਣੇ ਫਾਰਮੂਲੇ ਵਿੱਚ ਉਸ ਸੈੱਲ ਦਾ ਹਵਾਲਾ ਦੇ ਸਕਦੇ ਹੋ:
=DATEDIF(B1, B2,"Y") & " Years, "& DATEDIF(B1,B2,"YM") & " Months, "&DATEDIF(B1,B2, "MD") & " Days"
ਜਿੱਥੇ B1 DOB ਹੈ, ਅਤੇ B2 ਉਹ ਤਾਰੀਖ ਹੈ ਜਿਸ 'ਤੇ ਤੁਸੀਂ ਉਮਰ ਦੀ ਗਣਨਾ ਕਰਨਾ ਚਾਹੁੰਦੇ ਹੋ।
ਉਮਰ ਦੀ ਇੱਕ ਨਿਸ਼ਚਿਤ ਵਿੱਚ ਗਣਨਾ ਕਰੋ ਸਾਲ
ਇਹ ਫਾਰਮੂਲਾ ਉਹਨਾਂ ਸਥਿਤੀਆਂ ਵਿੱਚ ਕੰਮ ਆਉਂਦਾ ਹੈ ਜਦੋਂ ਗਣਨਾ ਕਰਨ ਦੀ ਪੂਰੀ ਮਿਤੀ ਪਰਿਭਾਸ਼ਿਤ ਨਹੀਂ ਕੀਤੀ ਗਈ ਹੈ, ਅਤੇ ਤੁਸੀਂ ਸਿਰਫ ਸਾਲ ਜਾਣਦੇ ਹੋ।
ਮੰਨ ਲਓ ਕਿ ਤੁਸੀਂ ਇੱਕ ਮੈਡੀਕਲ ਡੇਟਾਬੇਸ ਨਾਲ ਕੰਮ ਕਰ ਰਹੇ ਹੋ, ਅਤੇ ਤੁਹਾਡੇ ਟੀਚਾ ਮਰੀਜ਼ਾਂ ਦੀ ਉਮਰ ਦਾ ਪਤਾ ਲਗਾਉਣਾ ਹੈ ਜਿਸ ਸਮੇਂ ਉਹ ਘੱਟ ਹਨ ਆਖਰੀ ਪੂਰੀ ਡਾਕਟਰੀ ਜਾਂਚ ਕੀਤੀ।
ਇਹ ਮੰਨਦੇ ਹੋਏ ਕਿ ਜਨਮ ਤਾਰੀਖਾਂ ਕਤਾਰ 3 ਤੋਂ ਸ਼ੁਰੂ ਹੋਣ ਵਾਲੇ ਕਾਲਮ B ਵਿੱਚ ਹਨ, ਅਤੇ ਆਖਰੀ ਡਾਕਟਰੀ ਜਾਂਚ ਦਾ ਸਾਲ ਕਾਲਮ C ਵਿੱਚ ਹੈ, ਉਮਰ ਦੀ ਗਣਨਾ ਦਾ ਫਾਰਮੂਲਾ ਇਸ ਤਰ੍ਹਾਂ ਹੈ:
=DATEDIF(B3,DATE(C3, 1, 1),"y")
ਕਿਉਂਕਿ ਡਾਕਟਰੀ ਜਾਂਚ ਦੀ ਸਹੀ ਮਿਤੀ ਪਰਿਭਾਸ਼ਿਤ ਨਹੀਂ ਕੀਤੀ ਗਈ ਹੈ, ਤੁਸੀਂ DATE ਫੰਕਸ਼ਨ ਨੂੰ ਇੱਕ ਆਰਬਿਟਰੇਰੀ ਮਿਤੀ ਅਤੇ ਮਹੀਨੇ ਦੀ ਦਲੀਲ ਨਾਲ ਵਰਤਦੇ ਹੋ, ਉਦਾਹਰਨ ਲਈ. ਮਿਤੀ(C3, 1, 1)।
ਦDATE ਫੰਕਸ਼ਨ ਸੈੱਲ B3 ਤੋਂ ਸਾਲ ਕੱਢਦਾ ਹੈ, ਤੁਹਾਡੇ ਦੁਆਰਾ ਸਪਲਾਈ ਕੀਤੇ ਗਏ ਮਹੀਨੇ ਅਤੇ ਦਿਨ ਦੇ ਨੰਬਰਾਂ ਦੀ ਵਰਤੋਂ ਕਰਕੇ ਇੱਕ ਪੂਰੀ ਤਾਰੀਖ ਬਣਾਉਂਦਾ ਹੈ (ਇਸ ਉਦਾਹਰਨ ਵਿੱਚ 1-ਜਨਵਰੀ), ਅਤੇ ਉਸ ਮਿਤੀ ਨੂੰ DATEDIF ਨੂੰ ਪਾਸ ਕਰਦਾ ਹੈ। ਨਤੀਜੇ ਵਜੋਂ, ਤੁਸੀਂ ਮਰੀਜ਼ ਦੀ ਉਮਰ ਕਿਸੇ ਖਾਸ ਸਾਲ ਦੀ 1 ਜਨਵਰੀ ਤੋਂ ਪ੍ਰਾਪਤ ਕਰਦੇ ਹੋ:
ਇੱਕ ਮਿਤੀ ਦਾ ਪਤਾ ਲਗਾਓ ਜਦੋਂ ਕੋਈ ਵਿਅਕਤੀ N ਸਾਲ ਦੀ ਉਮਰ ਦਾ ਹੋ ਜਾਂਦਾ ਹੈ
<0 ਮੰਨ ਲਓ ਕਿ ਤੁਹਾਡੇ ਦੋਸਤ ਦਾ ਜਨਮ 8 ਮਾਰਚ 1978 ਨੂੰ ਹੋਇਆ ਸੀ। ਤੁਸੀਂ ਕਿਵੇਂ ਜਾਣਦੇ ਹੋ ਕਿ ਉਹ ਆਪਣੀ ਉਮਰ ਦੇ 50 ਸਾਲ ਕਿਸ ਤਾਰੀਖ ਨੂੰ ਪੂਰਾ ਕਰਦਾ ਹੈ? ਆਮ ਤੌਰ 'ਤੇ, ਤੁਸੀਂ ਵਿਅਕਤੀ ਦੀ ਜਨਮ ਮਿਤੀ ਵਿੱਚ ਸਿਰਫ਼ 50 ਸਾਲ ਜੋੜਦੇ ਹੋ। ਐਕਸਲ ਵਿੱਚ, ਤੁਸੀਂ DATE ਫੰਕਸ਼ਨ ਦੀ ਵਰਤੋਂ ਕਰਕੇ ਅਜਿਹਾ ਕਰਦੇ ਹੋ: =DATE(YEAR(B2) + 50, MONTH(B2), DAY(B2))
ਜਿੱਥੇ B2 ਜਨਮ ਮਿਤੀ ਹੈ।
ਵਿੱਚ ਸਾਲਾਂ ਦੀ ਸੰਖਿਆ ਨੂੰ ਹਾਰਡ-ਕੋਡਿੰਗ ਕਰਨ ਦੀ ਬਜਾਏ ਫਾਰਮੂਲਾ, ਤੁਸੀਂ ਇੱਕ ਖਾਸ ਸੈੱਲ ਦਾ ਹਵਾਲਾ ਦੇ ਸਕਦੇ ਹੋ ਜਿੱਥੇ ਤੁਹਾਡੇ ਉਪਭੋਗਤਾ ਕਿਸੇ ਵੀ ਸਾਲ (ਹੇਠਾਂ ਦਿੱਤੇ ਸਕ੍ਰੀਨਸ਼ਾਟ ਵਿੱਚ F1) ਇਨਪੁਟ ਕਰ ਸਕਦੇ ਹਨ:
ਦਿਨ, ਮਹੀਨੇ ਅਤੇ ਸਾਲ ਤੋਂ ਵੱਖ-ਵੱਖ ਰੂਪਾਂ ਵਿੱਚ ਉਮਰ ਦੀ ਗਣਨਾ ਕਰੋ ਸੈੱਲ
ਜਦੋਂ ਇੱਕ ਜਨਮ ਮਿਤੀ 3 ਵੱਖ-ਵੱਖ ਸੈੱਲਾਂ ਵਿੱਚ ਵੰਡੀ ਜਾਂਦੀ ਹੈ (ਜਿਵੇਂ ਕਿ ਸਾਲ B3 ਵਿੱਚ, ਮਹੀਨਾ C3 ਵਿੱਚ ਅਤੇ ਦਿਨ D3 ਵਿੱਚ), ਤੁਸੀਂ ਇਸ ਤਰੀਕੇ ਨਾਲ ਉਮਰ ਦੀ ਗਣਨਾ ਕਰ ਸਕਦੇ ਹੋ:
- ਪ੍ਰਾਪਤ ਕਰੋ DATE ਅਤੇ DATEVALUE ਫੰਕਸ਼ਨਾਂ ਦੀ ਵਰਤੋਂ ਕਰਕੇ ਜਨਮ ਮਿਤੀ:
DATE(B3,MONTH(DATEVALUE(C3&"1")),D3) - ਉਪਰੋਕਤ ਫਾਰਮੂਲੇ ਨੂੰ DATEDIF ਵਿੱਚ ਜੋੜੋ ਤਾਂ ਜੋ ਜਨਮ ਮਿਤੀ ਤੋਂ ਸਾਲ, ਮਹੀਨਿਆਂ ਅਤੇ ਦਿਨਾਂ ਵਿੱਚ ਉਮਰ ਦੀ ਗਣਨਾ ਕੀਤੀ ਜਾ ਸਕੇ:
=DATEDIF(DATE(B3, MONTH(DATEVALUE(C3&"1")), D3), TODAY(), "y") & " Years, "& DATEDIF(DATE(B3, MONTH(DATEVALUE(C3&"1")), D3),TODAY(), "ym") & " Months, "& DATEDIF(DATE(B3, MONTH(DATEVALUE(C3&"1")), D3), TODAY(), "md") & " Days"
ਕਿਸੇ ਮਿਤੀ ਤੋਂ ਪਹਿਲਾਂ/ਬਾਅਦ ਦੇ ਦਿਨਾਂ ਦੀ ਸੰਖਿਆ ਦੀ ਗਣਨਾ ਕਰਨ ਦੀਆਂ ਹੋਰ ਉਦਾਹਰਣਾਂ ਲਈ, ਕਿਰਪਾ ਕਰਕੇ ਐਕਸਲ ਵਿੱਚ ਇਸ ਤੋਂ ਬਾਅਦ ਜਾਂ ਹੁਣ ਤੱਕ ਦੇ ਦਿਨਾਂ ਦੀ ਗਣਨਾ ਕਿਵੇਂ ਕਰਨੀ ਹੈ ਵੇਖੋ।
ਉਮਰ ਐਕਸਲ ਵਿੱਚ ਕੈਲਕੁਲੇਟਰ
ਜੇਕਰ ਤੁਸੀਂ ਆਪਣਾ ਖੁਦ ਦਾ ਹੋਣਾ ਚਾਹੁੰਦੇ ਹੋਐਕਸਲ ਵਿੱਚ ਉਮਰ ਕੈਲਕੁਲੇਟਰ, ਤੁਸੀਂ ਹੇਠਾਂ ਦੱਸੇ ਗਏ ਕੁਝ ਵੱਖਰੇ DATEDIF ਫਾਰਮੂਲੇ ਦੀ ਵਰਤੋਂ ਕਰਕੇ ਇੱਕ ਬਣਾ ਸਕਦੇ ਹੋ। ਜੇਕਰ ਤੁਸੀਂ ਪਹੀਏ ਨੂੰ ਦੁਬਾਰਾ ਨਹੀਂ ਬਣਾਉਣਾ ਚਾਹੁੰਦੇ ਹੋ, ਤਾਂ ਤੁਸੀਂ ਸਾਡੇ ਐਕਸਲ ਪੇਸ਼ੇਵਰਾਂ ਦੁਆਰਾ ਬਣਾਏ ਗਏ ਉਮਰ ਕੈਲਕੁਲੇਟਰ ਦੀ ਵਰਤੋਂ ਕਰ ਸਕਦੇ ਹੋ।
ਐਕਸਲ ਵਿੱਚ ਉਮਰ ਕੈਲਕੁਲੇਟਰ ਕਿਵੇਂ ਬਣਾਇਆ ਜਾਵੇ
ਹੁਣ ਜਦੋਂ ਤੁਸੀਂ ਜਾਣਦੇ ਹੋ ਐਕਸਲ ਵਿੱਚ ਉਮਰ ਫਾਰਮੂਲਾ, ਤੁਸੀਂ ਇੱਕ ਕਸਟਮ ਉਮਰ ਕੈਲਕੁਲੇਟਰ ਬਣਾ ਸਕਦੇ ਹੋ, ਉਦਾਹਰਨ ਲਈ ਇਹ ਇੱਕ:
ਨੋਟ। ਏਮਬੈਡਡ ਵਰਕਬੁੱਕ ਨੂੰ ਦੇਖਣ ਲਈ, ਕਿਰਪਾ ਕਰਕੇ ਮਾਰਕੀਟਿੰਗ ਕੂਕੀਜ਼ ਦੀ ਇਜਾਜ਼ਤ ਦਿਓ।
ਜੋ ਤੁਸੀਂ ਉੱਪਰ ਦੇਖਦੇ ਹੋ ਉਹ ਇੱਕ ਏਮਬੈਡਡ ਐਕਸਲ ਔਨਲਾਈਨ ਸ਼ੀਟ ਹੈ, ਇਸ ਲਈ ਸੰਬੰਧਿਤ ਸੈੱਲ ਵਿੱਚ ਆਪਣੀ ਜਨਮ ਮਿਤੀ ਦਰਜ ਕਰਨ ਲਈ ਬੇਝਿਜਕ ਮਹਿਸੂਸ ਕਰੋ, ਅਤੇ ਤੁਹਾਨੂੰ ਇੱਕ ਪਲ ਵਿੱਚ ਤੁਹਾਡੀ ਉਮਰ ਮਿਲ ਜਾਵੇਗੀ।
ਕੈਲਕੁਲੇਟਰ ਸੈੱਲ A3 ਵਿੱਚ ਜਨਮ ਮਿਤੀ ਅਤੇ ਅੱਜ ਦੀ ਮਿਤੀ ਦੇ ਆਧਾਰ 'ਤੇ ਉਮਰ ਦੀ ਗਣਨਾ ਕਰਨ ਲਈ ਹੇਠਾਂ ਦਿੱਤੇ ਫਾਰਮੂਲੇ ਦੀ ਵਰਤੋਂ ਕਰਦਾ ਹੈ।
- B5 ਵਿੱਚ ਫਾਰਮੂਲਾ ਸਾਲਾਂ, ਮਹੀਨਿਆਂ ਅਤੇ ਦਿਨਾਂ ਵਿੱਚ ਉਮਰ ਦੀ ਗਣਨਾ ਕਰਦਾ ਹੈ:
=DATEDIF(B2,TODAY(),"Y") & " Years, " & DATEDIF(B2,TODAY(),"YM") & " Months, " & DATEDIF(B2,TODAY(),"MD") & " Days" - B6 ਵਿੱਚ ਫਾਰਮੂਲਾ ਮਹੀਨਿਆਂ ਵਿੱਚ ਉਮਰ ਦੀ ਗਣਨਾ ਕਰਦਾ ਹੈ:
=DATEDIF($B$3,TODAY(),"m") - B7 ਵਿੱਚ ਫਾਰਮੂਲਾ ਦਿਨਾਂ ਵਿੱਚ ਉਮਰ ਦੀ ਗਣਨਾ ਕਰਦਾ ਹੈ:
=DATEDIF($B$3,TODAY(),"d")
ਜੇਕਰ ਤੁਹਾਡੇ ਕੋਲ ਐਕਸਲ ਫਾਰਮ ਨਿਯੰਤਰਣਾਂ ਨਾਲ ਕੁਝ ਅਨੁਭਵ ਹੈ, ਤੁਸੀਂ ਕਿਸੇ ਖਾਸ ਮਿਤੀ 'ਤੇ ਉਮਰ ਦੀ ਗਣਨਾ ਕਰਨ ਲਈ ਇੱਕ ਵਿਕਲਪ ਸ਼ਾਮਲ ਕਰ ਸਕਦੇ ਹੋ, ਜਿਵੇਂ ਕਿ ਹੇਠਾਂ ਦਿੱਤੇ ਸਕ੍ਰੀਨਸ਼ਾਟ ਵਿੱਚ ਦਿਖਾਇਆ ਗਿਆ ਹੈ:
ਇਸਦੇ ਲਈ, ਕੁਝ ਵਿਕਲਪ ਬਟਨ ਸ਼ਾਮਲ ਕਰੋ ( ਡਿਵੈਲਪਰ ਟੈਬ > ਇਨਸਰਟ ਕਰੋ > ਫਾਰਮ ਕੰਟਰੋਲ > ਵਿਕਲਪ ਬਟਨ ), ਅਤੇ ਉਹਨਾਂ ਨੂੰ ਕਿਸੇ ਸੈੱਲ ਨਾਲ ਲਿੰਕ ਕਰੋ। ਅਤੇ ਫਿਰ, ਅੱਜ ਦੀ ਮਿਤੀ 'ਤੇ ਜਾਂ ਉਪਭੋਗਤਾ ਦੁਆਰਾ ਨਿਰਧਾਰਤ ਮਿਤੀ 'ਤੇ ਉਮਰ ਪ੍ਰਾਪਤ ਕਰਨ ਲਈ ਇੱਕ IF/DATEDIF ਫਾਰਮੂਲਾ ਲਿਖੋ।
ਫ਼ਾਰਮੂਲਾ ਹੇਠਾਂ ਦਿੱਤੇ ਨਾਲ ਕੰਮ ਕਰਦਾ ਹੈ।ਤਰਕ:
- ਜੇਕਰ ਅੱਜ ਦੀ ਮਿਤੀ ਵਿਕਲਪ ਬਾਕਸ ਨੂੰ ਚੁਣਿਆ ਜਾਂਦਾ ਹੈ, ਤਾਂ ਮੁੱਲ 1 ਲਿੰਕ ਕੀਤੇ ਸੈੱਲ ਵਿੱਚ ਦਿਖਾਈ ਦਿੰਦਾ ਹੈ (ਇਸ ਉਦਾਹਰਨ ਵਿੱਚ I5), ਅਤੇ ਉਮਰ ਫਾਰਮੂਲਾ ਅੱਜ ਦੀ ਮਿਤੀ ਦੇ ਆਧਾਰ 'ਤੇ ਗਣਨਾ ਕਰਦਾ ਹੈ। :
IF($I$5=1, DATEDIF($B$3,TODAY(),"Y") & " Years, " & DATEDIF($B$3,TODAY(), "YM") & " Months, " & DATEDIF($B$3, TODAY(), "MD") & " Days") - ਜੇਕਰ ਖਾਸ ਮਿਤੀ ਵਿਕਲਪ ਬਟਨ ਨੂੰ ਚੁਣਿਆ ਜਾਂਦਾ ਹੈ ਅਤੇ ਸੈੱਲ B7 ਵਿੱਚ ਇੱਕ ਮਿਤੀ ਦਰਜ ਕੀਤੀ ਜਾਂਦੀ ਹੈ, ਤਾਂ ਉਮਰ ਦੀ ਗਣਨਾ ਨਿਰਧਾਰਤ ਮਿਤੀ 'ਤੇ ਕੀਤੀ ਜਾਂਦੀ ਹੈ:
IF(ISNUMBER($B$7), DATEDIF($B$3, $B$7,"Y") & " Years, " & DATEDIF($B$3, $B$7,"YM") & " Months, " & DATEDIF($B$3, $B$7,"MD") & " Days", ""))
ਅੰਤ ਵਿੱਚ , ਉਪਰੋਕਤ ਫੰਕਸ਼ਨਾਂ ਨੂੰ ਇੱਕ ਦੂਜੇ ਵਿੱਚ ਨੇਸਟ ਕਰੋ, ਅਤੇ ਤੁਹਾਨੂੰ ਪੂਰਾ ਉਮਰ ਗਣਨਾ ਫਾਰਮੂਲਾ ਮਿਲੇਗਾ (B9 ਵਿੱਚ):
=IF($I$5=1, DATEDIF($B$3, TODAY(), "Y") & " Years, " & DATEDIF($B$3, TODAY(), "YM") & " Months, " & DATEDIF($B$3, TODAY(), "MD") & " Days", IF(ISNUMBER($B$7), DATEDIF($B$3, $B$7,"Y") & " Years, " & DATEDIF($B$3, $B$7,"YM") & " Months, " & DATEDIF($B$3, $B$7,"MD") & " Days", ""))
B10 ਅਤੇ B11 ਵਿੱਚ ਫਾਰਮੂਲੇ ਇੱਕੋ ਤਰਕ ਨਾਲ ਕੰਮ ਕਰਦੇ ਹਨ। ਬੇਸ਼ੱਕ, ਉਹ ਬਹੁਤ ਸਰਲ ਹਨ ਕਿਉਂਕਿ ਉਹਨਾਂ ਵਿੱਚ ਕ੍ਰਮਵਾਰ ਪੂਰੇ ਮਹੀਨਿਆਂ ਜਾਂ ਦਿਨਾਂ ਦੀ ਸੰਖਿਆ ਵਜੋਂ ਉਮਰ ਵਾਪਸ ਕਰਨ ਲਈ ਸਿਰਫ਼ ਇੱਕ DATEDIF ਫੰਕਸ਼ਨ ਸ਼ਾਮਲ ਹੈ।
ਵੇਰਵੇ ਜਾਣਨ ਲਈ, ਮੈਂ ਤੁਹਾਨੂੰ ਇਸ ਐਕਸਲ ਉਮਰ ਕੈਲਕੁਲੇਟਰ ਨੂੰ ਡਾਊਨਲੋਡ ਕਰਨ ਅਤੇ ਜਾਂਚ ਕਰਨ ਲਈ ਸੱਦਾ ਦਿੰਦਾ ਹਾਂ। ਸੈੱਲ B9:B11 ਵਿੱਚ ਫਾਰਮੂਲੇ।
ਐਕਸਲ ਲਈ ਉਮਰ ਕੈਲਕੁਲੇਟਰ ਡਾਊਨਲੋਡ ਕਰੋ
ਐਕਸਲ ਲਈ ਵਰਤੋਂ ਲਈ ਤਿਆਰ ਉਮਰ ਕੈਲਕੁਲੇਟਰ
ਸਾਡੇ ਅਲਟੀਮੇਟ ਸੂਟ ਦੇ ਉਪਭੋਗਤਾਵਾਂ ਕੋਲ ਨਹੀਂ ਹੈ ਐਕਸਲ ਵਿੱਚ ਆਪਣੇ ਖੁਦ ਦੇ ਉਮਰ ਕੈਲਕੁਲੇਟਰ ਬਣਾਉਣ ਦੀ ਚਿੰਤਾ ਕਰਨ ਲਈ - ਇਹ ਸਿਰਫ ਕੁਝ ਕਲਿੱਕਾਂ ਦੀ ਦੂਰੀ 'ਤੇ ਹੈ:
- ਇੱਕ ਸੈੱਲ ਚੁਣੋ ਜਿੱਥੇ ਤੁਸੀਂ ਉਮਰ ਫਾਰਮੂਲਾ ਪਾਉਣਾ ਚਾਹੁੰਦੇ ਹੋ, ਐਬਲਬਿਟਸ ਟੂਲਸ<'ਤੇ ਜਾਓ। 2> ਟੈਬ > ਮਿਤੀ & ਸਮਾਂ ਸਮੂਹ, ਅਤੇ ਕਲਿੱਕ ਕਰੋ ਤਾਰੀਖ & ਟਾਈਮ ਵਿਜ਼ਾਰਡ ਬਟਨ।
- ਤਾਰੀਕ & ਟਾਈਮ ਵਿਜ਼ਾਰਡ ਸ਼ੁਰੂ ਹੋ ਜਾਵੇਗਾ, ਅਤੇ ਤੁਸੀਂ ਸਿੱਧੇ ਉਮਰ ਟੈਬ 'ਤੇ ਜਾਂਦੇ ਹੋ।
- ਉਮਰ ਟੈਬ 'ਤੇ, ਤੁਹਾਡੇ ਲਈ ਨਿਰਧਾਰਤ ਕਰਨ ਲਈ 3 ਚੀਜ਼ਾਂ ਹਨ:
- ਜਨਮ ਦਾ ਡੇਟਾ ਏ
