Упатството прикажува различни начини за добивање возраст од роденден во Excel. Ќе научите неколку формули за да ја пресметате возраста како број на целосни години, да ја добиете точната возраст во години, месеци и денови на денешниот датум или одреден датум.

Нема посебна функција за пресметување возраста во Excel, но постојат неколку различни начини за претворање на датумот на раѓање во возраст. Овој туторијал ќе ги објасни предностите и недостатоците на секој начин, покажува како да направите совршена формула за пресметување возраст во Excel и да ја прилагодите за решавање на некои специфични задачи.

Како да ја пресметате возраста од датум на раѓање во Excel

Во секојдневниот живот, прашањето „ Колку години имаш? “ обично подразбира одговор кој покажува колку години сте живи. Во Microsoft Excel, можете да направите формула за да пресметате точна возраст во месеци, денови, часови, па дури и минути. Но, ајде да бидеме традиционални и прво да научиме како да ја пресметаме возраста од DOB во години.

Основна формула на Excel за возраста во години

Како вообичаено ја одредувате нечија возраст? Едноставно со одземање на датумот на раѓање од тековниот датум. Оваа конвенционална формула за возраст може да се користи и во Excel.

Претпоставувајќи дека датумот на раѓање е во ќелијата B2, формулата за пресметување на возраста во години оди на следниов начин:

=(TODAY()-B2)/365

The првиот дел од формулата (TODAY()-B2) ја враќа разликата помеѓу тековниот датум и датумот на раѓање е денови, а потоа ја делитереференца на ќелија или датум во формат мм/дд/гггг.

Готово!

Формулата моментално се вметнува во избраната ќелија, а вие кликнете двапати на рачката за пополнување за да ја копирате во колоната.

Како што можеби забележавте, формулата создадена од нашиот Excel калкулатор за возраста е посложена од оние што ги дискутиравме досега, но се грижи за еднина и множина на временски единици како што се „ден“ и „денови“.

Ако сакате да се ослободите од нула единици како „0 дена“, изберете го полето за избор Не покажувај нула единици :

Ако сте љубопитни да го тестирате овој калкулатор за возраст, како и да откриете уште 60 додатоци за Excel за заштеда на време, добредојдени сте да преземете пробна верзија на нашиот Ultimate Suite на крајот од овој пост.

Како да истакнете одредени возрасти (под или над а специфична возраст)

Во некои ситуации, можеби ќе треба не само да ја пресметате возраста во Excel, туку и да ги потенцирате ќелиите кои содржат возрасти кои се под или над одредена возраст.

Ако формулата за пресметување на вашата возраст го враќа бројот на целосни години, а потоа можете да креирате редовно правило за условно форматирање врз основа на едноставна формула како овие:

• За да се истакнат возрасти еднакви или поголеми од18: =$C2>=18
• За означување на возраст под 18 години: =$C2<18

Каде што C2 е најгорната ќелија во колоната Age (не вклучувајќи ја заглавие на колоната).

Но, што ако вашата формула ја прикажува возраста во години и месеци или во години, месеци и денови? Во овој случај, ќе треба да креирате правило засновано на формулата DATEDIF која ја пресметува возраста од датумот на раѓање во години.

Да претпоставиме дека датумите на раѓање се во колоната Б, почнувајќи од редот 2, формулите се како што следува:

• За истакнување на возраста под 18 (жолта): =DATEDIF($B2, TODAY(),"Y")<18
• За истакнување на возраста помеѓу 18 и 65 години (зелена): =AND(DATEDIF($B2, TODAY(),"Y")>=18, DATEDIF($B2, TODAY(),"Y")<=65)
• За означување возрасти над 65 (сино): =DATEDIF($B2, TODAY(),"Y")>65

За да креирате правила врз основа на горенаведените формули, изберете ги ќелиите или цели редови што сакате да ги означите , одете во групата Дома > Стилови и кликнете Условно форматирање > Ново правило... > Користете формула за одредување кои ќелии да се форматираат .

Деталните чекори можете да ги најдете овде: Како да направите правило за условно форматирање врз основа на формулата.

Вака ја пресметувате возраста во Excel. Се надевам дека формулите ви беа лесни за учење и ќе ги пробате во вашите работни листови. Ви благодариме што прочитавте и се надеваме дека ќе се видиме на нашиот блог следната недела!

Достапни преземања

Примери за пресметување на возраста на Excel (датотека .xlsx)

14-дневен Ultimate Suite целосно -функционална верзија (датотека .exe)

Формулата е очигледна и лесна за паметење, сепак, постои мал проблем. Во повеќето случаи, враќа децимален број како што е прикажано на сликата подолу.

За да се прикаже бројот на цели години, користете ја функцијата INT за да заокружите децимална надолу на најблискиот цел број:

=INT((TODAY()-B2)/365)

Недостатоци: Користењето на оваа формула за возраст во Excel дава прилично точни резултати, но не и беспрекорни. Поделувањето со просечниот број на денови во годината најчесто функционира добро, но понекогаш погрешно ја прави возраста. На пример, ако некој е роден на 29 февруари, а денес е 28 февруари, формулата ќе го направи човекот еден ден постар.

Како алтернатива, може да се подели со 365,25 наместо 365 бидејќи секоја четврта година има 366 денови. Сепак, ниту овој пристап не е совршен. На пример, ако ја пресметувате возраста на детето кое сè уште не преживеало престапна година, делењето со 365,25 дава погрешен резултат.

Генерално, одземањето на датумот на раѓање од тековниот датум функционира одлично во нормален живот, но не е идеален пристап во Excel. Понатаму во ова упатство, ќе научите неколку специјални функции кои беспрекорно ја пресметуваат возраста, без разлика на годината.

Пресметајте ја возраста од датумот на раѓање со функцијата YEARFRAC

Посигурен начин за претворање DOB to age во Excel ја користи функцијата YEARFRAC којаго враќа делот од годината, т.е. бројот на цели денови помеѓу два датума.

Синтаксата на функцијата YEARFRAC е следна:

првите два аргументи се очигледни и едвај бараат дополнително објаснување. Основа е изборен аргумент кој ја дефинира основата за броење на денови што треба да се користи.

За да се направи совршено вистинска формула за возраста, доставете ги следните вредности на функцијата YEARFRAC:

• Start_date - датум на раѓање.
• End_Date - TODAY() функција за враќање на денешниот датум.
• Основа - користете ја основата 1 која му кажува на Excel да го подели вистинскиот број на денови месечно со вистинскиот број на денови годишно.

Со оглед на горенаведеното, Excel формула за пресметување возраста од датумот на раѓање е како што следува:

Претпоставувајќи дека датумот на раѓање е во ќелијата B2, формулата ја добива следната форма:

=YEARFRAC(B2, TODAY(), 1)

Како и во претходниот пример, резултатот од функцијата YEARFRAC е исто така децимален број. За да го поправите ова, користете ја функцијата ROUNDDOWN со 0 во последниот аргумент бидејќи не сакате децимали.

Значи, еве ја подобрената формула YEARFRAC за пресметување на возраста во Excel:

=ROUNDDOWN(YEARFRAC(B2, TODAY(), 1), 0)

Пресметај возраст во Excel со DATEDIF

Уште еден начин за претворање на датумот на раѓање во возраст во Excel е користење на функцијата DATEDIF:

Оваа функција може да ја врати разликата помеѓу два датуми во различни временски единици, како што се години, месеци и денови, во зависност од вредноста што ја давате во аргументот единица :

• Y - го враќа бројот на целосни години помеѓу датумите на почеток и крај.
• M - го враќа бројот на целосни месеци помеѓу датумите.
• D - го враќа бројот на денови помеѓу двата датума.
• YM - враќа месеци , игнорирајќи ги деновите и годините.
• MD - ја враќа разликата во денови , игнорирајќи месеци и години.
• YD - ја враќа разликата во денови , игнорирајќи ги годините.

Бидејќи имаме за цел да пресметаме возраст за години , ја користиме единицата „y“:

Во овој пример, DOB е во ќелијата B2, а вие ја повикувате оваа ќелија во формулата за вашата возраст:

=DATEDIF(B2, TODAY(), "y")

Не е потребна дополнителна функција за заокружување во овој случај бидејќи формулата DATEDIF со t единицата „y“ го пресметува бројот на полни години:

Како да ја добиете возраста од роденден во години, месеци и денови

Како што штотуку видовте , пресметувањето на возраста како број на полни години што ги живеело лицето е лесно, но не е секогаш доволно. Ако сакате да ја знаете точната возраст, односно колку години, месеци и денови има помеѓу нечиј датум на раѓање и тековниот датум, напишете 3различни функции DATEDIF:

1. За да го добиете бројот на години: =DATEDIF(B2, TODAY(), "Y")
2. За да го добиете бројот на месеци: =DATEDIF(B2, TODAY(), "YM")
3. За да го добиете бројот на денови: =DATEDIF(B2,TODAY(),"MD")

Каде B2 е датумот на раѓање.

И потоа, спојте ги горенаведените функции во една формула, вака:

=DATEDIF(B2,TODAY(),"Y") & DATEDIF(B2,TODAY(),"YM") & DATEDIF(B2,TODAY(),"MD")

Горенаведената формула враќа 3 броеви (години, месеци и денови) споени во една текстуална низа, како што е прикажано на екранот подолу:

Нема многу смисла, ух ? За да ги направите резултатите позначајни, одделете ги броевите со запирки и дефинирајте што значи секоја вредност:

=DATEDIF(B2,TODAY(),"Y") & " Years, " & DATEDIF(B2,TODAY(),"YM") & " Months, " & DATEDIF(B2,TODAY(),"MD") & " Days"

Резултатот сега изгледа многу подобро:

Формулата работи одлично, но можете уште повеќе да ја подобрите со криење на нула вредности. За ова, додадете 3 IF изјави кои проверуваат за 0, по еден на секој DATEDIF:

=IF(DATEDIF(B2, TODAY(),"y")=0,"",DATEDIF(B2, TODAY(),"y")&" years, ")& IF(DATEDIF(B2, TODAY(),"ym")=0,"",DATEDIF(B2, TODAY(),"ym")&" months, ")& IF(DATEDIF(B2, TODAY(),"md")=0,"",DATEDIF(B2, TODAY(),"md")&" days")

Следната слика од екранот ја покажува конечната формула за возраст на Excel во акција - ја враќа староста во години, месеци, и денови, прикажувајќи само не-нула вредности:

Совет. Ако барате формула на Excel за пресметување на возраста во години и месеци , земете ја горната формула и отстранете го последниот блок IF(DATEDIF()) што ги пресметува деновите.

Специфични формули за пресметајте ја возраста во Excel

Генеричките формули за пресметување на возраста дискутирани погоре функционираат одлично во повеќето случаи. Меѓутоа, во некои ситуации, можеби ќе ви треба нешто многу специфично. Се разбира, не е можно да се покрие секоји секое сценарио, но следните примери ќе ви дадат неколку идеи за тоа како можете да ја измените формулата за возраст во зависност од вашата конкретна задача.

Како да ја пресметате возраста на одреден датум во Excel

Ако сакате да знаете нечија возраст на одреден датум, користете ја формулата за возраст DATEDIF дискутирана погоре, но заменете ја функцијата TODAY() во вториот аргумент со конкретниот датум.

Претпоставувајќи дека датумот на раѓање е во B1, следнава формула ќе ја врати староста од 1 јануари 2020 година:

=DATEDIF(B1, "1/1/2020","Y") & " Years, " & DATEDIF(B1, "1/1/2020","YM") & " Months, " & DATEDIF(B1, "1/1/2020", "MD") & " Days"

За да ја направите формулата за возраст пофлексибилна, можете да го внесете датумот во некоја ќелија и да ја наведете таа ќелија во вашата формула:

=DATEDIF(B1, B2,"Y") & " Years, "& DATEDIF(B1,B2,"YM") & " Months, "&DATEDIF(B1,B2, "MD") & " Days"

Каде B1 е DOB, а B2 е датумот на кој сакате да ја пресметате возраста.

Пресметајте ја возраста во одредено година

Оваа формула е корисна во ситуации кога не е дефиниран целосниот датум за пресметување, а ја знаете само годината.

Да речеме дека работите со медицинска база на податоци и целта е да се дознае возраста на пациентите во времето кога тие се под отишол на последниот целосен лекарски преглед.

Претпоставувајќи дека датумите на раѓање се во колоната Б, почнувајќи од редот 3, а годината на последниот медицински преглед е во колоната В, формулата за пресметување возраст оди како што следува:

=DATEDIF(B3,DATE(C3, 1, 1),"y")

Бидејќи не е дефиниран точниот датум на медицинскиот преглед, ја користите функцијата ДАТУМ со произволен аргумент за датум и месец, на пр. DATE(C3, 1, 1).

TheФункцијата DATE ја извлекува годината од ќелијата B3, прави целосен датум користејќи ги броевите на месецот и денот што сте ги дале (1-Јан во овој пример) и го пренесува тој датум на DATEDIF. Како резултат на тоа, ја добивате возраста на пациентот од 1 јануари одредена година:

Дознајте датум кога лицето ќе наполни N години

Да претпоставиме дека твојот пријател е роден на 8 март 1978 година. Како знаеш на кој датум ги пополнува своите 50 години? Вообичаено, едноставно додавате 50 години на датумот на раѓање на лицето. Во Excel, истото го правите користејќи ја функцијата DATE:

=DATE(YEAR(B2) + 50, MONTH(B2), DAY(B2))

Каде B2 е датумот на раѓање.

Наместо тврдокодирање на бројот на години во формула, можете да упатите одредена ќелија каде што вашите корисници можат да внесат кој било број години (F1 на сликата од екранот подолу):

Пресметајте ја возраста од ден, месец и година во различни ќелии

Кога датумот на раѓање е поделен на 3 различни ќелии (на пр. годината е во B3, месецот во C3 и денот во D3), можете да ја пресметате возраста на овој начин:

• Добијте датумот на раѓање со користење на функциите DATE и DATEVALUE:

  DATE(B3,MONTH(DATEVALUE(C3&"1")),D3)

• Вметнете ја горната формула во DATEDIF за да ја пресметате возраста од датумот на раѓање во години, месеци и денови: =DATEDIF(DATE(B3, MONTH(DATEVALUE(C3&"1")), D3), TODAY(), "y") & " Years, "& DATEDIF(DATE(B3, MONTH(DATEVALUE(C3&"1")), D3),TODAY(), "ym") & " Months, "& DATEDIF(DATE(B3, MONTH(DATEVALUE(C3&"1")), D3), TODAY(), "md") & " Days"

  

За повеќе примери за пресметување на бројот на денови пред/по датумот, погледнете Како да се пресметаат деновите од или до датумот во Excel.

Возраст калкулатор во Excel

Ако сакате да имате својкалкулатор за возраст во Excel, можете да го направите со користење на неколку различни формули DATEDIF објаснети подолу. Ако не сакате повторно да го измислите тркалото, можете да го користите калкулаторот за возраст создаден од нашите професионалци во Excel.

Како да креирате калкулатор за возраст во Excel

Сега кога знаете како да направите формулата за возраст во Excel, можете да изградите сопствен калкулатор за возраст, на пример овој:

Забелешка. За да ја видите вградената работна книга, ве молиме дозволете маркетиншки колачиња.

Она што го гледате погоре е вграден лист на Excel Online, затоа слободно внесете го вашиот датум на раѓање во соодветната ќелија и ќе ја добиете вашата возраст за момент.

Калкулаторот ги користи следните формули за да ја пресмета возраста врз основа на датумот на раѓање во ќелијата A3 и денешниот датум.

• Формулата во B5 ја пресметува возраста во години, месеци и денови: =DATEDIF(B2,TODAY(),"Y") & " Years, " & DATEDIF(B2,TODAY(),"YM") & " Months, " & DATEDIF(B2,TODAY(),"MD") & " Days"
• Формулата во B6 ја пресметува возраста во месеци: =DATEDIF($B$3,TODAY(),"m")
• Формулата во B7 ја пресметува возраста во денови: =DATEDIF($B$3,TODAY(),"d")

Ако имате одредено искуство со контролите на Excel Form, можете да додадете опција за пресметување на возраста на одреден датум, како што е прикажано на следнава слика од екранот:

За ова, додадете неколку копчиња за опции ( картичка за програмери > Вметни > Контроли за форма > Копче за опции ) и поврзете ги со некоја ќелија. А потоа, напишете формула IF/DATEDIF за да добиете возраст или на денешниот датум или на датумот наведен од корисникот.

Формулата работи со следновологика:

• Ако е избрано полето за опција Денешен датум , вредноста 1 се појавува во поврзаната ќелија (I5 во овој пример), а формулата за возраст се пресметува врз основа на денешниот датум : IF($I$5=1, DATEDIF($B$3,TODAY(),"Y") & " Years, " & DATEDIF($B$3,TODAY(), "YM") & " Months, " & DATEDIF($B$3, TODAY(), "MD") & " Days")
• Ако е избрано копчето за опција Специфичен датум И се внесе датум во ќелијата B7, возраста се пресметува на наведениот датум: IF(ISNUMBER($B$7), DATEDIF($B$3, $B$7,"Y") & " Years, " & DATEDIF($B$3, $B$7,"YM") & " Months, " & DATEDIF($B$3, $B$7,"MD") & " Days", ""))

Конечно , вгнездувајте ги горенаведените функции една во друга и ќе ја добиете целосната формула за пресметување на возраста (во B9):

=IF($I$5=1, DATEDIF($B$3, TODAY(), "Y") & " Years, " & DATEDIF($B$3, TODAY(), "YM") & " Months, " & DATEDIF($B$3, TODAY(), "MD") & " Days", IF(ISNUMBER($B$7), DATEDIF($B$3, $B$7,"Y") & " Years, " & DATEDIF($B$3, $B$7,"YM") & " Months, " & DATEDIF($B$3, $B$7,"MD") & " Days", ""))

Формулите во B10 и B11 работат со истата логика. Се разбира, тие се многу поедноставни бидејќи вклучуваат само една функција DATEDIF за враќање на возраста како број на целосни месеци или денови, соодветно.

За да ги дознаете деталите, ве поканувам да го преземете овој калкулатор за возраста на Excel и да истражите формулите во ќелиите B9:B11.

Преземете го калкулаторот за возраст за Excel

Подготвен за употреба калкулатор за возраст за Excel

Корисниците на нашиот Ultimate Suite немаат да се мачат околу правењето сопствен калкулатор за возраст во Excel - тоа е само неколку клика далеку:

1. Изберете клетка каде што сакате да вметнете формула за возраста, одете во Алатки Ablebits картичката > Датум & Групата Време и кликнете на Датум & засилувач; Копче „Волшебник за време“ .

   

2. Датумот & засилувач; Волшебникот за време ќе започне и ќе одите директно во табулаторот Возраст .
3. На картичката Возраст , има 3 работи што треба да наведете:
   • Податоци за раѓање како а