Sie lernen eine Handvoll Formeln kennen, um das Alter in ganzen Jahren zu berechnen, das genaue Alter in Jahren, Monaten und Tagen zum heutigen Datum oder zu einem bestimmten Datum zu erhalten.

Es gibt keine spezielle Funktion, um das Alter in Excel zu berechnen, aber es gibt verschiedene Möglichkeiten, das Geburtsdatum in das Alter umzurechnen. In diesem Tutorial werden die Vor- und Nachteile jeder Methode erklärt und es wird gezeigt, wie man eine perfekte Formel für die Altersberechnung in Excel erstellt und sie für die Lösung einiger spezifischer Aufgaben optimiert.

Wie berechnet man das Alter aus dem Geburtsdatum in Excel?

Im Alltag wird die Frage " Wie alt sind Sie? "In Microsoft Excel können Sie eine Formel erstellen, um ein genaues Alter in Monaten, Tagen, Stunden und sogar Minuten zu berechnen. Aber lassen Sie uns erst einmal lernen, wie man das Alter aus dem Geburtsdatum in Jahren berechnet.

Excel-Grundformel für Alter in Jahren

Wie ermittelt man normalerweise das Alter einer Person? Ganz einfach, indem man das Geburtsdatum vom aktuellen Datum subtrahiert. Diese herkömmliche Altersformel kann auch in Excel verwendet werden.

Angenommen, das Geburtsdatum steht in Zelle B2, dann lautet die Formel zur Berechnung des Alters in Jahren wie folgt:

=(HEUTE()-B2)/365

Der erste Teil der Formel (HEUTE()-B2) gibt die Differenz zwischen dem aktuellen Datum und dem Geburtsdatum in Tagen an, und dann teilen Sie diese Zahl durch 365, um die Anzahl der Jahre zu erhalten.

Die Formel ist offensichtlich und leicht zu merken, allerdings gibt es ein kleines Problem: In den meisten Fällen liefert sie eine Dezimalzahl, wie in der folgenden Abbildung zu sehen ist.

Um die Anzahl der vollen Jahre anzuzeigen, verwenden Sie die Funktion INT, um eine Dezimalzahl auf die nächste Ganzzahl abzurunden:

=INT((HEUTE()-B2)/365)

Nachteilig: Die Verwendung dieser Altersformel in Excel führt zu ziemlich genauen, aber nicht fehlerfreien Ergebnissen. Die Division durch die durchschnittliche Anzahl der Tage in einem Jahr funktioniert meistens gut, aber manchmal wird das Alter falsch berechnet. Wenn jemand zum Beispiel am 29. Februar geboren wurde und heute der 28. Februar ist, macht die Formel die Person einen Tag älter.

Alternativ können Sie auch durch 365,25 statt durch 365 teilen, da jedes vierte Jahr 366 Tage hat. Aber auch dieser Ansatz ist nicht perfekt: Wenn Sie zum Beispiel das Alter eines Kindes berechnen, das noch kein Schaltjahr erlebt hat, führt die Division durch 365,25 zu einem falschen Ergebnis.

Insgesamt funktioniert das Subtrahieren des Geburtsdatums vom aktuellen Datum im normalen Leben gut, ist aber in Excel nicht der ideale Ansatz. Im weiteren Verlauf dieses Tutorials lernen Sie einige spezielle Funktionen kennen, die das Alter unabhängig vom Jahr einwandfrei berechnen.

Berechnung des Alters aus dem Geburtsdatum mit der Funktion YEARFRAC

Ein zuverlässigerer Weg, das Geburtsdatum in Excel in das Alter umzurechnen, ist die Funktion YEARFRAC, die den Bruchteil des Jahres, d. h. die Anzahl der ganzen Tage zwischen zwei Daten, zurückgibt.

Die Syntax der YEARFRAC-Funktion lautet wie folgt:

Die ersten beiden Argumente liegen auf der Hand und bedürfen kaum einer zusätzlichen Erklärung. Basis ist ein optionales Argument, das die zu verwendende Basis der Tageszählung definiert.

Um eine perfekt korrekte Altersformel zu erstellen, geben Sie der Funktion YEARFRAC die folgenden Werte:

• Start_datum - Geburtsdatum.
• Ende_Datum - TODAY()-Funktion, um das heutige Datum zurückzugeben.
• Basis - Verwendungsbasis 1 die Excel anweist, die tatsächliche Anzahl von Tagen pro Monat durch die tatsächliche Anzahl von Tagen pro Jahr zu dividieren.

Unter Berücksichtigung der obigen Ausführungen lautet eine Excel-Formel zur Berechnung des Alters anhand des Geburtsdatums wie folgt:

Angenommen, das Geburtsdatum steht in Zelle B2, dann sieht die Formel wie folgt aus:

=YEARFRAC(B2, TODAY(), 1)

Wie im vorherigen Beispiel ist das Ergebnis der Funktion YEARFRAC ebenfalls eine Dezimalzahl. Um dies zu beheben, verwenden Sie die Funktion ROUNDDOWN mit 0 im letzten Argument, da Sie keine Nachkommastellen haben wollen.

Hier ist also eine verbesserte YEARFRAC-Formel zur Berechnung des Alters in Excel:

=ROUNDDOWN(YEARFRAC(B2, TODAY(), 1), 0)

Altersberechnung in Excel mit DATEDIF

Eine weitere Möglichkeit, das Geburtsdatum in Excel in das Alter umzuwandeln, ist die DATEDIF-Funktion:

Diese Funktion kann die Differenz zwischen zwei Daten in verschiedenen Zeiteinheiten wie Jahren, Monaten und Tagen zurückgeben, je nach dem Wert, den Sie in der Option Einheit Argument:

• Y - gibt die Anzahl der ganze Jahre zwischen dem Start- und dem Enddatum.
• M - gibt die Anzahl der ganze Monate zwischen den Terminen.
• D - gibt die Anzahl der Tage zwischen den beiden Terminen.
• YM - Rückkehr Monate ohne Berücksichtigung von Tagen und Jahren.
• MD - gibt die Differenz in Tage und ignoriert dabei Monate und Jahre.
• YD - gibt die Differenz in Tage und ignoriert Jahre.

Da wir Folgendes berechnen wollen Alter in Jahre verwenden wir die Einheit "y":

In diesem Beispiel befindet sich das Geburtsdatum in Zelle B2, und Sie verweisen in Ihrer Altersformel auf diese Zelle:

=DATEDIF(B2, TODAY(), "y")

In diesem Fall ist keine zusätzliche Rundungsfunktion erforderlich, da eine DATEDIF-Formel mit der Einheit "y" die Anzahl der vollen Jahre berechnet:

Wie erhalte ich das Alter von meinem Geburtstag in Jahren, Monaten und Tagen?

Wie Sie soeben gesehen haben, ist die Berechnung des Alters als Anzahl der vollen Jahre, die eine Person gelebt hat, einfach, aber nicht immer ausreichend. Wenn Sie das genaue Alter wissen wollen, d. h. wie viele Jahre, Monate und Tage zwischen dem Geburtsdatum einer Person und dem aktuellen Datum liegen, schreiben Sie 3 verschiedene DATEDIF-Funktionen:

1. Um die Anzahl der Jahre zu erhalten: =DATEDIF(B2, TODAY(), "Y")
2. Um die Anzahl der Monate zu erhalten: =DATEDIF(B2, TODAY(), "YM")
3. So erhalten Sie die Anzahl der Tage: =DATEDIF(B2,TODAY(), "MD")

Dabei ist B2 das Geburtsdatum.

Und dann verketten Sie die oben genannten Funktionen in einer einzigen Formel, wie folgt:

=DATEDIF(B2,TODAY(), "Y") & DATEDIF(B2,TODAY(), "YM") & DATEDIF(B2,TODAY(), "MD")

Die obige Formel gibt 3 Zahlen (Jahre, Monate und Tage) zurück, die in einer einzigen Textzeichenfolge verkettet sind, wie in der folgenden Abbildung gezeigt:

Um die Ergebnisse aussagekräftiger zu machen, trennen Sie die Zahlen durch Kommata und definieren Sie, was jeder Wert bedeutet:

=DATEDIF(B2,TODAY(), "Y") & " Jahre, " & DATEDIF(B2,TODAY(), "YM") & " Monate, " & DATEDIF(B2,TODAY(), "MD") & " Tage"

Das Ergebnis sieht jetzt viel besser aus:

Die Formel funktioniert gut, aber Sie können sie noch weiter verbessern, indem Sie Nullwerte ausblenden. Fügen Sie dazu 3 IF-Anweisungen hinzu, die auf 0 prüfen, eine für jedes DATEDIF:

=IF(DATEDIF(B2, HEUTE(), "y")=0,"",DATEDIF(B2, HEUTE(), "y")&" Jahre, ")& IF(DATEDIF(B2, HEUTE(), "ym")=0,"",DATEDIF(B2, HEUTE(), "ym")&" Monate, ")& IF(DATEDIF(B2, HEUTE(), "md")=0,"",DATEDIF(B2, HEUTE(), "md")&" Tage")

Der folgende Screenshot zeigt die endgültige Excel-Altersformel in Aktion - sie liefert das Alter in Jahren, Monaten und Tagen und zeigt nur Nicht-Null Werte:

Tipp: Wenn Sie eine Excel-Formel suchen, um das Alter in Jahre und Monate Nehmen Sie die obige Formel und entfernen Sie den letzten IF(DATEDIF()) Block, der die Tage berechnet.

Spezielle Formeln zur Berechnung des Alters in Excel

Die oben besprochenen allgemeinen Formeln zur Altersberechnung funktionieren in den meisten Fällen gut. In manchen Situationen benötigen Sie jedoch etwas ganz Spezielles. Natürlich ist es nicht möglich, jedes einzelne Szenario abzudecken, aber die folgenden Beispiele geben Ihnen einige Ideen, wie Sie eine Altersformel je nach Ihrer speziellen Aufgabe abwandeln können.

Berechnung des Alters zu einem bestimmten Datum in Excel

Wenn Sie das Alter einer Person zu einem bestimmten Datum wissen wollen, verwenden Sie die oben beschriebene DATEDIF-Altersformel, ersetzen aber die Funktion HEUTE() im zweiten Argument durch das spezifische Datum.

Unter der Annahme, dass das Geburtsdatum in B1 liegt, ergibt die folgende Formel das Alter zum 1. Januar 2020:

=DATEDIF(B1, "1/1/2020", "Y") & " Jahre, " & DATEDIF(B1, "1/1/2020", "YM") & " Monate, " & DATEDIF(B1, "1/1/2020", "MD") & " Tage"

Um Ihre Altersformel flexibler zu gestalten, können Sie das Datum in eine Zelle eingeben und auf diese Zelle in Ihrer Formel verweisen:

=DATEDIF(B1, B2, "Y") & " Jahre,"& DATEDIF(B1,B2, "YM") & " Monate,"&DATEDIF(B1,B2, "MD") & " Tage"

Dabei steht B1 für das Geburtsdatum und B2 für das Datum, an dem Sie das Alter berechnen möchten.

Berechnen des Alters in einem bestimmten Jahr

Diese Formel ist nützlich, wenn das vollständige Datum, zu dem die Berechnung erfolgen soll, nicht definiert ist und Sie nur das Jahr kennen.

Angenommen, Sie arbeiten mit einer medizinischen Datenbank und möchten das Alter der Patienten zum Zeitpunkt der letzten vollständigen medizinischen Untersuchung herausfinden.

Angenommen, die Geburtsdaten stehen in Spalte B, beginnend mit Zeile 3, und das Jahr der letzten ärztlichen Untersuchung steht in Spalte C, so lautet die Formel zur Altersberechnung wie folgt:

=DATEDIF(B3,DATE(C3, 1, 1), "y")

Da das genaue Datum der medizinischen Untersuchung nicht definiert ist, verwenden Sie die Funktion DATE mit einem beliebigen Datums- und Monatsargument, z. B. DATE(C3, 1, 1).

Die Funktion DATUM extrahiert das Jahr aus Zelle B3, erstellt ein vollständiges Datum aus den von Ihnen angegebenen Monats- und Tageszahlen (in diesem Beispiel 1-Jan) und übergibt dieses Datum an DATEDIF. Als Ergebnis erhalten Sie das Alter des Patienten zum 1. Januar eines bestimmten Jahres:

Ermitteln Sie das Datum, an dem eine Person das Alter von N Jahren erreicht

Angenommen, Ihr Freund wurde am 8. März 1978 geboren. Woher wissen Sie, an welchem Datum er 50 Jahre alt wird? Normalerweise addieren Sie einfach 50 Jahre zum Geburtsdatum der Person. In Excel machen Sie das Gleiche mit der Funktion DATE:

=DATUM(JAHR(B2) + 50, MONAT(B2), TAG(B2))

Dabei ist B2 das Geburtsdatum.

Anstatt die Anzahl der Jahre in der Formel fest zu kodieren, können Sie auf eine bestimmte Zelle verweisen, in die Ihre Benutzer eine beliebige Anzahl von Jahren eingeben können (F1 im Screenshot unten):

Berechnung des Alters aus Tag, Monat und Jahr in verschiedenen Zellen

Wenn ein Geburtsdatum in 3 verschiedene Zellen aufgeteilt ist (z. B. Jahr in B3, Monat in C3 und Tag in D3), können Sie das Alter auf diese Weise berechnen:

• Ermitteln Sie das Geburtsdatum mit Hilfe der Funktionen DATE und DATEVALUE:

  DATE(B3,MONAT(DATEVALUE(C3& "1")),D3)

• Setzen Sie die obige Formel in DATEDIF ein, um das Alter anhand des Geburtsdatums in Jahren, Monaten und Tagen zu berechnen: =DATEDIF(DATE(B3, MONTH(DATEVALUE(C3& "1")), D3), TODAY(), "y") & " Jahre,"& DATEDIF(DATE(B3, MONTH(DATEVALUE(C3& "1")), D3),TODAY(), "ym") & " Monate,"& DATEDIF(DATE(B3, MONTH(DATEVALUE(C3& "1")), D3), TODAY(), "md") & " Tage"

  

Weitere Beispiele für die Berechnung der Anzahl der Tage vor/nach einem Datum finden Sie unter Berechnung der Tage seit oder bis zu einem Datum in Excel.

Altersberechnung in Excel

Wenn Sie Ihren eigenen Altersrechner in Excel haben möchten, können Sie ihn mit Hilfe einiger verschiedener DATEDIF-Formeln erstellen, die im Folgenden erläutert werden. Wenn Sie das Rad nicht neu erfinden möchten, können Sie den von unseren Excel-Experten erstellten Altersrechner verwenden.

Wie man einen Altersrechner in Excel erstellt

Da Sie nun wissen, wie man eine Altersformel in Excel erstellt, können Sie einen benutzerdefinierten Altersrechner erstellen, zum Beispiel diesen:

Hinweis: Um die eingebettete Arbeitsmappe zu sehen, lassen Sie bitte Marketing-Cookies zu.

Was Sie oben sehen, ist ein eingebettetes Excel-Online-Blatt. Geben Sie einfach Ihr Geburtsdatum in die entsprechende Zelle ein, und Sie erhalten Ihr Alter in einem Augenblick.

Der Rechner verwendet die folgenden Formeln, um das Alter auf der Grundlage des Geburtsdatums in Zelle A3 und des heutigen Datums zu berechnen.

• Die Formel in B5 berechnet das Alter in Jahren, Monaten und Tagen: =DATEDIF(B2,TODAY(), "Y") & " Jahre, " & DATEDIF(B2,TODAY(), "YM") & " Monate, " & DATEDIF(B2,TODAY(), "MD") & " Tage"
• Die Formel in B6 berechnet das Alter in Monaten: =DATEDIF($B$3,TODAY(), "m")
• Die Formel in B7 berechnet das Alter in Tagen: =DATEDIF($B$3,TODAY(), "d")

Wenn Sie etwas Erfahrung mit Excel-Formularsteuerelementen haben, können Sie eine Option zur Berechnung des Alters zu einem bestimmten Datum hinzufügen, wie im folgenden Screenshot gezeigt:

Fügen Sie dazu ein paar Optionsschaltflächen ( Registerkarte "Entwickler > einfügen. > Formularsteuerung > Optionstaste Und dann schreiben Sie eine IF/DATEDIF-Formel, um das Alter entweder zum heutigen Datum oder zu dem vom Benutzer angegebenen Datum zu erhalten.

Die Formel funktioniert nach der folgenden Logik:

• Wenn die Heutiges Datum ausgewählt ist, erscheint der Wert 1 in der verknüpften Zelle (in diesem Beispiel I5), und die Altersformel wird auf der Grundlage des heutigen Datums berechnet: IF($I$5=1, DATEDIF($B$3,TODAY(), "Y") & " Jahre, " & DATEDIF($B$3,TODAY(), "YM") & " Monate, " & DATEDIF($B$3, TODAY(), "MD") & " Tage")
• Wenn die Bestimmtes Datum ausgewählt UND ein Datum in Zelle B7 eingegeben wird, wird das Alter zum angegebenen Datum berechnet: IF(ISNUMBER($B$7), DATEDIF($B$3, $B$7, "Y") & " Jahre, " & DATEDIF($B$3, $B$7, "YM") & " Monate, " & DATEDIF($B$3, $B$7, "MD") & " Tage", ""))

Wenn Sie schließlich die oben genannten Funktionen ineinander verschachteln, erhalten Sie die vollständige Formel für die Altersberechnung (in B9):

=IF($I$5=1, DATEDIF($B$3, HEUTE(), "Y") & " Jahre, " & DATEDIF($B$3, HEUTE(), "YM") & " Monate, " & DATEDIF($B$3, HEUTE(), "MD") & " Tage", IF(ISNUMBER($B$7), DATEDIF($B$3, $B$7, "Y") & " Jahre, " & DATEDIF($B$3, $B$7, "YM") & " Monate, " & DATEDIF($B$3, $B$7, "MD") & " Tage", ""))

Die Formeln in B10 und B11 funktionieren nach der gleichen Logik, sind aber viel einfacher, da sie nur eine DATEDIF-Funktion enthalten, die das Alter als die Anzahl der vollständigen Monate bzw. Tage zurückgibt.

Um die Details zu erfahren, lade ich Sie ein, diesen Excel-Altersrechner herunterzuladen und die Formeln in den Zellen B9:B11 zu untersuchen.

Altersberechnung für Excel herunterladen

Gebrauchsfertiger Altersrechner für Excel

Die Nutzer unserer Ultimate Suite müssen sich nicht die Mühe machen, ihren eigenen Altersrechner in Excel zu erstellen - er ist nur ein paar Klicks entfernt:

1. Markieren Sie eine Zelle, in die Sie eine Altersformel einfügen möchten, und gehen Sie auf die Registerkarte Ablebits Tools tab> Datum & Uhrzeit Gruppe und klicken Sie auf die Datum & Zeit-Assistent Taste.

   

2. Der Date & Time Wizard wird gestartet, und Sie gehen direkt zu den Alter tab.
3. Auf der Alter Registerkarte müssen Sie 3 Dinge angeben:
   • Daten der Geburt als Zellbezug oder als Datum im Format mm/dd/yyyy.
   • Alter bei heutiges Datum oder bestimmtes Datum .
   • Wählen Sie, ob das Alter in Tagen, Monaten, Jahren oder exakt berechnet werden soll.
4. Klicken Sie auf die Formel einfügen Taste.

Erledigt!

Die Formel wird kurzzeitig in die ausgewählte Zelle eingefügt, und Sie doppelklicken auf den Füllgriff, um sie in die Spalte zu kopieren.

Wie Sie vielleicht bemerkt haben, ist die von unserem Excel-Altersrechner erstellte Formel komplexer als die bisher besprochenen, aber sie berücksichtigt Singular und Plural von Zeiteinheiten wie "Tag" und "Tage".

Wenn Sie Null-Einheiten wie "0 Tage" loswerden möchten, wählen Sie das Nicht Null Einheiten anzeigen Kontrollkästchen:

Wenn Sie neugierig darauf sind, diesen Altersrechner zu testen und 60 weitere zeitsparende Add-Ins für Excel zu entdecken, können Sie gerne eine Testversion unserer Ultimate Suite am Ende dieses Beitrags herunterladen.

Wie kann man bestimmte Altersgruppen hervorheben (unter oder über einem bestimmten Alter)?

In manchen Situationen müssen Sie nicht nur das Alter in Excel berechnen, sondern auch Zellen markieren, die ein bestimmtes Alter überschreiten oder darunter liegen.

Wenn Ihre Formel zur Altersberechnung die Anzahl der vollen Jahre angibt, können Sie eine reguläre bedingte Formatierungsregel erstellen, die auf einer einfachen Formel wie der folgenden basiert:

• Zum Hervorheben von Altersgruppen gleich oder größer als 18: =$C2>=18
• Zum Hervorheben von Altersgruppen unter 18 Jahren: =$C2<18

Dabei ist C2 die oberste Zelle in der Spalte Alter (ohne die Spaltenüberschrift).

Was aber, wenn Ihre Formel das Alter in Jahren und Monaten oder in Jahren, Monaten und Tagen anzeigt? In diesem Fall müssen Sie eine Regel erstellen, die auf einer DATEDIF-Formel basiert, die das Alter anhand des Geburtsdatums in Jahren berechnet.

Angenommen, die Geburtsdaten stehen in Spalte B, beginnend mit Zeile 2, dann lauten die Formeln wie folgt:

• Um Altersgruppen hervorzuheben unter 18 (gelb): =DATEDIF($B2, TODAY(), "Y")<18
• Um Altersgruppen hervorzuheben zwischen 18 und 65 (grün): =AND(DATEDIF($B2, TODAY(), "Y")>=18, DATEDIF($B2, TODAY(), "Y")<=65)
• Um Altersgruppen hervorzuheben über 65 (blau): =DATEDIF($B2, TODAY(), "Y")>65

Um Regeln auf der Grundlage der obigen Formeln zu erstellen, markieren Sie die Zellen oder ganze Zeilen, die Sie hervorheben möchten, und gehen Sie zum Fenster Startseite tab> Stile Gruppe, und klicken Sie auf Bedingte Formatierung > Neue Vorschrift... > Verwenden Sie eine Formel, um die zu formatierenden Zellen zu bestimmen .

Die detaillierten Schritte finden Sie hier: Wie man eine bedingte Formatierungsregel auf der Grundlage einer Formel erstellt.

So berechnet man das Alter in Excel. Ich hoffe, die Formeln waren für Sie leicht zu erlernen und Sie werden sie in Ihren Arbeitsblättern ausprobieren. Ich danke Ihnen für die Lektüre und hoffe, Sie nächste Woche auf unserem Blog zu sehen!

Verfügbare Downloads

Excel-Beispiele zur Altersberechnung (.xlsx-Datei)

Ultimate Suite 14 Tage voll funktionsfähige Version (.exe-Datei)