Udžbenik pokazuje različite načine za dobivanje dobi od rođendana u Excelu. Naučit ćete pregršt formula za izračunavanje dobi kao broja punih godina, dobiti točnu dob u godinama, mjesecima i danima na današnji ili određeni datum.

Ne postoji posebna funkcija za izračunavanje dob u Excelu, no postoji nekoliko različitih načina za pretvaranje datuma rođenja u dob. Ovaj će vodič objasniti prednosti i nedostatke svakog načina, pokazati kako napraviti savršenu formulu za izračun dobi u Excelu i prilagoditi je za rješavanje nekih specifičnih zadataka.

Kako izračunati dob od datuma rođenja u Excelu

U svakodnevnom životu pitanje " Koliko imaš godina? " obično podrazumijeva odgovor koji pokazuje koliko godina živiš. U programu Microsoft Excel možete napraviti formulu za izračunavanje točne dobi u mjesecima, danima, satima pa čak i minutama. Ali budimo tradicionalni i prvo naučimo kako izračunati dob prema DOB-u u godinama.

Osnovna Excelova formula za dob u godinama

Kako obično izračunate nečiju dob? Jednostavno oduzimanjem datuma rođenja od trenutnog datuma. Ova konvencionalna formula za dob također se može koristiti u Excelu.

Pod pretpostavkom da je datum rođenja u ćeliji B2, formula za izračun dobi u godinama je sljedeća:

=(TODAY()-B2)/365

The prvi dio formule (TODAY()-B2) vraća razliku između trenutnog datuma i datuma rođenja u danima, a zatim to podijelitereferenca ćelije ili datum u formatu mm/dd/gggg.

Gotovo!

Formula se trenutno umeće u odabranu ćeliju, a vi dvaput kliknete ručicu za popunjavanje da biste je kopirali niz stupac.

Kao što ste možda primijetili, formula koju je izradio naš Excel kalkulator starosti složenija je od onih o kojima smo do sada govorili, ali služi za jedninu i množinu vremenskih jedinica kao što su "dan" i "dani".

Ako se želite riješiti nultih jedinica kao što je "0 dana", odaberite potvrdni okvir Nemoj prikaži nulte jedinice :

Ako ste znatiželjni testirati ovaj kalkulator dobi, kao i otkriti još 60 dodataka za Excel koji štede vrijeme, dobrodošli ste preuzeti probnu verziju našeg Ultimate Suitea na kraju ovaj post.

Kako istaknuti određene dobi (ispod ili iznad a određena dob)

U nekim situacijama možda ćete trebati ne samo izračunati dob u Excelu, već i istaknuti ćelije koje sadrže dob ispod ili iznad određene dobi.

Ako vaša formula za izračun dobi vraća broj potpunih godina, tada možete stvoriti redovito pravilo uvjetnog oblikovanja na temelju jednostavne formule poput ovih:

• Za isticanje dobi jednakih ili viših od18: =$C2>=18
• Za isticanje dobi ispod 18 godina: =$C2<18

Gdje je C2 najviša ćelija u stupcu Dob (ne uključujući zaglavlje stupca).

Ali što ako vaša formula prikazuje dob u godinama i mjesecima ili u godinama, mjesecima i danima? U ovom slučaju, morat ćete izraditi pravilo temeljeno na formuli DATEDIF koja izračunava dob od datuma rođenja u godinama.

Pretpostavimo da su datumi rođenja u stupcu B počevši od retka 2, formule su sljedeće:

• Za isticanje dobi ispod 18 (žuto): =DATEDIF($B2, TODAY(),"Y")<18
• Za isticanje dobi između 18 i 65 (zeleno): =AND(DATEDIF($B2, TODAY(),"Y")>=18, DATEDIF($B2, TODAY(),"Y")<=65)
• Za označavanje dobi preko 65 (plavo): =DATEDIF($B2, TODAY(),"Y")>65

Za stvaranje pravila na temelju gornjih formula, odaberite ćelije ili cijele retke koje želite istaknuti , idite na karticu Početna > Stilovi grupu i kliknite Uvjetno oblikovanje > Novo pravilo… > Koristi formulu za određivanje ćelija za formatiranje .

Detaljne korake možete pronaći ovdje: Kako izraditi pravilo uvjetnog oblikovanja na temelju formule.

Ovako izračunavate dob u Excelu. Nadam se da su vam formule bile jednostavne za naučiti i da ćete ih isprobati u svojim radnim listovima. Hvala vam na čitanju i nadamo se da se vidimo na našem blogu sljedeći tjedan!

Dostupna preuzimanja

Primjeri proračuna dobi u Excelu (.xlsx datoteka)

Ultimate Suite 14-dnevno u potpunosti -funkcionalna verzija (.exe datoteka)

Formula je očita i lako pamtljiva, međutim, postoji mali problem. U većini slučajeva vraća decimalni broj kao što je prikazano na snimci zaslona u nastavku.

Za prikaz broja potpunih godina upotrijebite funkciju INT za zaokruživanje decimale na nižu najbliži cijeli broj:

=INT((TODAY()-B2)/365)

Nedostatci: Korištenje ove formule za dob u Excelu daje prilično točne rezultate, ali ne i besprijekorne. Dijeljenje s prosječnim brojem dana u godini dobro funkcionira većinu vremena, ali ponekad dobije krivu dob. Na primjer, ako je netko rođen 29. veljače, a danas je 28. veljače, formula će osobu učiniti jedan dan starijom.

Kao alternativu, možete podijeliti s 365,25 umjesto s 365 jer svaka četvrta godina ima 366 dana. Međutim, ni ovaj pristup nije savršen. Na primjer, ako izračunavate dob djeteta koje još nije doživjelo prijestupnu godinu, dijeljenje s 365,25 daje pogrešan rezultat.

Općenito, oduzimanje datuma rođenja od trenutnog datuma odlično funkcionira u normalan život, ali nije idealan pristup u Excelu. Dalje u ovom vodiču naučit ćete nekoliko posebnih funkcija koje besprijekorno izračunavaju dob bez obzira na godinu.

Izračunajte dob prema datumu rođenja pomoću YEARFRAC funkcije

Pouzdaniji način pretvorbe DOB za dob u Excelu koristi YEARFRAC funkciju kojavraća dio godine, tj. broj cijelih dana između dva datuma.

Sintaksa funkcije YEARFRAC je sljedeća:

The prva dva argumenta su očita i ne zahtijevaju dodatno objašnjenje. Osnova je izborni argument koji definira osnovu brojanja dana za upotrebu.

Da biste napravili savršeno istinitu formulu za dob, unesite sljedeće vrijednosti u funkciju YEARFRAC:

• Start_date - datum rođenja.
• End_date - funkcija TODAY() za vraćanje današnjeg datuma.
• Osnova - koristite osnovu 1 koja govori Excelu da podijeli stvarni broj dana u mjesecu sa stvarnim brojem dana u godini.

S obzirom na gore navedeno, Excelova formula za izračun dob od datuma rođenja je sljedeća:

Pod pretpostavkom da je datum rođenja u ćeliji B2, formula ima sljedeći oblik:

=YEARFRAC(B2, TODAY(), 1)

Kao u prethodnom primjeru, rezultat funkcije YEARFRAC također je decimalni broj. Da biste to popravili, upotrijebite funkciju ROUNDDOWN s 0 u zadnjem argumentu jer ne želite nikakva decimalna mjesta.

Dakle, evo poboljšane formule YEARFRAC za izračunavanje dobi u Excelu:

=ROUNDDOWN(YEARFRAC(B2, TODAY(), 1), 0)

Izračunajte dob u Excelu pomoću DATEDIF

Još jedan način za pretvaranje datuma rođenja u dob u Excelu je korištenje funkcije DATEDIF:

Ova funkcija može vratiti razliku između dva datuma u različitim vremenskim jedinicama kao što su godine, mjeseci i dani, ovisno o vrijednosti koju navedete u argumentu jedinica :

• Y - vraća broj punih godina između početnog i završnog datuma.
• M - vraća broj punih mjeseci između datume.
• D - vraća broj dana između dva datuma.
• YM - vraća mjeseci , zanemarujući dane i godine.
• MD - vraća razliku u dana , zanemarujući mjesece i godine.
• YD - vraća razliku u dana , zanemarujući godine.

Budući da nam je cilj izračunati dob u godinama , koristimo jedinicu "y":

U ovom primjeru, DOB je u ćeliji B2, a vi upućujete na ovu ćeliju u svojoj formuli za dob:

=DATEDIF(B2, TODAY(), "y")

U ovom slučaju nije potrebna nikakva dodatna funkcija zaokruživanja jer formula DATEDIF s t jedinica "y" izračunava broj punih godina:

Kako izračunati dob od rođendana u godinama, mjesecima i danima

Kao što ste upravo vidjeli , izračunati dob kao broj punih godina koje je osoba proživjela je jednostavno, ali nije uvijek dovoljno. Ako želite znati točnu dob, odnosno koliko godina, mjeseci i dana ima između datuma nečijeg rođenja i sadašnjeg datuma, napišite 3različite DATEDIF funkcije:

1. Da biste dobili broj godina: =DATEDIF(B2, TODAY(), "Y")
2. Da biste dobili broj mjeseci: =DATEDIF(B2, TODAY(), "YM")
3. Da biste dobili broj dana: =DATEDIF(B2,TODAY(),"MD")

Gdje je B2 datum rođenja.

I zatim spojite gornje funkcije u jednu formulu, ovako:

=DATEDIF(B2,TODAY(),"Y") & DATEDIF(B2,TODAY(),"YM") & DATEDIF(B2,TODAY(),"MD")

Gornja formula vraća 3 broja (godine, mjesece i dane) spojena u jedan tekstualni niz, kao što je prikazano na snimci zaslona u nastavku:

Nema smisla, uh ? Kako bi rezultati bili smisleniji, odvojite brojeve zarezima i definirajte što svaka vrijednost znači:

=DATEDIF(B2,TODAY(),"Y") & " Years, " & DATEDIF(B2,TODAY(),"YM") & " Months, " & DATEDIF(B2,TODAY(),"MD") & " Days"

Rezultat sada izgleda puno bolje:

Formula radi odlično, ali je možete dodatno poboljšati skrivanjem nultih vrijednosti. U tu svrhu dodajte 3 IF naredbe koje provjeravaju nule, po jednu za svaki DATEDIF:

=IF(DATEDIF(B2, TODAY(),"y")=0,"",DATEDIF(B2, TODAY(),"y")&" years, ")& IF(DATEDIF(B2, TODAY(),"ym")=0,"",DATEDIF(B2, TODAY(),"ym")&" months, ")& IF(DATEDIF(B2, TODAY(),"md")=0,"",DATEDIF(B2, TODAY(),"md")&" days")

Sljedeća snimka zaslona prikazuje konačnu Excel formulu za dob na djelu - vraća dob u godinama, mjesecima, i dana, prikazujući samo vrijednosti ne-nula :

Savjet. Ako tražite Excel formulu za izračunavanje dobi u godinama i mjesecima , uzmite gornju formulu i uklonite zadnji IF(DATEDIF()) blok koji izračunava dane.

Određene formule za izračunajte dob u Excelu

Općenite formule za izračun dobi o kojima smo govorili u većini slučajeva rade odlično. U nekim situacijama, međutim, možda ćete trebati nešto vrlo specifično. Naravno, nije moguće pokriti svei svaki scenarij, ali sljedeći primjeri dat će vam neke ideje o tome kako možete prilagoditi formulu za dob ovisno o vašem određenom zadatku.

Kako izračunati dob na određeni datum u Excelu

Ako želite znati nečiju dob na određeni datum, upotrijebite formulu za dob DATEDIF o kojoj smo govorili gore, ali zamijenite funkciju TODAY() u 2. argumentu određenim datumom.

Pod pretpostavkom da je datum rođenja u B1, sljedeća formula vratit će dob od 1. siječnja 2020.:

=DATEDIF(B1, "1/1/2020","Y") & " Years, " & DATEDIF(B1, "1/1/2020","YM") & " Months, " & DATEDIF(B1, "1/1/2020", "MD") & " Days"

Kako biste svoju formulu za dob učinili fleksibilnijom, možete unijeti datum u neku ćeliju i referencirati tu ćeliju u svojoj formuli:

=DATEDIF(B1, B2,"Y") & " Years, "& DATEDIF(B1,B2,"YM") & " Months, "&DATEDIF(B1,B2, "MD") & " Days"

Gdje je B1 DOB, a B2 datum na koji želite izračunati dob.

Izračunajte dob u određenom godina

Ova formula je korisna u situacijama kada cijeli datum za izračunavanje nije definiran, a vi znate samo godinu.

Recimo da radite s medicinskom bazom podataka i vaš cilj je saznati dob pacijenata u trenutku kada su mlađi otišao na zadnji potpuni liječnički pregled.

Pod pretpostavkom da su datumi rođenja u stupcu B počevši od retka 3, a godina zadnjeg liječničkog pregleda u stupcu C, formula za izračun dobi je sljedeća:

=DATEDIF(B3,DATE(C3, 1, 1),"y")

Budući da točan datum liječničkog pregleda nije definiran, koristite funkciju DATE s proizvoljnim argumentom datuma i mjeseca, npr. DATUM(C3, 1, 1).

TheFunkcija DATE izvlači godinu iz ćelije B3, stvara potpuni datum pomoću brojeva mjeseca i dana koje ste unijeli (1. siječnja u ovom primjeru) i prosljeđuje taj datum u DATEDIF. Kao rezultat, dobivate dob pacijenta na dan 1. siječnja određene godine:

Pronađite datum kada osoba navršava N godina starosti

Pretpostavimo da je vaš prijatelj rođen 8. ožujka 1978. Kako znate na koji datum on navršava 50 godina? Obično biste jednostavno dodali 50 godina datumu rođenja osobe. U Excelu radite isto pomoću funkcije DATE:

=DATE(YEAR(B2) + 50, MONTH(B2), DAY(B2))

Gdje je B2 datum rođenja.

Umjesto tvrdog kodiranja broja godina u formuli, možete referencirati određenu ćeliju u koju vaši korisnici mogu unijeti bilo koji broj godina (F1 na slici ispod):

Izračunajte dob prema danu, mjesecu i godini u različitim ćelije

Kada je datum rođenja podijeljen u 3 različite ćelije (npr. godina je u B3, mjesec u C3 i dan u D3), možete izračunati dob na ovaj način:

• Get datum rođenja pomoću funkcija DATE i DATEVALUE:

  DATE(B3,MONTH(DATEVALUE(C3&"1")),D3)

• Ugradite gornju formulu u DATEDIF za izračunavanje dobi od datuma rođenja u godinama, mjesecima i danima: =DATEDIF(DATE(B3, MONTH(DATEVALUE(C3&"1")), D3), TODAY(), "y") & " Years, "& DATEDIF(DATE(B3, MONTH(DATEVALUE(C3&"1")), D3),TODAY(), "ym") & " Months, "& DATEDIF(DATE(B3, MONTH(DATEVALUE(C3&"1")), D3), TODAY(), "md") & " Days"

  

Za više primjera izračuna broja dana prije/nakon datuma, pogledajte Kako izračunati dane od ili do datuma u Excelu.

Dob kalkulator u Excelu

Ako želite imati svoj vlastitikalkulator dobi u Excelu, možete ga izraditi pomoću nekoliko različitih DATEDIF formula objašnjenih u nastavku. Ako radije ne biste ponovno izmišljali kotač, možete upotrijebiti kalkulator dobi koji su izradili naši stručnjaci za Excel.

Kako izraditi kalkulator dobi u Excelu

Sada kada znate kako napraviti formulu dobi u Excelu, možete izraditi prilagođeni kalkulator dobi, na primjer ovaj:

Napomena. Da biste pogledali ugrađenu radnu bilježnicu, dopustite marketinške kolačiće.

Ono što vidite gore je ugrađeni Excel Online list, stoga slobodno unesite svoj datum rođenja u odgovarajuću ćeliju i začas ćete saznati svoju dob.

Kalkulator koristi sljedeće formule za izračun dobi na temelju datuma rođenja u ćeliji A3 i današnjeg datuma.

• Formula u B5 izračunava dob u godinama, mjesecima i danima: =DATEDIF(B2,TODAY(),"Y") & " Years, " & DATEDIF(B2,TODAY(),"YM") & " Months, " & DATEDIF(B2,TODAY(),"MD") & " Days"
• Formula u B6 izračunava dob u mjesecima: =DATEDIF($B$3,TODAY(),"m")
• Formula u B7 izračunava dob u danima: =DATEDIF($B$3,TODAY(),"d")

Ako imate iskustva s kontrolama obrazaca programa Excel, možete dodati opciju za izračunavanje dobi na određeni datum, kao što je prikazano na sljedećoj snimci zaslona:

Za ovo dodajte nekoliko gumba opcija ( kartica Razvojni programer > Umetni > Kontrole obrasca > Gumb opcije ) i povežite ih s nekom ćelijom. Zatim napišite formulu IF/DATEDIF da dobijete dob ili na današnji datum ili na datum koji odredi korisnik.

Formula radi sa sljedećimlogika:

• Ako je odabran okvir opcije Današnji datum , vrijednost 1 pojavljuje se u povezanoj ćeliji (I5 u ovom primjeru), a formula dobi izračunava se na temelju današnjeg datuma : IF($I$5=1, DATEDIF($B$3,TODAY(),"Y") & " Years, " & DATEDIF($B$3,TODAY(), "YM") & " Months, " & DATEDIF($B$3, TODAY(), "MD") & " Days")
• Ako je odabran gumb opcije Određeni datum I unese se datum u ćeliju B7, dob se izračunava na navedeni datum: IF(ISNUMBER($B$7), DATEDIF($B$3, $B$7,"Y") & " Years, " & DATEDIF($B$3, $B$7,"YM") & " Months, " & DATEDIF($B$3, $B$7,"MD") & " Days", ""))

Na kraju , ugniježdite gornje funkcije jednu u drugu i dobit ćete potpunu formulu za izračun dobi (u B9):

=IF($I$5=1, DATEDIF($B$3, TODAY(), "Y") & " Years, " & DATEDIF($B$3, TODAY(), "YM") & " Months, " & DATEDIF($B$3, TODAY(), "MD") & " Days", IF(ISNUMBER($B$7), DATEDIF($B$3, $B$7,"Y") & " Years, " & DATEDIF($B$3, $B$7,"YM") & " Months, " & DATEDIF($B$3, $B$7,"MD") & " Days", ""))

Formule u B10 i B11 rade s istom logikom. Naravno, mnogo su jednostavniji jer uključuju samo jednu funkciju DATEDIF za vraćanje dobi kao broja cijelih mjeseci ili dana.

Da biste saznali pojedinosti, pozivam vas da preuzmete ovaj Excelov kalkulator dobi i istražite formule u ćelijama B9:B11.

Preuzmite kalkulator dobi za Excel

Kalkulator dobi spreman za korištenje za Excel

Korisnici našeg Ultimate Suite-a nemaju potruditi se oko izrade vlastitog kalkulatora dobi u Excelu - udaljen je samo nekoliko klikova:

1. Odaberite ćeliju u koju želite umetnuti formulu za dob, idite na Alate Bits kartica > Datum & Vrijeme i kliknite Datum & Gumb Čarobnjak za vrijeme .

   

2. Datum & Pokrenut će se čarobnjak za vrijeme i otići ćete izravno na karticu Dob .
3. Na kartici Dob postoje 3 stvari koje morate odrediti:
   • Podaci o rođenju kao a