Tutorialak ADDRESS funtzioaren sintaxiaren sarrera labur bat ematen du eta Excel gelaxka-helbide bat eta gehiago itzultzeko nola erabili erakusten du.

Excel-en gelaxka-erreferentzia bat sortzeko, zutabe eta errenkaden koordenatuak eskuz idatz ditzake. Bestela, Excel gelaxka-helbide bat lor dezakezu HELBIDEA funtzioari emandako errenkada eta zutabe-zenbakietatik. Berez ia alferrikakoa, beste funtzio batzuekin konbinatuta, teknika hau soluzio bakarra izan daiteke gelaxka bati zuzenean erreferentzia egitea posible ez den egoeretan.

Excel ADDRESS funtzioa - sintaxia eta oinarrizko erabilerak

HELBIDEA funtzioa Excel-en gelaxka-helbide bat lortzeko diseinatuta dago, zehaztutako errenkada eta zutabe-zenbakietan oinarrituta. Gelaxka-helbide bat testu-kate gisa itzultzen da, ez benetako erreferentzia gisa.

Funtzioa Microsoft 365 - Excel 2007rako Excel-en bertsio guztietan dago eskuragarri.

HELBIDEA funtzioaren sintaxia da. honela:

Lehen bi argumentuak beharrezkoak dira:

errenkada_zenbakia - errenkada gelaxka-erreferentzian erabili beharreko zenbakia.

zutabe_zenbakia - gelaxka-erreferentzia eraikitzeko zutabe-zenbakia.

Azken hiru argumentuak, gelaxka-erreferentziaren formatua zehazten dutenak, dira. aukerakoa:

abs_num - erreferentzia mota, absolutua edo erlatiboa. Beheko zenbakietako edozein har dezake; lehenetsia absolutua da.

• 1 edo kenduta -$A$1
• 2 bezalako gelaxka-erreferentzia absolutua - erreferentzia mistoa: zutabe erlatiboa eta errenkada absolutua A$1 bezalako
• 3 - erreferentzia mistoa: zutabe absolutua eta errenkada erlatiboa $A1
<10 bezalako>4 - gelaxka-erreferentzia erlatiboa, hala nola A1

a1 - erreferentzia estiloa, A1 edo R1C1. Baztertzen bada, lehenetsitako A1 estiloa erabiltzen da.

• 1 edo EGIA edo baztertuta - A1 erreferentzia estiloko gelaxka-helbidea itzultzen du, non zutabeak letrak diren eta errenkadak zenbakiak diren.
• 0 edo GEZURRA - gelaxka-helbidea itzultzen du R1C1 erreferentzia-estiloan, non errenkadak eta zutabeak zenbaki bidez adierazten diren.

sheet_text - kanpoko erreferentzian sartu beharreko lan-orriaren izena. Orri-izena testu-kate gisa eman behar da eta komatxoen artean sartu, adibidez. "Fitxa 2". Ezeztatzen bada, ez da lan-orriaren izenik erabiltzen, eta helbideak uneko orria izango du lehenetsia.

Adibidez:

=ADDRESS(1,1) - lehen gelaxkaren helbidea itzultzen du (hau da, gelaxkaren elkargunean dagoena). lehenengo errenkada eta lehen zutabea) $A$1 gelaxka-erreferentzia absolutu gisa.

=ADDRESS(1,1,4) - lehen gelaxkaren helbidea A1 gelaxka-erreferentzia erlatibo gisa itzultzen du.

Ondoko taulan, ADDRESS formulen bidez itzul daitezkeen erreferentzia mota batzuk aurkituko dituzu.

Nola erabili ADDRESS funtzioa Excel-en - formula adibideak

Beheko adibideek erakusten dute nola erabili ADDRESS funtzioa formula handien barruan gehiago lortzeko. zeregin zailak.

Itzuli gelaxka-balio bat errenkada eta zutabe jakin batean

Zure helburua gelaxka zehatz batetik balio bat lortzea bada bere errenkada eta zutabe-zenbakietan oinarrituta, erabili HELBIDEA fun dibertsioa. Akzioarekin batera ZEHARKOAK:

HELBIDEA funtzioak gelaxka-helbidea testu gisa ateratzen du. ZEHARKAKO funtzioak testu hori erreferentzia normal bihurtzen du eta dagokion gelaxkaren balioa itzultzen du.

Adibidez, E1 errenkada-zenbakian eta E2-ko zutabe-zenbakian oinarritutako gelaxka-balio bat lortzeko, erabili formula hau. :

=INDIRECT(ADDRESS(E1,E2))

Lortu helbideaBalio altuena edo baxuena duen gelaxka baten

Adibide honetan, lehenik B2:B7 barrutian dauden baliorik altuenak eta baxuenak aurkituko ditugu MAX eta MIN funtzioak erabiliz eta balio horiek gelaxka berezietara aterako ditugu:

E2 gelaxka: =MAX(B2:B7)

F2 gelaxka: =MIN(B2:B7)

Eta gero, HELBIDEA MATCH funtzioarekin batera erabiliko dugu. lortu gelaxken helbideak.

Gehieneko balioa duen gelaxka:

=ADDRESS(MATCH(E2,B:B,0), COLUMN(B2))

Gutxieneko balioa duen gelaxka:

=ADDRESS(MATCH(F2,B:B,0), COLUMN(B2))

Baliorik altuena eta baxuena gelaxka bereizietan nahi ez baduzu, MAX/MIN funtzioa MATCH-en lehen argumentuan habia dezakezu. Adibidez:

Balio handiena duen gelaxka:

=ADDRESS(MATCH(MAX(B2:B7),B:B,0), COLUMN(B2))

Balio txikiena duen gelaxka:

=ADDRESS(MATCH(MIN(B2:B7),B:B,0), COLUMN(B2))

Nola formula hauek work

Errenkada-zenbakia aurkitzeko, MATCH(lookup_value, lookup_array, [match_type]) funtzioa erabiltzen duzu bilaketa_balioaren posizio erlatiboa itzultzen duena lookup_array-n. Gure formulan, bilaketa-balioa MAX edo MIN funtzioak itzultzen duen zenbakia da, eta bilaketa-matrizea zutabe osoa da. Ondorioz, bilaketa-balioaren posizio erlatiboa matrizean bat dator zehatz-mehatz orriko errenkada-zenbakiarekin.

Zutabe-zenbakia aurkitzeko, COLUM funtzioa erabiltzen duzu. Noski, ezerk ez dizu eragozten zenbakia formulan zuzenean idaztea, baina ZUBATZAK eskuzko zenbaketa arazoak aurrezten ditu helburu-zutabea orriaren erdian badago.

Lortu zutabe letra bat.zutabe-zenbaki batetik

Edozein zenbaki bat zutabe-letra bihurtzeko, erabili ORDEZKOA-ren barneko HELBIDEA funtzioa:

Adibide gisa, aurki dezagun A2-ko zenbakiari dagokion zutabe-letra:

=SUBSTITUTE(ADDRESS(1,A2,4),"1","")

Beheko emaitzak ikusita, lehen zutabea dela esan dezakegu. fitxan A dago, begi-bistakoa dena; 10. zutabea J da, 50. zutabea AX eta 100. zutabea CV:

Formula honek nola funtzionatzen duen

Hasteko, konfiguratu HELBIDEA funtzioa xede zutabeko lehen gelaxkara erreferentzia erlatiboa itzultzeko:

• Errenkada-zenbakirako, erabili 1.
• Zutabe-zenbakirako, eman gelaxkaren erreferentzia. zenbakia duen, A2 gure adibidean.
• Abs_num argumenturako, idatzi 4.

Ondorioz, HELBIDEAK(1,A2,4) A1 itzuliko luke.

Errenkadaren koordenatua kentzeko, bildu goiko formula ORDEZKO funtzioan eta ordezkatu "1" kate huts batekin (""). Eginda!

Lortu izendun barruti baten helbidea

Excel-en izendun barruti baten helbidea aurkitzeko, lehenengo eta azken gelaxka-erreferentziak lortu beharko dituzu, eta gero elkartu. . Honek modu desberdinean funtzionatzen du Excel aurredinamikoetan (2019 eta zaharragoetan) eta Dynamic Array Excel-en (Office 365 eta Excel 2021). Beheko adibideak Excel 2019 - Excel 2007rako dira. Excel 365 eta Excel 2021rako argibideak dira.hemen.

Nola lortu barruti bateko lehen gelaxkaren helbidea

Izeneko barruti bateko lehen gelaxkari erreferentzia bat itzultzeko, erabili formula generiko hau:

Barrutia "Salmentak" izena duela suposatuz, benetako formula hauxe da:

=ADDRESS(ROW(Sales), COLUMN(Sales))

Eta barrutian goiko ezkerreko gelaxkaren helbidea itzultzen du:

Formula honetan, ERRENKAADA eta ZUTABE funtzioek errenkada eta zutabe zenbaki guztien array bat itzultzen dute. sorta, hurrenez hurren. Zenbaki horietan oinarrituta, ADDRESS funtzioak gelaxka-helbideen sorta bat eraikitzen du. Baina formula gelaxka bakarrean sartzen denez, matrizeko lehen elementua bakarrik bistaratzen da, barrutiko lehen gelaxkari dagokiona.

Nola lortu barruti bateko azken gelaxkaren helbidea

Izeneko barruti bateko azken gelaxkaren helbidea aurkitzeko, erabili formula generiko hau:

"Salmentak" izeneko gure barrutiari aplikatuta, formulak forma hau hartzen du:

=ADDRESS(ROW(Sales) + ROWS(Sales)-1, COLUMN(Sales) + COLUMNS(Sales)-1)

Eta barrutiaren beheko eskuineko gelaxkara itzultzen du erreferentzia:

Oraingoan, kalkulu konplexuagoak behar ditugu errenkada lantzeko zenbakia. Aurreko adibidean bezala, ROW funtzioak barrutiko errenkada-zenbaki guztien array bat ematen digu, gure kasuan {4;5;6;7}. Zenbaki hauek errenkada-zenbaketa osoaren ken 1aren arabera "desplazatu" behar ditugu, horrelaarrayko lehen elementua azken errenkada-zenbakia bihurtzen da. Errenkada-zenbaketa osoa aurkitzeko, ROWS funtzioa erabiltzen dugu eta 1 kenduko diogu emaitzari: (4-1=3). Ondoren, hasierako matrizeko elementu bakoitzari 3 gehitzen diogu behar den aldaketa egiteko: {4;5;6;7} + 3 = {7;8;9;10}.

Zutabe-zenbakia da. antzeko era batean kalkulatuta: {2,3,4}+3-1 = {4,5,6}

Goiko errenkada eta zutabe zenbakien matrizeetatik, ADDRESS funtzioak gelaxka-helbideen array bat biltzen du. , baina barrutiko azken gelaxkari dagokion lehenengoa bakarrik itzultzen du.

Emaitza bera lor daiteke errenkada eta zutabe zenbakien matrizeetatik gehienezko balioak hautatuz. Hala ere, hau matrize formula batean bakarrik funtzionatzen du, eta horrek Ctrl + Shift + Sartu sakatu behar du behar bezala osatzeko:

=ADDRESS(MAX(ROW(Sales)), MAX(COLUMN(Sales)))

Nola lortu izendun barruti baten helbide osoa

Izeneko barruti baten helbide osoa itzultzeko, aurreko adibideetako bi formulak kateatu eta tarteko operadorea (:) tartean sartu besterik ez duzu behar.

Gure lagin-datu-multzorako funtziona dezan, "barrutia" generikoa ordezkatuko dugu "Salmenta" benetako barrutiaren izenarekin:

=ADDRESS(ROW(Sales), COLUMN(Sales)) & ":" & ADDRESS(ROW(Sales) + ROWS(Sales)-1, COLUMN(Sales) + COLUMNS(Sales)-1)

Eta barrutiaren helbide osoa lortuko dugu. absolutua erreferentzia $B$4:$D$7:

Barrutia itzultzekohelbidea erlatibo erreferentzia gisa ($ zeinurik gabe, B4:D7 bezala), ezarri abs_num argumentua ADDRESS funtzioetan 4 gisa:

=ADDRESS(ROW(Sales), COLUMN(Sales), 4) & ":" & ADDRESS(ROW(Sales) + ROWS(Sales)-1, COLUMN(Sales) + COLUMNS(Sales)-1, 4)

Noski, aldaketa berdinak egin daitezke lehen eta azken gelaxketarako banakako formuletan, eta emaitza honen antzekoa izango da:

Nola lortu izendun barruti baten helbidea Excel-en 365 eta Excel 2021

Bertsio zaharretako "formula bat - gelaxka bat" portaera tradizionala ez bezala, Excel berrian, balio anitz itzul ditzakeen edozein formulak automatikoki egiten du hori. Jokabide horri isurketa deritzo.

Adibidez, lehenengo gelaxkaren helbidea itzuli beharrean, beheko formulak gelaxka bakoitzaren helbideak ateratzen ditu izendun barruti batean:

=ADDRESS(ROW(Sales), COLUMN(Sales))

lehen gelaxkaren helbidea soilik lortzeko, elkargune inplizitua gaitu behar duzu, lehenespenez Excel 2019 eta zaharragoetan abiarazten dena. Horretarako, jarri @ ikurra (ebakidura-eragile inplizitua) barruti-izenen aurretik:

=ADDRESS(@ROW(Sales), @COLUMN(Sales))

Antzera, beste formula batzuk konpondu ditzakezu.

azken gelaxka barrutian:

=ADDRESS(@ROW(Sales) + ROWS(Sales)-1, @COLUMN(Sales) + COLUMNS(Sales)-1)

Izeneko barruti baten helbidea lortzeko:

=ADDRESS(@ROW(Sales), @COLUMN(Sales)) & ":" & ADDRESS(@ROW(Sales) + ROWS(Sales)-1, @COLUMN(Sales) + COLUMNS(Sales)-1)

Beheko pantaila-argazkiak emaitzak erakusten ditu:

Aholkua. Excel array dinamikoan bertsio zaharrago batean sortutako formulekin lan-orri bat irekitzean, Excel-ek ebakidura-operadore inplizitu bat txertatzen du automatikoki.

Horrela duzu.Excel-en gelaxka-helbide bat itzuli. Tutorial honetan eztabaidatutako formula guztiak gertutik ikusteko, ongi etorria deskargatu dezakezu beheko gure lan-koadernoaren adibidea. Eskerrik asko irakurtzeagatik eta datorren astean gure blogean ikustea espero dut!

Landu koadernoa deskargatzeko

Excel ADDRESS funtzioa - formula adibideak (.xlsx fitxategia)