La lernilo montras kiel uzi la tutnovan funkcion TEXTSPLIT por disigi ŝnurojn en Excel 365 per iu ajn limigilo, kiun vi specifas.

Povas esti diversaj situacioj, kiam vi bezonas disigi. ĉeloj en Excel. En pli fruaj versioj, ni jam estis ekipitaj per kelkaj instrumentoj por plenumi la taskon kiel Teksto al Kolumnoj kaj Plenigi Flash. Nun, ni ankaŭ havas specialan funkcion por ĉi tio, TEXTSPLIT, kiu povas apartigi ŝnuron en plurajn ĉelojn tra kolumnoj aŭ/kaj vicoj surbaze de la parametroj kiujn vi specifas.

Excel TEXTSPLIT-funkcio.

La funkcio TEXTSPLIT en Excel dividas tekstajn ŝnurojn per difinita limigilo tra kolumnoj aŭ/kaj vicoj. La rezulto estas dinamika tabelo, kiu aŭtomate disvastiĝas en plurajn ĉelojn.

La funkcio prenas eĉ 6 argumentojn, el kiuj nur la unuaj du estas bezonataj.

TEXTSPLIT(teksto, kol_delimiter, [row_delimiter], [ignore_empty], [match_mode], [pad_with])

teksto (postulata) - la teksto por disdividi. Povas esti liverita kiel ĉeno aŭ ĉela referenco.

col_delimiter (postulata) - signo(j) kiu indikas kie disigi la tekston inter kolumnoj. Se ellasita, row_delimiter devas esti difinita.

row_delimiter (laŭvola) - signo(j) kiu indikas kie dividi la tekston inter vicoj.

ignore_empty (laŭvola) - specifas ĉu ignori malplenajn valorojn aŭ ne:

• FALSE (defaŭlte) -krei malplenajn ĉelojn por sinsekvaj limigiloj sen valoro intera.
• VERA - ignoru malplenajn valorojn, t.e. ne kreu malplenajn ĉelojn por du aŭ pli da sinsekvaj limigiloj.

match_mode (nedeviga) - determinas usklecon por la limigo. Ebligita defaŭlte.

• 0 (defaŭlte) - uskle-distinga
• 1 - uskle-maldistinga

pad_with (laŭvola ) - valoro por uzi anstataŭ mankantaj valoroj en dudimensiaj tabeloj. La defaŭlta estas #N/A eraro.

Ekzemple, por dividi tekstĉenon en A2 en plurajn ĉelojn uzante komon kaj spacon kiel apartigilon, la formulo estas:

=TEXTSPLIT(A2, ", ")

Disponibilidad de TEXTSPLIT

La funkcio TEXTSPLIT disponeblas nur en Excel por Microsoft 365 (Vindozo kaj Mac) kaj Excel por la reto.

Konsiletoj:

• En Excel-versioj, kie la funkcio TEXTSPLIT ne disponeblas (krom Excel 365), vi povas uzi la asistanton Teksto al Kolumnoj por dividi ĉelojn.
• Por plenumi la inversan taskon, t.e. kunigi la enhavon de pluraj ĉeloj en unu uzante certan limigilon, TEXTJOIN estas la funkcio por uzi.

Baza TEXTSPLIT-formulo por dividi ĉelon en Excel

Por komenci, ni vidu kiel uzi TEXTSPLIT. formulo en ĝia plej simpla formo por dividi tekstan ĉenon per aparta limigilo.

Disigi ĉelon horizontale trans kolumnoj

Por dividi la enhavon de donita ĉelo en plurajn kolumnojn, liverureferenco al la ĉelo enhavanta la originan ĉenon por la unua ( teksto ) argumento kaj la limigilo kiu markas la punkton kie la disigo devus okazi por la dua ( col_delimiter ) argumento.

Ekzemple, por apartigi la ĉenon en A2 horizontale per komo, la formulo estas:

=TEXTSPLIT(A2, ",")

Por la limigilo, ni uzas komon enfermitan inter citiloj (",") .

Kiel rezulto, ĉiu ero apartigita per komo iras en unuopan kolumnon:

Disigi ĉelon vertikale trans vicoj

Por dividi tekston tra pluraj vicoj, la tria argumento ( row_delimiter ) estas kie vi metas la limigilon. La dua argumento ( col_delimiter ) estas preterlasita en ĉi tiu kazo.

Ekzemple, por apartigi la valorojn en A2 en malsamajn vicojn, la formulo estas:

=TEXTSPLIT(A2, ,",")

Bonvolu noti, ke, en ambaŭ kazoj, la formulo estas enmetita nur en unu ĉelo (C2). En najbaraj ĉeloj, la revenitaj valoroj disverŝas aŭtomate. La rezulta tabelo (kiu nomiĝas verŝintervalo) estas emfazita per blua rando indikante, ke ĉio ene de ĝi estas kalkulita per la formulo en la supra maldekstra ĉelo.

Dividu tekston per subĉeno

En multaj kazoj, la valoroj en la fontĉeno estas apartigitaj per sinsekvo de signoj, komo kaj spaco estas tipa ekzemplo. Por trakti ĉi tiun scenaron, uzu subĉenon por la limigilo.

Ekzemple, por apartigi la tekston en A2 en plurajn kolumnojn.per komo kaj spaco, uzu la ĉenon ", " por col_delimiter .

=TEXTSPLIT(A2, ", ")

Ĉi tiu formulo iras al B2, kaj tiam vi kopiu ĝin malsupren tra tiom da ĉeloj laŭbezone.

Disdividu ĉenon en kolumnojn kaj vicojn samtempe

Por dividi tekstoĉenon en vicojn kaj kolumnojn samtempe, difinu ambaŭ limilojn en via TEXTSPLIT-formulo.

Ekzemple, por dividi la tekstĉenon en A2 tra kolumnoj kaj vicoj, ni provizas:

• La egalsignon ("=") por col_delimiter
• Komo kaj spaco (", ") por row_delimiter

La kompleta formulo prenas ĉi tiun formon:

=TEXTSPLIT(A2, "=", ", ")

La rezulto estas 2-D tabelo konsistanta el 2 kolumnoj kaj 3 vicoj:

Apartigu ĉelojn per multoblaj limigiloj

Por pritrakti plurajn aŭ malkonsekvencajn limigilojn en la fonta ĉeno, uzu tabelkonstanto kiel {"x","y" ,"z"} por la argumento de limigilo.

En la suba ekrankopio, la teksto en A2 estas limigita per kaj komoj (",") kaj punktokomoj (";") kun kaj sen spacoj. Por dividi la ŝnuron vertikale en vicojn per ĉiuj 4 varioj de la limigilo, la formulo estas:

=TEXTSPLIT(A2, , {",",", ",";","; "})

Aŭ, vi povas inkluzivi nur komon (",") kaj punktokomon ("; ") en la tabelo, kaj poste forigu kromajn spacojn helpe de la TRIM-funkcio:

=TRIM(TEXTSPLIT(A2, , {",",";"}))

Dividu tekston ignorante malplenajn valorojn

Se la ĉeno enhavas du aŭ pli sinsekvaj limigiloj sen valoro inter ili, vi povas elekti ĉu ignori tiajn malplenajnvaloroj aŭ ne. Ĉi tiu konduto estas regata de la kvara parametro ignore_empty , kiu defaŭlte estas FALSE.

Defaŭlte, la funkcio TEXTSPLIT ne ignoras malplenajn valorojn. La defaŭlta konduto bone funkcias por strukturitaj datumoj kiel en la suba ekzemplo.

En ĉi tiu specimena tabelo, la poentoj mankas en kelkaj ĉenoj. La formulo TEXTSPLIT kun la argumento ignore_empty preterlasita aŭ agordita al FALSO perfekte traktas ĉi tiun kazon, kreante malplenan ĉelon por ĉiu malplena valoro.

=TEXTSPLIT(A2, ", ")

Aŭ

=TEXTSPLIT(A2, ", ", FALSE)

Kiel rezulto, ĉiuj valoroj aperas en la taŭgaj kolumnoj.

Se viaj ĉenoj enhavas homogenajn datumojn, eble estas prudente ignori malplenajn valorojn. Por tio, agordu la argumenton ignore_empty al VERA aŭ 1.

Ekzemple, por dividi t la subajn ŝnurojn metante ĉiun kapablon en apartan ĉelon sen interspacoj, la formulo estas:

=TEXTSPLIT(A2, ", ", ,TRUE)

En ĉi tiu kazo, la mankantaj valoroj inter sinsekvaj limigiloj estas tute ignoritaj:

Ĉeldividado majuskkle aŭ nedistinge

Por kontroli la usklekon- sentemo de la limigilo, uzu la kvinan argumenton, match_mode .

Defaŭlte, match_mode estas agordita al 0, igante TEXTSPLIT majuskle-distingeblan .

En ĉi tiu ekzemplo, la ciferoj estas apartigitaj per la minuskla "x" kaj majuskla "X" literoj.

La formulo kun la defaŭlta majuskla distingo akceptas nur la minusklan "x". "kiel lalimigilo:

=TEXTSPLIT(A2, " x ")

Bonvolu atenti, ke la limigilo havas spacon ambaŭflanke de la litero "x" por malhelpi antaŭajn kaj postajn spacojn en la rezultoj.

Por malŝalti minusklecon, vi provizas 1 por match_mode por devigi la TEXTSPLIT-formulon ignori la majusklojn:

=TEXTSPLIT(A2, " x ", , ,1)

Nun, ĉiuj la ŝnuroj estas disigitaj ĝuste per ambaŭ limigiloj:

Pad mankantaj valoroj en 2D tabelo

La lasta argumento de la funkcio TEXTSPLIT, pad_with , utilas se oni aŭ pli da valoroj mankas en la fonta ĉeno. Kiam tia ĉeno estas dividita en ambaŭ kolumnojn kaj vicojn, defaŭlte, Excel resendas #N/A-eraroj anstataŭ la mankantaj valoroj por ne difekti la strukturon de dudimensia tabelo.

En la suba ĉeno, ne estas "=" ( col_delimiter ) post "Poentaro". Por konservi la integrecon de la rezulta tabelo, TEXTSPLIT eligas #N/A apud "Poentaro".

Por fari la rezulton pli afabla, vi povas anstataŭigi la eraron #N/A per iu ajn valoro, kiun vi volas. Simple, tajpu la deziratan valoron en la argumento pad_with .

En nia kazo, tio povus esti streketo ("-"):

=TEXTSPLIT(A2, "=", ", ", , ,"-")

Aŭ malplena ĉeno (""):

=TEXTSPLIT(A2, "=", ", ", , ,"")

Nun kiam vi lernis praktikajn uzojn de ĉiu argumento de la funkcio TEXTSPLIT, ni diskutu kelkajn altnivelajn ekzemplojn kiuj povas helpi vin elteni ne-trivialajn defiojn en viaj Excel-kalkultabeloj.

Dividu datojnen tagon, monaton kaj jaron

Por dividi daton en individuajn unuojn, unue vi devas konverti daton al teksto ĉar la funkcio TEXTSPLIT traktas tekstajn ĉenojn dum Excel-datoj estas nombroj.

La plej facila. maniero konverti numeran valoron al teksto estas uzante la TEXT-funkcion. Nur nepre liveru taŭgan formatan kodon por via dato.

En nia kazo, la formulo estas:

=TEXT(A2, "m/d/yyyy")

La sekva paŝo estas nesti la supran funkcion en la 1-an argumenton de TEXTSPLIT kaj enigu la respondan limigilon por la 2-a aŭ 3-a argumento, laŭ ĉu vi dividas inter kolumnoj aŭ vicoj. En ĉi tiu ekzemplo, la datunuoj estas limigitaj per oblikvoj, do ni uzas "/" por la argumento col_delimiter :

=TEXTSPLIT(TEXT(A2, "m/d/yyyy"), "/")

Disigi ĉelojn kaj forigu iujn signojn

Imagu ĉi tion: vi dividis longan ŝnuron en pecojn, sed la rezulta tabelo ankoraŭ enhavas kelkajn nedeziratajn signojn, kiel krampoj en la ekrankopio malsupre:

=TEXTSPLIT(A2, " ", "; ")

Por senigi de la malfermaj kaj fermaj krampoj samtempe, nestu du funkciojn SUBSTITUTE unu en la alian (ĉiu anstataŭigante unu krampon per malplena ĉeno) kaj uzu la formulon TEXTSPLIT por la argumento text de la interna SUBSTITUTE:

=SUBSTITUTE(SUBSTITUTE(TEXTSPLIT(A2, " ", "; "), "(", ""), ")", "")

Konsileto. Se la fina tabelo enhavas tro multajn kromajn signojn, vi povas purigi ilin uzante unu el la metodoj priskribitaj en ĉi tiu artikolo: Kiel forigi nedeziratajn signojn en Excel.

Dividu ŝnurojn preterpasante iujn valorojn

Supoze, ke vi volas apartigi la subajn ŝnurojn en 4 kolumnojn: Prenomnomo , Familinomo , Poentaro , kaj Rezulto . La problemo estas, ke iuj ŝnuroj enhavas la titolon "Mr." aŭ "S-ino", pro kio la rezultoj ĉiuj estas malĝustaj:

La solvo ne estas evidenta sed tute simpla :)

Krom la ekzistantaj limiloj, kiuj estas spaco (" ") kaj komon kaj spacon (", "), vi inkluzivas la ĉenojn "Mr. " kaj "Ms. " en la tabelkonstanto col_delimiter , tiel ke la funkcio uzas la titolojn mem por apartigi la teksto. Por ignori malplenajn valorojn, vi starigas la argumenton ignore_empty al VERA.

=TEXTSPLIT(A2, {" ",", ","Mr. ","Ms. "}, ,TRUE)

Nun, la rezultoj estas absolute perfektaj!

TEXTSPLIT-alternativoj

En Excel-versioj kie la funkcio TEXTSPLIT ne estas subtenata, vi povas dividi ŝnurojn uzante malsamajn kombinaĵojn de la funkcio SEARCH/FIND kun LEFT, RIGHT kaj MID. Precipe:

• Majusksence SEARCH aŭ majuskle-distinga FIND determinas la pozicion de la limigilo ene de ĉeno, kaj
• La funkcioj LEFT, RIGHT kaj MID ĉerpas subĉenon antaŭ ol , post aŭ inter du okazoj de la limigilo.

En nia kazo, por dividi la valorojn apartigitajn per komo kaj spaco , la formuloj iras jene.

Por ĉerpi la nomon:

=LEFT(A2, SEARCH(",", A2, 1) -1)

Por tiri la poentaron:

=MID(A2, SEARCH(",", A2) + 2, SEARCH(",", A2, SEARCH(",",A2)+1) - SEARCH(",", A2) - 2)

Por akiri larezulto:

=RIGHT(A2, LEN(A2) - SEARCH(",",  A2, SEARCH(",",  A2) + 1)-1)

Por la detala klarigo pri la logiko de la formuloj, vidu Kiel disigi ŝnurojn laŭ signo aŭ masko.

Bonvolu memori, ke male al la dinamika tabelo TEXTSPLIT funkcio, ĉi tiuj formuloj sekvas la tradician unu-formulo-unu-ĉelan aliron. Vi enigu la formulon en la unua ĉelo, kaj tiam trenu ĝin laŭ la kolumno por kopii al la subaj ĉeloj.

La ekrankopio malsupre montras la rezultojn:

Tiel disigi ĉelojn en Excel 365. uzante TEXTSPLIT aŭ alternativajn solvojn en pli fruaj versioj. Mi dankas vin pro legado kaj esperas vidi vin en nia blogo venontsemajne!

Praktiku laborlibron por elŝuto

TEXTSPLIT-funkcio por disigi ŝnurojn - formulekzemploj (.xlsx-dosiero)

3>