Mục lục
Hướng dẫn cho biết cách bạn có thể tận dụng hàm SEQUENCE mới để nhanh chóng tạo danh sách ngày trong Excel và sử dụng tính năng Tự động điền để điền ngày, ngày làm việc, tháng hoặc năm vào một cột.
Cho đến gần đây, chỉ có một cách dễ dàng để tạo ngày tháng trong Excel - tính năng Tự động điền. Sự ra đời của hàm SEQUENCE mảng động mới đã giúp bạn có thể tạo một chuỗi ngày tháng bằng một công thức. Hướng dẫn này xem xét kỹ cả hai phương pháp để bạn có thể chọn phương pháp phù hợp nhất với mình.
Cách điền chuỗi ngày trong Excel
Khi nào bạn cần điền ngày tháng vào cột trong Excel, cách nhanh nhất là sử dụng tính năng Tự động điền.
Tự động điền chuỗi ngày tháng trong Excel
Điền ngày tháng tăng dần vào cột hoặc hàng một ngày thật dễ dàng:
- Nhập ngày đầu tiên vào ô đầu tiên.
- Chọn ô có ngày đầu tiên và kéo núm điều khiển điền (hình vuông nhỏ màu xanh lá cây ở dưới cùng -góc phải) xuống dưới hoặc sang phải.
Excel sẽ ngay lập tức tạo ra một chuỗi ngày có cùng định dạng với ngày đầu tiên bạn nhập thủ công.
Điền ngày trong tuần, tháng hoặc năm vào cột
Để tạo chuỗi ngày, tháng hoặc năm làm việc, hãy thực hiện một trong các thao tác sau:
- Điền cột bằng ngày tuần tự như mô tả ở trên. Sau đó, nhấp vào nút Tùy chọn Tự động Điền và chọntùy chọn mong muốn, giả sử Điền tháng :
- Hoặc bạn có thể nhập ngày đầu tiên của mình, nhấp chuột phải vào núm điều khiển điền, giữ và kéo qua bao nhiêu ô khi cần thiết. Khi bạn nhả nút chuột, một menu ngữ cảnh sẽ bật lên cho phép bạn chọn tùy chọn cần thiết, Điền năm trong trường hợp của chúng tôi:
Điền chuỗi ngày tăng dần theo N ngày
Để tự động tạo chuỗi ngày, ngày trong tuần, tháng hoặc năm bằng bước cụ thể , bạn cần làm như sau:
- Nhập ngày đầu tiên vào ô đầu tiên.
- Chọn ô đó, nhấp chuột phải vào núm điều khiển điền, kéo nó qua bao nhiêu ô tùy ý rồi thả ra.
- Trong menu bật lên, hãy chọn Sê-ri (mục cuối cùng).
- Trong hộp thoại Sê-ri , hãy chọn Đơn vị ngày quan tâm và đặt Giá trị bước .
- Nhấp vào OK.
Để biết thêm ví dụ, vui lòng xem Cách chèn và tự động điền ngày tháng trong Excel.
Cách tạo chuỗi ngày tháng trong Excel bằng công thức
Trong một trong các hướng dẫn trước, chúng ta đã xem xét cách sử dụng hàm SEQUENCE mảng động mới để tạo ra một dãy số. Bởi vì các ngày nội bộ trong Excel được lưu trữ dưới dạng số sê-ri, nên hàm này cũng có thể dễ dàng tạo ra một chuỗi ngày. Tất cả những gì bạn phải làm là định cấu hình chính xác các đối số như được giải thích trong các ví dụ sau.
Lưu ý. Tất cả các công thức được thảo luận ở đây chỉ hoạt động trongphiên bản mới nhất của Excel 365 hỗ trợ mảng động. Trong Excel 2019 tiền động, Excel 2016 và Excel 2013, vui lòng sử dụng tính năng Tự động điền như được minh họa trong phần đầu tiên của hướng dẫn này.
Tạo một chuỗi ngày trong Excel
Để tạo một chuỗi ngày trong Excel, hãy thiết lập các đối số sau của hàm SEQUENCE:
SEQUENCE(hàng, [cột], [bắt đầu], [bước])- Hàng - số hàng để điền ngày.
- Cột - số cột cần điền ngày.
- Bắt đầu - ngày bắt đầu trong định dạng mà Excel có thể hiểu được, chẳng hạn như "8/1/2020" hoặc "1-Aug-2020". Để tránh nhầm lẫn, bạn có thể cung cấp ngày bằng cách sử dụng hàm DATE chẳng hạn như DATE(2020, 8, 1).
- Bước - gia số cho mỗi ngày tiếp theo trong một trình tự.
Ví dụ: để tạo danh sách gồm 10 ngày bắt đầu từ ngày 1 tháng 8 năm 2020 và tăng thêm 1 ngày, công thức là:
=SEQUENCE(10, 1, "8/1/2020", 1)
hoặc
=SEQUENCE(10, 1, DATE(2020, 8, 1), 1)
Ngoài ra, bạn có thể nhập số ngày (B1), ngày bắt đầu (B2) và bước (B3) vào các ô được xác định trước và tham chiếu các ô đó trong công thức của mình. Vì chúng tôi đang tạo danh sách nên số cột (1) được mã hóa cứng:
=SEQUENCE(B1, 1, B2, B3)
Nhập công thức bên dưới vào ô trên cùng (trong trường hợp của chúng tôi là A6), nhấn phím Enter và kết quả sẽ tự động tràn qua số lượng hàng và cột đã chỉ định.
Lưu ý. Với Chung mặc địnhđịnh dạng, kết quả sẽ xuất hiện dưới dạng số sê-ri. Để chúng được hiển thị chính xác, hãy đảm bảo áp dụng định dạng Ngày cho tất cả các ô trong phạm vi tràn.
Tạo chuỗi ngày làm việc trong Excel
Để chỉ nhận chuỗi ngày làm việc, hãy bọc SEQUENCE trong hàm WORKDAY hoặc WORKDAY.INTL theo cách này:
WORKDAY( start_date -1, SEQUENCE( no_of_days ))Vì hàm WORKDAY thêm số ngày được chỉ định trong đối số thứ hai vào ngày bắt đầu, chúng ta trừ 1 từ đối số đó để đưa chính ngày bắt đầu vào đối số thứ hai kết quả.
Ví dụ: để tạo chuỗi ngày làm việc bắt đầu từ ngày ở B2, công thức là:
=WORKDAY(B2-1, SEQUENCE(B1))
Trong đó B1 là kích thước chuỗi.
Mẹo và lưu ý:
- Nếu ngày bắt đầu là Thứ Bảy hoặc Chủ Nhật, loạt phim sẽ bắt đầu vào ngày làm việc tiếp theo.
- Hàm WORKDAY trong Excel giả định Thứ Bảy và Chủ Nhật là ngày cuối tuần. Để định cấu hình các ngày cuối tuần và ngày lễ tùy chỉnh, hãy sử dụng hàm WORKDAY.INTL thay thế.
Tạo chuỗi tháng trong Excel
Để tạo chuỗi ngày tăng dần theo một tháng, bạn có thể sử dụng công thức chung này:
DATE( year , SEQUENCE(12), day )Trong trường hợp này, bạn đặt năm mục tiêu trong đối số thứ nhất và ngày trong đối số lý lẽ thứ 3. Đối với đối số thứ 2, hàm SEQUENCE trả về các số thứ tự từ 1 đến 12. Dựa trên các tham số trên, hàm DATE tạo ra một chuỗicác ngày như được hiển thị ở phần bên trái của ảnh chụp màn hình bên dưới:
=DATE(2020, SEQUENCE(12), 1)
Để chỉ hiển thị tên tháng , hãy đặt một trong các định dạng ngày tùy chỉnh bên dưới cho phạm vi tràn :
- mmm - dạng rút gọn như Jan , Feb , Mar , v.v.
- mmmm - đầy đủ dạng như Tháng một , Tháng hai , Tháng ba , v.v.
Kết quả là, chỉ có tên tháng sẽ xuất hiện trong các ô, nhưng các giá trị cơ bản sẽ vẫn là ngày đầy đủ. Trong cả hai chuỗi trong ảnh chụp màn hình bên dưới, vui lòng lưu ý căn lề phải mặc định điển hình cho số và ngày trong Excel:
Để tạo chuỗi ngày tăng dần theo một tháng và bắt đầu với một ngày cụ thể , hãy sử dụng hàm SEQUENCE cùng với EDATE:
EDATE( start_date , SEQUENCE(12, 1, 0))Hàm EDATE trả về một ngày mà là số tháng được chỉ định trước hoặc sau ngày bắt đầu. Và hàm SEQUENCE tạo ra một mảng gồm 12 số (hoặc bao nhiêu số tùy bạn chỉ định) để buộc EDATE tăng dần theo từng tháng. Xin lưu ý rằng đối số bắt đầu được đặt thành 0, để ngày bắt đầu được đưa vào kết quả.
Với ngày bắt đầu ở B1, công thức sẽ có dạng như sau:
=EDATE(B1, SEQUENCE(12, 1, 0))
Lưu ý. Sau khi hoàn thành công thức, hãy nhớ áp dụng định dạng ngày thích hợp cho kết quả để chúng hiển thị chính xác.
Tạo chuỗi năm trong Excel
Để tạochuỗi ngày tăng dần theo năm, hãy sử dụng công thức chung sau:
NGÀY(SEQUENCE( n , 1, YEAR( start_date )), MONTH( start_date ), DAY( start_date ))Trong đó n là số ngày bạn muốn tạo.
Trong trường hợp này, DATE(năm, tháng, ngày) tạo ngày theo cách này:
- Năm được trả về bởi hàm SEQUENCE được định cấu hình để tạo n hàng theo 1 mảng cột gồm các số, bắt đầu từ giá trị năm từ start_date .
- Month và các giá trị day được lấy trực tiếp từ ngày bắt đầu.
Ví dụ: nếu bạn nhập ngày bắt đầu vào ô B1, công thức sau đây sẽ xuất ra một chuỗi 10 ngày theo gia số một năm:
=DATE(SEQUENCE(10, 1, YEAR(B1)), MONTH(B1), DAY(B1))
Sau được định dạng là ngày tháng, kết quả sẽ như sau:
Tạo chuỗi thời gian trong Excel
Bởi vì thời gian được lưu trữ trong Excel dưới dạng số thập phân đại diện cho một trong ngày, hàm SEQUENCE có thể hoạt động trực tiếp với thời gian.
A giả sử thời gian bắt đầu là ở B1, bạn có thể sử dụng một trong các công thức sau để tạo ra một chuỗi 10 lần. Sự khác biệt chỉ nằm ở đối số bước . Vì một ngày có 24 giờ, hãy sử dụng 1/24 để tăng thêm một giờ, 1/48 để tăng thêm 30 phút, v.v.
Cách nhau 30 phút:
=SEQUENCE(10, 1, B1, 1/48)
Cách nhau 1 giờ:
=SEQUENCE(10, 1, B1, 1/24)
Cách nhau 2 giờ:
=SEQUENCE(10, 1, B1, 1/12)
Ảnh chụp màn hình bên dưới hiển thịkết quả:
Nếu bạn không muốn tính toán bước theo cách thủ công, bạn có thể xác định bước đó bằng cách sử dụng hàm TIME:
SEQUENCE(hàng, cột, bắt đầu, TIME( hour , minute , second ))Đối với ví dụ này, chúng tôi sẽ nhập tất cả các biến trong các ô riêng biệt như minh họa trong ảnh chụp màn hình bên dưới . Sau đó, bạn có thể sử dụng công thức bên dưới để tạo chuỗi thời gian với bất kỳ kích thước bước tăng nào mà bạn chỉ định trong các ô E2 (giờ), E3 (phút) và E4 (giây):
=SEQUENCE(B2, B3, B4, TIME(E2, E3, E4))
Cách tạo lịch hàng tháng trong Excel
Trong ví dụ cuối cùng này, chúng ta sẽ sử dụng hàm SEQUENCE cùng với DATEVALUE và WEEKDAY để tạo lịch hàng tháng sẽ cập nhật tự động dựa trên năm và tháng mà bạn chỉ định.
Công thức trong A5 như sau:
=SEQUENCE(6, 7, DATEVALUE("1/"&B2&"/"&B1) - WEEKDAY(DATEVALUE("1/"&B2&"/"&B1)) + 1, 1)
Cách thức hoạt động của công thức này:
Bạn sử dụng hàm SEQUENCE để tạo mảng ngày tháng có 6 hàng (số tuần tối đa có thể có trong một tháng) theo 7 cột (số ngày trong một tuần) tăng thêm 1 ngày. Do đó, các đối số hàng , cột và bước không đặt ra câu hỏi nào.
Phần khó nhất trong đối số bắt đầu . Chúng tôi không thể bắt đầu lịch của mình với ngày đầu tiên của tháng mục tiêu vì chúng tôi không biết đó là ngày nào trong tuần. Vì vậy, chúng tôi sử dụng công thức sau để tìm Chủ nhật đầu tiên trước ngày đầu tiên của tháng được chỉ định vànăm:
DATEVALUE("1/"&B2&"/"&B1) - WEEKDAY(DATEVALUE("1/"&B2&"/"&B1)) + 1
Hàm DATEVALUE đầu tiên trả về một số sê-ri, trong hệ thống Excel nội bộ, đại diện cho ngày đầu tiên của tháng ở B2 và năm ở B1. Trong trường hợp của chúng tôi, đó là 44044 tương ứng với ngày 1 tháng 8 năm 2020. Tại thời điểm này, chúng tôi có:
44044 - WEEKDAY(DATEVALUE("1/"&B2&"/"&B1)) + 1
Hàm WEEKDAY trả về ngày trong tuần tương ứng với ngày đầu tiên của mục tiêu tháng dưới dạng số từ 1 (Chủ Nhật) đến 7 (Thứ Bảy). Trong trường hợp của chúng tôi, đó là 7 vì ngày 1 tháng 8 năm 2020 là Thứ Bảy. Và công thức của chúng tôi rút gọn thành:
44044 - 7 + 1
44044 - 7 là 4403, tương ứng với Thứ Bảy, ngày 25 tháng 7 năm 2020. Khi cần Chủ Nhật, chúng tôi thêm phần điều chỉnh +1.
Bằng cách này, chúng ta có một công thức đơn giản xuất ra một mảng các số sê-ri bắt đầu bằng 4404:
=SEQUENCE(6, 7, 4404, 1)
Định dạng kết quả dưới dạng ngày tháng và bạn sẽ nhận được lịch hiển thị trong ảnh chụp màn hình ở trên. Ví dụ: bạn có thể sử dụng một trong các định dạng ngày sau:
- d-mmm-yy để hiển thị các ngày như 1-Aug-20
- mmm d để hiển thị tháng và ngày như Aug 20
- d để chỉ hiển thị ngày
Đợi đã, nhưng mục tiêu của chúng tôi là tạo lịch hàng tháng. Tại sao một số ngày của tháng trước và tháng sau hiển thị? Để ẩn những ngày không liên quan đó, hãy thiết lập quy tắc định dạng có điều kiện bằng công thức bên dưới và áp dụng màu phông chữ trắng :
=MONTH(A5)MONTH(DATEVALUE($B$2 & "1"))
Trong đó A5 là ô ngoài cùng bên trái của lịch của bạn và B2 là mục tiêutháng.
Để biết các bước chi tiết, vui lòng xem Cách tạo quy tắc định dạng có điều kiện dựa trên công thức trong Excel.
Đó là cách bạn có thể tạo một chuỗi của ngày tháng trong Excel. Tôi cảm ơn bạn đã đọc và hy vọng sẽ gặp bạn trên blog của chúng tôi vào tuần tới!
Sách bài tập thực hành để tải xuống
Chuỗi ngày tháng trong Excel - ví dụ về công thức (tệp .xlsx)
