قم بإنشاء تسلسل تاريخ في Excel وسلسلة تاريخ الملء التلقائي

Michael Brown

14-09-2023 اكسل
  • شارك هذا
Michael Brown

يوضح البرنامج التعليمي كيف يمكنك الاستفادة من وظيفة SEQUENCE الجديدة لإنشاء قائمة بالتواريخ في Excel بسرعة واستخدام ميزة الملء التلقائي لملء عمود بالتواريخ أو أيام العمل أو الأشهر أو السنوات.

حتى وقت قريب ، كانت هناك طريقة واحدة سهلة لإنشاء التواريخ في Excel - وهي ميزة الملء التلقائي. أتاح إدخال الدالة SEQUENCE للصفيف الديناميكي الجديدة إمكانية إنشاء سلسلة من التواريخ باستخدام صيغة أيضًا. يلقي هذا البرنامج التعليمي نظرة متعمقة على كلتا الطريقتين بحيث يمكنك اختيار الطريقة الأفضل بالنسبة لك.

    كيفية ملء سلسلة التاريخ في Excel

    متى تحتاج إلى ملء عمود بالتواريخ في Excel ، أسرع طريقة هي استخدام ميزة الملء التلقائي.

    ملء تلقائي لسلسلة التاريخ في Excel

    ملء عمود أو صف بالتواريخ التي تزيد بمقدار يوم واحد سهل للغاية:

    1. اكتب التاريخ الأولي في الخلية الأولى.
    2. حدد الخلية مع التاريخ الأولي واسحب مقبض التعبئة (مربع أخضر صغير في الأسفل -الزاوية اليمنى) لأسفل أو إلى اليمين.

    سيقوم Excel على الفور بإنشاء سلسلة من التواريخ بنفس تنسيق التاريخ الأول الذي كتبته يدويًا.

    املأ العمود بأيام الأسبوع أو الأشهر أو السنوات

    لإنشاء سلسلة من أيام العمل أو الأشهر أو السنوات ، قم بأحد الإجراءات التالية:

    • املأ العمود بـ التواريخ المتسلسلة كما هو موضح أعلاه. بعد ذلك ، انقر فوق الزر خيارات الملء التلقائي واختر ملفالخيار المطلوب ، قل ملء الأشهر :

    • أو يمكنك إدخال تاريخك الأول ، انقر بزر الماوس الأيمن فوق مقبض التعبئة ، واضغط باستمرار واسحب عبر أكبر عدد من الخلايا كما هو مطلوب. عند تحرير زر الماوس ، ستظهر قائمة سياق منبثقة تتيح لك تحديد الخيار المطلوب ، ملء السنوات في حالتنا:

    املأ سلسلة من التواريخ التي تتزايد بمقدار N أيام

    لإنشاء سلسلة من الأيام أو أيام الأسبوع أو الأشهر أو السنوات تلقائيًا باستخدام خطوة محددة ، هذا ما عليك القيام به:

    1. أدخل التاريخ الأولي في الخلية الأولى.
    2. حدد تلك الخلية ، وانقر بزر الماوس الأيمن فوق مقبض التعبئة ، واسحبه عبر العديد من الخلايا حسب الحاجة ، ثم حرر.
    3. في القائمة المنبثقة ، اختر السلسلة (العنصر الأخير).
    4. في مربع الحوار السلسلة ، حدد وحدة التاريخ المهمة وقم بتعيين قيمة الخطوة .
    5. انقر فوق "موافق".

    لمزيد من الأمثلة ، يرجى الاطلاع على كيفية أدخل التواريخ وقم بتعبئتها تلقائيًا في Excel.

    كيفية عمل تسلسل تاريخ في Excel باستخدام صيغة

    في أحد البرامج التعليمية السابقة ، نظرنا في كيفية استخدام وظيفة الصفيف الديناميكي الجديدة SEQUENCE من أجل توليد تسلسل رقمي. نظرًا لأنه يتم تخزين التواريخ داخليًا في Excel كأرقام تسلسلية ، يمكن للوظيفة بسهولة إنتاج سلسلة تاريخ أيضًا. كل ما عليك فعله هو تكوين الوسائط بشكل صحيح كما هو موضح في الأمثلة التالية.

    ملاحظة. جميع الصيغ التي تمت مناقشتها هنا تعمل فقط في ملفأحدث إصدارات Excel 365 التي تدعم الصفائف الديناميكية. في Excel 2019 و Excel 2016 و Excel 2013 ما قبل الديناميكي ، يرجى استخدام ميزة الملء التلقائي كما هو موضح في الجزء الأول من هذا البرنامج التعليمي.

    إنشاء سلسلة من التواريخ في Excel

    لإنشاء تسلسل التواريخ في Excel ، قم بإعداد الوسيطات التالية للدالة SEQUENCE:

    SEQUENCE (صفوف ، [أعمدة] ، [بدء] ، [خطوة])
    • صفوف - عدد الصفوف المراد ملؤها بالتواريخ.
    • الأعمدة - عدد الأعمدة المراد ملؤها بالتواريخ.
    • البداية - تاريخ البدء في تنسيق يستطيع Excel فهمه ، مثل "8/1/2020" أو "1 أغسطس -2020". لتجنب الأخطاء ، يمكنك توفير التاريخ باستخدام وظيفة DATE مثل DATE (2020، 8، 1).
    • الخطوة - الزيادة لكل تاريخ لاحق في تسلسل.

    على سبيل المثال ، لإعداد قائمة من 10 تواريخ تبدأ من 1 أغسطس 2020 وتزداد بمقدار يوم واحد ، تكون الصيغة:

    =SEQUENCE(10, 1, "8/1/2020", 1)

    أو

    =SEQUENCE(10, 1, DATE(2020, 8, 1), 1)

    بدلاً من ذلك ، يمكنك إدخال عدد التواريخ (B1) وتاريخ البدء (B2) والخطوة (B3) في الخلايا المحددة مسبقًا والإشارة إلى هذه الخلايا في الصيغة. نظرًا لأننا نقوم بإنشاء قائمة ، فإن رقم الأعمدة (1) مشفر بشكل ثابت:

    =SEQUENCE(B1, 1, B2, B3)

    اكتب الصيغة أدناه في الخلية العلوية (A6 في حالتنا) ، واضغط على مفتاح Enter ، و ستنتشر النتائج عبر العدد المحدد من الصفوف والأعمدة تلقائيًا.

    ملاحظة. مع الافتراضي عام ستظهر النتائج كأرقام تسلسلية. لعرضها بشكل صحيح ، تأكد من تطبيق تنسيق التاريخ على جميع الخلايا في نطاق الانسكاب.

    إنشاء سلسلة من أيام العمل في Excel

    للحصول على سلسلة من أيام العمل فقط ، قم بلف SEQUENCE في دالة WORKDAY أو WORKDAY.INTL بهذه الطريقة:

    WORKDAY ( تاريخ البدء -1 ، SEQUENCE ( no_of_days ))

    نظرًا لأن الدالة WORKDAY تضيف عدد الأيام المحددة في الوسيطة الثانية إلى تاريخ البدء ، فإننا نطرح 1 منه لتضمين تاريخ البدء نفسه في النتائج.

    على سبيل المثال ، لإنشاء تسلسل من أيام العمل بدءًا من التاريخ الموجود في B2 ، تكون الصيغة:

    =WORKDAY(B2-1, SEQUENCE(B1))

    حيث يكون B1 هو حجم التسلسل.

    نصائح وملاحظات:

    • إذا كان تاريخ البدء هو السبت أو الأحد ، فستبدأ السلسلة في يوم العمل التالي.
    • تفترض وظيفة Excel WORKDAY أن يومي السبت والأحد هما عطلة نهاية الأسبوع. لتكوين عطلات نهاية الأسبوع والعطلات المخصصة ، استخدم الدالة WORKDAY.INTL بدلاً من ذلك.

    قم بإنشاء تسلسل شهري في Excel

    لإنشاء سلسلة من التواريخ التي تزداد بمقدار شهر واحد ، يمكنك استخدام هذه الصيغة العامة:

    التاريخ ( السنة ، SEQUENCE (12) ، اليوم )

    في هذه الحالة ، تضع السنة المستهدفة في الوسيطة الأولى واليوم في الحجة الثالثة. بالنسبة للوسيطة الثانية ، تُرجع الدالة SEQUENCE أرقامًا متسلسلة من 1 إلى 12. استنادًا إلى المعلمات المذكورة أعلاه ، تنتج الدالة DATE سلسلة منالتواريخ كما هو موضح في الجزء الأيسر من لقطة الشاشة أدناه:

    =DATE(2020, SEQUENCE(12), 1)

    لعرض أسماء الشهور فقط ، قم بتعيين أحد تنسيقات التاريخ المخصصة أدناه لنطاق الانسكاب :

    • ملم - شكل قصير مثل يناير ، فبراير ، مارس ، إلخ.
    • ش ش ش - ممتلئ شكل مثل يناير ، فبراير ، مارس ، إلخ.

    نتيجة لذلك ، ستظهر أسماء الأشهر فقط في الخلايا ، لكن القيم الأساسية ستظل تواريخ كاملة. في كلتا السلسلتين في لقطة الشاشة أدناه ، يرجى ملاحظة المحاذاة الصحيحة الافتراضية النموذجية للأرقام والتواريخ في Excel:

    لإنشاء تسلسل تاريخ يزيد بمقدار شهر واحد و يبدأ بتاريخ محدد ، استخدم الدالة SEQUENCE مع EDATE:

    EDATE ( start_date ، SEQUENCE (12، 1، 0))

    ترجع الدالة EDATE التاريخ الذي هو عدد الأشهر المحدد قبل تاريخ البدء أو بعده. وتنتج الدالة SEQUENCE مصفوفة من 12 رقمًا (أو العدد الذي تحدده) لإجبار EDATE على المضي قدمًا بزيادات قدرها شهر واحد. يرجى ملاحظة أن الوسيطة start مضبوطة على 0 ، بحيث يتم تضمين تاريخ البدء في النتائج.

    مع تاريخ البدء في B1 ، تأخذ الصيغة هذا الشكل:

    =EDATE(B1, SEQUENCE(12, 1, 0))

    ملاحظة. بعد إكمال الصيغة ، يرجى تذكر تطبيق تنسيق تاريخ مناسب على النتائج حتى يتم عرضها بشكل صحيح.

    إنشاء تسلسل سنوي في Excel

    لعملسلسلة من التواريخ المتزايدة حسب السنة ، استخدم هذه الصيغة العامة:

    DATE (SEQUENCE ( n ، 1، YEAR ( start_date ))، MONTH ( start_date ) ، DAY ( start_date ))

    حيث n هو عدد التواريخ التي تريد إنشاؤها.

    في هذه الحالة ، DATE (سنة ، تُنشئ الدالة month، day) تاريخًا بهذه الطريقة:

    • يتم إرجاع السنة بواسطة دالة SEQUENCE التي تم تكوينها لإنشاء صفوف n بمقدار 1 صفيف الأعمدة من الأرقام ، بدءًا من قيمة السنة من تاريخ_البدء . يتم سحب قيم
    • الشهر و اليوم مباشرة من تاريخ البدء.

    على سبيل المثال ، إذا أدخلت تاريخ البدء في B1 ، فستخرج الصيغة التالية سلسلة من 10 تواريخ بزيادات لمدة سنة واحدة:

    =DATE(SEQUENCE(10, 1, YEAR(B1)), MONTH(B1), DAY(B1))

    بعد عند تنسيقها كتواريخ ، ستظهر النتائج على النحو التالي:

    إنشاء تسلسل الأوقات في Excel

    نظرًا لأنه يتم تخزين الأوقات في Excel كأرقام عشرية تمثل جزء من اليوم ، يمكن أن تعمل دالة SEQUENCE مع الأوقات مباشرة.

    A بجمع وقت البدء في B1 ، يمكنك استخدام إحدى الصيغ التالية لإنتاج سلسلة من 10 مرات. يكون الاختلاف فقط في الوسيطة الخطوة . نظرًا لوجود 24 ساعة في اليوم ، استخدم 1/24 للزيادة بمقدار ساعة ، و 1/48 للزيادة بمقدار 30 دقيقة ، وهكذا.

    30 دقيقة على حدة:

    =SEQUENCE(10, 1, B1, 1/48)

    بفارق ساعة واحدة:

    =SEQUENCE(10, 1, B1, 1/24)

    ساعتان متباعدتان:

    =SEQUENCE(10, 1, B1, 1/12)

    توضح لقطة الشاشة أدناهالنتائج:

    إذا كنت لا تريد عناء حساب الخطوة يدويًا ، يمكنك تحديدها باستخدام وظيفة الوقت:

    SEQUENCE (صفوف ، أعمدة ، ابدأ ، TIME ( ساعة ، دقيقة ، ثانية ))

    في هذا المثال ، سنقوم بإدخال جميع المتغيرات في خلايا منفصلة كما هو موضح في لقطة الشاشة أدناه . وبعد ذلك ، يمكنك استخدام الصيغة أدناه لإنشاء سلسلة زمنية بأي حجم خطوة زيادة تحدده في الخلايا E2 (بالساعات) و E3 (بالدقائق) و E4 (بالثواني):

    =SEQUENCE(B2, B3, B4, TIME(E2, E3, E4))

    كيفية إنشاء تقويم شهري في Excel

    في هذا المثال الأخير ، سنستخدم دالة SEQUENCE مع DATEVALUE و WEEKDAY لإنشاء تقويم شهري سيتم تحديثه تلقائيًا استنادًا إلى السنة والشهر اللذين تحددهما.

    الصيغة في A5 هي كما يلي:

    =SEQUENCE(6, 7, DATEVALUE("1/"&B2&"/"&B1) - WEEKDAY(DATEVALUE("1/"&B2&"/"&B1)) + 1, 1)

    كيف تعمل هذه الصيغة:

    تستخدم الدالة SEQUENCE لإنشاء 6 صفوف (أقصى عدد ممكن من الأسابيع في الشهر) من خلال 7 أعمدة (عدد الأيام في الأسبوع) مصفوفة من التواريخ تزداد بمقدار يوم واحد. وبالتالي ، فإن الصفوف و الأعمدة و الخطوة لا تثير أي أسئلة.

    الجزء الأصعب في الوسيطة ابدأ . لا يمكننا بدء تقويمنا مع اليوم الأول من الشهر المستهدف لأننا لا نعرف أي يوم من أيام الأسبوع هو. لذلك ، نستخدم الصيغة التالية لإيجاد أول يوم أحد قبل اليوم الأول من الشهر المحدد وyear:

    DATEVALUE("1/"&B2&"/"&B1) - WEEKDAY(DATEVALUE("1/"&B2&"/"&B1)) + 1

    ترجع الدالة DATEVALUE الأولى رقمًا تسلسليًا يمثل ، في نظام Excel الداخلي ، اليوم الأول من الشهر في B2 والسنة في B1. في حالتنا ، إنها 44044 الموافق 1 أغسطس 2020. في هذه المرحلة ، لدينا:

    44044 - WEEKDAY(DATEVALUE("1/"&B2&"/"&B1)) + 1

    ترجع الدالة WEEKDAY يوم الأسبوع المقابل لليوم الأول من الهدف شهر كرقم من 1 (الأحد) إلى 7 (السبت). في حالتنا ، إنها 7 لأن 1 أغسطس 2020 هو يوم السبت. وتختزل الصيغة إلى:

    44044 - 7 + 1

    44044-7 هي 4403 ، وهو ما يتوافق مع يوم السبت 25 يوليو 2020. كما نحتاج يوم الأحد ، نضيف تصحيح +1.

    بهذه الطريقة ، نحصل على صيغة بسيطة تُخرج مصفوفة من الأرقام التسلسلية تبدأ بـ 4404:

    =SEQUENCE(6, 7, 4404, 1)

    نسِّق النتائج كتواريخ ، وسيظهر لك التقويم في لقطة الشاشة أعلاه. على سبيل المثال ، يمكنك استخدام أحد تنسيقات التاريخ التالية:

    • d-mmm-yy لعرض التواريخ مثل 1-Aug-20
    • ش ش ش د لعرض الشهر واليوم مثل 20 أغسطس
    • d لعرض اليوم

    انتظر ، لكننا نهدف إلى إنشاء تقويم شهري. لماذا تظهر بعض تواريخ الشهر السابق والقادم؟ لإخفاء تلك التواريخ غير ذات الصلة ، قم بإعداد قاعدة تنسيق شرطي باستخدام الصيغة أدناه وقم بتطبيق الخط الأبيض اللون:

    =MONTH(A5)MONTH(DATEVALUE($B$2 & "1"))

    حيث A5 هي الخلية الموجودة في أقصى اليسار التقويم الخاص بك و B2 هو الهدفالشهر.

    للحصول على الخطوات التفصيلية ، يرجى الاطلاع على كيفية إنشاء قاعدة تنسيق شرطي قائمة على الصيغة في Excel.

    هكذا يمكنك إنشاء تسلسل من التواريخ في Excel. أشكرك على القراءة وآمل أن أراك على مدونتنا الأسبوع المقبل!

    تدرب على المصنف للتنزيل

    تسلسل التاريخ في Excel - أمثلة على الصيغ (ملف .xlsx)

    المنشور السابق تصدير جهات الاتصال من Outlook إلى Excel
    آخر بعد كيفية إزالة ارتباطات تشعبية متعددة من أوراق عمل Excel في وقت واحد

    مايكل براون متحمس للتكنولوجيا ولديه شغف لتبسيط العمليات المعقدة باستخدام أدوات البرمجيات. مع أكثر من عشر سنوات من الخبرة في صناعة التكنولوجيا ، صقل مهاراته في Microsoft Excel و Outlook ، بالإضافة إلى جداول بيانات Google والمستندات. مدونة مايكل مكرسة لمشاركة معرفته وخبرته مع الآخرين ، وتقديم نصائح ودروس تعليمية سهلة المتابعة لتحسين الإنتاجية والكفاءة. سواء كنت محترفًا متمرسًا أو مبتدئًا ، تقدم مدونة مايكل رؤى قيمة ونصائح عملية للحصول على أقصى استفادة من أدوات البرامج الأساسية هذه.