Падручнік паказвае, як вы можаце выкарыстоўваць новую функцыю SEQUENCE для хуткага стварэння спісу дат у Excel і выкарыстоўваць функцыю аўтазапаўнення для запаўнення слупка датамі, працоўнымі днямі, месяцамі або гадамі.

Да нядаўняга часу існаваў толькі адзін просты спосаб стварэння дат у Excel - функцыя аўтазапаўнення. Увядзенне новага дынамічнага масіва функцыі SEQUENCE таксама зрабіла магчымым стварэнне серыі дат з дапамогай формулы. У гэтым падручніку дэталёва разглядаюцца абодва метады, каб вы маглі выбраць той, які лепш за ўсё падыходзіць для вас.

Як запоўніць шэраг дат у Excel

Калі вам трэба запоўніць слупок датамі ў Excel, самы хуткі спосаб - выкарыстоўваць функцыю аўтазапаўнення.

Аўтаматычнае запаўненне серыі дат у Excel

Запаўненне слупка або радка датамі, якія павялічваюцца на адзін дзень вельмі проста:

1. Увядзіце пачатковую дату ў першую ячэйку.
2. Абярыце ячэйку з пачатковай датай і перацягніце маркер запаўнення (маленькі зялёны квадрат унізе -правы вугал) уніз або направа.

Excel неадкладна згенеруе шэраг дат у тым жа фармаце, што і першая дата, якую вы ўвялі ўручную.

Запоўніце слупок днямі тыдня, месяцамі ці гадамі

Каб стварыць шэраг працоўных дзён, месяцаў ці гадоў, зрабіце адно з наступнага:

• Запоўніце слупок паслядоўныя даты, як апісана вышэй. Пасля гэтага націсніце кнопку Параметры аўтазапаўнення і абярыцежаданая опцыя, скажыце Запоўніць месяцы :

  

• Або вы можаце ўвесці сваю першую дату, пстрыкніце правай кнопкай мышы маркер запаўнення, утрымлівайце і перацягніце праз столькі вочак па меры неабходнасці. Калі вы адпусціце кнопку мышы, з'явіцца кантэкстнае меню, у якім вы зможаце выбраць патрэбны варыянт, Запоўніць гады у нашым выпадку:

  

Запоўніце серыю дат з павелічэннем на N дзён

Каб аўтаматычна згенераваць серыю дзён, будняў, месяцаў ці гадоў з канкрэтным крокам , вось што вам трэба зрабіць:

1. Увядзіце пачатковую дату ў першую ячэйку.
2. Выберыце гэтую ячэйку, пстрыкніце правай кнопкай мышы маркер запаўнення, перацягніце яе праз столькі вочак, колькі неабходна, а потым адпусціце.
3. Ва ўсплываючым меню выберыце Серый (апошні пункт).
4. У дыялогавым акне Серый выберыце Адзінку даты цікавасці і ўсталюйце Значэнне кроку .
5. Націсніце OK.

Больш прыкладаў глядзіце, як устаўка і аўтазапаўненне дат у Excel.

Як стварыць паслядоўнасць дат у Excel з дапамогай формулы

У адным з папярэдніх урокаў мы разгледзелі, як выкарыстоўваць новы дынамічны масіў SEQUENCE, каб стварыць лікавую паслядоўнасць. Паколькі ўнутрана ў Excel даты захоўваюцца ў выглядзе парадкавых нумароў, гэтая функцыя таксама можа лёгка стварыць шэраг дат. Усё, што вам трэба зрабіць, гэта правільна наладзіць аргументы, як тлумачыцца ў наступных прыкладах.

Заўвага. Усе разгледжаныя тут формулы працуюць толькі ўапошнія версіі Excel 365, якія падтрымліваюць дынамічныя масівы. У папярэдне дынамічных праграмах Excel 2019, Excel 2016 і Excel 2013 выкарыстоўвайце функцыю аўтазапаўнення, як паказана ў першай частцы гэтага падручніка.

Стварыце шэраг дат у Excel

Каб стварыць паслядоўнасць дат у Excel, усталюйце наступныя аргументы функцыі SEQUENCE:

• Радкі - колькасць радкоў для запаўнення датамі.
• Слупкі - колькасць слупкоў для запаўнення датамі.
• Пачатак - дата пачатку ў фармат, зразумелы Excel, напрыклад "8/1/2020" або "1-Aug-2020". Каб пазбегнуць памылак, вы можаце ўвесці дату з дапамогай функцыі ДАТА, напрыклад ДАТА(2020, 8, 1).
• Крок - крок для кожнай наступнай даты ў паслядоўнасці.

Напрыклад, каб скласці спіс з 10 дат, пачынаючы з 1 жніўня 2020 г. і павялічваючыся на 1 дзень, формула:

=SEQUENCE(10, 1, "8/1/2020", 1)

або

=SEQUENCE(10, 1, DATE(2020, 8, 1), 1)

У якасці альтэрнатывы вы можаце ўвесці колькасць дат (B1), дату пачатку (B2) і крок (B3) у загадзя вызначаныя ячэйкі і спасылацца на гэтыя ячэйкі ў формуле. Паколькі мы ствараем спіс, нумар слупка (1) жорстка закадзіраваны:

=SEQUENCE(B1, 1, B2, B3)

Увядзіце формулу ніжэй у самую верхнюю ячэйку (у нашым выпадку A6), націсніце клавішу Enter і вынікі будуць аўтаматычна размешчаны па вызначанай колькасці радкоў і слупкоў.

Заўвага. Са стандартным Агульныя фармат, вынікі будуць адлюстроўвацца ў выглядзе парадкавых нумароў. Каб яны правільна адлюстроўваліся, не забудзьцеся прымяніць фармат даты да ўсіх вочак у дыяпазоне разліву.

Стварыце серыю працоўных дзён у Excel

Каб атрымаць серыю толькі працоўных дзён, перанясіце SEQUENCE у функцыю WORKDAY або WORKDAY.INTL наступным чынам:

Паколькі функцыя WORKDAY дадае колькасць дзён, указаную ў другім аргументе, да даты пачатку, мы адымаем ад яе 1, каб сама дата пачатку была ўключана ў вынікі.

Напрыклад, для стварэння паслядоўнасці працоўных дзён, пачынаючы з даты ў B2, формула:

=WORKDAY(B2-1, SEQUENCE(B1))

Дзе B1 — памер паслядоўнасці.

Парады і заўвагі:

• Калі дата пачатку субота або нядзеля, серыя пачнецца ў наступны працоўны дзень.
• Функцыя Excel WORKDAY прадугледжвае, што субота і нядзеля будуць выхаднымі. Каб наладзіць карыстальніцкія выхадныя і святочныя дні, замест гэтага выкарыстоўвайце функцыю WORKDAY.INTL.

Стварыце паслядоўнасць месяцаў у Excel

Каб стварыць шэраг дат з павелічэннем на адзін месяц, вы можаце выкарыстоўваць гэтая агульная формула:

У гэтым выпадку вы змяшчаеце мэтавы год у 1-ы аргумент і дзень у 3-ці аргумент. Для другога аргумента функцыя SEQUENCE вяртае паслядоўныя нумары ад 1 да 12. На аснове прыведзеных вышэй параметраў функцыя DATE стварае шэрагдаты, як паказана ў левай частцы скрыншота ніжэй:

=DATE(2020, SEQUENCE(12), 1)

Каб адлюстроўваць толькі назвы месяцаў , усталюйце адзін з прыведзеных ніжэй нестандартных фарматаў даты для дыяпазону разліву :

• ммм - кароткая форма, напрыклад студзень , люты , сак і г.д.
• мммм - поўная у выглядзе студзень , люты , сакавік і г.д.

У выніку ў ячэйках з'явяцца толькі назвы месяцаў, але асноўныя значэнні ўсё роўна будуць поўнымі датамі. У абедзвюх серыях на скрыншоце ніжэй звярніце ўвагу на выраўноўванне па правым краі па змаўчанні, тыповае для лікаў і дат у Excel:

Каб стварыць паслядоўнасць дат, якая павялічваецца на адзін месяц і пачынаецца з пэўнай даты , выкарыстоўвайце функцыю SEQUENCE разам з EDATE:

Функцыя EDATE вяртае дату, якая гэта вызначаная колькасць месяцаў да або пасля даты пачатку. А функцыя SEQUENCE стварае масіў з 12 лікаў (або столькі, колькі вы пазначыце), каб прымусіць EDATE рухацца наперад з крокам у адзін месяц. Калі ласка, звярніце ўвагу, што аргумент пачатак усталяваны ў 0, так што дата пачатку ўключаецца ў вынікі.

З датай пачатку ў B1 формула прымае такую ​​форму:

=EDATE(B1, SEQUENCE(12, 1, 0))

Заўвага. Пасля завяршэння формулы не забудзьце прымяніць да вынікаў адпаведны фармат даты, каб яны правільна адлюстроўваліся.

Стварыце паслядоўнасць гадоў у Excel

Каб зрабіцьшэраг дат з павелічэннем на год, выкарыстоўвайце наступную агульную формулу:

Дзе n гэта колькасць дат, якія вы жадаеце стварыць.

У гэтым выпадку ДАТА(год, месяц, дзень) стварае дату такім чынам:

• Год вяртаецца функцыяй SEQUENCE, якая сканфігуравана для стварэння n радкоў на 1 масіў слупкоў лікаў, пачынаючы са значэння года з start_date .
• Месяц і дзень значэнні выцягваюцца непасрэдна з даты пачатку.

Напрыклад, калі вы ўводзіце дату пачатку ў B1, наступная формула вывядзе серыю з 10 дат з крокам у адзін год:

=DATE(SEQUENCE(10, 1, YEAR(B1)), MONTH(B1), DAY(B1))

Пасля у фармаце дат вынікі будуць выглядаць наступным чынам:

Стварыце паслядоўнасць раз у Excel

Паколькі час захоўваецца ў Excel як дзесятковыя лікі, якія прадстаўляюць долі дня, функцыя SEQUENCE можа працаваць непасрэдна з часам.

A калі выказаць здагадку, што час пачатку знаходзіцца ў B1, вы можаце выкарыстоўваць адну з наступных формул, каб стварыць серыю з 10 разоў. Розніца толькі ў аргуменце крок . Паколькі ў сутках 24 гадзіны, выкарыстоўвайце 1/24 для павелічэння на гадзіну, 1/48 для павелічэння на 30 хвілін і гэтак далей.

З інтэрвалам у 30 хвілін:

=SEQUENCE(10, 1, B1, 1/48)

З розніцай у 1 гадзіну:

=SEQUENCE(10, 1, B1, 1/24)

З розніцай у 2 гадзіны:

=SEQUENCE(10, 1, B1, 1/12)

На скрыншоце ніжэй паказанавынікі:

Калі вы не хочаце турбавацца аб вылічэнні кроку ўручную, вы можаце вызначыць яго з дапамогай функцыі ЧАС:

У гэтым прыкладзе мы ўвядзем усе зменныя ў асобныя ячэйкі, як паказана на скрыншоце ніжэй . Затым вы можаце выкарыстаць прыведзеную ніжэй формулу для стварэння часовага шэрагу з любым крокам прырашчэння, указаным вамі ў ячэйках E2 (гадзіны), E3 (хвіліны) і E4 (секунды):

=SEQUENCE(B2, B3, B4, TIME(E2, E3, E4))

Як стварыць штомесячны каляндар у Excel

У гэтым апошнім прыкладзе мы будзем выкарыстоўваць функцыю SEQUENCE разам з DATEVALUE і WEEKDAY для стварэння штомесячнага календара, які будзе абнаўляцца аўтаматычна на аснове года і месяца, якія вы ўказваеце.

Формула ў фармаце A5 наступная:

=SEQUENCE(6, 7, DATEVALUE("1/"&B2&"/"&B1) - WEEKDAY(DATEVALUE("1/"&B2&"/"&B1)) + 1, 1)

Як працуе гэтая формула:

Вы выкарыстоўваеце функцыю SEQUENCE для стварэння масіва дат з 6 радкоў (максімальна магчымая колькасць тыдняў у месяцы) і 7 слупкоў (колькасць дзён у тыдні). павялічваецца на 1 дзень. Такім чынам, аргументы радкі , слупкі і крок не выклікаюць пытанняў.

Самая складаная частка ў аргументе пачатак . Мы не можам пачаць наш каляндар з 1-га дня мэтавага месяца, таму што мы не ведаем, які гэта дзень тыдня. Такім чынам, мы выкарыстоўваем наступную формулу, каб знайсці першую нядзелю перад 1-м днём названага месяца іyear:

DATEVALUE("1/"&B2&"/"&B1) - WEEKDAY(DATEVALUE("1/"&B2&"/"&B1)) + 1

Першая функцыя DATEVALUE вяртае парадкавы нумар, які ва ўнутранай сістэме Excel прадстаўляе 1-ы дзень месяца ў B2 і год у B1. У нашым выпадку гэта 44044, што адпавядае 1 жніўня 2020 г. На дадзены момант мы маем:

44044 - WEEKDAY(DATEVALUE("1/"&B2&"/"&B1)) + 1

Функцыя WEEKDAY вяртае дзень тыдня, які адпавядае 1-му дню мэты месяц лікам ад 1 (нядзеля) да 7 (субота). У нашым выпадку гэта 7, таму што 1 жніўня 2020 года субота. І наша формула зводзіцца да:

44044 - 7 + 1

44044 - 7 роўна 4403, што адпавядае субоце, 25 ліпеня 2020 г. Паколькі нам патрэбна нядзеля, мы дадаем папраўку +1.

Такім чынам, мы атрымліваем простую формулу, якая выводзіць масіў парадкавых нумароў, якія пачынаюцца з 4404:

=SEQUENCE(6, 7, 4404, 1)

Адфарматуйце вынікі як даты, і вы атрымаеце каляндар, паказаны ў скрыншот вышэй. Напрыклад, вы можаце выкарыстоўваць адзін з наступных фарматаў даты:

• д-ммм-гг для адлюстравання такіх дат, як 1-жнівень-20
• mmm d для адлюстравання месяца і дня, напрыклад 20 жніўня
• d для адлюстравання толькі дня

Пачакайце, але мы імкнемся стварыць штомесячны каляндар. Чаму паказваюцца некаторыя даты папярэдняга і наступнага месяца? Каб схаваць гэтыя недарэчныя даты, усталюйце правіла ўмоўнага фарматавання з прыведзенай ніжэй формулай і прымяніце белы шрыфт колер:

=MONTH(A5)MONTH(DATEVALUE($B$2 & "1"))

Дзе A5 - гэта самая левая ячэйка ваш каляндар і B2 з'яўляецца мэтаймесяц.

Для падрабязных крокаў, калі ласка, глядзіце Як стварыць правіла ўмоўнага фарматавання на аснове формулы ў Excel.

Вось як вы можаце стварыць паслядоўнасць дат у Excel. Я дзякую вам за чытанне і спадзяюся ўбачыць вас у нашым блогу на наступным тыдні!

Практычны сшытак для спампоўкі

Паслядоўнасць дат у Excel - прыклады формул (файл .xlsx)