Excel හි දින ලැයිස්තුවක් ඉක්මනින් ජනනය කිරීමට සහ දින, වැඩ කරන දින, මාස හෝ වසර සහිත තීරුවක් පිරවීමට ස්වයංක්‍රීය පිරවුම් විශේෂාංගය භාවිතා කිරීමට ඔබට නව SEQUENCE ශ්‍රිතය ප්‍රයෝජනයට ගත හැකි ආකාරය නිබන්ධනය පෙන්වයි.

මෑත කාලය වන තුරු, Excel හි දින උත්පාදනය කිරීමට ඇත්තේ එක් පහසු ක්‍රමයක් පමණි - ස්වයංක්‍රීය පිරවුම් විශේෂාංගය. නව ගතික අරා SEQUENCE ශ්‍රිතය හඳුන්වාදීම නිසා සූත්‍රයක් සහිත දින මාලාවක් සෑදීමටද හැකිවී ඇත. මෙම නිබන්ධනය ඔබට වඩාත් සුදුසු එකක් තෝරා ගත හැකි වන පරිදි ක්‍රම දෙකම ගැඹුරින් විමසා බලයි.

Excel හි දින මාලාව පුරවන්නේ කෙසේද

කවදාද ඔබට Excel හි දිනයන් සහිත තීරුවක් පිරවීමට අවශ්‍ය වේ, වේගවත්ම ක්‍රමය නම් AutoFill විශේෂාංගය භාවිතා කිරීමයි.

Excel හි දින මාලාවක් ස්වයංක්‍රීයව පුරවන්න

තීරුවක් හෝ පේළියක් වැඩිවන දිනයන් පිරවීම එක් දිනක් ඉතා පහසුයි:

1. පළමු කොටුවේ ආරම්භක දිනය ටයිප් කරන්න.
2. ආරම්භක දිනය සහිත කොටුව තෝරන්න සහ පිරවුම් හසුරුව අදින්න (පහළ ඇති කුඩා කොළ පැහැති චතුරස්රයක් -දකුණු කෙළවර) පහළට හෝ දකුණට.

Excel විසින් ඔබ අතින් ටයිප් කළ පළමු දිනයට සමාන දින මාලාවක් වහාම ජනනය කරයි.

3>

සතියේ දින, මාස හෝ අවුරුදු සමඟ තීරුවක් පුරවන්න

වැඩ දින, මාස හෝ අවුරුදු මාලාවක් නිර්මාණය කිරීමට, පහත සඳහන් දේවලින් එකක් කරන්න:

• තීරුවක් පුරවන්න ඉහත විස්තර කර ඇති පරිදි අනුක්‍රමික දිනයන්. ඊට පසු, AutoFill Options බොත්තම ක්ලික් කර තෝරන්නඅවශ්‍ය විකල්පය, කියන්න මාස පුරවන්න :

  

• නැතහොත් ඔබට ඔබේ පළමු දිනය ඇතුළු කළ හැක, පිරවුම් හසුරුව දකුණු-ක්ලික් කර, කොටු ගණනාවක් අල්ලාගෙන අදින්න අවශ්ය පරිදි. ඔබ මූසික බොත්තම මුදා හරින විට, අවශ්‍ය විකල්පය තෝරාගැනීමට සන්දර්භය මෙනුවක් උත්පතන වනු ඇත, අවුරුදු පුරවන්න අපගේ නඩුවේදී:

  

දින N වලින් වැඩිවන දින මාලාවක් පුරවන්න

නිශ්චිත පියවරක් සමඟ දින, සතියේ දින, මාස හෝ අවුරුදු මාලාවක් ස්වයංක්‍රීයව උත්පාදනය කිරීමට, ඔබ කළ යුත්තේ මෙයයි:<3

1. පළමු කොටුවේ ආරම්භක දිනය ඇතුළත් කරන්න.
2. එම කොටුව තෝරන්න, පිරවුම් හසුරුව දකුණු-ක්ලික් කරන්න, අවශ්‍ය තරම් සෛල හරහා එය ඇදගෙන ගොස් නිදහස් කරන්න.
3. උපතේ ඇති මෙනුවේ, Series (අවසාන අයිතමය) තෝරන්න.
4. Series සංවාද කොටුව තුළ, දින ඒකකය<2 තෝරන්න> උනන්දුවක් දක්වන අතර පියවර අගය සකසන්න.
5. හරි ක්ලික් කරන්න.

වැඩිදුර උදාහරණ සඳහා, කරුණාකර බලන්න බලන්න Excel හි දින ඇතුළත් කර ස්වයංක්‍රීයව පුරවන්න.

සූත්‍රයක් සමඟ Excel හි දින අනුපිළිවෙලක් සාදා ගන්නේ කෙසේද

පෙර පාඩම් මාලාවක, අපි නව ගතික අරාව SEQUENCE ශ්‍රිතය භාවිතා කරන්නේ කෙසේදැයි සොයා බැලුවා. සංඛ්‍යා අනුපිළිවෙලක් ජනනය කරන්න. Excel හි අභ්‍යන්තරව දිනයන් අනුක්‍රමික අංක ලෙස ගබඩා කර ඇති බැවින්, ශ්‍රිතයට පහසුවෙන් දින මාලාවක් ද නිපදවිය හැක. ඔබ කළ යුත්තේ පහත උදාහරණවල පැහැදිලි කර ඇති ආකාරයට තර්ක නිවැරදිව වින්‍යාස කිරීම පමණි.

සටහන. මෙහි සාකච්ඡා කර ඇති සියලුම සූත්‍ර ක්‍රියාත්මක වන්නේ එහි පමණිගතික අරා සඳහා සහය දක්වන Excel 365 හි නවතම අනුවාදයන්. Pre-dynamic Excel 2019, Excel 2016 සහ Excel 2013 වලදී, කරුණාකර මෙම නිබන්ධනයේ පළමු කොටසේ පෙන්වා ඇති පරිදි AutoFill විශේෂාංගය භාවිතා කරන්න.

Excel හි දින මාලාවක් සාදන්න

ජනනය කිරීමට Excel හි දින අනුපිළිවෙල, SEQUENCE ශ්‍රිතයේ පහත තර්ක සකසන්න:

SEQUENCE(පේළි, [තීරු], [ආරම්භය], [පියවර])

• පේළි - දින පිරවිය යුතු පේළි ගණන.
• තීරු - දින පිරවිය යුතු තීරු ගණන.
• ආරම්භය - ආරම්භක දිනය "8/1/2020" හෝ "1-Aug-2020" වැනි Excel හට තේරුම් ගත හැකි ආකෘතිය. වැරදි මඟහරවා ගැනීම සඳහා, ඔබට DATE(2020, 8, 1) වැනි DATE ශ්‍රිතය භාවිතයෙන් දිනය සැපයිය හැක.
• පියවර - අනුපිළිවෙලින් එක් එක් ඊළඟ දිනය සඳහා වර්ධක.

උදාහරණයක් ලෙස, 2020 අගෝස්තු 1 දිනෙන් ආරම්භ වී දින 1කින් වැඩිවන දින 10ක ලැයිස්තුවක් සෑදීමට, සූත්‍රය වන්නේ:

=SEQUENCE(10, 1, "8/1/2020", 1)

හෝ

=SEQUENCE(10, 1, DATE(2020, 8, 1), 1)

විකල්පයක් ලෙස, ඔබට පූර්ව නිශ්චිත කොටු තුළ දින ගණන (B1), ආරම්භක දිනය (B2) සහ පියවර (B3) ඇතුළත් කර ඔබේ සූත්‍රයේ එම කොටු යොමු කළ හැක. අපි ලැයිස්තුවක් ජනනය කරන බැවින්, තීරු අංකය (1) දෘඪ කේත කර ඇත:

=SEQUENCE(B1, 1, B2, B3)

ඉහළම කොටුවේ පහත සූත්‍රය ටයිප් කරන්න (අපගේ නඩුවේ A6), Enter යතුර ඔබන්න, සහ ප්‍රතිඵල ස්වයංක්‍රීයව නියමිත පේළි සහ තීරු ගණන හරහා පැතිරෙනු ඇත.

සටහන. පෙරනිමි සාමාන්‍ය සමඟආකෘතිය, ප්රතිඵල අනුක්රමික අංක ලෙස දිස් වනු ඇත. ඒවා නිවැරදිව ප්‍රදර්ශනය කිරීමට, ස්පිල් පරාසයේ ඇති සියලුම කොටු සඳහා දින ආකෘතිය යෙදීමට වග බලා ගන්න.

Excel හි වැඩ කරන දින මාලාවක් සාදන්න

වැඩ කරන දින මාලාවක් පමණක් ලබා ගැනීමට, WORKDAY හෝ WORKDAY.INTL ශ්‍රිතයේ SEQUENCE ඔතා මේ ආකාරයට:

WORKDAY( start_date -1, SEQUENCE( no_of_days ))

WORKDAY ශ්‍රිතය දෙවන තර්කයේ සඳහන් කර ඇති දින ගණන ආරම්භක දිනයට එකතු කරන බැවින්, ආරම්භක දිනයම ඇතුළත් කිරීමට අපි එයින් 1ක් අඩු කරමු. ප්‍රතිඵල.

උදාහරණයක් ලෙස, B2 හි දිනයේ සිට වැඩකරන දින අනුපිළිවෙලක් උත්පාදනය කිරීම සඳහා, සූත්‍රය වන්නේ:

=WORKDAY(B2-1, SEQUENCE(B1))

B1 යනු අනුක්‍රමික ප්‍රමාණයයි.

ඉඟි සහ සටහන්:

• ආරම්භක දිනයක් සෙනසුරාදා හෝ ඉරිදා නම්, මාලාව ඊළඟ වැඩ කරන දිනයේ ආරම්භ වේ.
• Excel WORKDAY කාර්යය සෙනසුරාදා සහ ඉරිදා සති අන්ත ලෙස උපකල්පනය කරයි. අභිරුචි සති අන්ත සහ නිවාඩු දින වින්‍යාස කිරීමට, ඒ වෙනුවට WORKDAY.INTL ශ්‍රිතය භාවිතා කරන්න.

Excel හි මාස අනුපිළිවෙලක් උත්පාදනය කරන්න

මාසයකින් වැඩි කරන ලද දින මාලාවක් සෑදීමට, ඔබට භාවිතා කළ හැක මෙම සාමාන්‍ය සූත්‍රය:

DATE( වසර , SEQUENCE(12), day )

මෙම අවස්ථාවේදී, ඔබ ඉලක්ක වසර 1 වන තර්කයට සහ දිනය 3 වන තර්කය. 2වන තර්කය සඳහා, SEQUENCE ශ්‍රිතය 1 සිට 12 දක්වා අනුක්‍රමික සංඛ්‍යා ලබා දෙයි. ඉහත පරාමිති මත පදනම්ව, DATE ශ්‍රිතය මාලාවක් නිපදවයිපහත තිර රුවෙහි වම් කොටසෙහි පෙන්වා ඇති පරිදි දින:

=DATE(2020, SEQUENCE(12), 1)

මාස නම් පමණක් සංදර්ශන කිරීමට, කාන්දු පරාසය සඳහා පහත අභිරුචි දින ආකෘතිවලින් එකක් සකසන්න :

• mmm - ජන , පෙබරවාරි , මාර්තු , වැනි කෙටි ආකාරය
• mmmm - සම්පූර්ණයි. ජනවාරි , පෙබරවාරි , මාර්තු , වැනි පෝරමය.

ප්‍රතිඵලයක් ලෙස, සෛල තුළ දිස්වනු ඇත්තේ මාස නම් පමණි, නමුත් යටින් පවතින අගයන් තවමත් සම්පූර්ණ දිනයන් වනු ඇත. පහත තිර රුවෙහි ඇති ශ්‍රේණි දෙකෙහිම, කරුණාකර Excel හි අංක සහ දින සඳහා සාමාන්‍ය පෙරනිමි දකුණු පෙළගැස්ම සැලකිල්ලට ගන්න:

මාසයකින් සහ <17කින් වැඩිවන දින අනුපිළිවෙලක් උත්පාදනය කිරීමට>නිශ්චිත දිනයකින් ආරම්භ වේ , EDATE සමඟින් SEQUENCE ශ්‍රිතය භාවිතා කරන්න:

EDATE( ආරම්භ_දිනය , SEQUENCE(12, 1, 0))

EDATE ශ්‍රිතය එම දිනයක් ලබා දෙයි ආරම්භක දිනයට පෙර හෝ පසු නිශ්චිත මාස ගණන වේ. SEQUENCE ශ්‍රිතය මඟින් EDATE හට මාසයක වර්ධකයකින් ඉදිරියට යාමට බල කිරීමට අංක 12 (හෝ ඔබ සඳහන් කරන පරිදි) අරාවක් නිපදවයි. ආරම්භක තර්කය 0 ලෙස සකසා ඇති බව කරුණාවෙන් සලකන්න, එවිට ආරම්භක දිනය ප්‍රතිඵලවලට ඇතුළත් වේ.

B1 හි ආරම්භක දිනය සමඟ, සූත්‍රය මෙම හැඩය ගනී:

=EDATE(B1, SEQUENCE(12, 1, 0))

සටහන. සූත්‍රයක් සම්පූර්ණ කිරීමෙන් පසු, ප්‍රතිඵල නිවැරදිව සංදර්ශන කිරීම සඳහා සුදුසු දින ආකෘතියක් යෙදීමට කරුණාකර මතක තබා ගන්න.

එක්සෙල් හි වසර අනුපිළිවෙලක් සාදන්න

සෑදීමටවසරින් වැඩි කරන ලද දින මාලාවක්, මෙම සාමාන්‍ය සූත්‍රය භාවිතා කරන්න:

DATE(SEQUENCE( n , 1, YEAR( start_date )), MONTH( start_date ), DAY( start_date ))

n යනු ඔබට උත්පාදනය කිරීමට අවශ්‍ය දින ගණනයි.

මෙම අවස්ථාවේදී, DATE(වසර, මාසය, දිනය) ශ්‍රිතය මේ ආකාරයෙන් දිනයක් ගොඩනඟයි:

• වසර 1 මගින් n පේළියක් උත්පාදනය කිරීමට වින්‍යාස කර ඇති SEQUENCE ශ්‍රිතය මඟින් ආපසු ලබාදේ. සංඛ්‍යා තීරු අරාව, ආරම්භක_දිනය සිට වසර අගයෙන් ආරම්භ වේ.
• මාස සහ දින අගයන් ආරම්භක දිනයේ සිට සෘජුවම ඇද දමනු ලැබේ.

උදාහරණයක් ලෙස, ඔබ B1 හි ආරම්භක දිනය ඇතුළත් කළහොත්, පහත සූත්‍රය වසරක වර්ධක වලින් දින 10 ක මාලාවක් ප්‍රතිදානය කරයි:

=DATE(SEQUENCE(10, 1, YEAR(B1)), MONTH(B1), DAY(B1))

පසු දිනයන් ලෙස හැඩගස්වා ඇති විට, ප්‍රතිඵල පහත පරිදි පෙනෙනු ඇත:

Excel හි වේලා අනුපිළිවෙලක් උත්පාදනය කරන්න

මොකද වේලාවන් Excel හි ගබඩා කර ඇත්තේ දශම සංඛ්‍යා ලෙසිනි. දවසේ භාගය, SEQUENCE ශ්‍රිතය සෘජුවම වේලාවන් සමඟ ක්‍රියා කළ හැක.

A ආරම්භක වේලාව B1 හි ඇතැයි උපකල්පනය කළහොත්, ඔබට 10 ගුණයක ශ්‍රේණියක් නිෂ්පාදනය කිරීමට පහත සූත්‍රවලින් එකක් භාවිතා කළ හැක. වෙනස ඇත්තේ පියවර තර්කයේ පමණි. දිනකට පැය 24 ක් ඇති බැවින්, පැයකින් වැඩි කිරීමට 1/24, විනාඩි 30 කින් වැඩි කිරීමට 1/48, සහ යනාදිය භාවිතා කරන්න.

විනාඩි 30 ක පරතරය:

=SEQUENCE(10, 1, B1, 1/48)

පැය 1 පරතරය:

=SEQUENCE(10, 1, B1, 1/24)

පැය 2ක පරතරය:

=SEQUENCE(10, 1, B1, 1/12)

පහත තිර රුව පෙන්වයිප්‍රතිඵල:

ඔබට පියවර අතින් ගණනය කිරීමට කරදර කිරීමට අවශ්‍ය නැතිනම්, ඔබට TIME ශ්‍රිතය භාවිතයෙන් එය අර්ථ දැක්විය හැක:

SEQUENCE(පේළි, තීරු, ආරම්භය, TIME( පැය , මිනිත්තු , තත්පර ))

මෙම උදාහරණය සඳහා, අපි පහත තිර රුවෙහි පෙන්වා ඇති පරිදි සියලුම විචල්‍යයන් වෙන වෙනම කොටු තුළට ඇතුල් කරන්නෙමු. . ඉන්පසුව, E2 (පැය), E3 (විනාඩි) සහ E4 (තත්පර) තුළ ඔබ සඳහන් කරන ඕනෑම වර්ධක පියවර ප්‍රමාණයකින් කාල ශ්‍රේණියක් උත්පාදනය කිරීමට ඔබට පහත සූත්‍රය භාවිත කළ හැක:

=SEQUENCE(B2, B3, B4, TIME(E2, E3, E4))

Excel හි මාසික දින දර්ශනයක් සාදන ආකාරය

මෙම අවසාන උදාහරණයේ දී, යාවත්කාලීන කරනු ලබන මාසික දින දර්ශනයක් සෑදීමට අපි DATEVALUE සහ WEEKDAY සමඟ අනුක්‍රමික ශ්‍රිතය භාවිතා කරන්නෙමු. ඔබ සඳහන් කරන වර්ෂය සහ මාසය මත ස්වයංක්‍රීයව පදනම් වේ.

A5 හි සූත්‍රය පහත පරිදි වේ:

=SEQUENCE(6, 7, DATEVALUE("1/"&B2&"/"&B1) - WEEKDAY(DATEVALUE("1/"&B2&"/"&B1)) + 1, 1)

මෙම සූත්‍රය ක්‍රියා කරන ආකාරය:

තීරු 7කින් (සතියක දින ගණන) පේළි 6ක් (මාසයකට හැකි උපරිම සති ගණන) දින අරාවක් ජනනය කිරීමට ඔබ SEQUENCE ශ්‍රිතය භාවිත කරයි. දින 1 කින් වැඩි කරන ලදී. එබැවින්, පේළි , තීරු සහ පියවර තර්ක ප්‍රශ්න කිසිවක් මතු නොකරයි.

ආරම්භක තර්කයේ ඇති උපක්‍රමශීලීම කොටස . අපගේ දින දර්ශනය ඉලක්කගත මාසයේ පළමු දිනයෙන් ආරම්භ කළ නොහැක, මන්ද එය සතියේ කුමන දිනයදැයි අප නොදන්නා බැවිනි. එබැවින්, නිශ්චිත මාසයේ 1 වන දිනට පෙර පළමු ඉරිදා සොයා ගැනීමට අපි පහත සූත්‍රය භාවිතා කරමුyear:

DATEVALUE("1/"&B2&"/"&B1) - WEEKDAY(DATEVALUE("1/"&B2&"/"&B1)) + 1

පළමු DATEVALUE ශ්‍රිතය අභ්‍යන්තර Excel පද්ධතිය තුළ B2 හි මාසයේ 1 වන දිනය සහ B1 හි වර්ෂය නියෝජනය කරන අනුක්‍රමික අංකයක් ලබා දෙයි. අපගේ නඩුවේදී, එය 2020 අගෝස්තු 1 ට අනුරූප 44044 වේ. මෙම අවස්ථාවේදී, අපට ඇත්තේ:

44044 - WEEKDAY(DATEVALUE("1/"&B2&"/"&B1)) + 1

WEEKDAY ශ්‍රිතය ඉලක්කයේ 1 වන දිනට අනුරූපව සතියේ දිනය ලබා දෙයි 1 (ඉරිදා) සිට 7 (සෙනසුරාදා) දක්වා අංකයක් ලෙස මාසය. අපගේ නඩුවේදී, 2020 අගෝස්තු 1 සෙනසුරාදා බැවින් එය 7 වේ. සහ අපගේ සූත්‍රය පහත දක්වා අඩු කරයි:

44044 - 7 + 1

44044 - 7 යනු 4403, එය 2020 ජූලි 25 සෙනසුරාදාට අනුරූප වේ. අපට ඉරිදා අවශ්‍ය බැවින්, අපි +1 නිවැරදි කිරීම එකතු කරමු.

මේ ආකාරයට, අපට 4404 න් ආරම්භ වන අනුක්‍රමික අංක මාලාවක් ප්‍රතිදානය කරන සරල සූත්‍රයක් ලැබේ:

=SEQUENCE(6, 7, 4404, 1)

ප්‍රතිඵල දින ලෙස හැඩගස්වන්න, එවිට ඔබට දින දර්ශනයක් ලැබෙනු ඇත. ඉහත තිර රුව. උදාහරණයක් ලෙස, ඔබට 1-Aug-20 <12 වැනි දින සංදර්ශන කිරීමට පහත දින ආකෘතිවලින් එකක් භාවිතා කළ හැක:

• d-mmmm-yy
• අගෝස්තු 20 වැනි මාසය සහ දිනය සංදර්ශන කිරීමට
• mmm d
• d දවස පමණක් සංදර්ශන කිරීමට

රැඳී සිටින්න, නමුත් අපි මාසික දින දර්ශනයක් නිර්මාණය කිරීමට ඉලක්ක කරමු. පෙර සහ ඊළඟ මාසයේ සමහර දිනයන් පෙන්වන්නේ ඇයි? එම අදාළ නොවන දිනයන් සැඟවීමට, පහත සූත්‍රය සමඟ කොන්දේසිගත හැඩතල ගැන්වීමේ රීතියක් සකසා සුදු අකුරු වර්ණය යොදන්න:

=MONTH(A5)MONTH(DATEVALUE($B$2 & "1"))

A5 යනු වම්පස ඇති කොටුවයි. ඔබේ දින දර්ශනය සහ B2 ඉලක්කය වේමාසය.

සවිස්තරාත්මක පියවර සඳහා, කරුණාකර Excel හි සූත්‍ර-පාදක කොන්දේසි සහිත හැඩතල ගැන්වීමේ රීතියක් සාදන ආකාරය බලන්න.

ඔබට අනුක්‍රමයක් ජනනය කළ හැක්කේ එලෙසිනි. එක්සෙල් හි දිනයන්. කියවීම ගැන මම ඔබට ස්තූතිවන්ත වන අතර ලබන සතියේ අපගේ බ්ලොග් අඩවියෙන් ඔබව දැකීමට බලාපොරොත්තු වෙමි!

බාගැනීම සඳහා වැඩපොත පුහුණු වන්න

Excel හි දින අනුපිළිවෙල - සූත්‍ර උදාහරණ (.xlsx ගොනුව)