Упатството покажува како можете да ја искористите новата функција SEQUENCE за брзо генерирање листа на датуми во Excel и користење на функцијата Автоматско пополнување за да пополните колона со датуми, работни денови, месеци или години.

До неодамна, имаше само еден лесен начин за генерирање датуми во Excel - функцијата Автоматско пополнување. Воведувањето на новата функција на динамичка низа SEQUENCE овозможи да се направат и серија датуми со формула. Овој туторијал детално ги разгледува двата методи за да можете да го изберете оној кој најдобро функционира за вас.

Како да пополните серии датуми во Excel

Кога треба да пополните колона со датуми во Excel, најбрзиот начин е да ја користите функцијата Автоматско пополнување.

Автоматско пополнување на серијата датуми во Excel

Пополнување колона или ред со датуми кои се зголемуваат за еден ден е многу лесен:

1. Внесете го почетниот датум во првата ќелија.
2. Изберете ја ќелијата со почетниот датум и повлечете ја рачката за полнење (мал зелен квадрат на дното -десен агол) надолу или надесно.

Excel веднаш ќе генерира серија датуми во ист формат како првиот датум што сте го напишале рачно.

Пополнете колона со работни денови, месеци или години

За да креирате серија работни денови, месеци или години, направете едно од следново:

• Пополнете колона со последователни датуми како што е опишано погоре. После тоа, кликнете на копчето Опции за автоматско пополнување и изберете госаканата опција, кажете Пополнете месеци :

  

• Или можете да го внесете вашиот прв датум, кликнете со десното копче на рачката за пополнување, држете и повлечете низ исто толку ќелии колку што е потребно. Кога ќе го ослободите копчето на глувчето, ќе се појави контекстно мени кое ќе ви овозможи да ја изберете потребната опција, Пополнете години во нашиот случај:

  

Пополнете серија датуми кои се зголемуваат за N дена

За автоматски да генерирате серија од денови, работни денови, месеци или години со специфичен чекор , ова е она што треба да го направите:

1. Внесете го почетниот датум во првата ќелија.
2. Одберете ја таа ќелија, кликнете со десното копче на рачката за пополнување, повлечете ја низ онолку ќелии колку што е потребно, а потоа отпуштете ја.
3. Во менито што се појавува, изберете Серија (последната ставка).
4. Во полето за дијалог Серија , изберете ја Единицата за датум од интерес и поставете ја Чекорната вредност .
5. Кликнете ОК.

За повеќе примери, погледнете Како да вметнете и автоматско пополнување датуми во Excel.

Како да направите низа датуми во Excel со формула

Во едно од претходните упатства, разгледавме како да ја користиме функцијата SEQUENCE за новата динамичка низа за генерира бројна низа. Бидејќи внатрешно во Excel датумите се зачувуваат како сериски броеви, функцијата лесно може да произведе и серија датуми. Сè што треба да направите е правилно да ги конфигурирате аргументите како што е објаснето во следните примери.

Забелешка. Сите формули дискутирани овде функционираат само вонајновите верзии на Excel 365 кои поддржуваат динамички низи. Во преддинамичните Excel 2019, Excel 2016 и Excel 2013, користете ја функцијата Автоматско пополнување како што е прикажано во првиот дел од ова упатство.

Креирајте серија датуми во Excel

За да генерирате низа датуми во Excel, поставете ги следните аргументи на функцијата SEQUENCE:

• Редови - број на редови за пополнување со датуми.
• Колони - бројот на колони што треба да се пополнат со датуми.
• Почеток - датумот на започнување во формат што Excel може да го разбере, како „8/1/2020“ или „1-авг-2020“. За да избегнете грешки, можете да го наведете датумот со користење на функцијата DATE како DATE(2020, 8, 1).
• Чекор - зголемувањето за секој следен датум во низа.

На пример, за да направите листа од 10 датуми почнувајќи од 1 август 2020 година и зголемувајќи се за 1 ден, формулата е:

=SEQUENCE(10, 1, "8/1/2020", 1)

или

=SEQUENCE(10, 1, DATE(2020, 8, 1), 1)

Алтернативно, можете да го внесете бројот на датуми (B1), датумот на започнување (B2) и чекорот (B3) во однапред дефинираните ќелии и да ги повикате тие ќелии во вашата формула. Бидејќи генерираме список, колоните број (1) се тврдокодирани:

=SEQUENCE(B1, 1, B2, B3)

Впишете ја формулата подолу во најгорната ќелија (А6 во нашиот случај), притиснете го копчето Enter и резултатите автоматски ќе се прелеат низ наведениот број редови и колони.

Забелешка. Со стандардното Општо формат, резултатите ќе се појават како сериски броеви. За правилно прикажување, не заборавајте да го примените форматот на датум на сите ќелии во опсегот на излевање.

Направете серија работни денови во Excel

За да добиете само серија работни денови, завиткајте SEQUENCE во функцијата WORKDAY или WORKDAY.INTL на следниов начин:

Како што функцијата WORKDAY го додава бројот на денови наведени во вториот аргумент на датумот на почеток, ние одземаме 1 од него за да го вклучиме самиот почеток во резултати.

На пример, за генерирање на низа од работни денови почнувајќи од датумот во B2, формулата е:

=WORKDAY(B2-1, SEQUENCE(B1))

Каде B1 е големината на низата.

Совети и забелешки:

• Ако датумот на започнување е сабота или недела, серијата ќе започне следниот работен ден.
• Функцијата Excel WORKDAY претпоставува дека сабота и недела се викенди. За да ги конфигурирате сопствените викенди и празници, наместо тоа, користете ја функцијата WORKDAY.INTL.

Генерирајте месечна секвенца во Excel

За да креирате серија датуми зголемени за еден месец, можете да користите оваа генеричка формула:

Во овој случај, целната година ја ставате во првиот аргумент и денот во 3-ти аргумент. За вториот аргумент, функцијата SEQUENCE враќа секвенцијални броеви од 1 до 12. Врз основа на горенаведените параметри, функцијата DATE произведува серија оддатуми како што е прикажано во левиот дел од екранот подолу:

=DATE(2020, SEQUENCE(12), 1)

За да се прикажат само имињата на месеци , поставете еден од долунаведените сопствени формати на датуми за опсегот на излевање :

• mmmm - кратка форма како Jan , Feb , Mar , итн.
• mmmm - целосна форма како јануари , февруари , март итн.

Како резултат, само имињата на месеците ќе се појавуваат во ќелиите, но основните вредности сепак ќе бидат полни датуми. Во двете серии на сликата од екранот подолу, забележете го стандардното десно порамнување типично за броеви и датуми во Excel:

За да се генерира секвенца на датуми што се зголемува за еден месец и започнува со одреден датум , користете ја функцијата SEQUENCE заедно со EDATE:

Функцијата EDATE враќа датум што е наведениот број на месеци пред или по датумот на започнување. И функцијата SEQUENCE произведува низа од 12 броеви (или онолку колку што ќе наведете) за да го принуди EDATE да се движи напред во чекори од еден месец. Забележете дека аргументот почеток е поставен на 0, така што датумот на започнување се вклучува во резултатите.

Со датумот на започнување во B1, формулата ја добива оваа форма:

=EDATE(B1, SEQUENCE(12, 1, 0))

Забелешка. Откако ќе ја пополните формулата, не заборавајте да примените соодветен формат на датум на резултатите за правилно прикажување.

Креирајте годишна секвенца во Excel

За да направитесерија датуми зголемени по година, користете ја оваа генеричка формула:

Каде што n е бројот на датуми што сакате да ги генерирате.

Во овој случај, DATE(година, месец, ден) функцијата конструира датум на овој начин:

• Година се враќа со функцијата SEQUENCE која е конфигурирана да генерира n редови со 1 колона низа броеви, почнувајќи од вредноста на годината од почеток_датум .
• Месец и ден вредностите се повлекуваат директно од датумот на почеток.

На пример, ако го внесете датумот на почеток во B1, следнава формула ќе даде серија од 10 датуми во едногодишни чекори:

=DATE(SEQUENCE(10, 1, YEAR(B1)), MONTH(B1), DAY(B1))

По ако се форматираат како датуми, резултатите ќе изгледаат вака:

Генерирајте временска секвенца во Excel

Бидејќи времињата се зачувуваат во Excel како децимални броеви кои претставуваат дел од денот, функцијата SEQUENCE може директно да работи со времиња.

A Претпоставувајќи дека времето на започнување е во B1, можете да користите една од следните формули за да создадете серија од 10 пати. Разликата е само во аргументот чекор . Бидејќи има 24 часа во денот, користете 1/24 за зголемување за еден час, 1/48 за зголемување за 30 минути и така натаму.

30 минути растојание:

=SEQUENCE(10, 1, B1, 1/48)

1 час разлика:

=SEQUENCE(10, 1, B1, 1/24)

2 часа разлика:

=SEQUENCE(10, 1, B1, 1/12)

На сликата од екранот подолу се прикажанирезултати:

Ако не сакате да се мачите рачно да го пресметувате чекорот, можете да го дефинирате со користење на функцијата ВРЕМЕ:

За овој пример, ќе ги внесеме сите променливи во посебни ќелии како што е прикажано на сликата од екранот подолу . Потоа, можете да ја користите формулата подолу за да генерирате временска серија со која било големина на чекор за зголемување што ќе ја наведете во ќелиите E2 (часови), E3 (минути) и E4 (секунди):

=SEQUENCE(B2, B3, B4, TIME(E2, E3, E4))

Како да креирате месечен календар во Excel

Во овој последен пример, ќе ја користиме функцијата SEQUENCE заедно со DATEVALUE и WEEKDAY за да создадеме месечен календар кој ќе се ажурира автоматски врз основа на годината и месецот што ќе ги наведете.

Формулата во А5 е следна:

=SEQUENCE(6, 7, DATEVALUE("1/"&B2&"/"&B1) - WEEKDAY(DATEVALUE("1/"&B2&"/"&B1)) + 1, 1)

Како функционира оваа формула:

Ја користите функцијата SEQUENCE за да генерирате 6 реда (максималниот можен број недели во еден месец) со 7 колони (бројот на денови во неделата) низа датуми зголемена за 1 ден. Оттука, аргументите редови , колони и чекор не поставуваат прашања.

Најнезгодниот дел во аргументот start . Не можеме да го започнеме нашиот календар со 1-виот ден од целниот месец бидејќи не знаеме кој ден во неделата е. Значи, ја користиме следнава формула за да ја пронајдеме првата недела пред 1-виот ден од наведениот месец игодина:

DATEVALUE("1/"&B2&"/"&B1) - WEEKDAY(DATEVALUE("1/"&B2&"/"&B1)) + 1

Првата функција DATEVALUE враќа сериски број кој во внатрешниот Excel систем го претставува 1-виот ден од месецот во B2 и годината во B1. Во нашиот случај, тоа е 44044 што одговара на 1 август 2020 година. Во овој момент, имаме:

44044 - WEEKDAY(DATEVALUE("1/"&B2&"/"&B1)) + 1

Функцијата WEEKDAY го враќа денот во неделата што одговара на првиот ден од целта месец како број од 1 (недела) до 7 (сабота). Во нашиот случај, тоа е 7 бидејќи 1 август 2020 година е сабота. И нашата формула се намалува на:

44044 - 7 + 1

44044 - 7 е 4403, што одговара на сабота, 25 јули 2020 година. Како што ни треба недела, ја додаваме корекцијата +1.

На овој начин, добиваме едноставна формула која дава низа од сериски броеви кои започнуваат со 4404:

=SEQUENCE(6, 7, 4404, 1)

Форматирајте ги резултатите како датуми и ќе добиете календар прикажан во скриншот погоре. На пример, можете да користите еден од следниве формати на датуми:

• д-ммм-гг за прикажување датуми како 1-авг-20
• mm d за прикажување на месецот и денот како 20 август
• d за прикажување само на денот

Почекајте, но имаме за цел да создадеме месечен календар. Зошто се појавуваат некои датуми од претходниот и следниот месец? За да ги скриете тие неважни датуми, поставете правило за условно форматирање со формулата подолу и применете ја бојата белиот фонт :

=MONTH(A5)MONTH(DATEVALUE($B$2 & "1"))

Каде што A5 е најлевата ќелија од вашиот календар и Б2 е целтамесец.

За деталните чекори, погледнете Како да креирате правило за условно форматирање засновано на формула во Excel.

На тој начин можете да генерирате секвенца на датуми во Excel. Ви благодарам што прочитавте и се надевам дека ќе се видиме на нашиот блог следната недела!

Вежбајте ја работната книга за преземање

Секвенца на датуми во Excel - примери на формула (датотека .xlsx)